String Array Handler demo (STRING2.BAS)

String Array Handler demo by Richard Whitsell, 14

Description

String Array Handler demo by Richard Whitsell, 14

From the Antic disk of June 1988 (Vol. 7 No. 2) — disk A.

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 896 bytes

Dialect
Atari BASIC
Lines
36
Variables
MAXNUM, MAXLEN, STORAGE$, WORK$, LENARRAY(, INDEX, START, LENGTH, FINISH
BASIC listing (36 lines)
2 REM STRING ARRAY HANDLER #2
4 REM BY RICHARD WHITSELL
6 REM (c)1988, ANTIC PUBLISHING INC.
10 MAXNUM=10:MAXLEN=20
20 DIM STORAGE$(MAXNUM*MAXLEN)
30 DIM WORK$(MAXLEN)
35 DIM LENARRAY(MAXNUM)
40 GRAPHICS 0
50 PRINT "ENTER 10 NAMES"
60 FOR INDEX=0 TO MAXNUM-1
70 INPUT WORK$:GOSUB 6000
80 NEXT INDEX
90 GRAPHICS 0
100 PRINT "NAME",,"LENGTH"
105 REM =========================
110 FOR INDEX=0 TO MAXNUM-1
120 GOSUB 5000
130 PRINT WORK$,LEN(WORK$)
140 NEXT INDEX
145 REM =========================
150 END
4999 REM SUBROUTINE TO GET STRING
5000 START=INDEX*MAXLEN+1
5010 LENGTH=LENARRAY(INDEX)
5015 IF LENGTH=0 THEN WORK$="":RETURN
5020 FINISH=START+LENGTH-1
5030 WORK$=STORAGE$(START,FINISH)
5040 RETURN
5998 REM
5999 REM SUBROUTINE TO PUT STRING
6000 START=INDEX*MAXLEN+1
6010 LENARRAY(INDEX)=LEN(WORK$)
6015 IF LEN(WORK$)=0 THEN RETURN
6020 FINISH=START+LEN(WORK$)-1
6030 STORAGE$(START,FINISH)=WORK$
6040 RETURN