BSR (BSRK.BAS)

BSR (X-10) Interface Program by Walter D. Lazear (for Atari ST: binary load, BASIC, data)

Description

BSR (X-10) Interface Program by Walter D. Lazear (for Atari ST: binary load, BASIC, data)

From the Antic disk of August 1988 (Vol. 7 No. 4) — disk A.

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 6.6 KB

Dialect
Atari BASIC
Lines
144
Variables
N, MSG$, NN, A, FINISH, START, NREC, STAT$, DEVID$, LOC$, DAY$, TON$, TOFF$, LEVEL$, MODE$, NRECS, SYNC$, SECT(, CHAR(, INDEX$, RECORD$, REC$, RECS, SECT, CHAR, HOUR, TIME, MINUTE, DAY, FIELD, X, DAYS, Q$, DAY1, B$, O$, Z, Y
BASIC listing (144 lines)
10 REM BSR INTERFACE PROGRAM
11 REM BY WALTER D. LAZEAR
15 REM (c)1988, ANTIC PUBLISHING
20 GOSUB 400:GOTO 700
49 REM SET 850
50 CLOSE #5:OPEN #5,13,0,"R:":XIO 40,#5,0,0,"R:":RETURN
99 REM PUT MSG TO BSR
100 FOR N=1 TO LEN(MSG$):? #5;MSG$(N,N);:FOR NN=1 TO 5:NEXT NN
110 NEXT N:RETURN
149 REM GET MSG BYTE
150 GET #5,A:RETURN
199 REM GET ACK
200 FOR N=1 TO 7:GOSUB 150:NEXT N:CLOSE #5:RETURN
249 REM DO CHECKSUM (USE START & FINISH)
250 MSG$(FINISH,FINISH)=CHR$(0):FOR N=START TO FINISH-1
260 MSG$(FINISH,FINISH)=CHR$(ASC(MSG$(FINISH,FINISH))+ASC(MSG$(N,N)))
270 NEXT N:RETURN
299 REM PRINT HEADER
300 ? "ID-ST DEV,LOC,DAYS,TON,TOFF,LVL,MODE"
310 ? " ":RETURN
349 REM SHOW RECORD
350 ? "                MTWTFSS"
355 IF NREC<10 THEN ? " ";
360 ? NREC;"-";STAT$;" ";DEVID$;",";LOC$(1,7);",";B$;",";TON$;",";TOFF$;",";LEVEL$;",";MODE$:RETURN
399 REM INIT PROG
400 NRECS=24
420 DIM LOC$(10),MSG$(50),SYNC$(16),MODE$(1),SECT(NRECS),CHAR(NRECS),INDEX$(20),RECORD$(20),REC$(32),Q$(9)
430 DIM DEVID$(2),LEVEL$(1),TON$(4),TOFF$(4),DAY$(7),STAT$(1),B$(7),O$(1):FOR N=1 TO 16
440 SYNC$(N,N)=CHR$(255):NEXT N:CLOSE #5:XIO 36,#5,9,0,"R1:":XIO 38,#5,32,0,"R1:"
445 INDEX$="D:INDEX.BSR":RECORD$="D:DATA.BSR":RETURN
449 REM WRITE RECORD
450 REC$(1)=" ":REC$(32)=" ":REC$(2)=REC$
460 REC$(1,2)=DEVID$:REC$(3,12)=LOC$:REC$(13,16)=TON$:REC$(17,20)=TOFF$:REC$(21,21)=LEVEL$
470 REC$(22,22)=MODE$:REC$(23,29)=DAY$:REC$(30,30)=STAT$:? #4;REC$:RETURN
499 REM READ RECORD
500 INPUT #4;REC$
510 DEVID$=REC$(1,2):LOC$=REC$(3,12):TON$=REC$(13,16):TOFF$=REC$(17,20):LEVEL$=REC$(21,21)
520 MODE$=REC$(22,22):DAY$=REC$(23,29):STAT$=REC$(30,30):GOSUB 6600
530 RETURN
549 REM GET INDEX
550 CLOSE #2:OPEN #2,4,0,INDEX$:INPUT #2;RECS
560 FOR N=1 TO RECS:INPUT #2;SECT:SECT(N)=SECT:INPUT #2;CHAR:CHAR(N)=CHAR:NEXT N
570 CLOSE #2:RETURN
599 REM PARSE TIME
600 HOUR=INT(TIME/100):MINUTE=TIME-(HOUR*100):RETURN
649 REM CLEAR INTERFACE
650 ? "Clearing Interface Memory, OK (Y,N)";:INPUT MSG$:IF MSG$<>"Y" THEN ? "Interface Not Changed":POP :RETURN
660 MSG$=SYNC$:MSG$(17,17)=CHR$(0):MSG$(18,18)=CHR$(96)
670 GOSUB 50:GOSUB 100:GOSUB 200:RETURN
699 REM MAIN
700 TRAP 700:? "↰":?
710 ? "     BSR MASTER PROGRAM":?
720 ? "     1. Init Database"
730 ? "     2. Set Time"
740 ? "     3. Update Records"
750 ? "     4. Show Active Records"
760 ? "     5. Show All Records"
770 ? "     6. Load BSR Interface"
780 ? "     7. QUIT"
790 INPUT A:TRAP 40000:IF (A>0 AND A<8) THEN ON A GOSUB 1000,2000,3000,4000,5000,6000,7000
800 GOTO 700
999 REM INIT DATABASE
1000 CLOSE #2:OPEN #2,8,0,INDEX$:CLOSE #4:OPEN #4,8,0,RECORD$
1010 DEVID$="0 ":LOC$="          ":TON$="0   ":TOFF$="0   ":LEVEL$="0":MODE$="X":DAY$="0      "
1020 FOR N=1 TO NRECS:STAT$="I":NOTE #4,SECT,CHAR:SECT(N)=SECT:CHAR(N)=CHAR:GOSUB 450:NEXT N
1030 ? #2;NRECS:FOR N=1 TO NRECS:? #2;SECT(N):? #2;CHAR(N):NEXT N
1040 CLOSE #2:CLOSE #4:? "Initialized ";NRECS;" RECORDS":RETURN
1999 REM SET INTERFACE TIME
2000 ? "Day of Week (MON=1,SUN=7)";:INPUT DAY:? "Hour";:INPUT HOUR:? "Minute";:INPUT MINUTE
2010 MSG$=SYNC$:MSG$(17,17)=CHR$(2):MSG$(18,18)=CHR$(MINUTE):MSG$(19,19)=CHR$(HOUR)
2020 MSG$(20,20)=CHR$(2^(DAY-1)):START=18:FINISH=21:GOSUB 250:GOSUB 50:GOSUB 100:GOSUB 200
2030 ? "DONE":RETURN
2999 REM UPDATE RECORD
3000 ? "↰":GOSUB 550:? "Record #";:INPUT NREC:IF NREC<0 OR NREC>NRECS THEN 3000
3010 CLOSE #4:OPEN #4,12,0,RECORD$:POINT #4,SECT(NREC),CHAR(NREC):GOSUB 500
3020 GOSUB 350:? :? "1 = Status"
3030 ? "2 = Device ID"
3040 ? "3 = Location"
3050 ? "4 = Days"
3060 ? "5 = Time ON"
3070 ? "6 = Time OFF"
3080 ? "7 = Level"
3090 ? "8 = Mode"
3095 ? "--------"
3100 ? "9 = QUIT UPDATE"
3105 ?
3110 ? "Field";:INPUT FIELD
3111 IF FIELD>0 AND FIELD<10 THEN ON FIELD GOSUB 3210,3220,3230,3240,3250,3260,3270,3280,3290
3120 ? "↰":GOTO 3020
3210 ? "STATUS (Active, Inactive)";:INPUT STAT$:IF STAT$<>"A" AND STAT$<>"I" THEN 3210
3212 RETURN
3220 ? "Device ID (1-8)";:INPUT DEVID$:IF VAL(DEVID$)<1 OR VAL(DEVID$)>8 THEN 3220
3222 RETURN
3230 ? "Location";:INPUT LOC$
3235 Z=LEN(LOC$):IF Z<7 THEN LOC$(Z+1,Z+1)=" ":GOTO 3235
3237 RETURN
3240 GOSUB 6200:DAY$=STR$(DAY1)
3242 RETURN
3250 ? "Time ON (24HR)";:INPUT TON$:IF VAL(TON$)<0 OR VAL(TON$)>2400 THEN 3250
3252 RETURN
3260 ? "Time OFF (24HR)";:INPUT TOFF$:IF VAL(TOFF$)<0 OR VAL(TOFF$)>2400 THEN 3260
3262 RETURN
3270 ? "Level(0=High,8=Low)";:INPUT LEVEL$:IF VAL(LEVEL$)<0 OR VAL(LEVEL$)>8 THEN 3270
3272 RETURN
3280 ? "Mode (Normal,Security";:INPUT MODE$:IF MODE$<>"N" AND MODE$<>"S" THEN 3280
3282 RETURN
3290 POINT #4,SECT(NREC),CHAR(NREC):GOSUB 450:CLOSE #4:POP :RETURN
3999 REM SHOW ACTIVE RECORDS
4000 GOSUB 550:CLOSE #4:OPEN #4,4,0,RECORD$:GOSUB 300
4010 FOR NREC=1 TO NRECS:GOSUB 500:IF STAT$="A" THEN GOSUB 350
4020 NEXT NREC:CLOSE #2:CLOSE #4:GOSUB 4500:RETURN
4500 ? " PRESS ANY KEY TO CONTINUE";:POKE 764,255
4510 IF PEEK(764)=255 THEN 4510
4520 POKE 764,255:RETURN
4999 REM SHOW ALL RECORDS
5000 GOSUB 550:CLOSE #4:OPEN #4,4,0,RECORD$:GOSUB 300:FOR NREC=1 TO NRECS:GOSUB 500:GOSUB 350
5010 NEXT NREC:CLOSE #2:CLOSE #4:GOSUB 4500:RETURN
5999 REM WRITE TO INTERFACE
6000 CLOSE #4:OPEN #4,4,0,RECORD$:GOSUB 550:GOSUB 650:? "WRITING RECORD":FOR NREC=1 TO RECS:GOSUB 500
6010 IF STAT$="I" THEN 6140
6020 ? NREC;:MSG$=SYNC$:X=NREC*16:MSG$(17,17)=CHR$(3):IF X>255 THEN X=X-256:GOTO 6020
6030 MSG$(18,18)=CHR$(X):MSG$(19,19)=CHR$(INT(NREC/16)):MSG$(20,20)=CHR$(8):IF MODE$="S" THEN MSG$(20,20)=CHR$(9)
6040 MSG$(21,21)=CHR$(VAL(DAY$))
6050 TIME=VAL(TON$):GOSUB 600:MSG$(22,22)=CHR$(HOUR):MSG$(23,23)=CHR$(MINUTE)
6060 X=VAL(DEVID$):IF X<9 THEN MSG$(24,24)=CHR$(2^(8-X)):MSG$(25,25)=CHR$(0)
6070 IF X>8 THEN MSG$(24,24)=CHR$(0):MSG$(25,25)=CHR$(2^(16-X))
6080 MSG$(26,26)=CHR$(96):MSG$(27,27)=CHR$((VAL(LEVEL$)*32)+2)
6090 IF LEVEL$<>"8" THEN MSG$(27,27)=CHR$(ASC(MSG$(27,27))+3)
6100 START=20:FINISH=28:GOSUB 250:GOSUB 50:GOSUB 100:GOSUB 200:? ".";
6110 MSG$(18,18)=CHR$(ASC(MSG$(18,18))+8)
6120 TIME=VAL(TOFF$):GOSUB 600:MSG$(22,22)=CHR$(HOUR):MSG$(23,23)=CHR$(MINUTE)
6130 MSG$(27,27)=CHR$(3):GOSUB 250:GOSUB 50:GOSUB 100:GOSUB 200:? ".";
6140 NEXT NREC:? "DONE":CLOSE #2:CLOSE #4:RETURN
6200 ? "↰        DAYS":RESTORE 6500:B$="-------"
6210 DAY1=0:? :FOR X=1 TO 7:READ Q$
6220 ? Q$;" (Yes/No)",:INPUT O$
6230 IF  NOT (O$="Y" OR O$="N") THEN ? "↑↑";:GOTO 6220
6240 B$(X,X)=CHR$(45-3*(O$="Y")):IF O$="Y" THEN DAY1=DAY1+2^(X-1)
6250 NEXT X:RETURN
6500 DATA Monday,Tuesday,Wednesday,Thursday,Friday,Saturday,Sunday
6600 DAY1=VAL(DAY$):B$="-------"
6610 FOR X=7 TO 1 STEP -1:Y=2^(X-1):IF DAY1>=Y THEN DAY1=DAY1-Y:B$(X,X)="*"
6620 NEXT X:RETURN
7000 ? "QUITTING":END