Personal Pocket Calendar (APNTCAL.BAS)
Personal Pocket Calendar by Jim Hodny, 128
Description
Personal Pocket Calendar by Jim Hodny, 128
From the Antic disk of November 1988 (Vol. 7 No. 7).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 15.5 KB
- Dialect
- Atari BASIC
- Lines
- 265
- Variables
MNAME$,DATE$,STUFF$,YN$,C$,C1$,LINE$,NAME$,APC$,MODLINE$,DATEMAT(,DT$,UNLINE1$,L$,INFO$,BL$,D$,Y$,MO$,RS$,IN,M$,DY$,DAY$,BLINE$,OFF,CLNDR,LOD,QUIT,NWCAL,PRNT,PLACE,K,C,X,M,Y,DY,T1,A,B,DIR,MM,U,CTR,T2,XX,Z,D,DATE,N,NUM
BASIC listing (265 lines)
10 REM PERSONAL POCKET CALENDAR
20 REM BY JIM HODNY
30 REM (c)1988, ANTIC PUBLISHING INC.
100 GRAPHICS 0:POKE 710,0:POKE 752,3:DIM MNAME$(13),DATE$(2),STUFF$(30):POKE 195,0
110 DIM YN$(1),C$(1122),C1$(1122),LINE$(34),NAME$(25),APC$(34),MODLINE$(34),DATEMAT(42),DT$(100),UNLINE1$(40)
120 LINE$(1,1)="-":LINE$(34)=LINE$:LINE$(2)=LINE$:DT$(1)=" ":DT$(100)=DT$:DT$(2)=DT$:CLOSE #3:OPEN #3,4,0,"K:"
130 APC$=" *** Appointments and memos *** ":MODLINE$=" ----------------------------- "
140 DIM L$(187),INFO$(1088),BL$(34),D$(13),Y$(15),MO$(9),RS$(26):UNLINE1$=" ":IN=1
150 DIM M$(15),DY$(24),DAY$(21),BLINE$(34):BLINE$=" | | | | | | | |":DAY$="SUNMONTUEWEDTHUFRISAT"
160 BL$(1,1)=" ":BL$(34)=BL$:BL$(2)=BL$:INFO$(1,1)=" ":INFO$(1088)=INFO$:INFO$(2)=INFO$:OFF=0:CLNDR=OFF:LOD=OFF
170 C$(1)=" ":C$(1122)=C$:C$(2)=C$:C1$=C$:D$="D:X":QUIT=OFF:NWCAL=OFF:PRNT=OFF
180 RS$="▶Press any key to continue"
190 PLACE=35:INFO$(1,34)=" SUN MON TUE WED THR FRI SAT "
200 TRAP 210:CLOSE #4:OPEN #4,4,0,"D:NAME":INPUT #4;NAME$:CLOSE #4
210 TRAP 40000
220 IF NAME$=BL$(1,25) OR PEEK(195)=170 THEN ? "↰Do you want to personalize the":? "calendar ( Y/N )":GOTO 240
230 GOTO 260
240 GET #3,K:IF CHR$(K)<>"N" AND CHR$(K)<>"n" AND CHR$(K)<>"y" AND CHR$(K)<>"Y" THEN 240
250 IF CHR$(K)="y" OR CHR$(K)="Y" THEN 2830
260 REM MAIN MENU
270 POKE 764,255:POKE 702,64:POKE 710,147:POKE 752,1:? "↰":? " ";NAME$:? " Personal pocket calendar"
290 ? :? :? " 1. Create a new calendar"
300 ? " 2. Load a calendar from disk"
310 ? " 3. Enter/edit appointments/memos"
320 ? " 4. Save the present calendar to disk"
330 ? " 5. Print the present calendar"
340 ? " 6. Display present calendar on screen";
350 ? " 7. List calendars on this disk"
360 ? " 8. End program"
370 ? :? "Make the desired selection-->___←←";
380 GET #3,K:IF K<49 OR K>56 THEN 380
390 YN$=CHR$(K):? YN$;:? :? :C=VAL(YN$)+1:IF C<>2 AND C<>3 AND C<>9 THEN 450
400 IF CLNDR=IN THEN RESTORE 2820:FOR X=1 TO M:READ MO$:NEXT X:? :? "DO YOU WANT TO SAVE YOUR":? MO$;", ";Y;
410 IF CLNDR=IN THEN ? " CALENDAR ( Y/N )?";:GET #3,K:IF CHR$(K)="Y" THEN C=5:?
420 IF CHR$(K)="Y" AND YN$="9" THEN QUIT=OFF
430 IF YN$="2" OR YN$="3" THEN NWCAL=IN
440 IF CLNDR=IN THEN ? "↑↑↑↑↑";
450 IF C=2 OR C=3 THEN CLNDR=IN:PRNT=IN
460 IF C>3 AND C<8 THEN IF CLNDR=OFF AND PRNT=OFF THEN ? "↰↓↓↓ THERE IS NO CALENDAR IN MEMORY..."
470 IF C>3 AND C<8 THEN IF CLNDR=OFF AND PRNT=OFF THEN POSITION 5,23:? RS$;:GET #3,K:GOTO 260
480 IF C=2 OR C=3 THEN C$(1,1)=" ":C$(1122)=C$:C$(2)=C$:C1$=C$
490 IF C=1 THEN 270
500 IF C=9 THEN POKE 710,148:END
510 IF C=2 THEN GOSUB 2300:GOTO 260
520 IF C=3 THEN 590
530 IF C=8 THEN ? "↰":POP :CLOSE #2:OPEN #2,6,0,"D:*.CAL":GOTO 720
540 IF C=7 THEN 2090
550 IF C=6 THEN 830
560 IF C=5 AND NWCAL=IN OR QUIT=IN THEN ? :? " ●●●Saving calendar●●●":? :CLNDR=OFF:GOTO 1350
570 IF C=5 THEN ? :? " ●●●Saving calendar●●●":? :GOTO 1350
580 IF C=4 THEN 1510
590 REM LOAD CALENDAR FROM DISK
600 M$="":C=0:M=0:Y=0:LOD=IN:GOSUB 2300
610 ? "↑↑↑↑↑↑↑↑↑↑↑↑↑↑↓↓↓↓ ●●●Loading calendar●●●";:? :? " please wait "
620 TRAP 40000:M$=STR$(M):IF M<10 THEN M$="00":M$(2,2)=STR$(M)
621 Y$=STR$(Y):D$(LEN(D$)+1)=M$:M$(LEN(M$)+1)=Y$:D$(LEN(D$)+1)=Y$
625 D$(LEN(D$)+1)=".CAL"
630 TRAP 700:CLOSE #1:OPEN #1,4,0,D$:INPUT #1;Y:INPUT #1;M:INPUT #1;DY
640 GOSUB 2640
650 PLACE=1:FOR T1=1 TO 6:INPUT #1;L$:C$(PLACE,PLACE+186)=L$:PLACE=PLACE+187:NEXT T1
660 PLACE=1:FOR T1=1 TO 6:INPUT #1;L$:C1$(PLACE,PLACE+186)=L$:PLACE=PLACE+187:NEXT T1
670 CLOSE #1
680 RESTORE 2820:FOR X=1 TO M:READ MO$:NEXT X:D$="D:X"
690 TRAP 40000:GOTO 260
700 TRAP 40000:CLOSE #2:OPEN #2,6,0,"D:*.CAL":? "↰"
710 POSITION 3,1:? "That calendar is not on this disk":CLNDR=OFF
720 POSITION 7,2:? "Months on this disk are:"
730 A=2:B=5:POKE 195,0
740 FOR DIR=1 TO 2:INPUT #2,MNAME$
750 IF MNAME$(3,3)="X" THEN MM=VAL(MNAME$(4,LEN(MNAME$)-8)):RESTORE 2820:FOR X=1 TO MM:READ MO$:NEXT X
760 IF B=20 THEN A=A+17:B=5
770 DIR=DIR-1:IF MNAME$(3,3)="X" THEN POSITION A,B:? MO$;", ";MNAME$(LEN(MNAME$)-7,LEN(MNAME$)-4):B=B+1
780 IF MNAME$(5,8)="FREE" THEN DIR=2:U=INT(VAL(MNAME$(1,3))):POSITION 9,21:? "Room for ";INT(U/19);" calendars."
790 IF DIR=2 AND A=2 AND B=5 THEN POSITION 2,10:? "There are no calendars on this disk."
800 NEXT DIR
810 D$="D:X":POKE 764,255:POSITION 5,23:? RS$;:GET #3,K
820 GOTO 260
830 REM PRINT PRESENT CALENDAR
840 TRAP 1320:POKE 710,228
850 ? :? :? " ●●●Printing calendar●●●"
860 CLOSE #7:OPEN #7,8,0,"P:":? #7;"␛@";:REM OPEN CHANNEL TO PRINTER AND RESET DEFAULTS
870 REM CREATE PAGE 2" BY 3" NEXT TO A LIKE-SIZED PAGE
880 ? #7;"␛C";CHR$(66);:REM SET FORM LENGTH IN LINES
890 ? #7;CHR$(15);CHR$(27);"3";CHR$(12):REM SET COMPRESSED PRINT AND SET LINE SPACING TO 12 L.P.I.
900 ? #7;LINE$,LINE$
910 ? #7;"␛S1";:REM SET PRINTER SUPERSCRIPT MODE
920 ? #7;"␛U1";:REM EPSON UNIDIRECTIONAL MODE
930 CTR=17-LEN(Y$)/2:FOR X=1 TO CTR:? #7;" ";:NEXT X:? #7;Y$,
940 FOR X=18+LEN(Y$)/2 TO 34:? #7;" ";:NEXT X:? #7;APC$
950 ? #7
960 CTR=17-LEN(MO$):FOR X=1 TO CTR:? #7;" ";:NEXT X:? #7;"␛W1";MO$;"␛W0";
970 FOR X=18+LEN(MO$) TO 40:? #7;" ";:NEXT X
980 ? #7;C$(7*34+1,8*34)
990 ? #7;BL$,C1$(7*34+1,8*34)
1000 ? #7;" SUN MON TUE WED THU FRI SAT ",C$(8*34+1,9*34)
1010 PLACE=1:FOR T1=1 TO 6
1020 INFO$(PLACE,PLACE+33)=MODLINE$:PLACE=PLACE+34
1030 FOR T2=1 TO 4:INFO$(PLACE,PLACE+33)=BLINE$:PLACE=PLACE+34:NEXT T2
1070 NEXT T1
1080 INFO$(PLACE,PLACE+33)=MODLINE$
1090 XX=1:FOR Z=71 TO 951 STEP 170:FOR X=Z TO Z+24 STEP 4:INFO$(X+2,X+3)=DT$(XX,XX+1)
1100 IF DT$(XX,XX)<>" " THEN D=INT(VAL(DT$(XX,XX+1))):GOTO 1130
1110 IF DT$(XX+1,XX+1)<>" " THEN D=INT(VAL(DT$(XX+1,XX+1))):GOTO 1130
1120 GOTO 1150
1130 IF C$(D*34-29,D*34-1)<>BL$(1,29) THEN INFO$(X+69,X+69)="*"
1140 IF C1$(D*34-29,D*34-1)<>BL$(1,29) THEN INFO$(X+70,X+70)="*"
1150 XX=XX+2:NEXT X:NEXT Z
1160 ? #7;INFO$(1,34),C$(8*34+1,9*34)
1170 ? #7;INFO$(35,67),C1$(8*34+1,9*34)
1180 Z=10:FOR X=69 TO 1088 STEP 68
1190 ? #7;INFO$(X,X+33),C$((Z-1)*34+1,Z*34)
1200 ? #7;INFO$(X+34,X+67),C1$((Z-1)*34+1,Z*34):Z=Z+1
1210 NEXT X
1220 CTR=17-LEN(NAME$)/2:FOR X=1 TO CTR:? #7;" ";:NEXT X
1225 ? #7;NAME$;:FOR X=CTR+LEN(NAME$)+0.5 TO 40:? #7;" ";:NEXT X
1230 ? #7;C$(24*34+1,25*34)
1240 ? #7;BL$,C1$(24*34+1,25*34)
1250 ? #7;APC$,C$(25*34+1,26*34)
1260 ? #7;BL$,C1$(25*34+1,26*34)
1270 FOR X=1 TO 7
1280 ? #7;C$((X-1)*34+1,X*34),C$((X+25)*34+1,(X+26)*34)
1290 ? #7;C1$((X-1)*34+1,X*34),C1$((X+25)*34+1,(X+26)*34)
1300 NEXT X
1310 ? #7;LINE$,LINE$
1320 IF PEEK(195)=138 THEN ? "↰↰↓↓↓↓↓↓↓↓ PRINTER DOES NOT RESPOND"
1330 IF PEEK(195)=138 THEN POSITION 6,23:? RS$;:GET #3,K
1340 GOTO 260
1350 REM SAVE CALENDAR TO DISK
1360 M$=STR$(M):IF M<10 THEN M$="00":M$(2,2)=STR$(M)
1362 Y$=STR$(Y):D$(LEN(D$)+1)=M$:M$(LEN(M$)+1)=Y$:D$(LEN(D$)+1)=Y$
1365 D$(LEN(D$)+1)=".CAL"
1370 TRAP 1410:CLOSE #2:OPEN #2,4,0,D$:? "This calendar already exists on this":? "disk. Replace Y/N ?";
1380 TRAP 40000:GET #3,K:IF CHR$(K)<>"N" AND CHR$(K)<>"Y" THEN 1380
1390 IF CHR$(K)="N" THEN M$=D$(4):D$=D$(1,3):NWCAL=OFF:QUIT=OFF:CLNDR=IN:GOTO 260
1400 ? "↑↑↑↑↑";
1410 IF PEEK(195)=138 THEN ? "↑↑↑↑↓↓ Disk drive does not respond...":POSITION 5,23:? RS$;:GET #3,K:GOTO 1480
1420 REM "PRINT" CALENDAR TO DISK
1430 TRAP 1460:CLOSE #2:OPEN #2,8,0,D$:? #2;Y:? #2;M:? #2;DY
1440 PLACE=1:FOR T1=1 TO 6:? #2;C$(PLACE,PLACE+186):PLACE=PLACE+187:NEXT T1
1450 PLACE=1:FOR T1=1 TO 6:? #2;C1$(PLACE,PLACE+186):PLACE=PLACE+187:NEXT T1
1460 IF PEEK(195)=162 THEN CLOSE #2:? "↑↑↑↑↓↓":? ," Disk is full ":XIO 33,#2,0,0,D$:POSITION 5,23:? RS$;:GET #3,K
1470 IF PEEK(195)=144 THEN ? "↑↑↑↑↓↓ Trouble writing to disk":POSITION 5,23:? RS$;:GET #3,K
1480 TRAP 40000:D$="D:X":CLOSE #2
1490 IF YN$="9" THEN END
1500 GOTO 260
1510 REM ENTER/EDIT CALENDAR
1520 TRAP 1520:POKE 82,2:DATE$="":? "↰":STUFF$=BL$(1,31)
1530 ? "Appointment for which date? __":? :? "Press ESC to return to main menu↑↑←←←←";
1540 GET #3,K:IF K<>27 AND K<48 OR K>58 AND K<>155 THEN 1540
1550 IF K=27 OR K=155 THEN POKE 82,2:TRAP 40000:GOTO 260
1560 ? CHR$(K);:DATE$(1,1)=CHR$(K):CLNDR=IN
1570 GET #3,K:IF K<>27 AND K<48 OR K>58 AND K<>126 AND K<>155 THEN 1570
1580 IF K=27 OR K=155 THEN 1610
1590 IF K=126 THEN ? "◀_←";:GOTO 1540
1600 ? CHR$(K);:DATE$(2,2)=CHR$(K)
1610 DATE=INT(VAL(DATE$))
1620 IF DATE>DY THEN ? :? "↰↰↓↓↓↓↓Only ";DY;" days in ";MO$;", ";Y;".":POSITION 5,23:? RS$;:GET #3,K:GOTO 1510
1630 ? "↰"
1640 IF C$(DATE*34-30,DATE*34)<>BL$(1,31) THEN POSITION 5,10:? "One Appointment/memo listed for"
1650 IF C$(DATE*34-30,DATE*34)<>BL$(1,31) THEN POSITION 13,11:? " ";MO$;" ";DATE;" ":POSITION 1,14:? "1."
1660 IF C$(DATE*34-30,DATE*34)<>BL$(1,31) THEN FOR X=13 TO (X+LEN(MO$)+LEN(DATE$))+4:POSITION X,12:? "▔":NEXT X
1670 IF C1$(DATE*34-30,DATE*34)<>BL$(1,31) THEN POSITION 5,10:? "Two Appointment▶s/memo▶s":POSITION 1,16:? "2."
1680 POSITION 3,3:? "▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂":POSITION 3,5:? "▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔";
1690 POSITION 2-LEN(DATE$),4:? DATE$;".";:POSITION 4,4:? BL$(1,29);"▎":POSITION 4,4
1700 POSITION 4,14:? C$(DATE*34-30,DATE*34):POSITION 4,16:? C1$(DATE*34-30,DATE*34):POSITION 3,4:? " ◀";
1710 POSITION 6,0:? "Enter appointment/memo":POSITION 6,1:? " or press 'ESC' "
1720 FOR X=1 TO 31
1730 GET #3,K:IF X<2 AND (K=27 OR K=155) THEN 1510
1740 IF K=125 THEN POSITION 3,4:? BL$(1,30):X=1:GOTO 1730
1750 IF X=31 AND K<>155 AND K<>126 THEN 1730
1760 IF K<27 OR K=96 OR K=123 OR (K>125 AND K<>126 AND K<>155 AND K<157) THEN 1730
1770 IF X<2 AND K=126 THEN 1730
1780 IF X>1 AND K=126 THEN X=X-1:POSITION (2+X),4:? " ":GOTO 1730
1790 IF K=155 THEN STUFF$=STUFF$(1,30):GOTO 1820
1800 POSITION (2+X),4:? CHR$(K):STUFF$(X,X)=CHR$(K)
1810 NEXT X
1820 IF C$(DATE*34-30,DATE*34)=BL$(1,31) THEN C$(DATE*34-30,DATE*34)=STUFF$:GOTO 1510
1830 IF C1$(DATE*34-30,DATE*34)=BL$(1,31) THEN C1$(DATE*34-30,DATE*34)=STUFF$:GOTO 1510
1840 POSITION 3,18:? "Whick one do you want to replace":? " 1 2 or 0 (for neither) "
1850 GET #3,K:IF K<48 OR K>50 THEN 1850
1860 IF K=49 THEN C$(DATE*34-30,DATE*34)=STUFF$:GOTO 1880
1870 IF K=50 THEN C1$(DATE*34-30,DATE*34)=STUFF$
1880 IF C$(DATE*34-30,DATE*34)=BL$(1,31) THEN C$(DATE*34-30,DATE*34)=C1$(DATE*34-30,DATE*34):GOTO 1900
1890 GOTO 1910
1900 C1$(DATE*34-30,DATE*34)=BL$(1,31)
1910 GOTO 1510
2090 REM SHOW CALENDAR
2100 RESTORE 2820:FOR X=1 TO M:READ MO$:NEXT X
2110 PLACE=35:INFO$(1,34)=" SUN MON TUE WED THR FRI SAT "
2120 FOR T1=1 TO 6:INFO$(PLACE,PLACE+33)=MODLINE$:PLACE=PLACE+34
2130 FOR X=1 TO 2:INFO$(PLACE,PLACE+33)=BLINE$:PLACE=PLACE+34:NEXT X
2150 NEXT T1
2160 ? "↰";:? ," ";Y$:FOR X=1 TO 15-LEN(MO$)/2:? " ";:NEXT X:? MO$:?
2170 INFO$(PLACE,PLACE+33)=MODLINE$
2180 XX=1:FOR Z=71 TO 650 STEP 102:FOR X=Z TO Z+24 STEP 4:INFO$(X+2,X+3)=DT$(XX,XX+1)
2190 IF DT$(XX,XX)<>" " THEN D=INT(VAL(DT$(XX,XX+1))):GOTO 2220
2200 IF DT$(XX+1,XX+1)<>" " THEN D=INT(VAL(DT$(XX+1,XX+1))):GOTO 2220
2210 GOTO 2240
2220 IF C$(D*34-29,D*34-1)<>BL$(1,29) THEN INFO$(X+35,X+35)="*"
2230 IF C1$(D*34-29,D*34-1)<>BL$(1,29) THEN INFO$(X+36,X+36)="*"
2240 XX=XX+2:NEXT X:NEXT Z
2250 FOR X=1 TO 650 STEP 34
2260 ? INFO$(X,X+33)
2270 NEXT X:POKE 764,255
2280 ? RS$;:GET #3,K
2290 POKE 82,2:GOTO 260
2300 REM DETERMINE YEAR AND MONTH
2310 POKE 710,69:M$="":IF LOD=IN THEN POKE 710,85:? "Load calendar for what month 1-12 ?";:GOTO 2330
2320 ? "Create calendar for what month 1-12?";
2330 GET #3,K:IF K<>27 AND K<48 OR K>57 THEN 2330
2340 IF K=27 THEN POP :GOTO 260
2350 M$(1,1)=CHR$(K):? M$(1,1);
2360 GET #3,K
2370 IF K=27 THEN POP :GOTO 260
2380 IF K<48 OR K>57 AND K<>155 AND K<>126 THEN 2360
2390 IF K=155 THEN M=INT(VAL(M$)):GOTO 2420
2400 IF K=126 THEN ? CHR$(K);:GOTO 2330
2410 M$(2,2)=CHR$(K):? M$(2,2);:M=INT(VAL(M$))
2420 IF NOT (M<1 OR M>12) THEN 2430
2425 ? :? :? ,"ONLY 1 - 12, PLEASE":POSITION 5,23:? RS$;:GET #3,K:? "↑↑↑↑↑↑↑↑↑↑↑↑↑↑":GOTO 2300
2430 ? :? :? "For what year --ex. 1988 ?";
2440 GET #3,K:IF K<>27 AND K<48 OR K>57 THEN 2440
2450 IF K=27 THEN POP :GOTO 260
2460 Y$(1,1)=CHR$(K):? Y$(1,1);
2470 GET #3,K:IF K<>27 AND K<48 OR K>57 AND K<>155 AND K<>126 THEN 2470
2480 IF K=126 THEN ? CHR$(K);:GOTO 2440
2490 IF K=155 THEN Y=INT(VAL(Y$)):GOTO 2620
2500 IF K=27 THEN POP :GOTO 260
2510 Y$(2,2)=CHR$(K):? Y$(2,2);
2520 GET #3,K:IF K<>27 AND K<48 OR K>57 AND K<>155 AND K<>126 THEN 2520
2530 IF K=126 THEN ? CHR$(K);:GOTO 2470
2540 IF K=155 THEN Y=INT(VAL(Y$)):GOTO 2620
2550 IF K=27 THEN POP :GOTO 260
2560 Y$(3,3)=CHR$(K):? Y$(3,3);
2570 GET #3,K:IF K<>27 AND K<48 OR K>57 AND K<>155 AND K<>126 THEN 2570
2580 IF K=126 THEN ? CHR$(K);:GOTO 2520
2590 IF K=155 THEN Y=INT(VAL(Y$)):GOTO 2620
2600 IF K=27 THEN POP :GOTO 260
2610 Y$(4,4)=CHR$(K):Y=INT(VAL(Y$)):? Y$(4,4)
2620 IF LOD=IN THEN LOD=OFF:RETURN
2630 ? "↑↑↑↑↑↑↑↑↑↑↑↓↓↓↓ ●●●Creating calendar●●●":? :? " please wait ";
2640 TRAP 40000:DY$="312831303130313130313031"
2650 IF M<3 THEN M=M+12:Y=Y-1
2660 N=2*M+INT(0.6*(M+1))+Y+INT(Y/4)-INT(Y/100)+INT(Y/400)+3
2670 N=INT((N/7-INT(N/7))*7+0.05):IF N=0 THEN N=7
2680 IF M>12 THEN M=M-12:Y=Y+1
2690 DY=VAL(DY$(M*2-1,M*2))
2700 IF M=2 THEN IF (Y/4=INT(Y/4) AND Y/400<>INT(Y/400)) THEN DY=DY+1
2710 RESTORE 2820:FOR X=1 TO M:READ MO$:NEXT X
2720 FOR X=1 TO 42:DATEMAT(X)=0:NEXT X:NUM=1:FOR X=N TO DY+N-1:DATEMAT(X)=NUM:NUM=NUM+1:NEXT X
2730 XX=1:FOR X=1 TO 42:IF DATEMAT(X)>9 THEN DT$(XX,XX+1)=STR$(DATEMAT(X)):GOTO 2750
2740 DT$(XX+1,XX+1)=STR$(DATEMAT(X)):DT$(XX,XX)=" ":IF DATEMAT(X)=0 THEN DT$(XX+1,XX+1)=" "
2750 XX=XX+2
2760 NEXT X
2770 FOR X=1 TO DY:IF X<10 THEN C$(X*34-33,X*34-33)=" ":C$(X*34-32,X*34-32)=STR$(X):C$(X*34-31,X*34-30)=". "
2780 IF X>9 THEN C$(X*34-33,X*34-32)=STR$(X):C$(X*34-31,X*34-30)=". "
2790 NEXT X
2800 C1$=C$
2810 RETURN
2820 DATA JANUARY,FEBRUARY,MARCH,APRIL,MAY,JUNE,JULY,AUGUST,SEPTEMBER,OCTOBER,NOVEMBER,DECEMBER
2830 REM PERSONALIZE CALENDAR
2840 TRAP 40000:CLOSE #4:OPEN #4,8,0,"D:NAME":? "↰↓↓↓What is your name (up to 23":? "characters)?";
2850 INPUT #16;NAME$:IF NAME$="" THEN NAME$=" ":? #4;NAME$:CLOSE #4:GOTO 200
2860 STUFF$(1,1)=" ":STUFF$(25,25)=STUFF$:STUFF$(2)=STUFF$:NAME$(LEN(NAME$)+1,LEN(NAME$)+2)="'s"
2870 STUFF$(12-LEN(NAME$)/2,12+LEN(NAME$))=NAME$:NAME$=STUFF$:? #4;NAME$:CLOSE #4:POKE 195,0:GOTO 200
