Colorvision (COLORVIS.BAS)

Colorvision, game by Erik Timmerman, 34

Description

Colorvision, game by Erik Timmerman, 34

From the Antic disk of September 1988 (Vol. 7 No. 5) — disk A.

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 3.8 KB

Dialect
Atari BASIC
Lines
132
Variables
N$, EXIT, DELAY, SCR, W, X, Y, Z, A, B, C, D, E, N, COLREG, POS, LUM, ANS, LOOP, COL
BASIC listing (132 lines)
10 REM COLORVISION
20 REM BY ERIK TIMMERMAN
30 REM (c)1988, ANTIC PUBLISHING
99 DIM N$(12)
100 GOSUB 1000:REM TITLE PAGE
300 GOSUB 3000:REM INITIALIZE
400 GOSUB 4000:REM PLAY GAME
500 GOSUB 5000:REM RESULTS
550 IF EXIT=0 THEN 300
599 GRAPHICS 0
600 END
1000 GRAPHICS 2
1010 POKE 710,0
1020 POSITION 4,5
1030 ? #6;"ColOrvIsioN"
1040 POKE 755,0
1050 ? "         by Erik Timmerman"
1060 ? "     (c)1988, Antic Publishing"
1070 FOR DELAY=1 TO 1700
1080 NEXT DELAY
1999 RETURN
3000 GRAPHICS 23
3010 SCR=PEEK(559):EXIT=-1
3015 POKE 559,0:TRAP 3390
3020 W=2*INT(RND(2)*127):IF W=0 THEN 3020
3040 X=2*INT(RND(3)*127):IF X=0 THEN 3040
3060 IF X=W THEN GOTO 3040
3070 Y=2*INT(RND(4)*127):IF Y=0 THEN 3070
3090 IF Y=W OR Y=X THEN 3070
3110 Z=2*INT(RND(5)*127):IF Z=0 OR Z=W OR Z=X OR Z=Y THEN 3110
3160 POKE 708,X:POKE 709,Y:POKE 710,Z
3190 REM DRAW RECTANGLES
3200 FOR A=1 TO 3:B=20*A:C=160-20*A:D=95-10*A:E=10*A
3210 GOSUB 6000:NEXT A
3380 POKE 712,W:POKE 559,SCR
3390 RETURN
4000 N=Z:COLREG=710:GOSUB 7000
4030 N=Y:COLREG=709:GOSUB 7000
4060 N=X:COLREG=708:GOSUB 7000
4999 RETURN
5000 X=PEEK(708):Y=PEEK(709)
5020 Z=PEEK(710)
5040 IF X<>Y THEN 5500
5050 IF X<>Z THEN 5500
5060 IF X<>W THEN 5500
5070 IF Y<>Z THEN 5500
5080 IF Y<>W THEN 5500
5090 IF Z<>W THEN 5500
5110 A=W
5140 GOSUB 8000
5150 GRAPHICS 18
5170 POSITION 2,5
5180 ? #6;"COngRaTuLatIOnS!"
5181 FOR DELAY=0 TO 400:NEXT DELAY
5185 ? #6;"↰"
5190 POSITION 6,5
5200 ? #6;"yoU WiN!"
5210 FOR DELAY=0 TO 400:NEXT DELAY
5230 ? #6;"↰":POSITION 7,3
5260 ? #6;"CoLOr:"
5262 LET POS=LEN(N$)
5265 POSITION INT((20-POS)/2),4
5266 ? #6;N$:POSITION 5,6
5280 ? #6;"lUmInANCe:"
5290 POSITION 9,7:? #6;LUM
5301 FOR DELAY=0 TO 500:NEXT DELAY
5310 ? #6;"↰":POSITION 2,5
5320 ? #6;"plAy AgAIn? (y/N)"
5325 CLOSE #2:OPEN #2,4,0,"K:"
5330 GET #2,ANS:CLOSE #2
5350 IF ANS=89 THEN EXIT=0
5499 RETURN
5500 GRAPHICS 0:POKE 710,194
5510 POKE 709,206:POKE 755,0
5530 POSITION 10,1
5540 ? "HOW WELL YOU DID":?
5560 ? "Small Rectangle:.....Luminance:":A=Z
5590 GOSUB 8000
5610 ? N$;:POSITION 33,4:? LUM
5630 ? :? :? "Middle Rectangle: ...Luminance:"
5640 A=Y
5650 GOSUB 8000
5660 ? N$;:POSITION 33,8:? LUM
5670 ? :?
5680 ? :? :? "Large Rectangle:     Luminance:"
5690 A=X
5700 GOSUB 8000
5710 ? N$;:POSITION 33,12:? LUM:? :?
5720 ? "Background:          Luminance:"
5730 A=W
5740 GOSUB 8000
5750 ? N$;:POSITION 33,16:? LUM
5770 ? :? :? :? "Do you want to play again?   (Y/N)"
5780 CLOSE #2:OPEN #2,4,0,"K:":GET #2,ANS:CLOSE #2
5810 IF ANS=89 THEN EXIT=0
5999 RETURN
6000 COLOR A:FOR LOOP=B TO C
6010 PLOT LOOP,E:DRAWTO LOOP,D
6020 SOUND 0,LOOP,14,14
6030 NEXT LOOP:SOUND 0,0,0,0:RETURN
7000 IF STICK(0)=11 THEN N=N-16
7010 IF STICK(0)=13 THEN N=N-2
7020 IF N<0 THEN N=N+256
7030 IF STICK(0)=7 THEN N=N+16
7040 IF STICK(0)=14 THEN N=N+2
7050 IF N>255 THEN N=N-256
7060 FOR DELAY=0 TO 20
7070 NEXT DELAY:REM SLOW-DOWN STICK
7080 POKE COLREG,N
7090 IF STRIG(0)=0 THEN 7997
7100 GOTO 7000
7997 FOR DELAY=0 TO 100:NEXT DELAY
7999 RETURN
8000 COL=INT(A/16)
8010 LUM=A-(COL*16)
8020 IF COL=0 THEN N$="Gray"
8030 IF COL=1 THEN N$="Gold"
8040 IF COL=2 THEN N$="Orange"
8050 IF COL=3 THEN N$="Red"
8060 IF COL=4 THEN N$="Pink"
8070 IF COL=5 THEN N$="Violet"
8100 IF COL=6 THEN N$="Blue-Purple"
8110 IF COL=7 THEN N$="Blue"
8120 IF COL=8 THEN N$="Light Blue"
8130 IF COL=9 THEN N$="Blue-Green"
8140 IF COL=10 THEN N$="Aqua"
8150 IF COL=11 THEN N$="Green-Blue"
8160 IF COL=12 THEN N$="Green"
8170 IF COL=13 THEN N$="Yellow-Green"
8180 IF COL=14 THEN N$="Orange-Green"
8190 IF COL=15 THEN N$="Orange II"
8999 RETURN