Wire-Frame Generator and sample (SPIN.BAS)

Wire-Frame Generator and sample by Robert Geddings, 174

Description

Wire-Frame Generator and sample by Robert Geddings, 174

From the Antic disk of July 1988 (Vol. 7 No. 3).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 8.0 KB

Dialect
Atari BASIC
Lines
194
Variables
CNTR, CPTS, INCR, SIDES, COUNTER, YCENTER, XCENTER, R, DIA(, PHI, X, Y, WIREX(, WIREY(, Z, WIREZ(, SX, SY, D, OLDSX, OLDSY, OPTION$, XA, CR1, SR1, YA, CR2, SR2, ZA, CR3, SR3, MX, MY, MZ, COLOUR, XOLD, YOLD, A, TX, TY, DELAY, CTR, R1, R2, R3, FILE$, VALUE, VALUE2
BASIC listing (194 lines)
10 REM WIRE-FRAME GENERATOR
20 REM BY ROBERT GEDDINGS
30 REM (c)1988, ANTIC PUBLISHING
40 GOSUB 1250:REM INIT
50 GOSUB 780:REM MENU
60 GOSUB 550:REM GET CONTROL POINTS
70 POKE 82,0
80 REM SPIN THE CONTROL POINTS
90 FOR CNTR=1 TO CPTS
100 INCR=360/SIDES:COUNTER=0
110 YCENTER=0:XCENTER=0:R=DIA(CNTR)
130 FOR PHI=0 TO 360 STEP INCR
140 COUNTER=COUNTER+1:IF COUNTER>SIDES THEN 180
150 X=R*COS(PHI):Y=R*SIN(PHI)
160 X=XCENTER+X:Y=YCENTER+Y
170 WIREX(CNTR,COUNTER)=X:WIREY(CNTR,COUNTER)=Y
180 NEXT PHI:NEXT CNTR
190 REM
200 REM DISPLAY WIRE-FRAME IN 3-D
210 REM
220 REM DRAW THE ARCS
230 GRAPHICS 8:POKE 710,0:POKE 709,15
240 PLOT 0,0:DRAWTO 319,0:DRAWTO 319,159:DRAWTO 0,159:DRAWTO 0,0
250 CNTR=0
251 CNTR=CNTR+1:IF CNTR>CPTS THEN 370
260 X=WIREX(CNTR,1):Y=WIREY(CNTR,1):Z=WIREZ(CNTR):GOSUB 500
270 IF SX>318 OR SY>158 THEN ? "Fitting to Screen....":D=D-20:GOTO 90
280 IF SX<1 OR SY<1 THEN ? "Fitting to Screen....":D=D-20:GOTO 90
290 PLOT SX,SY:OLDSX=SX:OLDSY=SY
300 COUNTER=1
305 COUNTER=COUNTER+1:IF COUNTER>SIDES THEN 340
307 X=WIREX(CNTR,COUNTER):Y=WIREY(CNTR,COUNTER):Z=WIREZ(CNTR):GOSUB 500
310 IF SX>318 OR SY>158 THEN ? "Fitting to Screen....":D=D-20:GOTO 90
320 IF SX<1 OR SY<1 THEN ? "Fitting to Screen....":D=D-20:GOTO 90
330 DRAWTO SX,SY:GOTO 305
340 DRAWTO OLDSX,OLDSY:GOTO 251
350 REM
360 REM DRAW THE DEPTH LINES
370 FOR CNTR=1 TO SIDES
380 X=WIREX(1,CNTR):Y=WIREY(1,CNTR):Z=WIREZ(1):GOSUB 500:PLOT SX,SY
390 FOR COUNTER=2 TO CPTS:X=WIREX(COUNTER,CNTR):Y=WIREY(COUNTER,CNTR):Z=WIREZ(COUNTER):GOSUB 500:DRAWTO SX,SY
400 NEXT COUNTER:NEXT CNTR
410 TRAP 420
420 ? :? :? :? "Type View, New, Print, Save or Quit:";:INPUT OPTION$
430 IF OPTION$(1)="N" THEN RUN
440 IF OPTION$(1)="Q" THEN GRAPHICS 0:END
450 IF OPTION$(1)="S" THEN 1290
460 IF OPTION$(1)="P" THEN 1400
470 IF OPTION$(1)="V" THEN 1570
480 GOTO 420
490 REM GENERATE 3-D COORDINATES
500 XA=CR1*X-SR1*Y:YA=SR1*X+CR1*Y:X=CR2*XA+SR2*Z:ZA=CR2*Z-SR2*XA:Y=CR3*YA-SR3*ZA:Z=SR3*YA+CR3*ZA:X=X+MX:Y=Y+MY
510 Z=Z+MZ:SX=D*X/Y:SY=D*Z/Y:SX=SX+159:SY=SY+80:RETURN
530 REM A LITTLE CAD
540 REM
550 GRAPHICS 8:POKE 710,0:POKE 709,15:COLOR 1
560 PLOT 0,0:DRAWTO 319,0:DRAWTO 319,159:DRAWTO 0,159:DRAWTO 0,0:PLOT 160,0:DRAWTO 160,159
570 POKE 752,1
580 FOR CNTR=1 TO CPTS
590 LOCATE X+160,Y+80,COLOUR:PLOT X+160,Y+80:XOLD=X:YOLD=Y:COLOR COLOUR:PLOT XOLD+160,YOLD+80:COLOR 1
595 ? "↑Point=";CNTR;"  X=";X;"  Y=";Y*-1;"     "
600 IF STRIG(0)=0 THEN 710
610 A=STICK(0):IF A=15 THEN 590
620 TX=(A=5 OR A=6 OR A=7)-(A=9 OR A=10 OR A=11):TY=(A=5 OR A=9 OR A=13)-(A=6 OR A=10 OR A=14)
630 IF (X+TX)<-158 THEN X=-158:GOTO 680
640 IF (X+TX)>158 THEN X=158:GOTO 680
650 IF (Y+TY)<-78 THEN Y=-78:GOTO 680
660 IF (Y+TY)>78 THEN Y=78:GOTO 680
670 X=X+TX:Y=Y+TY
680 ? "↑Point=";CNTR;"  X=";X;"  Y=";Y*-1;"     "
690 IF STRIG(0)<>1 THEN 710
700 GOTO 590
710 SOUND 0,100,10,10:FOR DELAY=1 TO 50:NEXT DELAY:SOUND 0,0,0,0
720 DIA(CNTR)=X:WIREZ(CNTR)=Y
730 COLOR 1:PLOT (DIA(1)+160),(WIREZ(1)+80)
740 FOR CTR=1 TO CNTR:DRAWTO (DIA(CTR)+160),(WIREZ(CTR)+80):NEXT CTR:NEXT CNTR
750 ? :? :? :? "Spinning the Profile.....       "
760 RETURN
770 REM MENU
780 GRAPHICS 0:POKE 710,0:POKE 709,12
790 POSITION 16,0:? "S P I N":POSITION 9,1:? "A WIRE-FRAME GENERATOR"
800 POSITION 11,3:? "by Robert Geddings"
810 ? :? "New or Load file: ";:INPUT OPTION$:IF OPTION$(1)<>"L" AND OPTION$(1)<>"N" THEN ? "↑↑↑":GOTO 810
820 IF OPTION$(1)="L" THEN 1110
830 TRAP 860
840 ? :? "Enter # Control Points [30 max]:";:INPUT CPTS
850 IF CPTS>1 AND CPTS<31 THEN 870
860 ? "↑↑↑":GOTO 840
870 TRAP 900
880 ? :? "Enter # Sides [30 max]:";:INPUT SIDES
890 IF SIDES>1 AND SIDES<31 THEN 910
900 ? "↑↑↑":GOTO 880
910 ? :? "Use Default View [Y/N]: ";:INPUT OPTION$:IF OPTION$(1)<>"Y" AND OPTION$(1)<>"N" THEN ? "↑↑↑":GOTO 910
920 IF OPTION$(1)="Y" THEN 1070
930 TRAP 940
940 POSITION 2,13:? "Magnification= ";D:POSITION 16,13:INPUT D
950 TRAP 960
960 POSITION 2,14:? "MX= ";MX:POSITION 5,14:INPUT MX
970 TRAP 980
980 POSITION 2,15:? "MY= ";MY:POSITION 5,15:INPUT MY
990 TRAP 1000
1000 POSITION 2,16:? "MZ= ";MZ:POSITION 5,16:INPUT MZ
1010 TRAP 1020
1020 POSITION 2,17:? "Yaw (Degrees)= ";R1:POSITION 16,17:INPUT R1
1030 TRAP 1040
1040 POSITION 2,18:? "Roll (Degrees)= ";R2:POSITION 17,18:INPUT R2
1050 TRAP 1060
1060 POSITION 2,19:? "Pitch (Degrees)= ";R3:POSITION 18,19:INPUT R3
1070 SR1=SIN(R1):SR2=SIN(R2):SR3=SIN(R3):CR1=COS(R1):CR2=COS(R2):CR3=COS(R3)
1080 DIM WIREX(CPTS,SIDES),WIREY(CPTS,SIDES),WIREZ(CPTS),DIA(CPTS):RETURN
1090 REM
1100 REM LOAD A FILE
1110 ? :? "Filename to load [Dn:Filename.Ext]:";:INPUT FILE$
1120 TRAP 780
1130 CLOSE #1:OPEN #1,4,0,FILE$:INPUT #1,CPTS:INPUT #1,SIDES:INPUT #1,MX:INPUT #1,MY:INPUT #1,MZ
1140 INPUT #1,D:INPUT #1,R1:INPUT #1,R2:INPUT #1,R3
1150 DIM WIREX(CPTS,SIDES),WIREY(CPTS,SIDES),WIREZ(CPTS),DIA(CPTS)
1160 TRAP 1220
1170 FOR CNTR=1 TO SIDES:FOR COUNTER=1 TO CPTS:INPUT #1,VALUE:INPUT #1,VALUE2:WIREX(COUNTER,CNTR)=VALUE
1180 WIREY(COUNTER,CNTR)=VALUE2:NEXT COUNTER:NEXT CNTR
1190 FOR CNTR=1 TO CPTS:INPUT #1,VALUE:INPUT #1,VALUE2:WIREZ(CNTR)=VALUE:DIA(CNTR)=VALUE2:NEXT CNTR:CLOSE #1
1200 SR1=SIN(R1):SR2=SIN(R2):SR3=SIN(R3):CR1=COS(R1):CR2=COS(R2):CR3=COS(R3)
1210 POP :GOTO 230
1220 ? "Problem with File - Try again.":FOR DELAY=1 TO 200:NEXT DELAY:POP :GOTO 780
1230 REM
1240 REM INIT.
1250 DIM FILE$(15),OPTION$(1)
1255 DEG :D=200:R1=360:R2=360:R3=360:MX=0:MY=250:MZ=0
1260 FOR CNTR=675 TO 678:POKE CNTR,0:NEXT CNTR:RETURN
1270 REM
1280 REM
1290 TRAP 1380
1300 ? "Datafile to save [Dn:Filename.Ext]":? ": ";:INPUT FILE$:IF LEN(FILE$)<1 THEN 1352
1305 CLOSE #1:OPEN #1,8,0,FILE$
1310 ? #1,CPTS:? #1,SIDES:? #1,MX:? #1,MY:? #1,MZ:? #1,D:? #1,R1:? #1,R2:? #1,R3
1320 FOR CNTR=1 TO SIDES:FOR COUNTER=1 TO CPTS:VALUE=WIREX(COUNTER,CNTR):VALUE2=WIREY(COUNTER,CNTR)
1330 ? #1,VALUE:? #1,VALUE2:NEXT COUNTER:NEXT CNTR
1340 FOR CNTR=1 TO CPTS:VALUE=WIREZ(CNTR):VALUE2=DIA(CNTR)
1350 PRINT #1,VALUE:PRINT #1,VALUE2:NEXT CNTR:CLOSE #1
1352 ? "Picture to save [Dn:Filename.Ext]":? ": ";:INPUT FILE$:IF LEN(FILE$)<1 THEN 1369
1353 CLOSE #1:OPEN #1,8,0,FILE$:POKE 850,11:POKE 852,PEEK(88):POKE 853,PEEK(89)
1354 POKE 856,0:POKE 857,30:CNTR=USR(ADR("hhh*LVd"),16)
1360 PUT #1,PEEK(712):FOR CNTR=708 TO 710:PUT #1,PEEK(CNTR):NEXT CNTR:CLOSE #1
1369 GOTO 410
1370 REM
1380 ? "Problem Saving file...Try Again.":FOR DELAY=1 TO 200:NEXT DELAY:GOTO 410
1390 REM PRINT ROUTINES
1400 ? "Print Data or Graph: ";:INPUT OPTION$
1410 IF OPTION$(1)="D" THEN 1440
1420 IF OPTION$(1)="G" THEN 1680
1430 GOTO 1400
1440 ? "Ready Printer and press [RETURN]";:INPUT OPTION$
1450 CLOSE #1:OPEN #1,8,0,"P:"
1460 ? #1,"# OF CONTROL POINTS:  ";CPTS
1470 ? #1,"# OF SIDES:  ";SIDES
1480 ? #1,"MAGNIFICATION:  ";D
1490 ? #1,"MX:  ";MX;"   MY:  ";MY;"   MZ:  ";MZ
1500 ? #1,"YAW:  ";R1;"   ROLL:  ";R2;"   PITCH:  ";R3
1510 ? #1,"SIDE","CONTROL POINT","X","Y","Z","RADIUS"
1520 FOR CNTR=1 TO SIDES:FOR COUNTER=1 TO CPTS
1530 ? #1,CNTR,COUNTER,,WIREX(COUNTER,CNTR),WIREY(COUNTER,CNTR),WIREZ(COUNTER),DIA(COUNTER)
1540 NEXT COUNTER:NEXT CNTR:CLOSE #1:GOTO 410
1550 REM
1560 REM CHANGE VIEW PARAMETERS
1570 GOSUB 1260:? "↰Magnification → ";D:? "↑▶";:INPUT D
1580 GOSUB 1260:? "MX → ";MX:? "↑▶";:INPUT MX
1590 ? "MY → ";MY:? "↑▶";:INPUT MY
1600 ? "MZ → ";MZ:? "↑▶";:INPUT MZ
1610 GOSUB 1260:? "Yaw → ";R1:? "↑▶";:INPUT R1
1620 GOSUB 1260:? "Roll → ";R2:? "↑▶";:INPUT R2
1630 GOSUB 1260:? "Pitch → ";R3:? "↑▶";:INPUT R3
1640 SR1=SIN(R1):SR2=SIN(R2):SR3=SIN(R3):CR1=COS(R1):CR2=COS(R2):CR3=COS(R3)
1650 ? :? :? :? :GOTO 230
1660 REM
1670 REM 1020 PLOTTER ROUTINE
1680 ? "Ready Plotter and press <RETURN>";:INPUT OPTION$
1690 CLOSE #2:OPEN #2,8,0,"P:"
1700 ? #2,CHR$(27);CHR$(7):REM SET 1020 TO GRAPHICS MODE
1710 ? #2,"H"
1720 ? #2,"C0"
1730 FOR CNTR=1 TO CPTS
1740 X=WIREX(CNTR,1):Y=WIREY(CNTR,1):Z=WIREZ(CNTR):GOSUB 500
1750 SX=SX*1.5:SY=SY*-1.5:? #2;"M";SX;",";SY
1760 OLDSX=SX:OLDSY=SY
1770 FOR COUNTER=2 TO SIDES:X=WIREX(CNTR,COUNTER):Y=WIREY(CNTR,COUNTER):Z=WIREZ(CNTR)
1780 GOSUB 500:SX=SX*1.5:SY=SY*1.5
1790 ? #2,"D";SX;",";SY:NEXT COUNTER
1800 ? #2,"D";OLDSX;",";OLDSY:NEXT CNTR
1810 REM ADD THE DEPTH LINES
1820 FOR CNTR=1 TO SIDES
1830 X=WIREX(1,CNTR):Y=WIREY(1,CNTR):Z=WIREZ(1):GOSUB 500:SX=SX*1.5:SY=SY*1.5:? #2,"M";SX;",";SY
1840 FOR COUNTER=2 TO CPTS:X=WIREX(COUNTER,CNTR):Y=WIREY(COUNTER,CNTR):Z=WIREZ(COUNTER):GOSUB 500
1850 SX=SX*1.5:SY=SY*1.5:? #2;"D";SX;",";SY
1860 NEXT COUNTER:NEXT CNTR:CLOSE #2:GOTO 410