Polyhedron Designer (SHAPES.BAS)

Polyhedron Designer by Irvine W. Smith, 141

Description

Polyhedron Designer by Irvine W. Smith, 141

From the Antic disk of October 1988 (Vol. 7 No. 6) — disk A.

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 17.2 KB

Dialect
Atari BASIC
Lines
240
Variables
A(, P1(, P2(, P3(, P4(, G$, R$, S$, A$, B$, C$, D$, E$, N$, Q$, T$, AR$, BL$, PR$, SV, A, B, C, D, E, F, G, N, I1, I2, I3, Q, Z, W, S, M, U1, PQ, L, QQ, X, Y, SC, CH, CT, I, S1, S2, S3, H, P764, J, J1, U2, U3, U, S4, S5, S6, S7, X1, X2, S8, S9
BASIC listing (240 lines)
10 REM POLYHEDRON DESIGNER
12 REM BY IRVINE W. SMITH
14 REM (c)1988, ANTIC PUBLISHING
20 DIM A(7,25),P1(25),P2(25),P3(25),P4(25),G$(25),R$(20),S$(25)
30 DEG :DIM A$(11),B$(10),C$(10),D$(14),E$(10),N$(14),Q$(10),T$(14),AR$(10),BL$(40),PR$(10):SV=1.1:? "↰"
40 ? "This program allows design of a three-level polyhedron.   A top view and a"
50 ? "side view are accurately scaled on thescreen. A scale drawing may be plottedon a 1020 Atari Plotter."
60 ? :? "  To make a new design, four radii    must be entered (top, mid and bottom) and 3 vertical heights."
70 ? "  Up to 24 polygon sides, with panels of triangular or 4-sided shape, may beused.":?
80 ? "PRESS 1 FOR MENU 1, or any other key  for a sample drawing-then press RETURN"
85 TRAP 90:INPUT A:IF A=1 THEN 1270
90 TRAP 40000
100 A=10:B=9:C=2:D=5:E=4:F=8:G=2:N=12:I1=3:I2=4:I3=3:G$="LAMPSHADE"
110 ? "Note that this lampshade has three-   sided panels top and bottom and four- sided panels at mid level."
120 POKE 752,5:? :? "NOW COMPUTING -PLEASE WAIT":Q=180/N:Z=COS(Q):SOUND 0,243,10,4
130 IF A>=B AND A>=C AND A>D THEN W=A:GOTO 170
140 IF B>=C AND B>=D THEN W=B:GOTO 170
150 IF C>=A AND C>=D THEN W=C:GOTO 170
160 W=D
170 IF 2*W/Z>SV*(E+F+G) THEN 190
180 S=160/SV/(E+F+G):M=1:GOTO 200
190 S=70/W*Z:M=1
195 S=S*1:REM CHANGE TO ADJUST SCALE
200 U1=W:PQ=M:FOR L=0 TO N:IF L=N THEN M=PQ
210 P1(L)=M*Q:A(0,L)=A*S*COS(P1(L))/Z:A(1,L)=A*S*SIN(P1(L))/SV/Z
220 M=M+2:NEXT L:SOUND 1,193,10,4
230 IF I1=3 THEN M=0:GOTO 250
240 M=1
250 PQ=M:FOR L=0 TO N:IF L=N THEN M=PQ
260 P2(L)=M*Q:A(2,L)=B*S*COS(P2(L))/Z:A(3,L)=B*S*SIN(P2(L))/SV/Z
270 M=M+2:NEXT L:SOUND 2,162,10,4
280 IF I1=I2 THEN M=1:GOTO 300
290 M=0
300 PQ=M:FOR L=0 TO N:IF L=N THEN M=PQ
310 P3(L)=M*Q:A(4,L)=C*S*COS(P3(L))/Z:A(5,L)=C*S*SIN(P3(L))/SV/Z
320 M=M+2:NEXT L:SOUND 3,121,10,4
330 IF I3=4 THEN M=PQ:GOTO 350
340 M=PQ+1:IF M=2 THEN M=0
350 PQ=M:FOR L=0 TO N:IF L=N THEN M=PQ
360 P4(L)=M*Q:A(6,L)=D*S*COS(P4(L))/Z:A(7,L)=D*S*SIN(P4(L))/SV/Z
370 M=M+2:NEXT L:SOUND 3,0,0,0:SOUND 2,0,0,0:SOUND 1,0,0,0:SOUND 0,0,0,0
380 GRAPHICS 24:POKE 710,12:POKE 712,12:POKE 709,2:COLOR 1:PLOT 0,80:DRAWTO 160,80
385 PLOT 84,0:DRAWTO 84,145:PLOT 83,0:DRAWTO 83,145
390 PLOT 84+A(0,N),80+A(1,N)
400 FOR L=0 TO N:DRAWTO 84+A(0,L),80+A(1,L):NEXT L
410 PLOT 83+A(0,N),80+A(1,N):FOR L=0 TO N:DRAWTO 83+A(0,L),80+A(1,L):NEXT L
420 PLOT 84+A(2,N-1),80+A(3,N-1):FOR L=0 TO N:DRAWTO 84+A(2,L),80+A(3,L):NEXT L
430 PLOT 83+A(2,N-1),80+A(3,N-1):FOR L=0 TO N:DRAWTO 83+A(2,L),80+A(3,L):NEXT L
440 PLOT 84+A(4,N-1),80+A(5,N-1):FOR L=0 TO N:DRAWTO 84+A(4,L),80+A(5,L):NEXT L
450 PLOT 83+A(4,N-1),80+A(5,N-1):FOR L=0 TO N:DRAWTO 83+A(4,L),80+A(5,L):NEXT L
460 PLOT 84+A(6,N-1),80+A(7,N-1):FOR L=0 TO N:DRAWTO 84+A(6,L),80+A(7,L):NEXT L
470 PLOT 83+A(6,N-1),80+A(7,N-1):FOR L=0 TO N:DRAWTO 83+A(6,L),80+A(7,L):NEXT L
480 FOR QQ=0 TO 50:IF (84+QQ*S)>240 THEN 520
490 PLOT 84+QQ*S,158:IF QQ/5-INT(QQ/5)=0 THEN 510
500 DRAWTO 84+QQ*S,153:NEXT QQ:GOTO 520
510 DRAWTO 84+QQ*S,153:PLOT 83+QQ*S,158:DRAWTO 83+QQ*S,153:NEXT QQ
520 PLOT 240,155:DRAWTO 240,0:A$="0":X=10:Y=145:GOSUB 570
525 IF S>31 THEN 560
530 A$="5":X=10+S*5/8:Y=145:GOSUB 570
540 IF S>15.5 THEN 560
550 A$="10":X=10+S*10/8:Y=145:GOSUB 570
560 GOTO 650
570 SC=PEEK(88)+PEEK(89)*256:CH=SC+Y*40+X
580 FOR Z=1 TO LEN(A$):S$=A$(Z,Z):GOSUB 610
590 CT=57344+X*8:FOR I=0 TO 7:POKE CH+I*40,PEEK(CT+I):NEXT I
600 CH=CH+1:NEXT Z:RETURN
610 X=ASC(S$):IF X>127 THEN X=X-128
620 IF X>31 AND X<96 THEN X=X-32:GOTO 640
630 IF X<32 THEN X=X+64
640 RETURN
650 S1=E*S/SV:S2=(E+F)*S/SV:S3=(E+F+G)*S/SV
660 IF I1=4 THEN 710
670 FOR L=0 TO N-1:PLOT 84+A(0,L),80+A(1,L):DRAWTO 84+A(2,L+1),80+A(3,L+1):NEXT L
680 FOR L=0 TO N-1:PLOT 83+A(0,L),80+A(1,L):DRAWTO 83+A(2,L+1),80+A(3,L+1):NEXT L
690 FOR L=0 TO N-1:PLOT 240+A(0,L),150:DRAWTO 240+A(2,L+1),150-S1:NEXT L
700 FOR L=0 TO N-1:PLOT 239+A(0,L),150:DRAWTO 239+A(2,L+1),150-S1:NEXT L
710 FOR L=0 TO N-1:PLOT 84+A(0,L),80+A(1,L):DRAWTO 84+A(2,L),80+A(3,L):NEXT L
720 FOR L=0 TO N-1:PLOT 83+A(0,L),80+A(1,L):DRAWTO 83+A(2,L),80+A(3,L):NEXT L
730 FOR L=0 TO N-1:PLOT 240+A(0,L),150:DRAWTO 240+A(2,L),150-S1:NEXT L
740 FOR L=0 TO N-1:PLOT 239+A(0,L),150:DRAWTO 239+A(2,L),150-S1:NEXT L
750 FOR L=0 TO N/2:PLOT 240+A(0,L),150:DRAWTO 240+A(0,L+1),150:NEXT L
760 FOR L=0 TO N/2:PLOT 240+A(2,L),150-S1:DRAWTO 240+A(2,L+1),150-S1:NEXT L
770 IF I2=4 THEN 890
780 IF I1=I2 THEN 820
790 FOR L=0 TO N-1:PLOT 84+A(2,L),80+A(3,L):DRAWTO 84+A(4,L+1),80+A(5,L+1):NEXT L
800 FOR L=0 TO N-1:PLOT 83+A(2,L),80+A(3,L):DRAWTO 83+A(4,L+1),80+A(5,L+1):NEXT L
810 GOTO 870
820 FOR L=0 TO N-1:PLOT 84+A(4,L),80+A(5,L):DRAWTO 84+A(2,L+1),80+A(3,L+1):NEXT L
830 FOR L=0 TO N-1:PLOT 83+A(4,L),80+A(5,L):DRAWTO 83+A(2,L+1),80+A(3,L+1):NEXT L
840 FOR L=0 TO N-1:PLOT 240+A(4,L),150-S2:DRAWTO 240+A(2,L+1),150-S1:NEXT L
850 FOR L=0 TO N-1:PLOT 239+A(4,L),150-S2:DRAWTO 239+A(2,L+1),150-S1:NEXT L
860 GOTO 890
870 FOR L=0 TO N-1:PLOT 240+A(2,L),150-S1:DRAWTO 240+A(4,L+1),150-S2:NEXT L
880 FOR L=0 TO N-1:PLOT 239+A(2,L),150-S1:DRAWTO 239+A(4,L+1),150-S2:NEXT L
890 FOR L=0 TO N-1:PLOT 84+A(2,L),80+A(3,L):DRAWTO 84+A(4,L),80+A(5,L):NEXT L
900 FOR L=0 TO N-1:PLOT 83+A(2,L),79+A(3,L):DRAWTO 83+A(4,L),79+A(5,L):NEXT L
910 FOR L=0 TO N:PLOT 240+A(2,L),150-S1:DRAWTO 240+A(4,L),150-S2:NEXT L
920 FOR L=0 TO N:PLOT 239+A(2,L),150-S1:DRAWTO 239+A(4,L),150-S2:NEXT L
930 FOR L=0 TO N/2:PLOT 240+A(4,L),150-S2:DRAWTO 240+A(4,L+1),150-S2:NEXT L
940 IF I3=4 THEN 1050
950 IF I1=I2 THEN 1010
960 FOR L=0 TO N-1:PLOT 84+A(6,L),80+A(7,L):DRAWTO 84+A(4,L+1),80+A(5,L+1):NEXT L
970 FOR L=0 TO N-1:PLOT 83+A(6,L),80+A(7,L):DRAWTO 83+A(4,L+1),80+A(5,L+1):NEXT L
980 FOR L=0 TO N-1:PLOT 240+A(6,L),150-S3:DRAWTO 240+A(4,L+1),150-S2:NEXT L
990 FOR L=0 TO N-1:PLOT 239+A(6,L),150-S3:DRAWTO 239+A(4,L+1),150-S2:NEXT L
1000 GOTO 1060
1010 FOR L=0 TO N-1:PLOT 84+A(4,L),80+A(5,L):DRAWTO 84+A(6,L+1),80+A(7,L+1):NEXT L
1020 FOR L=0 TO N-1:PLOT 83+A(4,L),80+A(5,L):DRAWTO 83+A(6,L+1),80+A(7,L+1):NEXT L
1030 FOR L=0 TO N-1:PLOT 240+A(4,L),150-S2:DRAWTO 240+A(6,L+1),150-S3:NEXT L
1040 FOR L=0 TO N-1:PLOT 239+A(4,L),150-S2:DRAWTO 239+A(6,L+1),150-S3:NEXT L
1050 FOR L=0 TO N-1:PLOT 84+A(4,L),80+A(5,L):DRAWTO 84+A(6,L),80+A(7,L):NEXT L
1060 FOR L=0 TO N-1:PLOT 83+A(4,L),80+A(5,L):DRAWTO 83+A(6,L),80+A(7,L):NEXT L
1070 FOR L=0 TO N:PLOT 240+A(4,L),150-S2:DRAWTO 240+A(6,L),150-S3:NEXT L
1080 FOR L=0 TO N:PLOT 239+A(4,L),150-S2:DRAWTO 239+A(6,L),150-S3:NEXT L
1090 FOR L=0 TO N/2:PLOT 240+A(6,L),150-S3:DRAWTO 240+A(6,L+1),150-S3:NEXT L
1100 A$="THIS ":X=42:Y=159:GOSUB 570:X=47:A$=G$:GOSUB 570:X=47+LEN(A$):A$=" HAS ":A$(6)=STR$(N)
1101 H=LEN(A$)+X:GOSUB 570:A$=" SIDES":X=H:GOSUB 570
1102 X=41:Y=168:A$="RADII:":GOSUB 570:X=47:A$=STR$(D):A$(LEN(A$)+1)=",":H=X+LEN(A$):GOSUB 570
1103 X=H:A$=STR$(C):A$(LEN(A$)+1)=",":H=X+LEN(A$):GOSUB 570
1108 X=H:A$=STR$(B):H=X+LEN(A$):GOSUB 570
1109 X=41:Y=176:A$="HEIGHTS:":GOSUB 570:X=49:A$=STR$(G):A$(LEN(A$)+1)=",":H=X+LEN(A$):GOSUB 570
1110 X=H:A$=STR$(F):A$(LEN(A$)+1)=",":H=X+LEN(A$):GOSUB 570
1111 X=H:A$=STR$(E):H=X+LEN(A$):GOSUB 570
1120 X=1:Y=0:A$="[S]ave Scre":GOSUB 570:X=12:A$="en | ANY KE":GOSUB 570:X=23:A$="Y to contin":GOSUB 570
1122 X=34:A$="ue":GOSUB 570
1130 POKE 764,255
1140 P764=PEEK(764):IF P764<>255 THEN POKE 764,255:GOTO 1155
1150 GOTO 1140
1155 IF P764=62 THEN GOSUB 2270
1160 GRAPHICS 0:POKE 752,5:POKE 709,206:POKE 710,192:? :? "  MENU 2  for SHAPES.BAS":?
1170 ? "1. GOTO MENU 1 (Create new design).":? :? "2. PRINT DESIGN DATA (Rate the design)"
1190 ? "3. PLOT THE DESIGN ON A 1020 PLOTTER.":?
1200 ? "Press One Of These Numbers (and       RETURN), to continue.":POKE 752,0
1220 TRAP 1250:INPUT H
1230 TRAP 40000:IF H<1 OR H>3 THEN 1250
1240 GOTO 1260
1250 TRAP 40000:? "PLEASE ENTER ONLY 1, 2, OR 3":GOTO 1200
1260 ON H GOTO 1270,1620,1800
1270 GRAPHICS 0:POKE 709,110:POKE 710,96:? :? "   MENU 1  for SHAPES.BAS":? :?
1280 ? "1. CREATE NEW DESIGN":? :? "2. LAMPSHADE":? :? "3. SWAGLAMP":? :? "4. PLANTER":? :? "5. BOWL":?
1290 ? "6. JEWEL BOX":? :? "7. DIAMOND":? :? "8. GEODOME":? :?
1300 POKE 752,5:? "PRESS A MENU NUMBER (and RETURN)"
1310 TRAP 1340:INPUT J:IF J>8 THEN 1300
1320 ON J GOTO 1410,1340,1350,1360,1370,1380,1390,1400,1300
1330 TRAP 40000:GOTO 1300
1340 A=12:B=10:C=6:D=2:E=3:F=7:G=2:N=12:I1=4:I2=3:I3=3:G$="LAMPSHADE":GOTO 120
1350 A=5:B=15:C=10:D=1:E=3:F=15:G=4:N=10:I1=3:I2=3:I3=3:G$="SWAGLAMP":GOTO 120
1360 A=4:B=8:C=10:D=0:E=4:F=12:G=6:N=8:I1=4:I2=3:I3=4:G$="PLANTER":GOTO 120
1370 A=5:B=8:C=10:D=12:E=2:F=8:G=2:N=16:I1=3:I2=4:I3=3:G$="BOWL":GOTO 120
1380 A=10:B=12:C=8:D=0:E=2:F=6:G=2:N=14:I1=3:I2=3:I3=4:G$="JEWEL BOX":GOTO 120
1390 A=0:B=12:C=8:D=4:E=6:F=3:G=1.5:N=18:I1=4:I2=3:I3=3:G$="DIAMOND":GOTO 120
1400 A=9.24:B=7.07:C=3.83:D=0:E=3.24:F=2.17:G=0.76:N=10:I1=3:I2=3:I3=4:G$="GEODOME":GOTO 120
1410 GRAPHICS 0:? "↰":? "If a wrong value is entered before    pressing RETURN, backspace and rewrite"
1420 ? "After RETURN a wrong value cannot be  corrected.   Continue to enter values"
1430 ? "until START AGAIN? appears and then   reenter all values.":?
1440 J1=1:TRAP 1360:? "ENTER TOP RADIUS";:INPUT D
1450 J1=2:? "ENTER TOP HEIGHT";:INPUT G
1460 J1=3:? "ENTER UPPER MID RADIUS";:INPUT C
1470 J1=4:? "ENTER MID HEIGHT";:INPUT F
1480 J1=5:? "ENTER LOWER MID RADIUS";:INPUT B
1490 J1=6:? "ENTER BOTTOM HEIGHT";:INPUT E
1500 J1=7:? "ENTER BOTTOM RADIUS";:INPUT A
1510 J1=8:? "Want to START AGAIN? (Y or N)";:INPUT A$:IF A$="Y" THEN 1440
1520 IF  NOT A$="N" THEN 1510
1530 J1=9:? "ENTER No. SIDES (4 to 24 max)";:INPUT N:IF N<4 OR N>24 THEN 1530
1540 J1=10:? "ENTER No. PANEL SIDES (3 or 4) BOTTOM";:INPUT I1:IF I1<3 OR I1>4 THEN 1540
1550 J1=11:? "ENTER No. PANEL SIDES (3 or 4) MID";:INPUT I2:IF I2<3 OR I2>4 THEN 11550
1560 J1=12:? "ENTER No. PANEL SIDES (3 or 4) TOP";:INPUT I3:IF I3<3 OR I3>4 THEN 1560
1570 J1=13:? "ENTER A NAME FOR IT (ex. PLANTER)";:INPUT G$
1580 J1=14:? "Want to redo those last ones? (Y or N)";:INPUT A$:IF A$="Y" THEN 1530
1590 IF  NOT A$="N" THEN 1340
1600 TRAP 40000:GOTO 120
1610 ? "WRONG ENTRY!";:ON J1 GOTO 1440,1450,1460,1470,1480,1490,1500,1510,1530,1540,1550,1560,1570,1580
1620 ? "↰":TRAP 1630:? "HOW DO YOU RATE IT? (GOOD, BAD, ETC)":INPUT R$:GOTO 1640
1630 TRAP 40000:? "USE LETTERS ONLY":GOTO 1620
1640 ? "IF THE PRINTER IS TURNED ON, PRESS ANYKEY TO CONTINUE"
1650 POKE 764,255
1660 IF PEEK(764)<>255 THEN 1680
1670 GOTO 1660
1680 POKE 764,255:LPRINT "THIS ";N;"-SIDED ";G$;" DESIGN IS RATED ";R$
1690 LPRINT "TOP RADIUS= ";D;"      TOP HEIGHT= ";G
1700 LPRINT "UPPER RADIUS= ";C;"    MID HEIGHT= ";F
1710 LPRINT "LOWER RADIUS= ";B;"    BOTTOM HEIGHT= ";E
1720 LPRINT "BOTTOM RADIUS= ";A
1730 LPRINT "No. PANEL EDGES: TOP ";I3;"  MID ";I2;"  BOTTOM ";I1
1740 LPRINT "-----------------------------":LPRINT
1750 GOTO 1160
1800 ? "↰":? "A 1020 PLOTTER IS REQUIRED FOR THIS.  TURN OFF PRINTER - TURN ON PLOTTER! ":CLOSE #2
1810 ? "Press Y to proceed, N to go to MENU 2":TRAP 1820:INPUT A$:GOTO 1830
1820 TRAP 40000:? "TYPE EITHER Y OR N":GOTO 1810
1830 IF A$="Y" THEN 1860
1840 IF  NOT A$="N" THEN 1810
1850 GOTO 1160
1860 ? :? "ENTER PEN COLOR (0=black, 1=blue,     2=green, 3=red":TRAP 1870:INPUT H:IF H>4 THEN 1860
1865 GOTO 1880
1870 TRAP 40000:? "ENTER 0, 1, 2, OR 3 ONLY":GOTO 1860
1880 OPEN #2,8,0,"P:":? #2;"␛╲":? #2;"C";H:U2=235*COS(Q)*3.78/U1/480:U3=INT(1/U2*1000)/1000
1890 ? :? "Full-width plotter scale is: ";U3:? "PRESS Y TO USE IT, N TO CHANGE IT":TRAP 1930
1900 INPUT A$:IF A$="Y" THEN 1970
1910 IF  NOT A$="N" THEN 1890
1920 GOTO 1940
1930 TRAP 40000:GOTO 1890
1940 ? :? "ENTER DESIRED PLOTTER SCALE (not less)":TRAP 1960:INPUT U3:U2=1/U3
1950 GOTO 1970
1960 TRAP 40000:GOTO 1940
1970 U=U2*480/3.78/S:S4=400-U2*127*(E+F+G):S5=400-U2*127*(G+F):S6=400-U2*127*G:S7=400
1980 ? #2;"M240,-400":? #2;"I";"*M0,";S4
1990 FOR Y=S4 TO 400 STEP 50:? #2;"D0,";Y+5;"*M0,";Y+15;"*D0,";Y+40;"*M0,";Y+50:NEXT Y:REM CENTERLINE
2000 ? #2;"M0,";S7;"*D";U*A(6,0);",";S7;"*D";U*A(4,0);",";S6;"*D";-U*A(4,0);",";S6;"*D";-U*A(2,0);",";S5
2010 ? #2;"D";U*A(2,0);",";S5;"*D";U*A(0,0);",";S4;"*D";-U*A(0,0);",";S4;"*D";-U*A(2,0);",";S5
2020 ? #2;"M0,";S7;"*D";-U*A(6,0);",";S7;"*D";-U*A(4,0);",";S6;"*M";U*A(4,0);",";S6;"*D";U*A(2,0);",";S5
2030 IF I1=4 THEN 2060
2040 FOR L=0 TO N/2-1:X1=U*A(0,L):X2=U*A(2,L+1):? #2;"M";X1;",";S4;"*D";X2;",";S5
2050 NEXT L
2060 FOR L=0 TO N/2-1:X1=U*A(0,L):X2=U*A(2,L):? #2;"M";X1;",";S4;"*D";X2;",";S5
2070 NEXT L
2080 IF I2=4 THEN 2140
2090 IF I1=I2 THEN 2120
2100 FOR L=0 TO N/2-1:X1=U*A(2,L):X2=U*A(4,L+1):? #2;"M";X1;",";S5;"*D";X2;",";S6:NEXT L
2110 GOTO 2140
2120 FOR L=0 TO N/2-1:X1=U*A(4,L):X2=U*A(2,L+1):? #2;"M";X1;",";S6;"*D";X2;",";S5
2130 NEXT L
2140 FOR L=0 TO N/2-1:X1=U*A(2,L):X2=U*A(4,L):? #2;"M";X1;",";S5;"*D";X2;",";S6
2150 NEXT L:IF I3=4 THEN 2210
2160 IF I1=I2 THEN 2190
2170 FOR L=0 TO N/2-1:X1=U*A(6,L):X2=U*A(4,L+1):? #2;"M";X1;",";S7;"*D";X2;",";S6
2180 NEXT L:GOTO 2210
2190 FOR L=0 TO N/2-1:X1=U*A(4,L):X2=U*A(6,L+1):? #2;"M";X1;",";S6;"*D";X2;",";S7
2200 NEXT L
2210 FOR L=0 TO N/2-1:X1=U*A(4,L):X2=U*A(6,L):? #2;"M";X1;",";S6;"*D";X2;",";S7
2220 NEXT L:S8=S4-50:? #2;"M-200,";S8:? #2;"PACTUAL SIZE IS ";U3;" TIMES LARGER"
2230 S8=S4-30:S9=LEN(G$)*6:? #2;"M";-S9;",";S8:? #2;"P";G$:? #2;"H":? #2;"M-240,";S4-50:CLOSE #2
2240 GRAPHICS 0:? "↰":? "TURN OFF THE PLOTTER":? :? "PRESS ANY KEY TO RETURN TO MENU 2"
2250 IF PEEK(764)<>255 THEN POKE 764,255:GOTO 1160
2260 GOTO 2250
2270 X=6:Y=0:A$="ing as PICT":GOSUB 570:X=17:A$="URE.PIC":GOSUB 570:COLOR 2:FOR X=0 TO 7
2275 PLOT 200,X:DRAWTO 300,X:NEXT X
2280 CLOSE #1:OPEN #1,8,0,"D:PICTURE.PIC":POKE 850,11:POKE 852,PEEK(88):POKE 853,PEEK(89)
2290 POKE 856,0:POKE 857,30:P764=USR(ADR("hhh*LVd"),16):PUT #1,PEEK(712):PUT #1,PEEK(708):PUT #1,PEEK(709)
2300 PUT #1,PEEK(710):CLOSE #1:RETURN