graphics utility (GEDIT.BAS)
graphics utility by Robin Alan Sherer, 42
Description
graphics utility by Robin Alan Sherer, 42
From the Antic disk of June 1988 (Vol. 7 No. 2) — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 5.1 KB
- Dialect
- Atari BASIC
- Lines
- 164
- Variables
BRK,WT$,FM$,MM$,SS$,CC$,PIC$,F$,G$,H(,SA,I,B,C,J,R,UC,N,CI,RI,X,T,S,K,C1,C2,C3,C4,W,A,Y
BASIC listing (164 lines)
1000 REM GEDIT.BAS
1010 REM BY ROBIN SHERER
1020 REM (c)1987, ANTIC PUBLISHING
1030 REM
1040 BRK=PEEK(53279)<>5
2000 REM ASSEMBLY ROUTINES
2020 DIM WT$(57):REM TDELAY.OBJ
2030 WT$="hh*◆♥p▌)▶▔▶╱◣ ╱"▶JP↰◢PxN▶╱Pq*JPgh*◆♥p─▔▶╱ ╱"▶JP↰◢PxN▶╱Pq◆"
2060 REM
2070 DIM FM$(54):REM FILMEM.OBJ
2080 FM$="hh┐Mh┐Lhh┐Nh*◆♥p♣ ▶%N┌L◢P♠┌LfMJPph(@♥p▂%N◢@♥p┐┌L◢P♠┌L◆"
2110 REM
2120 DIM MM$(49):REM MOVMEM.OBJ
2130 MM$="hh┐Oh┐Nh┐Mh┐Lh*◆♥p─ ▶1N┌L◢@▶PwfOfMJPnh(1N┌L◢@▶Pw◆"
2160 REM
2170 DIM SS$(95):REM SOUNDS.OBJ
2180 SS$="hhhI┘p>I▕p )●▔♥R".▂├R)▕▔↑▕)♥M↑▕P♠JJ▂├R◆ Pk◆)(▔♥R)*▔├R)♣▔↑▕)♥M↑▕P♠▔├R◆)▘▔♥R)J▔├R)♣▔↑▕)♥M↑▕P♠▔├R◆"
2230 REM
2240 DIM CC$(37):REM CIOCTL.OBJ
2250 CC$="hhh*)♥┴i♣JPz*hh↓B┘h↓E┘h↓D┘h↓I┘h↓H┘LVd"
3000 DIM PIC$(7689):PIC$(1)="♥":PIC$(7689)=PIC$:PIC$(2)=PIC$
4000 REM
4010 REM MAILINE
4020 DIM F$(16),G$(16)
4030 DIM H(10)
4040 GRAPHICS 10:GOSUB 5400
4050 SA=PEEK(88)+PEEK(89)*256
4060 RESTORE
4070 REM SET UP COLORS
4080 FOR I=704 TO 712
4090 READ B:POKE I,B
4100 NEXT I
4110 DATA 12,0,29,66,71
4120 DATA 123,156,214,234
4130 REM DRAW SCREEN
4140 COLOR 1
4150 PLOT 0,0:DRAWTO 79,0
4160 PLOT 0,182:DRAWTO 79,182
4170 FOR I=1 TO 8
4180 COLOR I:C=(I*10)-1
4190 FOR J=184 TO 188
4200 PLOT C-1,J:DRAWTO C-9,J
4210 NEXT J
4220 NEXT I
4230 C=37:R=90:UC=1:N=1:CI=2:RI=3
4240 REM GET USER INPUT
4250 X=USR(ADR(WT$),40)
4260 TRAP 5170:POKE 764,255
4270 T=STRIG(0):S=STICK(0)
4280 FOR I=1 TO 9
4290 H(I)=PEEK(703+I)
4300 NEXT I
4310 K=PEEK(764):IF T=1 THEN 4370
4320 REM PAINT
4330 FOR I=R-RI TO R
4340 PLOT C,I:DRAWTO C+CI,I
4350 NEXT I
4360 REM FLASH CURSOR
4370 LOCATE C,R,C1
4380 LOCATE C,R-RI,C2
4390 LOCATE C+CI,R-RI,C3
4400 LOCATE C+CI,R,C4
4410 COLOR 0:PLOT C,R
4420 PLOT C,R-RI
4430 PLOT C+CI,R-RI
4440 PLOT C+CI,R
4450 X=USR(ADR(WT$),1)
4460 COLOR 1
4470 X=USR(ADR(WT$),1)
4480 PLOT C,R
4490 PLOT C,R-RI
4500 PLOT C+CI,R-RI
4510 PLOT C+CI,R:POKE 77,0
4520 X=USR(ADR(WT$),1)
4530 COLOR C1:PLOT C,R
4540 COLOR C2:PLOT C,R-RI
4550 COLOR C3:PLOT C+CI,R-RI
4560 COLOR C4:PLOT C+CI,R
4570 COLOR N
4580 REM CHECK KEYBOARD
4590 IF K=255 THEN 5190
4595 X=USR(ADR(SS$),0)
4600 IF K=47 THEN POKE 764,255:END
4610 IF K=42 THEN N=0:GOTO 4250
4620 IF K=118 THEN 4040
4630 IF K<128 THEN 4750
4640 IF K=142 THEN RI=RI+1
4650 IF K=143 THEN RI=RI-1
4660 IF K=134 THEN CI=CI-1
4670 IF K=135 THEN CI=CI+1
4680 S=1:IF RI<0 THEN RI=0:S=2
4690 IF CI<0 THEN CI=0:S=2
4700 IF RI>20 THEN RI=20:S=2
4710 IF CI>20 THEN CI=20:S=2
4720 X=USR(ADR(SS$),S)
4730 GOTO 5290
4740 REM GET COLOR
4750 IF K<>18 THEN 5010
4760 N=INT((UC+10)/10):COLOR N
4770 COLOR 1
4780 PLOT UC-1,191:DRAWTO UC+7,191
4790 X=USR(ADR(WT$),40):COLOR W
4800 T=STRIG(0):IF T=0 THEN 4920
4810 S=STICK(0)
4820 REM COLOR HUE
4830 IF S<>13 AND S<>14 THEN 4910
4840 A=(N-1)*16
4850 IF S=14 THEN B=PEEK(704+N)+2
4860 IF S=13 THEN B=PEEK(704+N)-2
4870 IF B<0 THEN B=0
4880 IF B>255 THEN B=255
4890 POKE 704+N,B:GOTO 4790
4900 REM COLOR SELECTION
4910 IF S<>7 AND S<>11 THEN 4790
4920 COLOR 0
4930 PLOT UC-1,191:DRAWTO UC+7,191
4940 COLOR N
4950 IF T=0 THEN 4250
4960 IF S=7 THEN UC=UC+10
4970 IF S=11 THEN UC=UC-10
4980 IF UC<1 THEN UC=1
4990 IF UC>71 THEN UC=71
5000 GOTO 4760
5005 REM SAVE SCREEN
5010 IF K<>62 THEN 5095
5020 POKE 764,255:X=USR(ADR(MM$),(PEEK(88)+PEEK(89)*256),ADR(PIC$),7680)
5030 FOR X=704 TO 712:PIC$(6977+X,6977+X)=CHR$(PEEK(X)):NEXT X
5040 GRAPHICS 0:GOSUB 5400:? :? "Filename to SAVE";:INPUT G$:IF LEN(G$)<1 THEN 5080
5050 IF G$(1,1)="D" AND (G$(2,2)=":" OR G$(3,3)=":") THEN F$=G$:GOTO 5070
5060 F$(1,2)="D:":F$(3,LEN(G$)+2)=G$
5070 CLOSE #1:OPEN #1,8,0,F$:? #1;PIC$;:CLOSE #1
5080 POKE 559,0:GRAPHICS 10:GOSUB 5400:X=USR(ADR(MM$),ADR(PIC$),(PEEK(88)+PEEK(89)*256),7680)
5085 FOR X=704 TO 712:POKE X,ASC(PIC$(6977+X,6977+X)):NEXT X:POKE 559,34:GOTO 4250
5090 REM LOAD SCREEN
5095 IF K<>0 THEN 5190
5100 POKE 764,255:X=USR(ADR(MM$),(PEEK(88)+PEEK(89)*256),ADR(PIC$),7680)
5110 FOR X=704 TO 712:PIC$(6977+X,6977+X)=CHR$(PEEK(X)):NEXT X
5120 GRAPHICS 0:GOSUB 5400:? :? "Filename to LOAD";:INPUT G$:IF LEN(G$)<1 THEN 5080
5130 IF G$(1,1)="D" AND (G$(2,2)=":" OR G$(3,3)=":") THEN F$=G$:GOTO 5140
5135 F$(1,2)="D:":F$(3,LEN(G$)+2)=G$
5140 CLOSE #1:OPEN #1,4,0,F$
5150 GRAPHICS 10:GOSUB 5400:X=USR(ADR(CC$),1,7,SA,7680)
5155 FOR X=704 TO 712:GET #1,Y:POKE X,Y:NEXT X
5160 CLOSE #1:GOTO 4250
5170 X=USR(ADR(SS$),3):GOTO 4250
5180 REM CURSOR MOVEMENT
5190 IF S=15 THEN 4270
5200 IF S=14 THEN R=R-RI-1
5210 IF S=13 THEN R=R+RI+1
5220 IF S=11 THEN C=C-CI-1
5230 IF S=10 THEN R=R-RI-1:C=C-CI-1
5240 IF S=9 THEN R=R+RI+1:C=C-CI-1
5250 IF S=7 THEN C=C+CI+1
5260 IF S=6 THEN R=R-RI-1:C=C+CI+1
5270 IF S=5 THEN R=R+RI+1:C=C+CI+1
5280 REM CHECK CURSOR LIMITS
5290 IF C<0 THEN C=0
5300 IF C>79-CI THEN C=79-CI
5310 IF R<1+RI THEN R=1+RI
5320 IF R>181 THEN R=181
5330 GOTO 4260
5340 END
5400 IF BRK THEN POKE 16,112:POKE 53774,112
5410 RETURN
