Quizzer with sample (QUIZZER.BAS)
Quizzer with sample by Andrew R. Thomas, 80
Description
Quizzer with sample by Andrew R. Thomas, 80
From the Antic disk of October 1988 (Vol. 7 No. 6) — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 7.6 KB
- Dialect
- Atari BASIC
- Lines
- 229
- Variables
VADRH,VADR,VADRL,WPOS,PAIR,IT,ENG$,LW,W$,RUS$,EBAR$,RBAR$,ABAR$,OBAR$,CBAR$,PBAR$,ZBAR$,NBAR$,BAR$,KBAR$,BBAR$,QW$,AW$,ANS$,FILE$,FILE1$,VAR,NP,ORDER,RAMTOP,CHBAS,TIDS,LENG,LRUS,LF,LQW,LAW,QD,CIDS
BASIC listing (229 lines)
1 REM QUIZZER
2 REM BY ANDREW R. THOMAS
3 REM (c)1988, ANTIC PUBLISHING
10 GOTO 1000
99 REM SUBROUTINES
100 VADRH=INT(VADR/256):VADRL=VADR-VADRH*256
105 RETURN
200 REM E->R SCREEN
205 POKE 559,0
210 POKE 1700+3,66:POKE 1700+25,194
215 POKE 512,146:POKE 513,6
220 POKE 559,34:RETURN
230 REM R->E SCREEN
235 POKE 559,0
240 POKE 1700+3,194:POKE 1700+25,66
245 POKE 512,146:POKE 513,6
250 POKE 559,34:RETURN
300 REM ENG FIND
310 WPOS=1
320 IF PAIR=0 THEN 340
330 FOR IT=1 TO PAIR:WPOS=WPOS+ASC(ENG$(WPOS,WPOS))+1:NEXT IT
340 LW=ASC(ENG$(WPOS,WPOS)):W$=ENG$(WPOS+1,WPOS+LW):RETURN
400 REM RUS FIND
410 WPOS=1
420 IF PAIR=0 THEN 440
430 FOR IT=1 TO PAIR:WPOS=WPOS+ASC(RUS$(WPOS,WPOS))+1:NEXT IT
440 LW=ASC(RUS$(WPOS,WPOS)):W$=RUS$(WPOS+1,WPOS+LW):RETURN
800 REM DL
805 DATA 112,112,96,194,64,152,7,2,71,184,152,66,204,152,112,130,7,2,7,2,7,2,71,228,153,66,248,153
806 DATA 0,2,2,2,65,164,6
809 REM DLI
810 DATA 72,169,224,141,9,212,169,146,141,0,2,141,10,212,104,64
1000 REM VARS
1005 DIM EBAR$(7),RBAR$(6),ABAR$(6),OBAR$(5),CBAR$(6),PBAR$(6)
1010 DIM ZBAR$(38),NBAR$(38),BAR$(38),KBAR$(34),BBAR$(39)
1015 DIM ENG$(10000),RUS$(10000)
1020 DIM W$(19),QW$(19),AW$(19),ANS$(19)
1025 DIM FILE$(14),FILE1$(14)
1030 EBAR$="ENGLISH":RBAR$="RYSSKO":ABAR$="ANSWER":OBAR$="OTVET"
1031 CBAR$="RIGHT!":PBAR$="PRAVO!"
1032 ZBAR$=" Load Add End"
1033 NBAR$=" Load Save Add Quiz End"
1034 BAR$=" Load Save Add Delete Quiz Tally End"
1035 KBAR$=" << Press Space to Continue >>"
1036 BBAR$=" "
1050 FOR IT=0 TO 34:READ VAR:POKE 1700+IT,VAR:NEXT IT
1060 FOR IT=0 TO 15:READ VAR:POKE 1664+IT,VAR:POKE 1682+IT,VAR:NEXT IT
1061 POKE 1682+7,128
1080 NP=0
1090 POKE 752,1:POKE 764,255:? "↰Random or Consecutive?"
1091 IF PEEK(764)=255 THEN 1091
1092 VAR=PEEK(764):IF NOT (VAR=104 OR VAR=40 OR VAR=82 OR VAR=18) THEN POKE 764,255:GOTO 1090
1093 IF VAR=104 OR VAR=40 THEN ORDER=1:GOTO 1100
1094 ORDER=2:PAIR=-1
1100 REM C-SET
1101 RAMTOP=PEEK(106)-4:POKE 106,RAMTOP:GRAPHICS 0
1104 POKE 1682+2,RAMTOP:CLOSE #1
1110 OPEN #1,4,0,"D:CYRILL.FNT"
1120 CHBAS=RAMTOP*256
1130 VADR=CHBAS:GOSUB 100
1135 POKE 848+4,VADRL:POKE 848+5,VADRH
1140 VADR=1024:GOSUB 100
1145 POKE 848+8,VADRL:POKE 848+9,VADRH
1150 POKE 848+2,7
1160 VAR=USR(ADR("h"♣LVd")):CLOSE #1
1200 REM START
1210 POKE 559,0:POKE 54286,192
1215 POKE 512,146:POKE 513,6
1220 POKE 560,164:POKE 561,6
1225 POKE 710,0:POKE 82,0:POKE 559,34
1240 POKE 752,1
2000 REM CHOICE
2005 ? "↰"
2010 POKE 764,255
2020 POSITION 0,14
2030 IF NP=0 THEN ? ZBAR$;:GOTO 2050
2035 IF TIDS=0 THEN ? NBAR$;:GOTO 2050
2040 ? BAR$;
2050 VAR=PEEK(764):IF VAR=255 THEN 2050
2055 POKE 764,255
2060 IF VAR=64 OR VAR=0 THEN 3000
2065 IF (VAR=126 OR VAR=62) AND NP>0 THEN 4000
2070 IF VAR=127 OR VAR=63 THEN 5000
2080 IF (VAR=122 OR VAR=58) AND NP>0 AND TIDS>0 THEN 6000
2090 IF (VAR=111 OR VAR=47) AND NP>0 THEN 7000
2100 IF (VAR=109 OR VAR=45) AND NP>0 AND TIDS>0 THEN 8000
2110 IF VAR=106 OR VAR=42 THEN 31000
2120 GOTO 2050
3000 REM LOAD
3010 POSITION 0,12:? BBAR$;
3015 POSITION 0,12:? "File";:INPUT FILE$
3020 IF FILE$="" THEN 2000
3025 GOSUB 3500:TRAP 3300:CLOSE #1
3030 OPEN #1,4,0,FILE$:TRAP 40000
3040 INPUT #1,NP:INPUT #1,LENG:INPUT #1,LRUS
3045 ENG$(LENG,LENG)="♥":RUS$(LRUS,LRUS)="♥"
3050 VADR=LENG:GOSUB 100
3060 POKE 848+2,7:POKE 848+8,VADRL:POKE 848+9,VADRH
3070 VADR=ADR(ENG$):GOSUB 100
3075 POKE 848+4,VADRL:POKE 848+5,VADRH
3080 VAR=USR(ADR("h"♣LVd"))
3090 VADR=LRUS:GOSUB 100
3100 POKE 848+8,VADRL:POKE 848+9,VADRH
3110 VADR=ADR(RUS$):GOSUB 100
3120 POKE 848+4,VADRL:POKE 848+5,VADRH
3130 VAR=USR(ADR("h"♣LVd")):CLOSE #1
3220 GOTO 2000
3300 CLOSE #1:TRAP 40000
3310 POSITION 0,12:? "Can't load ";FILE$
3320 POSITION 0,13:? BBAR$;
3330 GOTO 2010
3500 LF=LEN(FILE$)
3510 IF LF>1 THEN IF FILE$(1,2)="D:" THEN 3600
3520 IF LF>2 THEN IF FILE$(1,1)="D" AND FILE$(3,3)=":" THEN 3600
3530 FILE1$="D:":FILE1$(3)=FILE$:FILE$=FILE1$
3600 RETURN
4000 REM SAVE
4010 POSITION 0,12:? BBAR$;
4015 POSITION 0,12:? "File";:INPUT FILE$
4020 IF FILE$="" THEN 2000
4025 GOSUB 3500:TRAP 4300:CLOSE #1
4030 OPEN #1,8,0,FILE$:TRAP 40000
4040 ? #1,NP
4050 LENG=LEN(ENG$):LRUS=LEN(RUS$)
4060 ? #1;LENG:? #1;LRUS
4070 VADR=LENG:GOSUB 100
4080 POKE 848+2,11:POKE 848+8,VADRL:POKE 848+9,VADRH
4090 VADR=ADR(ENG$):GOSUB 100
4095 POKE 848+4,VADRL:POKE 848+5,VADRH
4100 VAR=USR(ADR("h"♣LVd"))
4110 VADR=LRUS:GOSUB 100
4120 POKE 848+8,VADRL:POKE 848+9,VADRH
4130 VADR=ADR(RUS$):GOSUB 100
4140 POKE 848+4,VADRL:POKE 848+5,VADRH
4150 VAR=USR(ADR("h"♣LVd"))
4200 CLOSE #1
4210 POSITION 0,12:? BBAR$;
4220 GOTO 2000
4300 CLOSE #1:TRAP 40000
4310 POSITION 0,12:? "Can't save ";FILE$
4320 POSITION 0,13:? BBAR$;
4330 GOTO 2010
5000 REM ADD
5020 ? "↰":GOSUB 200
5030 POKE 1709,184
5040 POSITION 9-INT(0.5*LEN(EBAR$)),1:? EBAR$
5045 POSITION 0,3:INPUT QW$
5050 IF QW$="" THEN 2000
5055 LET LENG=LEN(QW$):IF LENG>19 THEN POSITION 13,12:? "Word too large";:GOTO 2010
5060 POSITION 29-INT(0.5*LEN(RBAR$)),5:? RBAR$
5065 POSITION 0,7:INPUT AW$
5070 IF AW$="" THEN 2000
5075 LRUS=LEN(AW$):IF LENG>19 THEN POSITION 13,12:? "Word too large";:GOTO 2010
5080 LET LENG=LEN(ENG$):LRUS=LEN(RUS$)
5090 LQW=LEN(QW$):LAW=LEN(AW$)
5100 IF LENG+LQW+1>10000 OR LRUS+LAW+1>10000 THEN POSITION 12,13:? "Not enough memory":GOTO 5140
5110 ENG$(LENG+1,LENG+1)=CHR$(LQW):RUS$(LRUS+1,LRUS+1)=CHR$(LAW)
5120 ENG$(LENG+2)=QW$:RUS$(LRUS+2)=AW$
5130 NP=NP+1
5140 POKE 764,255
5150 POSITION 0,12:? KBAR$
5160 VAR=PEEK(764):IF VAR=255 THEN 5160
5170 POKE 764,255
5180 IF VAR=33 THEN 5000
5190 GOTO 2000
6000 REM DELETE
6010 GOSUB 400
6015 IF WPOS+LW>=LEN(RUS$) THEN RUS$(WPOS)="":GOTO 6030
6020 RUS$(WPOS)=RUS$(WPOS+LW+1)
6030 GOSUB 300
6035 IF WPOS+LW>=LEN(ENG$) THEN ENG$(WPOS)="":GOTO 6050
6040 ENG$(WPOS)=ENG$(WPOS+LW+1)
6050 NP=NP-1
6060 POSITION 0,12:? W$;" deleted ↰";
6070 GOTO 2010
7000 REM QUIZ
7010 QD=INT(2*RND(0))+1
7020 ON ORDER GOTO 7025,7030
7025 PAIR=INT(NP*RND(0)):GOTO 7040
7030 PAIR=PAIR+1:IF PAIR>NP-1 THEN PAIR=0
7040 ON QD GOSUB 300,400
7050 QW$=W$
7060 ON QD GOSUB 400,300
7070 AW$=W$
7080 LQW=LEN(QW$):LAW=LEN(AW$)
7100 ? "↰"
7110 ON QD GOSUB 200,230
7300 ON QD GOTO 7310,7320
7310 POSITION 9-INT(0.5*LEN(EBAR$)),1:? EBAR$;:GOTO 7330
7320 POSITION 9-INT(0.5*LEN(RBAR$)),1:? RBAR$;
7330 POKE 1709,164
7340 POSITION 9-INT(0.5*LQW),3:? QW$;
7350 ON QD GOTO 7360,7370
7360 POSITION 29-INT(0.5*LEN(RBAR$)),5:? RBAR$;:GOTO 7380
7370 POSITION 29-INT(0.5*LEN(EBAR$)),5:? EBAR$;
7380 FOR IT=1 TO 20:POKE 1709,164+IT:NEXT IT
7390 POSITION 0,7:INPUT ANS$
7400 TIDS=TIDS+1
7410 IF NOT ANS$=AW$ THEN 7500
7420 CIDS=CIDS+1
7430 ON QD GOTO 7440,7450
7440 POSITION 29-INT(0.5*LEN(PBAR$)),8:? PBAR$;:GOTO 7460
7450 POSITION 29-INT(0.5*LEN(CBAR$)),8:? CBAR$;
7460 GOTO 7600
7500 ON QD GOTO 7510,7520
7510 POSITION 29-INT(0.5*LEN(OBAR$)),8:? OBAR$;:GOTO 7530
7520 POSITION 29-INT(0.5*LEN(ABAR$)),8:? ABAR$;
7530 POKE 1723,208
7540 POSITION 29-INT(0.5*LAW),10:? AW$;
7550 FOR IT=1 TO 20:POKE 1723,208+IT:NEXT IT
7600 POKE 764,255:POSITION 0,12:? KBAR$;
7605 POSITION 0,14:? BAR$;
7610 VAR=PEEK(764):IF VAR=255 THEN 7610
7630 IF VAR=33 THEN POKE 764,255:GOTO 7000
7640 POSITION 0,12:? BBAR$;:GOTO 2020
8000 REM TALLY
8010 POSITION 0,12:? BBAR$
8020 POSITION 0,12:? CIDS;" correct out of ";TIDS;" - ";INT(CIDS/TIDS*100+0.5);"%";
8030 GOTO 2010
31000 REM END
31010 POKE 106,PEEK(106)+4:GRAPHICS 0
31020 POKE 752,0:POKE 756,224:POKE 82,2
31050 ? "Your Name";:INPUT W$
31060 CLOSE #1:TRAP 31080:CLOSE #1
31070 OPEN #1,9,0,"D:QLOG":GOTO 31090
31080 CLOSE #1:OPEN #1,8,0,"D:QLOG"
31090 TRAP 40000
31100 ? #1;W$;" ";CIDS;" ";TIDS;" ";INT(CIDS/TIDS*100+0.5)
31110 END
