game (BLACKBOX.BAS)

game by Ken Arromdee, 60

Description

game by Ken Arromdee, 60

From the Antic disk of August 1988 (Vol. 7 No. 4) — disk A.

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 7.2 KB

Dialect
Atari BASIC
Lines
163
Variables
Q$, P, SIZE, OLDX, OLDY, OLDDIR, X1, Y1, TURNS, I, J, X, Y, D, LETTER, DIR, UNDER, DELAY, S, MOVE, FRONT, LEFT, RIGHT, CHBASE, DV, CHNUM, UNDER1, DL
BASIC listing (163 lines)
5 REM BLACK BOX
10 REM BY KEN ARROMDEE
15 REM (c)1988, ANTIC PUBLISHING
20 DIM Q$(1):Q$=CHR$(34)
30 GOSUB 1470
40 GRAPHICS 0:POKE 709,0:POKE 710,10:POKE 712,10
50 TRAP 80:? "How many particles? (8 maximum) ";:INPUT #16;P
60 IF P>8 THEN ? "The maximum is 8.":GOTO 50
70 IF P>0 AND P=INT(P) THEN TRAP 65535:GOTO 90
80 ? "Please type an integer.":GOTO 50
90 TRAP 110:? :? "Do you want the black box to be":? "    8 by 8  or  10 by 10?":? :? " (Type 8 or 10) ";
92 INPUT #16;SIZE
95 IF SIZE<>8 AND SIZE<>10 THEN 110
100 TRAP 40000:GOTO 120
110 ? "Type an 8 or 10.":GOTO 90
120 GOSUB 1080
130 OLDX=1:OLDY=-1:OLDDIR=4:X1=1:Y1=1:TURNS=0:IF SIZE=10 THEN OLDX=0:X1=0:Y1=0
140 IF SIZE=10 THEN COLOR 171:FOR I=1 TO 10:FOR J=1 TO 10:PLOT I,J:NEXT J:NEXT I:GOTO 180
150 COLOR 3:PLOT 1,1:COLOR 4:PLOT 2,1:DRAWTO 9,1:PLOT 2,10:DRAWTO 9,10
160 COLOR 5:PLOT 10,1:COLOR 7:PLOT 1,10:COLOR 8:PLOT 10,10:COLOR 6:PLOT 1,2:DRAWTO 1,9:PLOT 10,2:DRAWTO 10,9
170 COLOR 171:FOR I=2 TO 9:FOR J=2 TO 9:PLOT I,J:NEXT J:NEXT I
180 POKE 623,4:POKE 53256,3:POKE 53261,255:POKE 704,128:POKE 53248,144
190 POKE 53257,3:POKE 705,128:POKE 53262,255:POKE 53249,176
200 POKE 53258,3:POKE 706,128:POKE 53263,255:POKE 53250,208
210 POSITION 14,2:? #6;"black":POSITION 15,3:? #6;"box"
220 POSITION 13,5:? #6;"turns ";TURNS
230 POSITION 14,7:? #6;"PRESS"
240 POSITION 13,8:? #6;"SELECT"
250 POSITION 15,9:? #6;"TO "
260 POSITION 14,10:? #6;"GUESS"
270 FOR I=1 TO P
280 X=INT(RND(0)*SIZE)+2-(SIZE=10):Y=INT(RND(0)*SIZE)+2-(SIZE=10)
290 LOCATE X,Y,D:IF D<>171 THEN 280
300 COLOR 172:PLOT X,Y
310 NEXT I
320 LET LETTER=ASC("A")
330 X=OLDX:Y=OLDY:DIR=OLDDIR
340 LOCATE X+1,Y+1,UNDER:POSITION X+1,Y+1:? #6;"!"
350 FOR DELAY=1 TO 30:NEXT DELAY
360 IF STRIG(0)=0 AND UNDER=32 THEN 550
370 S=STICK(0)
380 POSITION X+1,Y+1:? #6;CHR$(UNDER)
390 IF PEEK(764)=33 THEN 1250
400 IF PEEK(53279)=5 THEN FOR I=1 TO 40:NEXT I:GOSUB 1330
410 IF S=15 THEN 340
420 ON DIR GOTO 430,460,490,520
430 Y=Y+(S=13)-(S=14):IF Y=(SIZE=8)-1 THEN Y=-1:X=(SIZE=8):DIR=4
440 IF Y=9+(SIZE=10) THEN Y=10:X=(SIZE=8):DIR=2
450 GOTO 340
460 X=X+(S=7)-(S=11):IF X=(SIZE=8)-1 THEN X=-1:Y=8+(SIZE=10):DIR=1
470 IF X=9+(SIZE=10) THEN X=10:Y=8+(SIZE=10):DIR=3
480 GOTO 340
490 Y=Y+(S=13)-(S=14):IF Y=(SIZE=8)-1 THEN Y=-1:X=8+(SIZE=10):DIR=4
500 IF Y=9+(SIZE=10) THEN Y=10:X=8+(SIZE=10):DIR=2
510 GOTO 340
520 X=X+(S=7)-(S=11):IF X=(SIZE=8)-1 THEN X=-1:Y=(SIZE=8):DIR=1
530 IF X=9+(SIZE=10) THEN X=10:Y=(SIZE=8):DIR=3
540 GOTO 340
550 POSITION X+1,Y+1:? #6;" ":MOVE=1
560 OLDX=X:OLDY=Y:OLDDIR=DIR:IF SIZE=10 THEN 610
570 IF X=10 THEN X=9
580 IF Y=10 THEN Y=9
590 IF X=-1 THEN X=0
600 IF Y=-1 THEN Y=0
610 ON DIR GOTO 630,670,710,750
620 REM DIR 1=MOVING RIGHT
630 LOCATE X+2,Y+1,FRONT:LOCATE X+2,Y,LEFT:LOCATE X+2,Y+2,RIGHT
640 GOSUB 930
650 X=X+1:GOTO 780
660 REM 2=MOVING UP
670 LOCATE X+1,Y,FRONT:LOCATE X,Y,LEFT:LOCATE X+2,Y,RIGHT
680 GOSUB 930
690 Y=Y-1:GOTO 780
700 REM 3=MOVING LEFT
710 LOCATE X,Y+1,FRONT:LOCATE X,Y,RIGHT:LOCATE X,Y+2,LEFT
720 GOSUB 930
730 X=X-1:GOTO 780
740 REM 4=MOVING DOWN
750 LOCATE X+1,Y+2,FRONT:LOCATE X+2,Y+2,LEFT:LOCATE X,Y+2,RIGHT
760 GOSUB 930
770 Y=Y+1
780 IF X>=(SIZE=8) AND X<=8+(SIZE=10) AND Y>=(SIZE=8) AND Y<=8+(SIZE=10) THEN 610
790 IF SIZE=10 THEN 850
800 ON DIR GOTO 810,820,830,840
810 X=X+1:GOTO 850
820 Y=Y-1:GOTO 850
830 X=X-1:GOTO 850
840 Y=Y+1
850 TURNS=TURNS+2:GOSUB 10000
860 POSITION X+1,Y+1:? #6;CHR$(LETTER):POSITION OLDX+1,OLDY+1
870 ? #6;CHR$(LETTER):LET LETTER=LETTER+1:GOTO 900
880 GOSUB 10000:TURNS=TURNS+1:POSITION OLDX+1,OLDY+1:? #6;CHR$(138):GOTO 900
890 GOSUB 10000:TURNS=TURNS+1:POSITION OLDX+1,OLDY+1:? #6;CHR$(9):GOTO 900
900 POSITION 13,5:IF TURNS>9 THEN POSITION 12,5
910 ? #6;"turns ";TURNS
920 GOTO 330
930 IF FRONT=172 OR FRONT=140 THEN POP :GOTO 880:REM ABSORPTION
940 IF MOVE=1 THEN IF LEFT=172 OR RIGHT=172 OR LEFT=140 OR RIGHT=140 THEN POP :GOTO 890:REM REFLECTION
950 IF (LEFT=172 OR LEFT=140) AND (RIGHT=172 OR RIGHT=140) THEN POP :GOTO 890:REM REFLECTION
960 MOVE=MOVE+1
970 IF LEFT<>172 AND RIGHT<>172 AND LEFT<>140 AND RIGHT<>140 THEN RETURN :REM NOTHING AHEAD
980 IF RIGHT=172 OR RIGHT=140 THEN 1040
990 REM BOUNCE RIGHT
1000 DIR=DIR-1:IF DIR=0 THEN DIR=4
1010 POP
1020 GOTO 610
1030 REM BOUNCE LEFT
1040 DIR=DIR+1:IF DIR=5 THEN DIR=1
1050 POP
1060 GOTO 610
1070 REM CHARACTER REDEFINITION
1080 GRAPHICS 18:POKE 106,PEEK(106)-3:CHBASE=PEEK(106)+1:GRAPHICS 18:POKE 756,CHBASE:CHBASE=CHBASE*256
1090 DV=USR(ADR("hh┐Uh┐Th┐Wh┐V"▕ ♥1T┌VHPyfUfWJPp◆"),57344,CHBASE)
1100 READ CHNUM:IF CHNUM=-1 THEN POKE 709,102:POKE 710,182:POKE 711,72:POKE 708,26:RETURN
1110 FOR I=CHBASE+8*CHNUM TO CHBASE+8*CHNUM+7:READ D:POKE I,D:NEXT I:GOTO 1100
1120 DATA 1,255,153,153,255,255,153,153,255
1130 DATA 3,0,0,0,31,31,24,24,24
1140 DATA 4,0,0,0,255,255,0,0,0
1150 DATA 5,0,0,0,248,248,24,24,24
1160 DATA 6,24,24,24,24,24,24,24,24
1170 DATA 7,24,24,24,31,31,0,0,0
1180 DATA 8,24,24,24,248,248,0,0,0
1190 DATA 9,60,82,137,197,163,145,74,60
1200 DATA 10,255,129,189,165,165,189,129,255
1210 DATA 11,255,129,129,129,129,129,129,255
1220 DATA 12,255,129,129,129,129,129,129,255
1230 DATA -1
1240 REM SHOW PARTICLE LOCATION
1250 RESTORE 1250:FOR I=CHBASE+96 TO CHBASE+103:READ D:POKE I,D:NEXT I
1260 DATA 60,126,255,255,255,255,126,60
1270 POSITION 13,8:? #6;"TRIGGER":POSITION 15,9:? #6;"TO":POSITION 14,10:? #6;"REDO "
1280 IF STRIG(0) THEN 1280
1290 POSITION 0,0:? #6;"↰"
1300 FOR I=CHBASE+96 TO CHBASE+103:POKE I,PEEK(I-8):NEXT I
1310 POKE 764,255:GOTO 130
1320 REM GUESS MODE
1330 POSITION 14,10:? #6;"PROBE"
1340 S=STICK(0)
1350 X1=X1+(S>=5 AND S<=7)-(S>=9 AND S<=11):IF X1>8+(SIZE=10) THEN X1=(SIZE=8)
1360 IF X1<(SIZE=8) THEN X1=8+(SIZE=10)
1370 Y1=Y1+(S=5 OR S=9 OR S=13)-(S=6 OR S=10 OR S=14):IF Y1>8+(SIZE=10) THEN Y1=(SIZE=8)
1380 IF Y1<(SIZE=8) THEN Y1=8+(SIZE=10)
1390 LOCATE X1+1,Y1+1,UNDER1:POSITION X1+1,Y1+1:? #6;"!"
1400 IF STRIG(0) THEN 1410
1405 FOR I=1 TO 30:NEXT I:UNDER1=UNDER1+32*(UNDER1<160)-32*(UNDER1>160)
1410 FOR I=1 TO 10:IF PEEK(53279)=5 THEN 1437
1415 NEXT I
1420 POSITION X1+1,Y1+1:? #6;CHR$(UNDER1)
1430 IF PEEK(764)=33 THEN POP :GOTO 1250
1435 GOTO 1340
1437 POSITION X1+1,Y1+1:? #6;CHR$(UNDER1)
1440 FOR I=1 TO 30:NEXT I:POSITION 14,10:? #6;"GUESS":RETURN
1450 GOTO 1330
1460 REM TITLE PAGE
1470 GRAPHICS 18:POKE 710,0:POKE 709,40:POKE 708,6
1480 DL=PEEK(560)+PEEK(561)*256:POKE DL+10,6
1490 POSITION 6,3:? #6;"black box"
1500 POSITION 3,5:? #6;"BY KEN ARROMDEE"
1510 POKE DL+13,2:POSITION 10,8:? #6;"PRESS TRIGGER TO PLAY"
1530 IF STRIG(0) THEN 1530
1540 RETURN
9999 REM RANDOM DELAY
10000 FOR I=1 TO 60-6*MOVE+40*RND(0):NEXT I:RETURN