Class Scheduler (CLASS.BAS)

Class Scheduler by Glenn K. Smith and Charles Jackson, 66

Description

Class Scheduler by Glenn K. Smith and Charles Jackson, 66

From the Antic disk of September 1988 (Vol. 7 No. 5) — disk A.

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 5.5 KB

Dialect
Atari BASIC
Lines
159
Variables
BRK, CN$, ST(, ET(, CS(, NAME$, TEMP$, FILE$, NS(, I, J, SC, NC, NUM, K, L, X, Y, X1, Y1, CF, OK, S1, S2, E1, E2, ED, TME, TOGGLE, TM, V, SCR, AD, Z, BYT
BASIC listing (159 lines)
10 REM CLASS SCHEDULER
20 REM BY GLENN K. SMITH
30 REM (c)1988, ANTIC PUBLISHING
110 DATA Mon,Tue,Wed,Thu,Fri
120 DATA 6,13,20,27,34
240 GRAPHICS 0:POKE 559,0:GOSUB 2240
250 BRK=USR(1536,BRK):REM DISABLE
260 DIM CN$(40),ST(8,40),ET(8,40),CS(8)
270 DIM NAME$(5),TEMP$(40),FILE$(20),NS(8)
280 ? "    ┌────────────────────────── ┐"
290 ? "    |      Class Scheduler      |"
300 ? "    |     By Glenn K. Smith     |"
310 ? "    | (c)1988, Antic Publishing |"
320 ? "    ├────────────────────────── ┤"
330 ? "    |   Press START to copy     |"
340 ? "    |a schedule to your printer |"
350 ? "    └────────────────────────── ┘"
370 REM INIT ARRAYS
390 CN$(1)="♥":CN$(40)=CN$:CN$(2)=CN$
430 FOR I=0 TO 8:NS(I)=0:CS(I)=0
470 FOR J=0 TO 40:ST(I,J)=0:ET(I,J)=0
480 NEXT J:NEXT I
500 SC=0:POKE 710,160:POKE 714,160:POKE 559,34
520 REM GET FILENAME
540 POKE 752,1
550 POSITION 2,10:? "↑↓Class data file ";
560 POKE 752,0:? ":";:TRAP 540
570 INPUT TEMP$:POKE 752,1:?
590 IF LEN(TEMP$)=0 THEN 540
595 FILE$="D1:":IF LEN(TEMP$)<3 THEN FILE$(4,20)=TEMP$:GOTO 620
600 IF TEMP$(2,2)<>":" AND TEMP$(3,3)<>":" THEN FILE$(4,20)=TEMP$:GOTO 620
610 FILE$=TEMP$
620 CLOSE #1:OPEN #1,4,0,FILE$
640 REM GET DATA FROM THE FILE
650 REM IF THERE IS AN ERROR
660 REM THEN CLOSE THE FILE
670 REM AND REPORT THE ERROR
690 TRAP 1470:POKE 559,0
700 INPUT #1;NC
710 FOR I=0 TO NC-1
720 INPUT #1;NAME$
730 IF LEN(NAME$)=0 THEN 720
740 CN$((I*5)+1,((I+1)*5))=NAME$
750 INPUT #1;NUM:NS(I)=NUM
770 FOR J=0 TO NS(I)-1
780 FOR K=0 TO 4:FOR L=0 TO 1
800 TEMP$=""
810 GET #1,X
820 IF X=32 OR X=155 THEN 810
830 TEMP$(1,1)=CHR$(X):GET #1,Y
850 IF Y<48 OR Y>57 THEN 880
860 TEMP$(2,2)=CHR$(Y):GET #1,Y
880 X=VAL(TEMP$)
890 IF Y<>58 THEN Y=0:GOTO 930
900 GET #1,X1:GET #1,Y1
910 TEMP$(1,1)=CHR$(X1):TEMP$(2,2)=CHR$(Y1)
920 Y=VAL(TEMP$)
930 IF X<7 AND X>0 THEN X=X+12
940 X=X*100+Y
950 IF L=0 THEN ST(I,(J*5)+K)=X
960 IF L=1 THEN ET(I,(J*5)+K)=X
970 NEXT L:NEXT K:NEXT J:NEXT I
1010 CLOSE #1
1030 REM MAIN ROUTINE.  SEARCH DATA,
1050 REM KILL CONFLICTS & FIND
1060 REM VALID ENTRIES
1080 CF=0:OK=0
1090 FOR I=0 TO NC-2
1100 FOR J=I+1 TO NC-1
1110 FOR K=0 TO 4
1120 S1=ST(I,(CS(I)*5)+K)
1130 S2=ST(J,(CS(J)*5)+K)
1140 E1=ET(I,(CS(I)*5)+K)
1150 E2=ET(J,(CS(J)*5)+K)
1160 IF (S1>=S2 AND S1<E2) OR (E1>S2 AND E1<=E2) THEN IF S1<>0 AND S2<>0 THEN CF=1
1170 NEXT K:NEXT J:NEXT I
1200 IF CF=0 THEN GOSUB 1520:GOSUB 1370:SC=1
1220 REM INC. SEC #S
1240 FOR I=0 TO NC-1:CS(I)=CS(I)+1
1260 IF CS(I)=NS(I) THEN CS(I)=0:GOTO 1280
1270 I=1000:REM EXIT LOOP
1280 NEXT I
1290 IF I=1001 THEN 1080
1300 IF SC=0 THEN ? "↰":POSITION 3,12:? "Not possible to schedule classes!";
1310 POSITION 2,23:IF SC=1 THEN ? "Unable to figure anymore schedules!";
1320 ED=1:GOSUB 1380
1330 GRAPHICS 0:GOTO 1490
1350 REM WAIT FOR KEYPRESS
1370 POSITION 8,23:? "Press any key to continue";:OK=1
1380 POKE 53279,8:POKE 764,255:POKE 559,34
1390 IF PEEK(764)=255 AND PEEK(53279)<>6 THEN 1390
1400 IF OK AND ED=0 AND PEEK(53279)=6 THEN GOSUB 2040:GOTO 1380
1410 IF PEEK(53279)=6 AND ED=0 THEN 1380
1420 POKE 764,255:POKE 559,0:RETURN
1440 REM ERROR TRAPPING AND END
1470 GRAPHICS 0:POSITION 2,2
1480 ? "Error #";PEEK(195);" in line #";PEEK(186)+256*PEEK(187)
1490 BRK=USR(1536,BRK):REM ENABLE
1500 TRAP 65535:POKE 764,255:? :END
1520 REM DRAW THE SCREEN
1540 POKE 752,1:? "↰":FOR I=1 TO 22
1570 POSITION 4,I:? "|";
1590 POSITION 39,I:? "|";:NEXT I
1610 FOR I=0 TO 39
1630 POSITION I,0:? " ";
1650 POSITION I,22:? "─";:NEXT I
1680 POSITION 4,22:? "┴";
1700 POSITION 39,22:? "┘";
1710 TME=700:TOGGLE=1
1720 FOR I=1 TO 21:POSITION 0,I
1740 IF TME<1000 THEN ? " ";
1750 ? TME;
1760 TOGGLE=(TOGGLE<>1)
1770 TME=TME+(TOGGLE*40)+30
1780 TME=TME-((TME=1300)*1200)
1790 NEXT I
1800 RESTORE 110
1810 FOR I=1 TO 5:READ TEMP$
1840 POSITION 7*I,0:? TEMP$;:NEXT I
1860 FOR I=0 TO NC-1:RESTORE 120
1880 FOR J=0 TO 4:READ X
1900 S1=ST(I,(CS(I)*5)+J):E1=ET(I,(CS(I)*5)+J)
1910 TOGGLE=1:TM=700:V=0
1920 V=V+1
1930 IF S1>TM OR E1<=TM THEN 1950
1940 POSITION X,V:? CN$((I*5)+1,((I+1)*5));
1950 TOGGLE=(TOGGLE<>1)
1960 TM=TM+(TOGGLE*40)+30
1970 IF TM<1800 THEN 1920
1980 NEXT J:NEXT I:RETURN
2020 REM SCREEN DUMP
2040 TRAP 2210:POKE 559,0
2060 CLOSE #4:OPEN #4,8,0,"P:"
2070 SCR=PEEK(88)+PEEK(89)*256
2080 FOR I=0 TO 21
2100 FOR J=0 TO 39:AD=SCR+(I*40)+J
2120 Z=PEEK(AD):Z=Z-(128*(Z>127))
2140 Z=Z+((Z>63 AND Z<96)*64)
2150 Z=Z+((Z<64)*32)
2160 TEMP$(J+1,J+1)=CHR$(Z):NEXT J
2180 IF I=0 THEN ? #4;TEMP$:? #4;"    |----------------------------------|"
2185 IF I=21 THEN ? #4;TEMP$:? #4;" ---|----------------------------------|"
2190 IF I>0 AND I<21 THEN ? #4;TEMP$
2200 NEXT I:CLOSE #4:TRAP 1470
2210 RETURN
2240 REM DISABLE/ENABLE BREAK
2260 RESTORE 2320
2270 FOR I=1536 TO 1610:READ BYT
2280 POKE I,BYT:NEXT I:RETURN
2320 DATA 120,104,104,104
2330 DATA 170,208,25,173,22,2
2340 DATA 141,61,6,173,23,2,141,62
2350 DATA 6,169,53,141,22,2,169,6
2360 DATA 141,23,2,232,208,13,173,61
2370 DATA 6,141,22,2,173,62,6,141
2380 DATA 23,2,202,134,212,169,0,133
2390 DATA 213,88,96,72,173,14,210,16
2400 DATA 4,104,76,60,6,169,127,141
2410 DATA 14,210,165,16,141,14,210,104,64