Top Banner, print utility (TBANNER.BAS)

Top Banner, print utility by Jacob Donham and Lee Brilliant, 135

Description

Top Banner, print utility by Jacob Donham and Lee Brilliant, 135

From the Antic disk of July 1988 (Vol. 7 No. 3).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 16.5 KB

Dialect
Atari BASIC
Lines
302
Variables
BCOUNT, BLANK$, PX$, N, SIZE, BG(, PR, FG(, ROW, INV, TMP$, HOLD(, BYTE, MEM, CYCLE, WIDE, COL, X, OX, MESG$, CMAX, RMAX, COL$, ROW$, HT(, WD(, MARGIN$, RESET$, SMALL$, FN$, FTM$, DP$, DUMMY$, FONT$, LO$, HI$, I, H, V, C, R, CHB, HC, K, PMAX, P, E, PS, W, VL, RG, J, VERT, IC, WH, HW, MARGIN, BASELINE, S, HI, LO, A, SECTOR, F, FSIZE, LAST, Z, A$
BASIC listing (302 lines)
10 REM CUSTOM BANNER II
20 REM BY JACOB DONHAM & LEE BRILLIANT
30 REM (c)1988, ANTIC PUBLISHING INC.
90 GRAPHICS 0:GOTO 1000
100 BCOUNT=0:BLANK$="":PX$="":FOR N=1 TO SIZE:BLANK$(N,N)=CHR$(BG(PR)):PX$(N,N)=CHR$(FG(PR)):NEXT N
102 IF ROW=0 THEN ROW=1
105 IF INV THEN TMP$=BLANK$:BLANK$=PX$:PX$=TMP$
110 FOR N=0 TO ROW-1:HOLD(N)=PEEK(N*BYTE+MEM+BCOUNT):NEXT N
120 CYCLE=128
125 TMP$="":FOR N=ROW-1 TO 0 STEP -1:IF HOLD(N)>=CYCLE THEN TMP$(LEN(TMP$)+1)=PX$:HOLD(N)=HOLD(N)-CYCLE:GOTO 140
130 TMP$(LEN(TMP$)+1)=BLANK$
140 NEXT N:FOR N=1 TO WIDE:? #2;TMP$:IF PEEK(764)=28 THEN 200
150 NEXT N:CYCLE=CYCLE/2
160 COL=COL-1:IF COL=0 THEN 190
170 IF CYCLE>0.5 THEN 125
180 BCOUNT=BCOUNT+1:GOTO 110
190 RETURN
200 POKE 764,255:POP :POSITION 2,1:GOSUB 5000:X=4:OX=4:GOTO 1140
300 BCOUNT=0:BLANK$="":PX$="":FOR N=1 TO SIZE:BLANK$(N,N)=CHR$(BG(PR)):PX$(N,N)=CHR$(FG(PR)):NEXT N
310 IF INV THEN TMP$=BLANK$:BLANK$=PX$:PX$=TMP$
320 N=COL:TMP$=""
330 HOLD(0)=PEEK(MEM+BCOUNT):CYCLE=128
340 IF HOLD(0)>=CYCLE THEN TMP$(LEN(TMP$)+1)=PX$:HOLD(0)=HOLD(0)-CYCLE:GOTO 360
350 TMP$(LEN(TMP$)+1)=BLANK$
360 N=N-1:IF N<1 THEN 390
370 CYCLE=CYCLE/2:IF CYCLE>0.5 THEN 340
380 BCOUNT=BCOUNT+1:GOTO 330
390 FOR N=1 TO WIDE:? #2;TMP$:IF PEEK(764)=28 THEN 200
395 NEXT N:ROW=ROW-1:IF ROW>0 THEN BCOUNT=BCOUNT+1:GOTO 320
400 RETURN
410 POKE 82,4:POKE 766,1:TMP$(1,LEN(MESG$))=MESG$
420 FOR N=1 TO 96 STEP 32:? TMP$(N,N+31):NEXT N
430 POKE 82,2:POKE 766,0:RETURN
450 CMAX=0:RMAX=0:FOR N=1 TO 59:X=ASC(COL$(N)):OX=ASC(ROW$(N)):IF X>CMAX THEN CMAX=X
460 IF OX>RMAX THEN RMAX=OX
470 NEXT N:RETURN
1000 DIM HT(100),WD(100),FG(100),BG(100),TMP$(130),MESG$(100),MARGIN$(6),RESET$(5),SMALL$(3),HOLD(38)
1001 DIM PX$(10),BLANK$(10),FN$(20),FTM$(32),DP$(10),DUMMY$(3),FONT$(11000),COL$(59),ROW$(59),LO$(59),HI$(59)
1010 RESET$="␛@␛A╲":MARGIN$="␛M":SMALL$="␛B┘"
1020 POKE 752,1:? CHR$(125)
1030 REM
1100 FOR I=1 TO 100:TMP$(I,I)=" ":HT(I)=10:WD(I)=7:FG(I)=88:BG(I)=32:NEXT I:H=1:V=1:C=1:R=1:CHB=57344:GOSUB 5000
1130 X=1:OX=1:OPEN #1,4,0,"K:":HC=1
1140 POKE 702,64:POKE 694,0:POSITION 10,OX+6:? " ":POSITION 10,X+6:? "␛→":GET #1,K:OX=X
1150 IF K=ASC("=") THEN X=X+1
1160 IF K=ASC("-") THEN X=X-1
1165 IF K=155 THEN 1200
1170 IF X<1 THEN X=5
1180 IF X>5 THEN X=1
1190 GOTO 1140
1200 ON X GOTO 1500,2000,3200,3000,3990
1500 POSITION 9,6:? "┌──────────────┐":POSITION 9,7:? "| Edit Message |"
1510 ? " ┌─────┴──────────────┴───────────┐":FOR I=1 TO 3:? " |                                |":NEXT I
1520 ? " └────────────────────────────────┘"
1521 TMP$(1)=" ":TMP$(96)=" ":TMP$(2)=TMP$:PMAX=LEN(MESG$)+1:P=0:POSITION 4,9:IF MESG$="" THEN PMAX=1:GOTO 1530
1522 GOSUB 410
1530 P=1:H=4:V=9:GOSUB 1621
1540 GET #1,K
1545 IF K=155 THEN 1628
1550 IF K=27 AND E=0 AND PS=0 THEN E=1:POSITION H,V:? CHR$(27);:GOTO 1540
1555 IF E=1 THEN E=0:GOTO 1610
1560 IF K=126 THEN POSITION H,V:GOSUB 1621:P=P-(P>1):H=H-1:GOTO 1624
1565 IF K=28 AND V>9 THEN GOSUB 1621:V=V-1:GOSUB 1621:P=P-32:GOTO 1540
1570 IF K=29 AND V<11 THEN GOSUB 1621:V=V+1:GOSUB 1621:P=P+32:GOTO 1540
1580 IF K=30 AND H>4 THEN GOSUB 1621:H=H-1:GOSUB 1621:P=P-1:GOTO 1540
1585 IF K=31 AND H<35 THEN GOSUB 1621:H=H+1:GOSUB 1621:P=P+1:GOTO 1540
1586 IF K>27 AND K<32 THEN 1540
1590 IF PS=1 THEN IF K<32 OR K>90 THEN 1540
1595 IF K=125 OR K>252 OR K=127 THEN 1540
1600 IF H<4 AND V>9 THEN H=35:V=V-1:IF H<4 THEN H=4
1610 TMP$(P,P)=CHR$(K):P=P+1:IF P>96 THEN P=96:GOTO 1540
1615 POSITION H,V:? CHR$(K):H=H+1:IF H>35 AND V<11 THEN V=V+1:H=4
1619 IF P>PMAX THEN PMAX=P
1620 GOSUB 1621:GOTO 1540
1621 LOCATE H,V,X:X=X+128:IF X>255 THEN X=X-256
1622 INV=128*(X>127):IF ((X-INV>26)*(X-INV<32))+(X-INV>124) THEN POSITION H,V:? "␛";
1623 POSITION H,V:? CHR$(X):RETURN
1624 IF H<4 AND V>9 THEN H=35:V=V-1
1625 IF P=PMAX-1 THEN PMAX=P
1626 IF H<4 THEN H=4:P=1
1627 POSITION H,V:? " ":TMP$(P,P)=" ":GOTO 1540
1628 IF P=1 THEN MESG$="":GOTO 1630
1629 MESG$=TMP$(1,PMAX-1)
1630 POSITION 2,1:GOSUB 5000
1710 X=1:OX=1:GOTO 1140
2000 POSITION 9,7:? "┌───────────────────┐":POSITION 9,8:? "| Change Parameters |"
2010 POSITION 9,9:? "├───────────────────┤":POSITION 9,10:? "|                   |"
2020 POSITION 9,11:? "|  Individual       |":POSITION 9,12:? "|  Overall          |"
2030 POSITION 9,13:? "|  Effects          |":POSITION 9,14:? "|                   |"
2040 POSITION 9,15:? "└───────────────────┘"
2050 X=1:OX=1
2060 POSITION 11,OX+10:? " ":POSITION 11,X+10:? "␛→":GET #1,K:OX=X
2070 IF K=ASC("=") THEN X=X+1
2080 IF K=ASC("-") THEN X=X-1
2090 IF K=155 THEN 2130
2095 IF K=27 THEN POSITION 2,1:GOSUB 5000:X=2:OX=2:GOTO 1140
2100 IF X<1 THEN X=3
2110 IF X>3 THEN X=1
2120 GOTO 2060
2130 ON X GOTO 2150,2300,2500
2150 POSITION 11,10:? "┌────────────┐":POSITION 11,11:? "| Individual |"
2160 ? " ┌───────┴────────────┴───────────┐":FOR I=1 TO 3:? " |                                |":NEXT I
2170 ? " └────────────────────────────────┘"
2175 ? "             ":? "             ":? "             "
2180 POKE 82,4:PMAX=LEN(MESG$)+1:P=0:POSITION 4,13:IF MESG$="" THEN ? "**NO MESSAGE**":GOTO 2200
2190 GOSUB 410:GOTO 2200
2200 POKE 82,2:P=1:H=4:V=13:GOSUB 1621
2210 GET #1,K
2220 IF K=155 THEN 4000
2230 IF K=27 THEN POSITION 2,1:GOSUB 5000:GOTO 2000
2235 IF K=28 AND V>13 THEN GOSUB 1621:V=V-1:GOSUB 1621:P=P-32:GOTO 2210
2240 IF K=29 AND V<15 AND P+32<PMAX THEN GOSUB 1621:V=V+1:GOSUB 1621:P=P+32:GOTO 2210
2250 IF K=30 AND H>4 THEN GOSUB 1621:H=H-1:GOSUB 1621:P=P-1:GOTO 2210
2260 IF K=31 AND H<35 AND P+1<PMAX THEN GOSUB 1621:H=H+1:GOSUB 1621:P=P+1:GOTO 2210
2270 IF P>96 THEN P=96:GOTO 2210
2280 GOTO 2210
2300 POSITION 10,11:? "┌─────────┐":POSITION 10,12:? "| Overall |":POSITION 10,13:? "├─────────┴─┐"
2310 POSITION 10,14:? "|Foregr:    |":POSITION 10,15:? "|Backgr:    |":POSITION 10,16:? "|Height:    |"
2320 POSITION 10,17:? "| Width:    |":POSITION 10,18:? "└───────────┘"
2330 W=14:GOSUB 2400:IF VL<256 THEN FOR RG=1 TO LEN(MESG$):FG(RG)=VL:NEXT RG
2340 W=15:GOSUB 2400:IF VL<256 THEN FOR RG=1 TO LEN(MESG$):BG(RG)=VL:NEXT RG
2350 W=16:GOSUB 2400:IF VL<11 THEN FOR RG=1 TO LEN(MESG$):HT(RG)=VL:NEXT RG
2360 W=17:GOSUB 2400:IF VL<11 THEN FOR RG=1 TO LEN(MESG$):WD(RG)=VL:NEXT RG
2370 POSITION 2,1:GOSUB 5000:X=1:OX=1:GOTO 2000
2400 J=1:DP$="   "
2405 POSITION J+17,W:? " ":GET #1,K
2410 IF K>ASC("0")-1 AND K<ASC("9")+1 AND J<4 THEN J=J+1:DP$(J-1,J-1)=CHR$(K)
2420 IF K=126 AND J>1 THEN J=J-1:DP$(J,J)=" ":POSITION J+18,W:? " "
2430 IF K=155 THEN TRAP 2440:DUMMY$=DP$(1,J-1):VL=VAL(DUMMY$):POSITION J+17,W:? " ":RETURN
2435 POSITION 18,W:? DP$:GOTO 2405
2440 VL=256:POSITION J+17,W:? " ":RETURN
2500 POSITION 10,12:? "┌─────────┐":POSITION 10,13:? "| Effects |":POSITION 10,14:? "├─────────┴──────┐"
2510 POSITION 10,15:? "|                |":POSITION 10,16:? "|  Resp. Foregr. |"
2520 POSITION 10,17:? "|  Resp. Backgr. |":POSITION 10,18:? "|  Growing       |"
2530 POSITION 10,19:? "|  Shrinking     |":POSITION 10,20:IF VERT=0 THEN ? "|  Vertical      |"
2535 IF VERT=1 THEN ? "|  Horizontal    |"
2540 POSITION 10,21:? "└────────────────┘":X=1:OX=1
2550 TRAP 2920
2560 POSITION 12,OX+15:? " ":POSITION 12,X+15:? "␛→":GET #1,K:OX=X
2570 IF K=ASC("=") THEN X=X+1
2580 IF K=ASC("-") THEN X=X-1
2583 IF K=27 THEN POSITION 2,1:X=1:OX=1:GOSUB 5000:GOTO 2000
2585 IF K=155 THEN 2620
2590 IF X<1 THEN X=5
2600 IF X>5 THEN X=1
2610 GOTO 2560
2620 ON X GOTO 2700,2750,2800,2850,2870
2700 FOR I=1 TO LEN(MESG$):FG(I)=ASC(MESG$(I,I)):NEXT I:GOTO 2900
2750 FOR I=1 TO LEN(MESG$):BG(I)=ASC(MESG$(I,I)):NEXT I:GOTO 2900
2800 IC=10/LEN(MESG$):WH=0:FOR I=1 TO LEN(MESG$):WH=WH+IC
2805 IF WH<1 THEN WH=1
2810 IF WH>10 THEN WH=10
2815 HW=INT(WH):WD(I)=HW:HT(I)=HW:NEXT I:GOTO 2900
2850 IC=10/LEN(MESG$):WH=0:FOR I=LEN(MESG$) TO I STEP -1:WH=WH+IC
2855 IF WH<1 THEN WH=1
2860 IF WH>10 THEN WH=10
2865 HW=INT(WH):WD(I)=HW:HT(I)=HW:NEXT I:GOTO 2900
2870 VERT= NOT VERT
2900 POSITION 11,15:? "┌──────┐":POSITION 11,16:? "| Done |":POSITION 11,17:? "└──────┘"
2910 GET #1,K:GOTO 2500
2920 POSITION 11,15:? "┌─────────┐":POSITION 11,16:? "|   No    |":POSITION 11,17:? "| Message |"
2930 POSITION 11,18:? "└─────────┘":GET #1,K:GOTO 2500
2999 END
3000 POSITION 9,9:? "┌──────────────┐":POSITION 9,10:? "| Print Banner |":POSITION 9,11:? "├──────────────┤"
3005 CLOSE #2:TRAP 40000:OPEN #2,8,0,"P:":GOTO 3017
3010 POSITION 9,12:? "|   Printer    |":POSITION 9,13:? "|    Is Not    |":POSITION 9,14:? "|  Responding  |"
3015 POSITION 9,15:? "└──────────────┘":GET #1,K:CLOSE #2:GOTO 3005
3017 IF LEN(MESG$)=0 THEN GOTO 3026
3020 POSITION 9,12:? "|              |":POSITION 9,13:? "|   Printing   |":POSITION 9,14:? "|              |"
3025 POSITION 9,15:? "└──────────────┘":GOTO 3029
3026 POSITION 9,12:? "|      No      |":POSITION 9,13:? "|   Message    |":POSITION 9,14:? "|              |"
3027 POSITION 9,15:? "└──────────────┘":GET #1,K:GOTO 3180
3029 ? #2;RESET$:FN$="                                                "
3030 FOR PR=1 TO LEN(MESG$):IC=ASC(MESG$(PR)):SIZE=HT(PR):WIDE=WD(PR):INV=128*(IC>127)
3035 IF PS THEN INV=0:GOTO 3080
3040 MARGIN=0:IF VERT THEN WIDE=HT(PR):SIZE=WD(PR):MARGIN=40-SIZE*4
3050 ? #2;MARGIN$;CHR$(MARGIN):IC=IC-INV:IF IC<96 THEN IC=IC-32
3060 IF IC<0 THEN IC=IC+96
3070 MEM=IC*8+CHB:ROW=8:COL=8:BYTE=1:GOSUB 100+VERT*200:NEXT PR:? CHR$(125):GOSUB 5000:X=4:OX=4:GOTO 1140
3080 IC=IC-31:N=ASC(COL$(IC)):BYTE=INT((N-1)/8)+1:COL=N:IF IC=1 THEN COL=N*WIDE:GOTO 3160
3090 REM
3100 REM
3110 ROW=ASC(ROW$(IC)):MEM=ASC(LO$(IC))+256*ASC(HI$(IC))-BASELINE+ADR(FONT$)
3120 IF VERT AND WIDE*CMAX>135 THEN WIDE=WIDE-1:GOTO 3120
3125 IF VERT THEN MARGIN=68-COL*WIDE/2:H=SIZE:SIZE=WIDE:WIDE=H:GOTO 3140
3130 IF SIZE*RMAX>135 THEN SIZE=SIZE-1:GOTO 3130
3135 MARGIN=136-ROW*SIZE-(136-RMAX*SIZE)/2
3140 ? #2;SMALL$;MARGIN$;CHR$(MARGIN):GOSUB 100+VERT*200:COL=2*SIZE:IF VERT THEN COL=2*WIDE
3160 FOR S=1 TO COL:? #2;CHR$(10):NEXT S
3170 NEXT PR
3180 ? CHR$(125):GOSUB 5000:X=4:OX=4:GOTO 1140
3200 POSITION 9,8:? "┌────────────────────┐":POSITION 9,9:? "| Font Selections    |"
3210 POSITION 9,10:? "├────────────────────┤":POSITION 9,11:? "|                    |"
3220 POSITION 9,12:? "|  8x8 ATARI Fonts   |":POSITION 9,13:? "|  Print Shop Fonts  |"
3230 POSITION 9,14:? "|                    |":POSITION 9,15:? "└────────────────────┘"
3235 X=1:OX=1
3240 POSITION 11,OX+11:? " ":POSITION 11,X+11:? "␛→":GET #1,K:OX=X
3250 IF K=ASC("=") THEN X=X+1
3260 IF K=ASC("-") THEN X=X+1
3265 IF K=27 THEN POSITION 2,1:X=3:OX=3:GOSUB 5000:GOTO 1140
3270 IF K=155 THEN 3300
3280 IF X<1 THEN X=2
3290 IF X>2 THEN X=1
3295 GOTO 3240
3300 ? CHR$(125):? "▶┌─────────────────────────┐":? "▶|    ** Font Loader **    |"
3310 ? "┌───────────────────────────────────┐":? "| Insert Font Disk and Press RETURN |"
3312 ? "└───────────────────────────────────┘"
3315 GET #1,K:IF K=155 THEN 3320
3316 IF K=27 THEN ? CHR$(125):GOSUB 5000:GOTO 3200
3317 GOTO 3315
3320 ? "┌─────────────────────┐":ON X GOTO 3350,3500
3350 P=0:PS=0:TRAP 5900:OPEN #3,6,0,"D:*.FNT":? "| STANDARD";CHR$(127);
3360 INPUT #3;FTM$:IF FTM$(11,13)<>"FNT" THEN 3360
3370 ? FTM$(3,10);" |":P=1
3380 INPUT #3;FTM$:IF FTM$(11,13)<>"FNT" THEN 3380
3385 ? "| ";FTM$(3,10);CHR$(127);:P=0:GOTO 3360
3390 CLOSE #3:TRAP 40000:IF P=0 THEN ? "         |"
3395 ? "└─────────────────────┘":POKE 752,0:? "Enter File Name   ◀◀◀";:INPUT FTM$
3400 IF FTM$="" THEN 3300
3405 IF FTM$="STANDARD" THEN CHB=57344:X=3:OX=3:? CHR$(125):GOSUB 5000:GOTO 1140
3410 FN$="D:":FN$(LEN(FN$)+1)=FTM$:FN$(LEN(FN$)+1)=".FNT"
3420 TRAP 5900:OPEN #3,4,0,FN$
3430 POKE 882,7:CHB=ADR(FONT$):HI=INT(CHB/256):LO=CHB-256*HI:POKE 884,LO:POKE 885,HI:POKE 888,0:POKE 889,4
3440 A=USR(ADR("h"0 Vd◆")):CLOSE #3:TRAP 40000:PRINT CHR$(125):GOSUB 5000:X=3:OX=3:GOTO 1140
3500 RESTORE 11000:? "|0 NEXT MENU          |":IF PS=0 THEN PS=1:MESG$=""
3510 P=1:FOR SECTOR=362 TO 365:GOSUB 10000
3520 FOR N=1 TO 128 STEP 32:FTM$(1,32)=TMP$(N):IF FTM$(1,1)<>"F" THEN 3580
3530 IF FTM$(2,3)="O." THEN 3560
3535 IC=ASC(FTM$(2))-48:IF IC<0 OR IC>9 THEN 3580
3540 POKE 182,IC:READ FTM$
3550 ? "|";P;" ";FTM$:GOTO 3570
3560 ? "|";P;" ";FTM$(4,16)
3570 POSITION 24,P+7:? "|":P=P+1
3580 NEXT N:NEXT SECTOR:P=P-1:? "└─────────────────────┘":POKE 752,0
3590 TRAP 3590:POSITION 2,P+9:? "Enter your selection    ◀◀◀";:INPUT F
3600 IF F<0 OR F>P THEN 3590
3610 TRAP 40000:IF F=0 THEN 3300
3620 IC=1:FOR SECTOR=362 TO 365:GOSUB 10000
3630 FOR N=1 TO 128 STEP 32:FTM$(1,32)=TMP$(N)
3640 IF FTM$(1,1)<>"F" THEN 3670
3650 IF IC=F THEN 3700
3660 IC=IC+1
3670 NEXT N:NEXT SECTOR
3700 SECTOR=ASC(FTM$(17))+256*ASC(FTM$(18)):FSIZE=ASC(FTM$(21))+ASC(FTM$(22))*256:LAST=INT(FSIZE/126)+SECTOR
3710 POKE 752,1:? "LOADING"
3720 BASELINE=24812:GOSUB 10000:IF FTM$(2,3)="O." THEN 3760
3730 COL$=TMP$(1,59):ROW$=TMP$(60,118):LO$=TMP$(119,126)
3740 SECTOR=SECTOR+1:GOSUB 10000:LO$(9)=TMP$(1,51):HI$=TMP$(52,110)
3750 FONT$=TMP$(111,126):GOTO 3780
3760 COL$=TMP$(13,71):ROW$=TMP$(72,126):SECTOR=SECTOR+1:GOSUB 10000:ROW$(56)=TMP$(1,4)
3770 LO$=TMP$(5,63):HI$=TMP$(64,122):FONT$=TMP$(123,126)
3780 SECTOR=SECTOR+1:IF SECTOR>LAST THEN POKE 755,2:? CHR$(125):GOSUB 450:GOSUB 5000:X=1:OX=1:GOTO 1140
3790 GOSUB 10000:FONT$(LEN(FONT$)+1)=TMP$(1,126):POKE 755,( NOT PEEK(755))*2:GOTO 3780
3990 GRAPHICS 0:END
3999 END
4000 POSITION 4,16:? "┌───────────┐":POSITION 4,17:? "|Foregr:    |":POSITION 4,18:? "|Backgr:    |"
4010 POSITION 4,19:? "|Height:    |":POSITION 4,20:? "| Width:    |":POSITION 4,21:? "└───────────┘"
4020 POSITION 12,17:? FG(P):POSITION 12,18:? BG(P):POSITION 12,19:? HT(P):POSITION 12,20:? WD(P)
4030 DP$=STR$(FG(P)):W=17:Z=LEN(DP$)
4040 GOSUB 4200:IF VL<256 THEN FG(P)=VL
4050 DP$=STR$(BG(P)):W=18:Z=LEN(DP$)
4060 GOSUB 4200:IF VL<256 THEN BG(P)=VL
4070 DP$=STR$(HT(P)):W=19:Z=LEN(DP$)
4080 GOSUB 4200:IF VL<11 THEN HT(P)=VL
4090 DP$=STR$(WD(P)):W=20:Z=LEN(DP$)
4100 GOSUB 4200:IF VL<11 THEN WD(P)=VL
4110 POSITION 4,16:? "─────────────":FOR S=17 TO 21:POSITION 4,S:? "             ":NEXT S:GOTO 2210
4200 J=Z+1
4203 POSITION J+11,W:? " ":GET #1,K
4205 IF K>ASC("0")-1 AND K<ASC("9")+1 AND J<4 THEN J=J+1:DP$(J-1,J-1)=CHR$(K)
4210 IF K=126 AND J>1 THEN J=J-1:DP$(J,J)=" ":POSITION J+12,W:? " "
4220 IF K=155 THEN TRAP 4203:DUMMY$=DP$(1,J-1):VL=VAL(DUMMY$):POSITION J+11,W:? " ":RETURN
4240 POSITION 12,W:? DP$:GOTO 4203
4999 END
5000 ? "      ┌───────────────────────┐"
5005 POKE 752,1
5010 ? "      |                       |"
5020 ? "      | Custom Banner Printer |"
5030 ? "      |                       |"
5040 ? "      ├───────────────────────┤"
5050 ? "      |                       |"
5060 ? "      |  Edit Message         |"
5070 ? "      |  Change Parameters    |     "
5080 ? "      |  Font Selections      |     "
5090 ? "      |  Print Banner         |     "
5100 ? "      |  Quit                 |     "
5110 ? "      |                       |     "
5120 ? "      └───────────────────────┘     "
5130 FOR X=1 TO 9:? "                                   ":NEXT X
5210 RETURN
5900 CLOSE #3:IF PEEK(195)<>136 THEN GOSUB 5990:GOSUB 5950:GOTO 3300
5905 GOTO 3390
5950 ? "┌────────────────────┐":? "|DISK ERROR ";PEEK(195);CHR$(127);"|":? "|   PRESS RETURN     |"
5955 ? "└────────────────────┘"
5960 GET #1,K:IF K<>155 THEN 5960
5970 RETURN
5990 SOUND 0,20,6,10:A=1^1:SOUND 0,25,6,10:A=1^1:SOUND 0,0,0,0:RETURN
10000 TMP$(129)="":MEM=ADR(TMP$):POKE 773,INT(MEM/256):POKE 772,MEM-INT(MEM/256)*256
10010 POKE 779,INT(SECTOR/256):POKE 778,SECTOR-INT(SECTOR/256)*256:POKE 769,1:POKE 770,82:H=USR(ADR("h Sd◆"))
10020 IF PEEK(771)=1 THEN RETURN
10030 POKE 195,PEEK(771):GOTO 5900
11000 DATA STANDARD,RSVP,ALEXIA,NEWS,TECH,PARTY,BLOCK,TYPEWRITER,STENCIL