Atariwriter Plus Default Adjuster (ADA.BAS)

Atariwriter Plus Default Adjuster by Paul Alhart, 20

Description

Atariwriter Plus Default Adjuster by Paul Alhart, 20

From the Antic disk of July 1988 (Vol. 7 No. 3).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.4 KB

Dialect
Atari BASIC
Lines
43
Variables
A(, B(, A$, C, E, Q, W, B, I, A
BASIC listing (43 lines)
1 REM ATARIWRITER PLUS DEFAULT ADJUSTER
3 REM BY PAUL ALHART
4 REM FOR THE ATARI FEDERATION
10 DIM A(55),B(27),A$(3):C=0:E=0
15 ? CHR$(125);"Place disk containing 'AP.OBJ'":? "in Drive #1."
20 ? "Press RETURN when ready":INPUT A$
30 TRAP 1000:POKE 82,2:OPEN #1,12,0,"D:AP.OBJ":NOTE #1,Q,W:Q=Q+79:W=W+56
40 IF C=2 THEN 1000
50 POINT #1,Q,W:B=0:FOR I=1 TO 4:GET #1,A:B=B+A:NEXT I
60 IF B<>262 THEN Q=Q+21:W=W+36:C=C+1:GOTO 40
70 FOR I=0 TO 55:GET #1,A:A(I)=A:NEXT I
80 ? CHR$(125),"CURRENT  DEFAULTS":? :? "POWER UP",,"TAB     KEY":POSITION 2,4:C=0:GOSUB 500
90 C=C+32:POKE 82,22:POSITION 22,4:GOSUB 500
100 POKE 82,8:? :? "Edit  Write  Quit":INPUT A$
110 IF A$(1,1)="Q" THEN END
120 IF A$(1,1)="W" AND E=1 THEN W=W+4:GOTO 700
130 POSITION 8,4:E=1
140 FOR I=0 TO 13:INPUT A$:A=VAL(A$):B(I)=A:NEXT I
150 POKE 82,28:POSITION 28,4
160 FOR I=14 TO 27:INPUT A$:A=VAL(A$):B(I)=A:NEXT I
170 GOTO 100
500 ? "B >--- ";A(C)
510 ? "D >--- ";A(C+2)
520 ? "G >--- ";A(C+5)
530 ? "I >--- ";A(C+7)
540 ? "J >--- ";A(C+8)
550 ? "L >--- ";A(C+10)
560 ? "M >--- ";A(C+11)
570 ? "N >--- ";A(C+12)
580 ? "Q >--- ";A(C+15)
590 ? "R >--- ";A(C+16)
600 ? "S >--- ";A(C+17)
610 ? "T >--- ";A(C+18)
620 ? "W >--- ";A(C+21)
630 ? "Y >--- ";A(C+23)
640 RETURN
700 A(0)=B(0):A(2)=B(1):A(5)=B(2):A(7)=B(3):A(8)=B(4):A(10)=B(5):A(11)=B(6)
710 A(12)=B(7):A(15)=B(8):A(16)=B(9):A(17)=B(10):A(18)=B(11):A(21)=B(12):A(23)=B(13)
720 A(32)=B(14):A(34)=B(15):A(37)=B(16):A(39)=B(17):A(40)=B(18):A(42)=B(19):A(43)=B(20)
730 A(44)=B(21):A(47)=B(22):A(48)=B(23):A(49)=B(24):A(50)=B(25):A(53)=B(26):A(55)=B(27)
740 POINT #1,Q,W:FOR I=0 TO 55:A=A(I):PUT #1,A:NEXT I
750 CLOSE #1:GOTO 30
1000 CLOSE #1:? "↰ERROR #             ";PEEK(195):END