Bond Broker (BOND.BAS)
Bond Broker by Jeffrey A. Summers, 32
Description
Bond Broker by Jeffrey A. Summers, 32
From the Antic disk of October 1988 (Vol. 7 No. 6) — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 3.9 KB
- Dialect
- Atari BASIC
- Lines
- 94
- Variables
VECTOR,PTR,X,RESPONSE$,DLIST,INV1$,INV2$,LD1,LD2,RATE1,RATE2,REIN1$,REIN2$,LDREIN1$,LDREIN2$,ENTRY,V1,V2,YEAR
BASIC listing (94 lines)
10 REM BOND BROKER
20 REM BY JEFFREY A. SUMMERS
30 REM (c)1988, ANTIC PUBLISHING
99 GOTO 10000:REM INITIALIZATION CODE
100 VECTOR=29:PTR=1
101 GET #1,X:IF X<28 OR X>31 THEN 110
105 VECTOR=X:RETURN
110 IF X=155 THEN RETURN
111 IF X=27 THEN VECTOR=27:RETURN
112 IF X<>126 THEN 115
113 IF PTR=1 THEN 101
114 ? CHR$(X);:PTR=PTR-1:GOTO 101
115 RESPONSE$(PTR,PTR)=CHR$(X):PTR=PTR+1:? CHR$(X);:GOTO 101
1000 GRAPHICS 0:POKE 710,4:DLIST=PEEK(560)+256*PEEK(561):IF PEEK(53279)<>5 THEN POKE 16,112:POKE 53774,112
1010 POKE DLIST+3,70:POKE DLIST+6,6:? " bond broker "
1020 POSITION 2,3:? "Name: ";INV1$:POSITION 22,3:? "Name: ";INV2$
1030 POSITION 2,5:? "Load%: ";LD1:POSITION 22,5:? "Load%: ";LD2
1040 POSITION 2,7:? "Rate%: ";RATE1:POSITION 22,7:? "Rate%: ";RATE2
1050 POSITION 2,9:? "Reinvest: ";REIN1$:POSITION 22,9:? "Reinvest: ";REIN2$
1060 POSITION 2,11:? "Load on Div.: ";LDREIN1$:POSITION 22,11:? "Load on Div.: ";LDREIN2$
1070 POSITION 5,15:? "Press <esc> to display tables":POSITION 5,16:? "Use cursor keys or <RETURN> to"
1080 POSITION 5,17:? "change or step through items"
2001 REM NAME 1
2010 POSITION 8,3:? "→←";:GOSUB 100
2020 IF PTR<>1 THEN INV1$=RESPONSE$(1,PTR-1)
2030 ON VECTOR-27 GOTO 6010,3010,2510,2510
2040 GOTO 7010
2501 REM NAME 2
2510 POSITION 28,3:? "→←";:GOSUB 100
2520 IF PTR<>1 THEN INV2$=RESPONSE$(1,PTR-1)
2530 ON VECTOR-27 GOTO 6510,3510,2010,2010
2540 GOTO 7010
3001 REM LOAD PERCENTAGE INVESTMENT 1
3010 POSITION 9,5:? "→←";:GOSUB 100
3020 IF PTR<>1 THEN TRAP 3030:ENTRY=VAL(RESPONSE$(1,PTR-1)):LD1=ENTRY
3030 ON VECTOR-27 GOTO 2010,4010,3510,3510
3040 GOTO 7010
3501 REM Load percentage investment 2
3510 POSITION 29,5:? "→←";:GOSUB 100
3520 IF PTR<>1 THEN TRAP 3530:ENTRY=VAL(RESPONSE$(1,PTR-1)):LD2=ENTRY
3530 ON VECTOR-27 GOTO 2510,4510,3010,3010
3540 GOTO 7010
4001 REM RATE OF RETURN INVESTMENT 1
4010 POSITION 9,7:? "→←";:GOSUB 100
4020 IF PTR<>1 THEN TRAP 4030:ENTRY=VAL(RESPONSE$(1,PTR-1)):RATE1=ENTRY
4030 ON VECTOR-27 GOTO 3010,5010,4510,4510
4040 GOTO 7010
4501 REM RATE OF RETURN INVESTMENT 2
4510 POSITION 29,7:? "→←";:GOSUB 100
4520 IF PTR<>1 THEN TRAP 4530:ENTRY=VAL(RESPONSE$(1,PTR-1)):RATE2=ENTRY
4530 ON VECTOR-27 GOTO 3510,5510,4010,4010
4540 GOTO 7010
5001 REM REINVEST DIVIDENDS? 1
5010 POSITION 12,9:? "→←";:GOSUB 100
5020 IF PTR<>1 THEN REIN1$=RESPONSE$
5030 ON VECTOR-27 GOTO 4010,6010,5510,5510
5040 GOTO 7010
5501 REM REINVEST DIVIDENDS? 2
5510 POSITION 32,9:? "→←";:GOSUB 100
5520 IF PTR<>1 THEN REIN2$=RESPONSE$
5530 ON VECTOR-27 GOTO 4510,6510,5010,5010
5540 GOTO 7010
6001 REM LOAD ON REINVESTED DIV? 1
6010 POSITION 16,11:? "→←";:GOSUB 100
6020 IF PTR<>1 THEN LDREIN1$=RESPONSE$
6030 ON VECTOR-27 GOTO 5010,2510,6510,6510
6040 GOTO 7010
6501 REM LOAD ON REINVESTED DIV? 2
6510 POSITION 36,11:? "→←";:GOSUB 100
6520 IF PTR<>1 THEN LDREIN2$=RESPONSE$
6530 ON VECTOR-27 GOTO 5510,2510,6010,6010
7001 REM SECOND SCREEN
7010 GRAPHICS 0:POKE 710,4:? INV1$:POSITION 22,0:? INV2$:V1=1-(LD1/100):V2=1-(LD2/100)
7020 FOR YEAR=1 TO 20:? YEAR:POSITION 5,YEAR
7025 IF REIN1$<>"Y" AND REIN1$<>"y" THEN V1=V1+RATE1/100:GOTO 7035
7030 V1=V1+V1*(RATE1/100)*(1-LD1*(LDREIN1$="Y" OR LDREIN1$="y")/100)
7035 IF REIN2$<>"Y" AND REIN2$<>"y" THEN V2=V2+RATE2/100:GOTO 7050
7040 V2=V2+V2*(RATE2/100)*(1-LD2*(LDREIN2$="Y" OR LDREIN2$="y")/100)
7050 ? (V1-1)*100:POSITION 22,YEAR:? (V2-1)*100
7060 NEXT YEAR
7070 ? :? " <esc> to return to data entry":POKE 752,1
7080 ? " <*> to end program";
7090 GET #1,X:IF X=27 THEN POKE 752,0:GOTO 1000
7100 IF X=42 THEN GRAPHICS 0:END
7110 GOTO 7090
10000 DIM INV1$(15),INV2$(15),RESPONSE$(15),REIN1$(1),REIN2$(1),LDREIN1$(1),LDREIN2$(1)
10010 CLOSE #1:OPEN #1,12,0,"K:"
10020 REM DEFAULT VALUES
10030 INV1$=" ":INV2$=" "
10040 LD1=0:LD2=0
10050 RATE1=7:RATE2=7
10060 REIN1$="Y":REIN2$="Y"
10070 LDREIN1$="N":LDREIN2$="N"
10999 GOTO 1000:REM START MAIN BODY
