Deluxe Adventure Creation Kit (CREATEDL.BAS)
Deluxe Adventure Creation Kit by Stephen Stout, 104
Description
Deluxe Adventure Creation Kit by Stephen Stout, 104
From the Antic disk of November 1988 (Vol. 7 No. 7).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 12.6 KB
- Dialect
- Atari BASIC
- Lines
- 287
- Variables
MVC,ML,MOVE$,WT(,WTR,WTD,MVS,MVD,MVN,MV1,MV2,A,SC$,M2$,Y,X,ST,IX,IY,M1$,P,AXE,BOAT,HORSE,KEY,MN$,MHP,MSP,HP2,HP,SP,I,PLAY,FL$,D,MD,L,CR,BR,BR$,DR,DR2$,ADRES,BYTES,IO,DR$,DM$,FILE$,PR,II,CHSET,CHAR$,IOCB,AH,AL,BH,BL
BASIC listing (287 lines)
2 REM DELUXE ADVENTURE CREATION KIT
4 REM BY STEPHEN STOUT
6 REM (c) 1988, ANTIC PUBLISHING
8 REM
10 GOTO 1460
20 IF MVC/2<>INT(MVC/2) THEN 50
30 ML=USR(ADR(MOVE$),WT(WTR),WTD,8)
40 WTR=WTR+1:IF WTR>3 THEN WTR=0
50 MVC=MVC+1:IF MVC<6 THEN RETURN
60 MVC=0
70 ML=USR(ADR(MOVE$),MVS,MVD,MVN)
80 IF MVS=MV1 THEN MVS=MV2:RETURN
90 MVS=MV1:RETURN
100 A=USR(ADR(SC$),ADR(M2$)+Y*70+X)
110 SOUND 0,0,0,15:SOUND 0,0,0,0
120 ST=STICK(0):IX=(ST=7)-(ST=11):IY=(ST=13)-(ST=14)
130 IF PEEK(764)=28 THEN M2$=M1$:GOTO 930
140 IF IX=0 AND IY=0 THEN GOSUB 20:GOTO 120
150 MVC=6:GOSUB 20
160 P=PEEK(40670+IX+20*IY):IF P=0 OR P=32 THEN X=X+IX:Y=Y+IY:SC$(53,53)="k":GOTO 100
170 IF P=35 AND AXE=1 THEN X=X+IX:Y=Y+IY:SC$(53,53)=CHR$(104):GOTO 100
180 IF P=164 AND BOAT=1 THEN X=X+IX:Y=Y+IY:SC$(53,53)=CHR$(105):GOTO 100
190 IF P=37 AND HORSE=1 THEN X=X+IX:Y=Y+IY:SC$(53,53)=CHR$(106):GOTO 100
200 IF P=166 AND KEY>0 THEN KEY=KEY-1:GOSUB 690:X=X+IX:Y=Y+IY:GOSUB 760:GOTO 100
210 IF P=103 THEN KEY=KEY+1:X=X+IX:Y=Y+IY:GOSUB 760:GOSUB 690:GOTO 100
220 IF P=104 THEN AXE=1:X=X+IX:Y=Y+IY:GOSUB 760:GOSUB 690:GOTO 100
230 IF P=105 THEN BOAT=1:X=X+IX:Y=Y+IY:GOSUB 760:GOSUB 690:GOTO 100
240 IF P=106 THEN HORSE=1:X=X+IX:Y=Y+IY:GOSUB 760:GOSUB 690:GOTO 100
250 IF P=96 THEN 560
260 IF P<>44 AND P<>237 AND P<>174 THEN 120
270 MN$="BLOB'S":MHP=30:MSP=10:IF P=44 THEN MHP=15:MSP=5:MN$="SNAKE'S"
280 IF P=174 THEN MHP=5:MSP=2:MN$="BAT'S"
290 HP2=HP
300 ? "↰TRIGGER TO ATTACK!,[SPACEBAR] TO FLEE"
310 ? MN$;" HIT POINTS: ";MHP:? "YOUR STRIKE POINTS: ";SP:POKE 764,255
320 A=INT(RND(0)*SP)+1:? " ";A;" ↑":SOUND 0,0,0,15:SOUND 0,0,0,0:POKE 77,0:MVC=6:GOSUB 20
330 IF PEEK(764)=33 THEN 550
340 IF STRIG(0)=1 THEN 320
350 MHP=MHP-A:FOR I=200 TO 100 STEP -5:SOUND 0,I,10,15:GOSUB 20:NEXT I:SOUND 0,0,0,0:IF MHP<1 THEN 480
360 ? "↰TRIGGER TO DEFEND!,[SPACEBAR] TO FLEE"
370 ? "YOUR HIT POINTS: ";HP:? MN$;" STRIKE POINTS: ";MSP:POKE 764,255
380 A=INT(RND(0)*MSP)+1:? " ";A;" ↑":SOUND 0,0,0,15:SOUND 0,0,0,0:POKE 77,0:MVC=6:GOSUB 20
390 IF PEEK(764)=33 THEN 550
400 IF STRIG(0)=1 THEN 380
410 HP=HP-A:FOR I=100 TO 200 STEP 5:SOUND 0,I,10,15:GOSUB 20:NEXT I:SOUND 0,0,0,0
420 IF HP>0 THEN 300
430 ? "↰":? " YOU ARE DEAD! ";
440 FOR I=250 TO 50 STEP -1:SOUND 0,I,10,15:NEXT I:SOUND 0,0,0,0
450 ? "HIT TRIGGER"
460 IF STRIG(0)=1 THEN 460
470 M2$=M1$:GOTO 930
480 MHP=10:MSP=5:IF P=44 THEN MHP=5:MSP=3
490 IF P=174 THEN MHP=3:MSP=1
500 HP=HP2
510 HP=HP+MHP:SP=SP+MSP
520 IF HP>40 THEN HP=40
530 IF SP>15 THEN SP=15
540 X=X+IX:Y=Y+IY
550 GOSUB 760:GOSUB 690:GOTO 100
560 ? "↰":? " YOU WON ! ";:FOR I=50 TO 250:SOUND 0,I,10,15:NEXT I:SOUND 0,0,0,0
570 PLAY=1:TRAP 620:I=LEN(FL$)-4:D=VAL(FL$(I,I)):IF D<1 OR D>8 THEN 620
580 TRAP 610:FL$(I,I)=STR$(D+1):CLOSE #1:OPEN #1,4,0,FL$:CLOSE #1
590 ? " <LOADING LEVEL ";D+1;">"
600 MD=4:GOTO 1350
610 FL$(I,I)=STR$(D):CLOSE #1
620 TRAP 50000:GOTO 450
630 HP=25:SP=5:HORSE=0:BOAT=0:AXE=0:KEY=0
640 X=0:Y=0:M2$=M1$
650 SC$(53,53)="k"
660 GOSUB 690
670 A=USR(ADR(SC$),ADR(M2$)+Y*70+X)
680 FOR I=250 TO 50 STEP -1:SOUND 0,I,10,15:NEXT I:SOUND 0,0,0,0:GOTO 100
690 ? "↰ HIT POINTS:";HP;" STRIKE POINTS:";SP
700 ? " KEYS:";KEY:? " ";:IF HORSE=1 THEN ? "HORSE ";
710 IF AXE=1 THEN ? "AXE ";
720 IF BOAT=1 THEN ? "BOAT ";
730 ?
740 ? " [ESC] TO QUIT↑"
750 RETURN
760 A=USR(ADR(SC$),ADR(M2$)+Y*70+X)
770 L=70*Y+X+70*5+11:M2$(L,L)=CHR$(0):SOUND 0,150,10,15:FOR D=1 TO 20:NEXT D:SOUND 0,0,0,0:RETURN
780 DATA 225,97
790 DATA 226,98
800 DATA 35,99
810 DATA 164,100
820 DATA 37,101
830 DATA 166,102
840 DATA 103,103
850 DATA 104,104
860 DATA 105,105
870 DATA 106,106
880 DATA 44,108
890 DATA 237,109
900 DATA 174,110
910 DATA 96,96
920 DATA 0,124
930 ML=USR(ADR(MOVE$),MV1,MVD,MVN)
940 POKE 752,1:POKE 559,34:? "↰ SAVE LOAD DISK DIRECTORY UNDO":? " PLAY GAME ERASE ALL ?-PRINT"
950 ? " OPTION/SELECT TO CHANGE CHARACTERS":? " MOVE WITH JOYSTICK/TRIGGER TO DRAW↑":POKE 764,255
960 SOUND 0,200,10,10:IF CR<0 THEN CR=14
970 IF CR>14 THEN CR=0
980 BR=ASC(BR$(CR+1,CR+1)):DR=ASC(DR2$(CR+1,CR+1)):SC$(53,53)=CHR$(DR)
990 A=USR(ADR(SC$),ADR(M1$)+70*Y+X)
1000 FOR D=1 TO 10:NEXT D:SOUND 0,0,0,0:M2$=M1$:FOR D=1 TO 10:NEXT D:GOTO 1020
1010 A=USR(ADR(SC$),ADR(M1$)+70*Y+X)
1020 POKE 77,0:P=PEEK(764)
1030 IF PEEK(53279)=3 THEN CR=CR-1:GOTO 960
1040 IF PEEK(53279)=5 THEN CR=CR+1:GOTO 960
1050 P=PEEK(764):IF PEEK(764)=255 THEN 1150
1060 IF PEEK(764)=58 THEN 1200
1070 IF PEEK(764)=102 THEN 1820
1080 IF PEEK(764)=10 THEN 630
1090 IF PEEK(764)=11 THEN M1$=M2$:GOTO 930
1100 IF PEEK(764)=62 OR PEEK(764)=0 THEN P=PEEK(764):GOTO 1220
1110 IF PEEK(764)<>42 THEN 1150
1120 ? "↰ ERASE ALL! ":? :? "ARE YOU SURE(Y/N)? ":POKE 764,255:GET #2,I
1130 IF I=89 THEN ? "↰":? "ERASING...":GOSUB 1640
1140 GOTO 930
1150 ST=STICK(0):IX=(ST=6 OR ST=7 OR ST=5)-(ST=11 OR ST=9 OR ST=10)
1160 IY=(ST=9 OR ST=13 OR ST=5)-(ST=10 OR ST=14 OR ST=6)
1170 IF STRIG(0)=0 THEN SOUND 0,100,10,15:L=70*Y+X+70*5+11:M1$(L,L)=CHR$(BR):SOUND 0,0,0,0
1180 IF IX=0 AND IY=0 OR PEEK(40670+IX+20*IY)=175 THEN 1020
1190 SOUND 0,0,0,15:X=X+IX:Y=Y+IY:SOUND 0,0,0,0:GOTO 1010
1200 GOSUB 1730
1210 GOTO 1700
1220 ? "↰ ENTER FILENAME ";:IF P=0 THEN ? "TO LOAD ":GOTO 1240
1230 ? "TO SAVE "
1240 ? " ........":POKE 752,0:? "?";:I=0:POKE 764,255:FL$="D:"
1250 GET #2,A:IF A>48 AND A<58 AND I>0 THEN 1270
1260 IF A<65 OR A>90 AND A<>155 AND A<>126 THEN 1250
1270 IF A=155 THEN POKE 752,1:? " ";
1280 IF A=155 AND I=0 THEN 930
1290 IF A=126 AND I>0 THEN I=I-1:? CHR$(A);
1300 IF A=155 THEN 1330
1310 IF A>64 AND A<91 AND I<8 OR A>48 AND A<58 AND I<8 THEN FL$(I+3,I+3)=CHR$(A):I=I+1:? CHR$(A);
1320 GOTO 1250
1330 FL$(I+3)=".ADV"
1340 PLAY=0:MD=4:IF P<>0 THEN MD=8
1350 M1$(7000)=CHR$(0):M2$=M1$:ADRES=ADR(M1$):BYTES=LEN(M1$):IO=1
1360 TRAP 1430:CLOSE #1:OPEN #1,6,0,FL$:CLOSE #1:OPEN #1,MD,0,FL$
1370 IF MD=8 THEN DR$="CREATION":? #1;DR$
1380 IF MD=4 THEN DR$="":INPUT #1;DR$:IF DR$<>"CREATION" THEN 1430
1390 GOSUB 2760:GOTO 1400
1400 CLOSE #1:TRAP 50000
1410 IF PLAY=1 THEN GOTO 640
1420 GOTO 930
1430 M1$=M2$:CLOSE #1:TRAP 50000:? "↰":? "↰ DISK ERROR! PRESS ANY KEY":POKE 764,255
1440 GET #2,A
1450 GOTO 930
1460 GRAPHICS 0:POKE 559,0:POKE 16,64:POKE 53774,64:CLR
1470 DIM DM$(125),M1$(7000),M2$(7000),FL$(15),SC$(61),FILE$(14),DR$(20),MN$(10),WT(3)
1480 DIM BR$(15),DR2$(15):RESTORE 780:FOR I=1 TO 15:READ BR:BR$(I,I)=CHR$(BR)
1490 READ DR:DR2$(I,I)=CHR$(DR):NEXT I
1500 MV1=144*256+ASC("p")*8
1510 MV2=144*256+ASC("v")*8
1520 MVN=6*8:MVS=MV1:MVC=0
1530 MVD=144*256+ASC("i")*8
1540 WT(0)=144*256+(ASC("┬")+64)*8
1550 WT(1)=144*256+(ASC("┴")+64)*8
1560 WT(2)=144*256+(ASC("▌")+64)*8
1570 WT(3)=144*256+(ASC("└")+64)*8
1580 WTR=0
1590 WTD=144*256+ASC("d")*8
1600 SC$(1,30)="hh┐Lh┐K"♥ ♥1K↓p←hH@●Pu◣┴i♥*◆pp"
1610 CLOSE #2:OPEN #2,4,0,"K:"
1620 SC$(31,61)="●j%K┴i9♣▕fL%K┴iF┐K┴♣V)k▔^←)♥┐M◆"
1630 GOSUB 1640:GOTO 1690
1640 M1$=CHR$(0):M1$(7000)=CHR$(0):M1$(2)=M1$:M2$=M1$
1650 M1$(282,350)="♥♥♥♥♥♥♥♥/////////////////////////////////////////////////////♥♥♥♥♥♥♥♥♥♥♥♥♥♥"
1660 M1$(6722,6790)="♥♥♥♥♥♥♥♥/////////////////////////////////////////////////////♥♥♥♥♥♥♥♥♥♥♥♥♥♥"
1670 FOR I=282+8 TO 6722+8 STEP 70:M1$(I,I)="/":M1$(I+52,I+52)="/":NEXT I:M2$=M1$
1680 RETURN
1690 X=0:Y=0:GOSUB 2140
1700 GRAPHICS 2:POKE 16,64:POKE 53774,64
1710 POKE 708,198:POKE 709,10:POKE 756,146:POKE 752,1:? "↰"
1720 GOTO 930
1730 GRAPHICS 0:POKE 16,64:POKE 53774,64
1740 POKE 709,4:POKE 82,13:POKE 752,1:POSITION 0,0:? "↰":POKE 709,10:? "CTRL-1 TO PAUSE":?
1750 TRAP 1810:CLOSE #1:OPEN #1,6,0,"D:*.*":? "DISK DIRECTORY"
1760 INPUT #1;DR$:IF DR$(2,2)=" " THEN ? DR$(3):GOTO 1760
1770 ? :? DR$:CLOSE #1:TRAP 50000
1780 ? :? " PRESS ANY KEY":POKE 82,2:? :POKE 764,255
1790 GET #2,A
1800 RETURN
1810 TRAP 50000:? :? " DISK ERROR!↰":CLOSE #1:GOTO 1780
1820 ? "↰<SELECT PRINTER>":? "EPSON COMPATIBLE":? "PRO-WRITER":? "SEIKOSHA GP-250X↑":POKE 764,255
1830 GET #2,P:IF P<>69 AND P<>80 AND P<>83 THEN 930
1840 PR=1:IF P=80 THEN PR=2
1850 IF P=83 THEN PR=3
1860 ? "↰":? "GET PRINTER READY PRESS ANY KEY":POKE 764,255:GET #2,P:TRAP 2120
1870 ? "↰":? "[ESC] TO QUIT":POKE 764,255
1880 DM$="♥♥♥♥♥♥♥♥":CLOSE #1:OPEN #1,8,0,"P:":D=280:? #1
1890 IF PR=1 THEN ? #1;CHR$(27);"A";CHR$(8);
1900 IF PR=2 THEN ? #1;CHR$(27);"T16"
1910 IF PR=3 THEN ? #1;CHR$(27);"L";CHR$(2);
1920 IF PR=1 THEN ? #1;CHR$(27);"K";CHR$(200);CHR$(1);:DM$="♥♥♥♥♥♥♥♥":? #1;DM$;DM$;DM$;DM$;
1930 IF PR=2 THEN ? #1;CHR$(27);"S0008"
1940 IF PR=3 THEN ? #1;CHR$(27);"G";CHR$(1);CHR$(200);:DM$="♥♥♥♥♥♥♥♥":? #1;DM$;DM$;DM$;DM$;
1950 I=10:POKE 77,0
1960 A=ASC(M1$(I+D,I+D)):IF A=0 OR A=32 THEN A=A*8+144*256:GOTO 2010
1970 IF A=96 THEN A=A*8+144*256:GOTO 2010
1980 IF A<97 THEN A=A+32:GOTO 1980
1990 IF A>122 THEN A=A-32:GOTO 1990
2000 A=A-32:A=A*8+144*256
2010 ML=USR(ADR(MOVE$),A,ADR(DM$),8)
2020 IF PR<>2 THEN 2070
2030 FOR II=8 TO 1 STEP -1
2040 ? #1;DM$(II,II);
2050 NEXT II
2060 GOTO 2080
2070 ? #1;DM$;
2080 I=I+1:IF I<63 THEN 1960
2090 ? #1;CHR$(10);
2100 D=D+70:IF D=6790 OR PEEK(764)=28 THEN ? #1:CLOSE #1:GOTO 930
2110 GOTO 1920
2120 POKE 559,34:CLOSE #1:TRAP 50000:? "↰":? " PRINTER ERROR! PRESS ANY KEY"
2130 POKE 764,255:GET #2,P:GOTO 930
2140 CHSET=144*256:DIM MOVE$(56)
2150 MOVE$="hh┐▕h┐├h┐┤h┐┘h┐╱h┐┐ ♥p♣1├┌┘f├P▕f▕f┘P▕f┤F┐%┐I▶PhF╱%╱I▶P◆◆"
2160 DIM CHAR$(8)
2170 ML=USR(ADR(MOVE$),57344,CHSET,1024)
2180 RESTORE 2220
2190 GOTO 2210
2200 READ CHAR$:ML=USR(ADR(MOVE$),ADR(CHAR$),CHSET+A*8,8)
2210 READ A:IF A<>-1 THEN GOTO 2200
2220 DATA 64,♥♥♥♥♥♥♥♥
2230 DATA 65,j.:+j.:+
2240 DATA 66,├╲→▶▶?▖┘
2250 DATA 67,▕◣*▶*◣▕♥
2260 DATA 68,L▌3fL▌3f
2270 DATA 69,H2♣L!H)─
2280 DATA 70,▶gogoGG▶
2290 DATA 71,♥┴♣┴♣88♥
2300 DATA 72,♥P ▶ P♥♥
2310 DATA 73,┤╱┘▶q3▎┤
2320 DATA 74, |▶↑↑→▘♥
2330 DATA 75,♥▗R||R▗♥
2340 DATA 76,@FI)))┌▕
2350 DATA 77,♥*|>|>T♥
2360 DATA 78,♣ ┴┴ ♣
2370 DATA 79,▶▶▶▶▶▶▶▶
2380 DATA 87,L▌3fL▌3f
2390 DATA 88,fL▌3fL▌3
2400 DATA 89,3fL▌3fL▌
2410 DATA 90,▌3fL▌3fL
2420 DATA 97,▶◢▶"▶D▶┌
2430 DATA 98,◢┴↑<>◀▶▶
2440 DATA 99,♥♣8♣|♣◀♣
2450 DATA 100,L▌3fL▌3f
2460 DATA 101,@●Ja▎♣A◣
2470 DATA 102,▶▶y├)▶▶▶
2480 DATA 103,♥♥╱◀V♥♥♥
2490 DATA 104,♥T8T♣♣♣♣
2500 DATA 111,▶▶▶▶▶▶▶▶
2510 DATA 112,♣┴↑←♣Sv<
2520 DATA 113,♥◆◆|◀◀$$
2530 DATA 114,<<┴<Z┴$B
2540 DATA 115,◆◆↑▕<@A>
2550 DATA 116,♥*|>|>T♥
2560 DATA 117,♥♥f▌┴♥♥♥
2570 DATA 118,♣┴↑↑●Sv<
2580 DATA 119,♥◆◆|◀◀HH
2590 DATA 120,<<┴<Z┴$$
2600 DATA 121,0p▂├>@@?
2610 DATA 122,♥T>|>|*♥
2620 DATA 123,♥♥├◀┴♥♥♥
2630 DATA 124,▶├→┘→→├▶
2640 DATA -1
2650 GRAPHICS 1+16:POKE 559,0:POKE 16,64:POKE 53774,64
2660 POKE 708,8:POKE 709,196
2670 POSITION 3,0:? #6;"antic magazine":POSITION 6,1:? #6;"presents"
2680 D=PEEK(560)+PEEK(561)*256+4:POKE D+6,7:POKE D+8,7:POKE D+5,7
2690 POSITION 2,4:? #6;"DELUXE ADVENTURE":POSITION 4,5:? #6;"CREATION KIT"
2700 POSITION 2,7:? #6;"BY STEPHEN STOUT"
2710 POSITION 2,20:? #6;"trigger to begin"
2720 POKE 559,34
2730 POKE 77,0:IF STRIG(0)=0 THEN 2750
2740 GOTO 2730
2750 POSITION 0,0:? #6;"↰":RETURN
2760 IOCB=832+IO*16
2770 POKE IOCB+2,7+4*(PEEK(IOCB+10)=8)
2780 AH=INT(ADRES/256):AL=ADRES-AH*256
2790 POKE IOCB+4,AL:POKE IOCB+5,AH
2800 BH=INT(BYTES/256):BL=BYTES-BH*256
2810 POKE IOCB+8,BL:POKE IOCB+9,BH
2820 ML=USR(ADR("hhh*LVd"),IO*16)
2830 RETURN
