Class Scheduler (CLASSMAK.BAS)

Class Scheduler by Glenn K. Smith and Charles Jackson, 66

Description

Class Scheduler by Glenn K. Smith and Charles Jackson, 66

From the Antic disk of September 1988 (Vol. 7 No. 5) — disk A.

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.6 KB

Dialect
Atari BASIC
Lines
65
Variables
CLASS$, BUFFR$, ST$, EN$, DAY$, CR$, TEMP$, FILE$, NUMCLASS, X, SCTNS, SNUM, BUFPTR, THEDAY, STAT, QT, XD, LB, V, COUNTER
BASIC listing (65 lines)
10 REM CLASS SCHEDULER, LISTING 2
20 REM BY CHARLES JACKSON
30 REM (c)1988, ANTIC PUBLISHING
40 DIM CLASS$(5),BUFFR$(600),ST$(5),EN$(5),DAY$(9),CR$(1),TEMP$(20),FILE$(20)
50 GRAPHICS 0:? :POKE 710,160
60 ? "    ┌───────────────────────┐"
70 ? "    |   Create Data Files   |"
80 ? "    |  for CLASS SCHEDULER  |"
90 ? "    |  (by Charles Jackson) |"
100 ? "    └───────────────────────┘"
110 POSITION 2,10
120 ? "↑↓Class file to create";
130 ? ":";:TRAP 110
140 INPUT TEMP$:?
150 IF LEN(TEMP$)=0 THEN 110
155 FILE$="D1:":IF LEN(TEMP$)<3 THEN FILE$(4,20)=TEMP$:GOTO 180
160 FILE$="D1:":IF TEMP$(2,2)<>":" AND TEMP$(3,3)<>":" THEN FILE$(4,20)=TEMP$:GOTO 180
170 FILE$=TEMP$
180 DATA MONDAY,TUESDAY,WEDNESDAY,THURSDAY,FRIDAY
190 NUMCLASS=0:CR$=CHR$(155)
200 CLOSE #1:OPEN #1,8,0,FILE$
210 ? #1;"XXX"
220 NUMCLASS=NUMCLASS+1
230 BUFFR$="     "
240 ? "↰↓↓↓↓[RETURN] to End.":? "↑↑↑Name of Class #";NUMCLASS;:INPUT CLASS$:IF CLASS$="" THEN 540
250 BUFFR$=CLASS$:BUFFR$(LEN(BUFFR$)+1)=CR$:X=1
260 ? :? "How many sections are available for":? CLASS$;:INPUT SCTNS:IF SCTNS<1 THEN ? "↑↑↑↑↑↑";:GOTO 260
270 BUFFR$(LEN(BUFFR$)+1)=STR$(SCTNS):BUFFR$(LEN(BUFFR$)+1)=CR$
280 FOR SNUM=1 TO SCTNS
290 BUFPTR=LEN(BUFFR$)+1:RESTORE :FOR THEDAY=1 TO 5:READ DAY$
300 ? "↰↓↓ When does Section ";SNUM;" of ";CLASS$:? " meet on ";DAY$;"?":?
310 ? "   (Type the time as hh:mm)"
320 POSITION 2,20:? "(Just press [RETURN] if class doesn't  meet on ";DAY$;")";
330 POSITION 3,10:? "Starting Time ";
340 INPUT ST$
350 IF ST$="" THEN ST$="0":EN$="0":GOTO 390
360 STAT=0:FOR QT=1 TO LEN(ST$):STAT=STAT+(ST$(QT,QT)=":"):NEXT QT:IF STAT=0 THEN ? "↰":GOTO 300
370 ? :? "   Ending Time ";:INPUT EN$
380 STAT=0:FOR QT=1 TO LEN(EN$):STAT=STAT+(EN$(QT,QT)=":"):NEXT QT:IF STAT=0 THEN ? "↰":GOTO 300
390 BUFFR$(LEN(BUFFR$)+1)=ST$:BUFFR$(LEN(BUFFR$)+1)=" "
400 BUFFR$(LEN(BUFFR$)+1)=EN$:BUFFR$(LEN(BUFFR$)+1)=" "
410 NEXT THEDAY
420 ? "↰      Verification":?
430 ? CLASS$:? " Section ";SNUM:?
440 RESTORE :FOR XD=1 TO 5:READ DAY$
450 GOSUB 600:ST$=TEMP$:GOSUB 600:EN$=TEMP$
460 IF ST$="0" THEN 480
470 ? DAY$;"▶";ST$;" => ";EN$
480 NEXT XD
490 ? :? "Is this OK (Y/N) ";:INPUT TEMP$
500 IF TEMP$<>"Y" THEN 230
510 LB=LEN(BUFFR$):IF BUFFR$(LB,LB)=" " THEN BUFFR$=BUFFR$(1,LB-1):GOTO 510
520 ? #1;BUFFR$:BUFFR$="":NEXT SNUM
530 GOTO 220
540 ? "↰":POSITION 7,12:? "* Writing ";FILE$;" *"
550 CLOSE #1:OPEN #1,12,0,FILE$
560 V=LEN(STR$(NUMCLASS-1)):TEMP$="   ":TEMP$(4-V,3)=STR$(NUMCLASS-1)
570 ? #1;TEMP$
580 CLOSE #1:GRAPHICS 0
590 END
600 FOR COUNTER=BUFPTR TO LEN(BUFFR$)
610 IF BUFFR$(COUNTER,COUNTER)<>" " THEN 630
620 TEMP$=BUFFR$(BUFPTR,COUNTER-1):BUFPTR=COUNTER+1:POP :GOTO 640
630 NEXT COUNTER
640 RETURN