P/M Editor with sample and AUTORUN.SYS, graphics utility (PMED.BAS)

P/M Editor with sample and AUTORUN.SYS, graphics utility by Tom LaRosa, 223

Description

P/M Editor with sample and AUTORUN.SYS, graphics utility by Tom LaRosa, 223

From the Antic disk of September 1988 (Vol. 7 No. 5) — disk A.

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 17.6 KB

Dialect
Atari BASIC
Lines
379
Variables
P(, P$, F$, CF$, P1$, BYTE(, V$, VP$, A$, H(, QB, Q, P1, Z, VP, PK, VIEW, U, MOVE, PMB, EDIT, QQ, EDM, W, I, A, B, O, C, D, M, C1, C2, R, CF, N, T, S, H, G, X, P, PM$, CL$, MEMTOP, PMBASE, ADJTOP, PO
BASIC listing (379 lines)
2 REM P/M EDITOR
4 REM BY TOM LAROSA
5 REM (c)1988, ANTIC PUBLISHING
6 REM DO *NOT* RENUMBER THIS PROGRAM!
7 CLR :GOSUB 30000:GOSUB 8:GOTO 50
8 DIM P(40,20),P$(220),F$(18),CF$(18),P1$(20),BYTE(20),V$(220),VP$(20),A$(18),H(20):QB=1:GOSUB 29500:Q=1
9 P1=ADR(P1$):POKE 709,15:POKE 712,PEEK(710):Z=ADR(P$)-11:VP=ADR(VP$):RETURN
10 REM PMED
50 ? "↰":POKE 752,1:GOSUB 29800
60 GOSUB 4001
61 POKE 1801,3:? "   | P M E D  BY: TOM A. LAROSA |":GOSUB 62:GOTO 64
62 ? "   ├───┬────────────────────────┤":RETURN
64 ? "   | M |  MAKE a Player         |":GOSUB 66:GOTO 68
66 ? "   ├───┼────────────────────────┤":RETURN
68 ? "   | A |  LOAD Animator         |":GOSUB 66
70 ? "   | S |  STORE Players (Disk)  |":GOSUB 66
72 ? "   | L |  LOAD Players          |":GOSUB 74:GOTO 80
74 ? "   └───┴────────────────────────┘":RETURN
80 GOSUB 29000
84 IF PK=37 THEN 1000
85 IF PK=62 THEN 4000
86 IF PK=0 THEN 5000
87 IF PK=63 THEN 8000
100 GOTO 80
400 ON VIEW=1 GOTO 460:POSITION 2,0:? "▶▶←←←───────┬───────┬───┬──────┐":GOSUB 430:U=USR(MOVE,1,PMB,0,0,0)
401 ? "|   I   | P |  E   |":GOSUB 430:? "|INVERSE|PUT| EDIT |":GOSUB 430
403 ? "├───────┴───┼──────┤":GOSUB 430:? "|     B     |  V   |":GOSUB 430
405 ? "| BI-DIRECT | VIEW |":GOSUB 430:? "├───────────┼──────┤":GOSUB 430
407 ? "|     U     |  C   |":GOSUB 430:? "|  UN-VIEW  |CLEAN!|":GOSUB 430
409 ? "├───────────┴──────┤":GOSUB 430:? "|ESC- FOR MAIN MENU|":GOSUB 430
420 ? "├──────────────────┤":GOSUB 430:? "|PLAYER #  -       |":GOSUB 430
422 ? "|REMAINING -       |":GOSUB 430:? "|SAVE MODE -       |":GOSUB 430
424 ? "|                  |":GOSUB 430:? "└──────────────────┘":GOSUB 430:GOTO 440
430 ? "▶▶▶←←←←";:RETURN
440 IF EDIT=0 THEN 450
441 POSITION 31,12:? QQ:GOTO 451
450 POSITION 31,12:? Q
451 POSITION 31,13:? 40-Q
452 IF EDIT=0 THEN POSITION 31,14:? "NORMAL":GOTO 456
453 POSITION 31,14:? "EDITING"
454 IF EDM=1 THEN POSITION 20,15:? "NEW-PLAYER SAVE":POSITION 31,12:? QQ;" = ";Q
455 IF EDM=2 THEN POSITION 20,15:? "REPLACE-SAVE"
456 IF Q>40 THEN POSITION 20,12:? "                  ":POSITION 20,13:? "  OUT OF MEMORY!"
457 IF Q>40 THEN POSITION 20,14:? "                  "
458 RETURN
460 POSITION 2,0:? "▶▶←←←───────┬────────┐":GOSUB 430
461 W=1:FOR I=1 TO 20
462 W=W+11:POSITION 19,I:? V$(W-11,W-1);"←";I:NEXT I
463 POSITION 19,21:? "          ":GOTO 471
464 FOR I=1 TO 9:POSITION 1,I:? I:NEXT I:FOR I=10 TO 20:POSITION 0,I:? I:NEXT I:RETURN
471 POSITION 28,0:? "┬─┬───────┐"
472 POSITION 30,1:? "|PL#-   |"
473 POSITION 30,2:? "|REM-   |"
474 POSITION 30,3:? "|STR-   |"
475 POSITION 30,4:? "|       |"
476 POSITION 30,5:? "├─┬─┬─┬─┤"
477 POSITION 30,6:? "|I|P|E|B|"
478 POSITION 30,7:? "├─┼─┼─┼─┤"
479 POSITION 30,8:? "|C|V|U| |"
480 POSITION 30,9:? "└─┴─┴─┴─┘"
481 IF EDIT=0 THEN 483
482 POSITION 35,1:? QQ:GOTO 484
483 POSITION 35,1:? Q
484 POSITION 35,2:? 40-Q
485 IF EDIT=0 THEN POSITION 31,4:? "NORMAL":GOTO 489
486 POSITION 35,3:? "EDT"
487 IF EDM=1 THEN POSITION 31,4:? "NORMAL "
488 IF EDM=2 THEN POSITION 31,4:? "REPLACE"
489 IF Q>40 THEN POSITION 31,1:? "OUT    ":POSITION 31,2:? "OF    ":POSITION 31,3:? "MEMORY!"
490 IF Q>40 THEN POSITION 31,4:? "      "
491 U=USR(MOVE,1,PMB,VP,114,22,20):GOSUB 29801:RETURN
494 FOR I=1 TO 9:POSITION 1,I:? I:NEXT I:FOR I=10 TO 20:POSITION 0,I:? I:NEXT I:RETURN
499 RETURN
500 IF STICK(0)=15 AND STRIG(0)<>0 THEN RETURN
501 IF STICK(0)=7 AND STRIG(0)<>0 THEN A=A+1:GOSUB 550:RETURN
502 IF STICK(0)=11 AND STRIG(0)<>0 THEN A=A-1:GOSUB 560:RETURN
503 IF STRIG(0)=0 AND STICK(0)=15 THEN POSITION A,B:GOTO 570
504 IF STICK(0)=14 AND STRIG(0)<>0 THEN B=B-1:GOSUB 590:RETURN
505 IF STICK(0)=13 AND STRIG(0)<>0 THEN B=B+1:GOSUB 595:RETURN
506 IF STICK(0)=7 AND STRIG(0)=0 THEN A=A+1:GOSUB 550:GOTO 600
507 IF STICK(0)=11 AND STRIG(0)=0 THEN A=A-1:GOSUB 560:GOTO 600
508 IF STICK(0)=14 AND STRIG(0)=0 THEN B=B-1:GOSUB 590:GOTO 600
509 IF STICK(0)=13 AND STRIG(0)=0 THEN B=B+1:GOSUB 595:GOTO 600
550 IF A>10 THEN A=3:RETURN
560 IF A<3 THEN A=10:RETURN
561 RETURN
570 GOTO 6000
580 GOTO 6000
589 RETURN
590 IF B<1 THEN B=20:RETURN
595 IF B>20 THEN B=1:RETURN
596 RETURN
600 GOTO 6000
607 RETURN
700 IF PEEK(764)=33 THEN 800
701 IF PEEK(764)=7 THEN A=A+1:POKE 764,255:GOTO 550
702 IF PEEK(764)=6 THEN A=A-1:POKE 764,255:GOTO 560
703 IF PEEK(764)=39 THEN POKE 764,255:POSITION A,B:GOTO 570
704 IF PEEK(764)=14 THEN B=B-1:POKE 764,255:GOTO 590
705 IF PEEK(764)=15 THEN B=B+1:POKE 764,255:GOTO 595
706 IF PEEK(764)=135 THEN A=A+1:POKE 764,255:GOSUB 550:GOTO 600
707 IF PEEK(764)=134 THEN A=A-1:POKE 764,255:GOSUB 560:GOTO 600
708 IF PEEK(764)=143 THEN B=B+1:POKE 764,255:GOSUB 595:GOTO 600
709 IF PEEK(764)=142 THEN B=B-1:POKE 764,255:GOSUB 590:GOTO 600
710 IF PEEK(764)=13 THEN GOTO 6600
711 IF PEEK(764)=10 THEN GOSUB 1500
712 IF PEEK(764)=42 THEN GOSUB 1800
713 IF PEEK(764)=28 THEN POP :GOSUB 29002:GOTO 50
714 IF PEEK(764)=21 THEN GOSUB 2000
715 IF PEEK(764)=18 THEN GOSUB 29002:GOSUB 1503
716 IF PEEK(764)=16 THEN GOSUB 29002:GOSUB 7000
717 IF PEEK(764)=11 THEN GOSUB 29002:GOSUB 7040
800 IF PEEK(764)=33 THEN O=O+1:IF O>1 THEN O=0:GOTO 830
830 IF O=0 THEN POSITION 2,21:? "ERASER OFF":POKE 764,255:RETURN
831 IF O=1 THEN POSITION 2,21:? "ERASER ON ":POKE 764,255:RETURN
1000 ? "↰┌──PMED──┬":? P$:? "↑ERASER OFF":A=3:B=1:O=0:GOSUB 400:GOSUB 494
1001 LOCATE A,B,C
1002 IF C=46 THEN POSITION A,B:GOTO 1004
1003 IF C=160 THEN POSITION A,B:GOTO 1006
1004 IF O=0 THEN ? "●":FOR D=1 TO 3:NEXT D:POSITION A,B:? ".":GOTO 1010
1005 ? "*":FOR D=1 TO 3:NEXT D:POSITION A,B:? ".":GOTO 1010
1006 IF O=0 THEN ? "●":FOR D=1 TO 3:NEXT D:POSITION A,B:? " ":GOTO 1010
1007 ? "*":FOR D=1 TO 3:NEXT D:POSITION A,B:? " ":GOTO 1010
1010 IF PEEK(764)<>255 THEN GOSUB 700
1030 GOSUB 500
1040 GOTO 1001
1500 GOSUB 29002:POSITION 2,22:? "PUT PLAYER IN MEMORY (Y/N)":GOSUB 29000
1501 IF PK<>43 THEN POSITION 2,22:? "↑":RETURN
1502 ON EDIT=1 GOTO 1506:ON Q>40 GOTO 1509:FOR I=1 TO 20:P(Q,I)=BYTE(I):NEXT I:Q=Q+1
1503 POSITION 2,22:? "↑":POSITION 2,22:? "CLEAN TABLET (Y/N)":GOSUB 29000
1504 IF PK<>43 THEN POSITION 2,22:? "↑":GOSUB 400:RETURN
1505 GOSUB 29500:POP :GOTO 1000
1506 IF EDM=2 THEN FOR I=1 TO 20:P(QQ,I)=BYTE(I):NEXT I:EDIT=0:GOTO 1508
1507 EDIT=0:FOR I=1 TO 20:P(Q,I)=BYTE(I):NEXT I:Q=Q+1
1508 GOSUB 400:GOTO 1503
1509 POSITION 2,22:? "↰◢ ERROR ◢ OUT OF MEMORY!":RETURN
1800 POKE 764,255:TRAP 1800:GOSUB 29002:POSITION 2,22:? "↑EDIT FROM (1-";Q;")";:INPUT QQ
1801 IF QQ<1 THEN POSITION 2,22:POKE 764,255:? "↑":QQ=Q:RETURN
1802 IF QQ>Q OR QQ>40 THEN POSITION 2,22:? "↑↰NUMBER OUT OF RANGE!":FOR I=1 TO 250:NEXT I:GOTO 1800
1803 POSITION 2,22:? "↑":IF VIEW=1 THEN GOSUB 7500:GOTO 1805
1804 POSITION 13,20:? "◢ 1 ◢ PUT AS NEW PLAYER":POSITION 13,22:? "◢ 2 ◢ REPLACE ORIGINAL"
1805 GOSUB 29000
1806 IF PK=31 THEN EDM=1:ON VIEW=1 GOSUB 7501:GOTO 1809
1807 IF PK=30 THEN EDM=2:ON VIEW=1 GOSUB 7501:GOTO 1809
1808 GOSUB 2006:RETURN
1809 EDIT=1:QB=QQ:ON VIEW=0 GOSUB 2006:GOSUB 7510:GOSUB 29600:POP :GOTO 1000
2000 GOSUB 29002:ON VIEW=1 GOSUB 7502
2001 IF VIEW=0 THEN POSITION 13,20:? "◢ 1 ◢ UP TO DOWN":POSITION 13,22:? "◢ 2 ◢ LEFT TO RIGHT"
2002 GOSUB 29000
2003 IF PK=31 THEN GOSUB 2007:GOTO 2010
2004 IF PK=30 THEN GOTO 2100
2005 ON VIEW=1 GOSUB 7501:ON VIEW=0 GOSUB 2006:RETURN
2006 POSITION 13,20:? "                        ":POSITION 13,22:? "                          ":RETURN
2007 ON VIEW=1 GOSUB 7501:ON VIEW=0 GOSUB 2006:GOSUB 7510:RETURN
2010 M=0:FOR I=20 TO 1 STEP -1:M=M+1:P1$(M,M)=CHR$(BYTE(I)):NEXT I
2020 FOR I=1 TO 20:BYTE(I)=ASC(P1$(I,I)):NEXT I:P1$=""
2021 GOSUB 29601:POP :GOTO 1000
2100 GOSUB 2007
2101 FOR I=1 TO 20:BYTE(I)=0:FOR D=1 TO 4:LOCATE D+2,I,C1:LOCATE 11-D,I,C2:GOSUB 2107:NEXT D:NEXT I
2106 GOSUB 29601:POP :GOTO 1000
2107 IF C1=C2 AND C1=46 THEN RETURN
2109 IF C1=C2 AND C1=160 THEN GOSUB 6149+D:GOSUB 2140:GOSUB 6149+9-D:GOSUB 2140:RETURN
2111 IF C1=46 THEN GOSUB 6149+D:GOSUB 2140:RETURN
2113 IF C1=160 THEN GOSUB 6149+9-D:GOSUB 2140:RETURN
2115 GOTO 8800
2140 BYTE(I)=BYTE(I)+R:RETURN
4000 ? "↰":GOSUB 4001:GOTO 4002
4001 ? "   ┌────────────────────────────┐":RETURN
4002 ? "   | P M E D -STORE PLAYER MENU |":GOSUB 62
4003 ? "   | C |  COMPUTER SAVE ONLY    |":GOSUB 66
4004 ? "   | D |  DATA STATEMENT SAVE   |":GOSUB 66
4005 ? "   | P |  PRE-CONFIGURED STRINGS|":GOSUB 66:GOSUB 4006:GOTO 4007
4006 ? "   |ESC| TO RETURN TO MAIN MENU |":RETURN
4007 GOSUB 74:GOSUB 29000
4008 IF PK=58 THEN GOSUB 4020:GOSUB 4100:GOSUB 4500:GOTO 50
4009 IF PK=18 THEN GOSUB 4020:GOSUB 4500:GOTO 50
4010 IF PK=10 THEN GOSUB 4020:GOSUB 4300:GOTO 50
4011 IF PK=28 THEN 50
4013 GOTO 4007
4020 ? "↓↓↑↑↑DO NOT USE DRIVE NUMBER OR EXTENDERS"
4021 ? "WHAT FILENAME";:INPUT F$
4022 IF F$="" THEN 4000
4023 CF$="D:":CF$(3)=F$:CF=LEN(CF$)+1
4024 TRAP 4800
4025 CLOSE #1:OPEN #1,4,0,CF$
4026 ? "↰FILE EXISTS- 'Y' TO REPLACE";:INPUT A$:IF A$<>"Y" THEN GOTO 4000
4030 RETURN
4100 CLOSE #1:LIST CF$,29999,30200
4110 OPEN #1,9,0,CF$
4112 ? #1;"10 GOSUB 30000:DIM P$(";Q*20;"),P(";Q;")"
4114 ? #1;"20 RESTORE:FOR I=1 TO ";Q*20;":READ A:P$(LEN(P$)+1)=CHR$(A):NEXT I"
4115 ? #1;"30 P(1)=ADR(P$):FOR I=1 TO ";Q-1;":P(I+1)=P(1)+I*20:NEXT I"
4116 FOR I=1 TO Q
4118 ? #1;I+3*10;" DATA";
4120 FOR D=1 TO 19
4121 ? #1;P(I,D);",";
4122 NEXT D:? #1;P(I,20):NEXT I
4123 CLOSE #1:RETURN
4300 CLOSE #1:LIST CF$,29999,30200:CLOSE #1
4301 OPEN #1,9,0,CF$
4302 ? #1;"10 GOSUB 30000:DIM P$(";Q*20;"),P(";Q;"),H$(20):TOTAL=";Q:CF=LEN(CF$)+1
4303 F$=".STR":CF$(LEN(CF$)+1)=F$:? #1;" 20 CLOSE #1:OPEN #1,4,0,";CHR$(34);CF$;CHR$(34)
4304 ? #1;"30 INPUT #1,TOTAL":? #1;"40 FOR I=1 TO TOTAL":? #1;"50 INPUT #1;H$:P$(LEN(P$)+1)=H$:NEXT I"
4307 ? #1;"60 P(1)=ADR(P$):FOR I=1 TO TOTAL-1:P(I+1)=ADR(P$)+(I*20):NEXT I"
4310 CLOSE #1
4320 OPEN #1,8,0,CF$
4330 ? #1,Q
4340 FOR I=1 TO Q
4350 FOR D=1 TO 20
4351 ? #1;CHR$(P(I,D));:NEXT D:? #1:NEXT I
4500 F$=".PMG":CF$(CF)=F$
4501 CLOSE #1:OPEN #1,8,0,CF$
4502 ? #1,Q:FOR I=1 TO Q:FOR D=1 TO 20:? #1,P(I,D):NEXT D:NEXT I:CLOSE #1:RETURN
4800 IF PEEK(195)=170 THEN GOTO 4030
4999 GOTO 8800
5000 ? "↰"
5001 GOSUB 4001:GOTO 5002
5002 ? "   | P M E D -LOAD PLAYERS MENU |":GOSUB 62
5003 ? "   | A |  APPEND (2 FILE LOAD)  |":GOSUB 66
5004 ? "   | D |  DIRECTORY .PMG FILES  |":GOSUB 66
5005 ? "   | L |  LOAD SINGLE FILE      |":GOSUB 66
5006 GOSUB 4006:GOSUB 74
5007 GOSUB 29000
5008 IF PK=58 THEN GOSUB 5020
5009 IF PK=28 THEN GOTO 50
5010 IF PK=0 THEN GOTO 5099
5011 IF PK=63 THEN GOTO 5300
5015 GOTO 5007
5020 TRAP 5050:POKE 82,2:POKE 83,37
5021 ? "↰"
5022 CLOSE #1:OPEN #1,7,0,"D:*.PMG"
5023 INPUT #1,F$
5024 IF F$(5,9)="FREE " THEN 5029
5025 ? F$(3,13);"|";
5026 GOTO 5023
5029 ? :? "         ";F$
5050 POSITION 3,22:? "[ PRESS ANY KEY ]";:GOSUB 29000:POKE 82,2:POKE 83,39:GOTO 5000
5099 GOSUB 5100:GOTO 5101
5100 GOSUB 5200:? "↓↓↑↑↑DO NOT USE DRIVE NUMBER OR EXTENDERS":RETURN
5101 ? "WHAT FILE TO LOAD";:INPUT F$
5102 IF F$="" THEN GOTO 5000
5103 TRAP 5800
5104 CF$="D:":CF$(3)=F$:F$=".PMG":CF$(LEN(CF$)+1)=F$
5105 CLOSE #1:OPEN #1,4,0,CF$
5106 TRAP 5110:INPUT #1,Q:FOR I=1 TO Q:FOR D=1 TO 20:INPUT #1,N:P(I,D)=N:NEXT D:NEXT I
5110 ? "◢ LOAD COMPLETE ◢":? "PUTTING LAST PLAYER IN BYTE REGISTER..":FOR T=1 TO 20:BYTE(T)=P(Q-1,T):NEXT T
5111 GOSUB 29601:EDIT=0:EDM=0:VIEW=0:GOTO 50
5200 IF Q>1 THEN GOTO 5210
5201 FOR I=1 TO 20:IF BYTE(I)>0 THEN GOTO 5210:NEXT I
5203 RETURN
5210 ? "↰ERASE PLAYERS IN MEMORY (Y/N)":GOSUB 29000:IF PK<>43 THEN POP :GOTO 50
5211 RETURN
5300 GOSUB 5100
5301 ? "FIRST FILE NAME";:INPUT F$:IF F$="" THEN GOTO 5000:TRAP 5800
5302 CF$="D:":CF$(3)=F$:F$=".PMG":CF$(LEN(CF$)+1)=F$
5303 CLOSE #1:OPEN #1,4,0,CF$
5304 INPUT #1,N:N=N-1
5305 ? "SECOND FILENAME";:INPUT F$:IF F$="" THEN GOTO 5000:TRAP 5800
5306 A$="D:":A$(3)=F$:F$=".PMG":A$(LEN(A$)+1)=F$
5307 CLOSE #2:OPEN #2,4,0,A$
5308 INPUT #2,S:S=S-1:Q=0:Q=Q+S+N
5309 IF Q>40 THEN ? "↰◢ ERROR ◢ -BUFFER OVERFLOW!":? "TO MANY PLAYERS TO HANDLE.":GOTO 5700
5310 FOR I=1 TO N:FOR D=1 TO 20:INPUT #1,H:P(I,D)=H:NEXT D:NEXT I
5311 FOR I=N+1 TO Q:FOR D=1 TO 20:INPUT #2,H:P(I,D)=H:NEXT D:NEXT I
5312 CLOSE #1:CLOSE #2:Q=Q+1:GOTO 5110
5700 FOR I=1 TO 250:NEXT I:GOTO 5000
5800 IF PEEK(195)=170 THEN ? "↰◢ ERROR ◢-FILE NOT FOUND!":FOR I=1 TO 250:NEXT I:GOTO 5000
5801 GOTO 50
6000 POSITION A,B:LOCATE A,B,C
6001 IF C=ASC(".") AND O=1 THEN 607
6002 IF C=ASC(" ") AND O=0 THEN GOTO 607
6003 IF O=0 THEN POSITION A,B:? " ":GOTO 6100
6004 IF O=1 THEN POSITION A,B:? ".":GOTO 6200
6100 GOSUB 6147+A
6101 BYTE(B)=BYTE(B)+R:P1$(B)=CHR$(BYTE(B)):GOTO 6300
6150 R=128:RETURN
6151 R=64:RETURN
6152 R=32:RETURN
6153 R=16:RETURN
6154 R=8:RETURN
6155 R=4:RETURN
6156 R=2:RETURN
6157 R=1:RETURN
6200 GOSUB 6147+A
6201 BYTE(B)=BYTE(B)-R:P1$(B)=CHR$(BYTE(B)):GOTO 6300
6300 LOCATE A,B,C:POKE B*11+Z+A-2,C:U=USR(MOVE,0,PMB,P1,98,22,20):RETURN
6600 GOTO 6638
6601 FOR I=1 TO 220:GOSUB 6620
6602 NEXT I:GOTO 6630
6620 IF P$(I,I)="|" THEN RETURN
6621 IF P$(I,I)="." THEN P$(I,I)=" ":RETURN
6622 IF P$(I,I)=" " THEN P$(I,I)=".":RETURN
6623 RETURN
6630 ? "↰":? P$:? "STILL PROCESING...";
6631 FOR I=1 TO 20:BYTE(I)=0:POSITION 20,10:? "TIME LEFT-  ←←";20-I
6632 FOR D=1 TO 8:A=D+2
6633 B=I:LOCATE A,B,C
6634 IF C=ASC(" ") THEN GOSUB 6147+A:BYTE(B)=BYTE(B)+R
6635 NEXT D:P1$(I)=CHR$(BYTE(I)):NEXT I
6636 POKE 764,255:GOTO 1000
6638 GOSUB 29002:POSITION 2,22:? "INVERSE PLAYER (Y/N)";
6639 GOSUB 29000
6640 IF PK<>43 THEN POSITION 2,22:? "↑":RETURN
6641 GOSUB 7510:GOTO 6601
7000 TRAP 1000:POSITION 2,22:? "WHICH PLAYER TO VIEW (1-";Q-1;")";:INPUT G
7001 IF G<1 THEN POSITION 2,22:? "↑":RETURN
7002 IF G>Q-1 THEN POSITION 2,22:? "↰↑NUMBER OUT OF RANGE!";:FOR I=1 TO 250:NEXT I:GOTO 2044
7003 POP :GOSUB 7510:GOSUB 29700:GOTO 1000
7040 IF VIEW=0 THEN 7050
7041 POSITION 2,22:? "PUT UP MENU (Y/N)";:GOSUB 29000
7042 IF PK<>43 THEN POSITION 2,22:? "↑":RETURN
7043 VIEW=0:POP :GOTO 1000
7044 POSITION 2,22:? "↑":RETURN
7050 POSITION 2,22:? "↰VIEW NOT IN PROGRESS!":FOR I=1 TO 250:NEXT I:POSITION 2,22:? "↑":RETURN
7500 POSITION 2,22:? "◢ 1 ◢ PUT AS NEW PLAYER":POSITION 2,23:? "◢ 2 ◢ OVERLAP ORIGONAL";:RETURN
7501 POSITION 2,22:? "↑↑↑";:RETURN
7502 POSITION 2,22:? "◢ 1 ◢ UP TO DOWN":POSITION 2,23:? "◢ 2 ◢ LEFT TO RIGHT";:RETURN
7510 POSITION 2,22:? "↑↑":POSITION 0,22:? "◣ PROCESING ◢":RETURN
8000 FOR I=1 TO 3:GOSUB 29002:NEXT I
8001 POSITION 2,16:? "LOAD IN ANIMATOR FILE. (Y/N)"
8002 GOSUB 29000
8003 IF PK<>43 THEN GOTO 50
8004 ? "↰"
8005 POSITION 2,14:? "INSERT PMED DISKETTE AND PRESS RETURN"
8006 GOSUB 29000
8007 IF PK<>12 THEN GOTO 50
8008 CLOSE #1
8009 TRAP 8800:OPEN #1,8,0,"D:TEMP.ANM"
8010 GOSUB 4502
8011 CLOSE #1
8012 TRAP 8013:RUN "D:PMED.ANM"
8013 TRAP 8014:XIO 33,#1,0,0,"D:TEMP.ANM"
8014 ? "↰◢ ERROR ◢ -ANIMATER NOT FOUND!":FOR I=1 TO 250:NEXT I:GOTO 50
8800 POP :POP :? "↰INTERNAL ◢ ERROR ◢ #";PEEK(195):FOR I=1 TO 250:NEXT I:GOTO 50
28999 END
29000 POKE 764,255
29001 IF PEEK(764)=255 THEN 29001
29002 PK=PEEK(764):POKE 764,255:SOUND 0,70,10,10:FOR I=1 TO 5:NEXT I:SOUND 0,0,0,0:RETURN
29500 VIEW=0:V$="":P$="":FOR I=1 TO 20:P$(LEN(P$)+1)="|........|":V$(LEN(V$)+1)="|........| "
29501 P$(LEN(P$)+1)=CHR$(155):BYTE(I)=0:NEXT I:P1$="♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥":U=USR(MOVE,0,PMB,P1,0,0,0)
29502 U=USR(MOVE,1,PMB,VP,0,0,0):RETURN
29600 FOR T=1 TO 20:BYTE(T)=P(QB,T):NEXT T:P$=""
29601 W=1:FOR T=1 TO 20:P1$(T,T)=CHR$(BYTE(T)):X=BYTE(T):D=X:P=128
29602 FOR I=1 TO 8
29603 IF I=1 THEN P$(W,W)="|":W=W+1
29604 IF INT(D/P)=1 THEN P$(W,W)=" ":D=D-P:W=W+1:GOTO 29606
29605 P$(W,W)=".":W=W+1
29606 P=P/2:NEXT I
29607 P$(W,W)="|":W=W+1:P$(W,W)=CHR$(155):W=W+1:NEXT T
29608 RETURN
29700 FOR T=1 TO 20:H(T)=P(G,T):NEXT T:VP$="":VIEW=1
29701 W=1:FOR T=1 TO 20:VP$(T,T)=CHR$(H(T)):X=H(T):D=X:P=128
29702 FOR I=1 TO 8
29703 IF I=1 THEN W=W+1
29704 IF INT(D/P)=1 THEN V$(W,W)=" ":D=D-P:W=W+1:GOTO 29606
29705 V$(W,W)=".":W=W+1
29706 P=P/2:NEXT I
29707 W=W+2:NEXT T
29708 U=USR(MOVE,1,PMB,VP,114,22,20):RETURN
29800 U=USR(MOVE,0,PMB,P1,0,0,0):U=USR(MOVE,1,PMB,VP,0,0,0):RETURN
29801 TRAP 29802:U=USR(MOVE,0,PMB,P1,0,0,0):RETURN
29802 GOTO 8800
30000 DIM PM$(100),CL$(255)
30001 PM$(1,50)="Xhhh┐Uh┴i▕┐Nh┐Mh┐Lh┐Khh┐Phh┐Qhh┴eQ┐O&Up♣%M┴i♥┐M%Ni"
30002 PM$(51,100)="♥┐NJPp ♥"♥DQ♣┼DO0▖┤T◣(1K$T┌Mh)♥p┤)♥┌MH@♥P◆&U%P↓♥P◆":MOVE=ADR(PM$):GRAPHICS 0
30003 CL$="♥":CL$(2)="♥":CL$(255)=CL$(2)
30004 MEMTOP=PEEK(741)+256*PEEK(742)-1:PMBASE=INT((MEMTOP-1024)/1024)*1024
30005 ADJTOP=PMBASE+384:POKE 742,INT(ADJTOP/256):POKE 741,ADJTOP-256*PEEK(742):POKE 559,46
30006 POKE 764,255:POKE 54279,124:PMB=124*256:POKE 53277,2:POKE 53256,0:POKE 53257,0
30007 PO=PMBASE+512:FOR A=PO TO PO+128:POKE A,0:NEXT A:POKE 710,0:POKE 709,15
30008 REM JNK=USR(MOVE,0,PMB,P(W),0,0,20)
30200 POKE 752,1:POKE 704,127:POKE 705,77:REM RETURN
30201 TRAP 30202:OPEN #1,4,0,"D:TEMP.ANM":GOTO 30203
30202 CLOSE #1:RETURN
30203 ? "PLAYERS BEING RE-LOADED":GOSUB 8
30306 TRAP 30310:INPUT #1,Q:FOR I=1 TO Q:FOR D=1 TO 20:INPUT #1,N:P(I,D)=N:NEXT D:NEXT I
30307 TRAP 30310:XIO 33,#1,0,0,"D:TEMP.ANM"
30310 ? "◢ RE-LOAD COMPLETE ◢":FOR T=1 TO 20:BYTE(T)=P(Q-1,T):NEXT T
30311 GOSUB 29601:EDIT=0:EDM=0:VIEW=0:GOTO 50