AUTORUN.SYS BASIC maker (AUTOGO.BAS)
AUTORUN.SYS BASIC maker, 21
Description
AUTORUN.SYS BASIC maker, 21
From the Antic disk of September 1988 (Vol. 7 No. 5) — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.5 KB
- Dialect
- Atari BASIC
- Lines
- 59
- Variables
A$,FILE$,FIRST,X,KEY,SIZE,COUNT,BYTE,L,DELAY
BASIC listing (59 lines)
100 REM AUTOGO
110 GRAPHICS 18:POKE 752,1
120 ? #6;" autogo"
130 ? #6;"___________________"
140 ? #6;" CREATES DOS 2.0S"
150 ? #6;" AUTORUN.SYS FILE"
160 DIM A$(128),FILE$(12)
170 ? #6:? #6:? #6;" enter filename "
180 TRAP 650:OPEN #1,4,0,"K:":FIRST=1
190 FOR X=1 TO 8
200 GET #1,KEY
210 IF FIRST AND (KEY<65 OR KEY>90) THEN FIRST=1:GOTO 200
220 IF KEY=155 THEN POP :GOTO 330
230 FIRST=0:IF KEY=46 THEN POP :GOTO 270
240 IF KEY=126 AND X>1 THEN X=X-1:POSITION X+3,8:? #6;" ";:GOTO 200
250 IF NOT ((KEY>47 AND KEY<58) OR (KEY>64 AND KEY<91)) THEN 200
260 POSITION X+3,8:? #6;CHR$(KEY);:FILE$(X,X)=CHR$(KEY):NEXT X
270 ? #6;".";:FILE$(LEN(FILE$)+1)=".":SIZE=LEN(FILE$)+1
280 FOR X=SIZE TO SIZE+3
290 GET #1,KEY:IF KEY=155 THEN POP :GOTO 330
300 IF KEY=126 AND X>12 THEN X=X-1:POSITION X+3,8:? #6;" ";:GOTO 290
310 IF NOT ((KEY>47 AND KEY<58) OR (KEY>64 AND KEY<91)) THEN 290
320 POSITION X+3,8:? #6;CHR$(KEY);:FILE$(LEN(FILE$)+1)=CHR$(KEY):NEXT X
330 CLOSE #1
340 TRAP 630:OPEN #1,8,0,"D:AUTORUN.SYS"
350 TRAP 640:FOR COUNT=1 TO 4:READ BYTE:PUT #1,BYTE:NEXT COUNT
360 A$(1,3)="RUN":A$(4,4)=CHR$(34):A$(5,6)="D:"
370 A$(LEN(A$)+1)=FILE$:A$(LEN(A$)+1)=CHR$(34)
380 L=123+LEN(A$)-1:PUT #1,L:PUT #1,6:FOR COUNT=1 TO 123:READ BYTE
390 IF COUNT=64 THEN PUT #1,LEN(A$)-1:GOTO 410
400 PUT #1,BYTE
410 NEXT COUNT
420 FOR COUNT=LEN(A$) TO 1 STEP -1:PUT #1,ASC(A$(COUNT,COUNT)):NEXT COUNT
430 FOR COUNT=1 TO 8:READ BYTE:PUT #1,BYTE:NEXT COUNT:CLOSE #1:END
440 DATA 255,255,0,6
450 DATA 162,0,189,26,3,201,69,240
460 DATA 5,232,232,232,208,244,232,142
470 DATA 105,6,189,26,3,133,205,169
480 DATA 107,157,26,3,232,189,26,3
490 DATA 133,206,169,6,157,26,3,160
500 DATA 0,162,16,177,205,153,107,6
510 DATA 200,202,208,247,169,67,141,111
520 DATA 6,169,6,141,112,6,169,10
530 DATA 141,106,6,96,172,106,6,240
540 DATA 9,185,123,6,206,106,6,160
550 DATA 1,96,138,72,174,105,6,165
560 DATA 205,157,26,3,232,165,206,157
570 DATA 26,3,104,170,169,155,160,1
580 DATA 96,0,0,0,0,0,0,0
590 DATA 0,0,0,0,0,0,0,76
600 DATA 0,0,0
610 DATA 255,255,226,2,227,2,0,6
620 REM ERROR HANDLERS
630 GOSUB 660:? "ERROR WHILE OPENING DISK FILE":GOSUB 680:RUN
640 GOSUB 660:? "ERROR WHILE WRITING TO DISK":GOSUB 680:RUN
650 GOSUB 660:? "ERROR DURING KEYBOARD INPUT":GOSUB 680:RUN
660 CLOSE #1:GRAPHICS 0:POSITION 2,10:POKE 752,1:RETURN
670 REM TIME DELAY
680 FOR DELAY=1 TO 500:NEXT DELAY:RETURN
