The Seven Skulls (SKULL.BAS)
The Seven Skulls, game by Bernard Taylor, 66
Description
The Seven Skulls, game by Bernard Taylor, 66
From the Antic disk of October 1988 (Vol. 7 No. 6) — disk B.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 8.0 KB
- Dialect
- Atari BASIC
- Lines
- 126
- Variables
C(,R,MV,J,Q,L,M,P,DE,N,DF,LVL,I(,TRY,A,DX,D(,Z,SS,MV1,Z1,K4,SH1,SH2,SH3,SH4,ST,T,K,S,G(,A$,DL,SK,E(,F(,AA$,BB$,K1,K2,K3,B$,KOL,C$,MU,CH,W,LO,BY,SH
BASIC listing (126 lines)
1 REM THE SEVEN SKULLS
2 REM BY BERNARD TAYLOR
3 REM (c)1988, ANTIC PUBLISHING INC.
4 GOSUB 1000:GOTO 2000
5 POSITION C(R),8:? #6;" ":MV=30
6 FOR J=1 TO 2:Q=2.8:L=15:M=12
7 FOR P=1 TO 2
8 FOR DE=L TO M STEP -Q:SOUND N,255,10,DE:SOUND 1,248+DE/2,10,DE:POSITION 9,2:? #6;" ":FOR DF=N TO 8:NEXT DF
9 POSITION 9,2:? #6;">?":SOUND 1,248+DE/2,10,DE:NEXT DE:L=10:M=N:Q=0.6
10 NEXT P:FOR DE=N TO 200:NEXT DE:IF LVL=1 THEN 16
11 NEXT J
12 FOR J=1 TO 7:POSITION C(J+1),5:GOSUB I(J):POSITION C(J+1),6:GOSUB I(J)+10:NEXT J:TRY=2
16 R=5:POSITION 9,8:? #6;"<=":POSITION N,1:? #6;MV
18 A=STICK(0):IF STRIG(0)=N THEN 200
20 IF PEEK(53279)=5 THEN 607
21 IF A=15 THEN 18
22 POSITION C(R),8:? #6;" "
25 DX=(A=7)-(A=11):R=R+DX
30 IF R>8 THEN R=2
32 IF R<2 THEN R=8
60 POSITION C(R),8:? #6;"<=":FOR DE=8 TO N STEP -1:SOUND N,80+DE,10,DE:NEXT DE
70 GOTO 18
200 FOR J=1 TO 3:LOCATE C(R+D(J)),6,Z:POSITION C(R+D(J)),5:GOSUB Z*10:POSITION C(R+D(J)),6:GOSUB Z*10+10
205 FOR DE=8 TO N STEP -1:SOUND N,140+DE,10,DE:NEXT DE:NEXT J:SS=N
206 MV=MV-1:MV1=MV1+1:POSITION N,1:? #6;" ":POSITION N,1:? #6;MV
208 FOR J=N TO 18 STEP 3:LOCATE J,5,Z1:IF Z1=33 THEN SS=SS+1:NEXT J
215 IF SS=7 THEN LVL=LVL+1:POSITION C(R),8:? #6;" ":POKE K4,N:GOTO 595
216 IF MV>N THEN POKE 77,N:GOTO 20
217 IF LVL=1 THEN 607
218 GOTO 607
360 ? #6;"&'":RETURN
370 ? #6;"()":RETURN
400 ? #6;"*+":RETURN
410 ? #6;",-":RETURN
440 ? #6;"./":RETURN
450 ? #6;":;":RETURN
580 ? #6;"!#":RETURN
590 ? #6;"$%":RETURN
595 FOR J=1 TO 3:RESTORE 3200
598 FOR P=1 TO 8:READ SH1,SH2,SH3,SH4
600 POKE ST+SH1,SH2:POKE ST+SH3,SH4
601 FOR DE=1 TO 3:NEXT DE:NEXT P:NEXT J
602 FOR T=14 TO N STEP -1:POKE K,T:S=INT(RND(0)*3)+2
603 SOUND N,G(14-T)/2,10,10:SOUND 1,G(14-T)/S,10,8:SOUND 2,G(14-T)/S+0.6,10,4:FOR DE=1 TO 40:NEXT DE:NEXT T
604 FOR DE=1 TO 80:NEXT DE:FOR J=N TO 2:SOUND J,N,N,N:NEXT J:MV=30:POSITION 18,1:? #6;LVL
605 IF LVL=9 THEN 1500
606 GOTO 615
607 FOR J=90 TO 12 STEP -2:POKE K,J:SOUND N,200-J,10,12:FOR DE=N TO 10:NEXT DE:NEXT J:SOUND N,N,N,N
608 IF TRY=1 AND LVL>3 AND INT(MV1/LVL)<20 THEN 5
610 RESTORE 3100:FOR J=1 TO LVL:READ A$:NEXT J:POSITION (20-LEN(A$))/2,3:? #6;A$
611 POKE DL+15,6:POKE DL+16,6:POSITION 1,10:? #6;"push START to play":POSITION 7,11:? #6;"again"
612 IF PEEK(53279)<>6 THEN 612
613 POKE 559,N
614 FOR DE=N TO 50:NEXT DE:POKE DL+15,7:POKE DL+16,7:POSITION C(R),8:? #6;" ":POKE K4,N:GOTO 2195
615 FOR J=2 TO 8
616 SK=INT(RND(0)*7)+1:IF E(SK)=N THEN 616
618 IF LVL>3 THEN I(J-1)=E(SK)
620 POSITION C(J),5:GOSUB E(SK):POSITION C(J),6:GOSUB E(SK)+10:E(SK)=N
625 NEXT J
630 FOR P=1 TO 7:E(P)=F(P):NEXT P
640 POSITION C(R),8:? #6;" ":POKE K,12:GOTO 16
1000 GRAPHICS 0:POKE 752,1:POKE 559,0:DIM AA$(22),BB$(22):K=708:K1=709:K2=710:K3=711:K4=712:N=0
1002 AA$="┌─┌─┌─┌─┌────┐─┐─┐─┐─┐":BB$="└─└─└─└─└────┘─┘─┘─┘─┘"
1005 SETCOLOR 2,N,N:POKE K,26:POKE K1,6:DL=PEEK(560)+256*PEEK(561):POKE DL+12,7:POKE DL+13,6:L=1:M=22:P=8
1007 FOR J=5 TO 1 STEP -1
1008 POSITION L+8,J:? #6;AA$(L,M):POSITION L+8,P:? #6;BB$(L,M)
1009 L=L+2:M=M-2:P=P+1:NEXT J
1010 POSITION 2,7:? #6;"THE SEVEN SKULLS":POSITION 11,15:? #6;"by Bernard Taylor"
1012 POSITION 9,17:? "● ONE MOMENT, PLEASE ●":COLOR 32:PLOT 2,0:POKE 559,34
1020 RETURN
1500 POSITION N,1:? #6;" ":POSITION 18,1:? #6;" ":POKE K,12:POKE K1,N
1501 POKE K3,N:POKE K4,N:B$(64,66)=STR$(MV1):KOL=USR(ADR(C$))
1502 FOR J=1 TO 160:POSITION N,4:? #6;B$(J,J+19)
1503 MU=INT(RND(0)*3)+2
1504 SOUND N,G(L)/2,10,8:SOUND 1,G(L)/MU,10,10:SOUND 2,G(L)/MU+0.6,10,4:L=L+1:IF L=24 THEN L=INT(RND(0)*16)
1506 FOR DE=1 TO 25:NEXT DE:NEXT J
1507 FOR J=N TO 2:SOUND J,N,N,N:NEXT J:FOR DE=N TO 100:NEXT DE:POSITION 7,3:? #6;"shogun"
1508 FOR J=1 TO 5
1509 FOR DE=14 TO N STEP -0.3:POKE K1,DE:NEXT DE
1510 FOR P=5 TO 100 STEP INT(RND(0)*2.5)+1.5
1511 SOUND N,P,8,(80*RND(0)+50)/P:SOUND 1,P+20,8,(80*RND(0)+50)/P:NEXT P
1512 SOUND N,N,N,N:SOUND 1,N,N,N
1513 NEXT J:POKE K1,6:POKE K3,106:POSITION 7,3:? #6;"SHOGUN":GOTO 611
2000 DIM A$(20),B$(182),C$(17),C(9),D(3),E(7),F(7),G(24),I(7)
2050 B$=" CONGRATULATIONS YOU DID THAT IN ONLY MOVES "
2060 B$(84,129)="YOU MARRY THE LOVELY PRINCESS TANUKI AND WITH "
2065 B$(130,182)="HER HELP YOU EVENTUALLY BECOME "
2070 C$="h)├┐●▘◣T▘└PH%●Pu◆"
2100 ST=(PEEK(742)-2)*256
2110 FOR J=N TO 487:POKE ST+J,PEEK(57344+J):NEXT J:CH=16:W=8
2115 FOR J=1 TO 3
2120 FOR LO=N TO CH-1:FOR BY=N TO 7:READ SH:POKE ST+(LO)*8+BY+W,SH:NEXT BY:NEXT LO:IF J=1 THEN CH=7:W=208
2125 IF J=2 THEN CH=2:W=472
2126 NEXT J
2150 FOR J=1 TO 9:READ S:C(J)=S:NEXT J
2160 FOR J=1 TO 3:READ S:D(J)=S:NEXT J:FOR J=1 TO 7:READ S:E(J)=S:F(J)=S:NEXT J
2165 FOR J=N TO 24:READ M:G(J)=M:NEXT J
2175 GRAPHICS 18:POKE 559,N:DL=PEEK(560)+256*PEEK(561):POKE DL+6,6
2180 POKE 756,ST/256:POKE K,12:POKE K1,6:POKE K2,26:POKE K3,106
2187 FOR J=2 TO 17 STEP 3:COLOR 96:PLOT J,8:NEXT J:PLOT 7,1:DRAWTO 11,1
2188 POSITION 2,N:? #6;"THE SEVEN SKULLS"
2189 COLOR 123:PLOT N,3:DRAWTO 3,3:PLOT 16,3:DRAWTO 19,3:COLOR 2:PLOT N,N:DRAWTO 1,N:PLOT 18,N:DRAWTO 19,N
2190 PLOT N,11:DRAWTO 19,11:PLOT N,2:DRAWTO 19,2:PLOT N,9:DRAWTO 19,9
2192 POSITION 3,1:? #6;"moves":POSITION 12,1:? #6;"level":COLOR 190:PLOT 9,2:COLOR 191:PLOT 10,2
2195 FOR J=1 TO 7:POSITION C(J+1),5:GOSUB E(J):POSITION C(J+1),6:GOSUB E(J)+10:NEXT J
2196 COLOR 32:PLOT 18,1:PLOT 4,3:DRAWTO 15,3:PLOT N,4:DRAWTO 19,4
2198 COLOR 2:PLOT N,10:DRAWTO 19,10:PLOT N,11:DRAWTO 17,11:COLOR 32:PLOT 5,10:PLOT 14,10:MV=30:MV1=N:TRY=1
2200 LVL=1:POSITION 18,1:? #6;LVL:COLOR 124
2205 FOR J=2 TO 17 STEP 3:PLOT J,10:NEXT J
2210 COLOR 32:PLOT N,7:DRAWTO 19,7:PLOT 5,10:PLOT 14,10:POKE 559,34:GOTO 6
3000 DATA 15,63,127,127,243,225,201,193,126,189,255,223,253,247,189,126,240,252,254,254,207,135,147,131
3005 DATA 102,62,20,7,9,14,7,0,102,124,40,224,144,112,224,0
3010 DATA 0,1,3,6,50,111,107,88,240,252,62,30,15,15,31,255,88,107,111,50,6,3,1,0,255,31,15,15,30,62,252,240
3020 DATA 0,7,14,9,7,20,62,102,0,224,112,144,224,40,124,102,193,193,225,243,127,127,63,15
3025 DATA 131,131,135,207,254,254,252,240
3030 DATA 15,63,124,120,240,240,248,255,0,128,192,96,76,246,214,26,0,60,102,102,102,102,60,0
3035 DATA 255,248,240,240,120,124,63,15,26,214,246,76,96,192,128,0
3040 DATA 1,3,6,15,28,7,27,53,128,192,96,240,56,224,216,172
3045 DATA 30,7,13,27,31,27,13,7,120,224,176,216,248,216,176,224,0,60,90,126,102,66,129,255
3050 DATA 255,0,255,223,126,90,60,0,255,195,165,153,153,165,195,255,18,0,3,6,9,12,15,18,0,0,-1,1
3052 DATA 360,400,440,580,360,400,440
3055 DATA 152,152,136,136,114,114,136,121,136,152,182,204,230,230,230,204,182,182,152,136,136,204,182,182,136
3100 DATA SHARK BAIT,SLAVE,FOOD TASTER,FOOT SOLDIER,BOWMAN
3150 DATA CASTLE GUARD,SAMURAI,DAIMYO
3200 DATA 14,193,30,131,13,229,29,167,13,225,29,135,14,195,30,195,14,193,30,131,15,197,31,163
3210 DATA 15,193,31,131,14,201,30,147
