Ballpark Figures (BALLPARK.BAS)
Ballpark Figures by Ed Brown, 107
Description
Ballpark Figures by Ed Brown, 107
From the Antic disk of April 1988 (Vol. 6 No. 12).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 11.8 KB
- Dialect
- Atari BASIC
- Lines
- 229
- Variables
ILF,C,NSP,A,BO(,PTR,FNAME$,NPIF,WIN,LOSS,FILE$,A$,PTR2,BK$,F6,F7,FIND$,CUR$,FPTR,ER,TITLE$,OAB,AVG,AWMO,SP,OBP,SAC,SH,S,D,T,H,RBI,GW,BB,R,SB,SBA,SO,HIDP,ABWMO,WMO,LP,CP,RP,TH,LH,CH,RH,AB,ETC,T$,L,FND,C1,WM,HT,F1,F2,F3,F5,INNING,Y,KEY,K,K$,GWF,F4,X,SORT$
BASIC listing (229 lines)
10 REM BALLPARK FIGURES
11 REM BY ED BROWN
15 REM (c)1988, ANTIC PUBLISHING
20 GOTO 1060
60 REM LINEUP CHECK
65 ILF=0:FOR C=1 TO NSP:IF A=BO(C) AND C<>PTR THEN ILF=1
70 NEXT C:IF ILF THEN ? "↰↑#";A;" already in lineup ":FOR C=1 TO 500:NEXT C
75 RETURN
80 REM SAVE
85 ? "Save to what filename";:INPUT FNAME$:GOSUB 395:OPEN #2,8,0,FNAME$:? #2;NPIF:? #2;WIN:? #2;LOSS
90 FOR C=1 TO LEN(FILE$) STEP 74:? #2;FILE$(C,C+73):NEXT C:CLOSE #2:RETURN
95 REM APPEND
100 POSITION 2,22:? "You want to append (Y or N)?":CLOSE #1:OPEN #1,4,0,"K:":GET #1,A:A$=CHR$(A)
105 IF A$="N" THEN POSITION 1,19:? " ":GOTO 130
110 IF A$<>"Y" THEN 100
115 POSITION 2,22:? "Enter the # of the new player";:INPUT A
120 PTR2=PTR:PTR=0:GOSUB 65:PTR=PTR2:IF ILF THEN 115
125 NSP=NSP+1:BO(NSP)=A
130 POSITION 2,22:? BK$:RETURN
135 REM SUBSTITUTE
140 POSITION 2,22:? "You want to substitute (Y or N)?":CLOSE #1:OPEN #1,4,0,"K:":GET #1,A:A$=CHR$(A)
141 IF A$="N" THEN POSITION 2,22:? BK$:POSITION 1,18:? " ":RETURN
142 IF A$<>"Y" THEN 140
144 GOSUB 810:IF F6 THEN F7=1
145 POSITION 2,22:? "Enter the # of the substitute ←←←";:INPUT A
150 GOSUB 65:IF ILF THEN 145
155 BO(PTR)=A:FIND$=STR$(A)
160 IF LEN(FIND$)=1 THEN FIND$(2)="♥"
165 GOSUB 440:CUR$=FILE$(FPTR,FPTR+73):GOSUB 495:GOSUB 520:RETURN
170 REM ERROR TRAP
175 ER=PEEK(195):POP :CLOSE #2:IF ER=138 THEN ? "DEVICE NOT ON":GOTO 200
180 IF ER=162 THEN ? "DISK FULL":GOTO 200
185 IF ER=170 THEN ? "FILE NOT FOUND":GOTO 200
190 IF ER=165 THEN ? "INVALID FILENAME":GOTO 200
195 ? "***ERROR: CODE ";ER
200 FOR C=1 TO 500:NEXT C:TRAP 175:GOTO 1080
205 REM PRINT
210 ? "Input team name";:INPUT CUR$:? "Input today's date";:INPUT FNAME$:LPRINT BK$;TITLE$
211 LPRINT CHR$(15):REM CONDENSED PRINT
215 LPRINT :LPRINT "Stats for ";CUR$;", ";FNAME$:LPRINT
220 LPRINT "Current Record: Won ";WIN;", Lost ";LOSS:LPRINT :OPEN #2,8,0,"P:"
225 ? #2;"PLAYER ";
230 ? #2;"AB AVG WMO SLUG% OB% SF SH H 2B 3B HR RBI GW BB R SB SBA SO GIDP"
235 POKE 201,3:FPTR=1:FOR C=1 TO NPIF:CUR$=FILE$(FPTR,FPTR+73):GOSUB 495:GOSUB 335
240 ? #2;"#";VAL(FILE$(FPTR,FPTR+1));" ";:IF VAL(FILE$(FPTR,FPTR+1))<10 THEN ? #2;" ";
245 ? #2;FILE$(FPTR+2,FPTR+16);" ";
250 A=OAB:GOSUB 275:A=AVG:GOSUB 300:A=AWMO:GOSUB 300:A=SP:GOSUB 300:A=OBP:GOSUB 300
255 A=SAC:GOSUB 275:A=SH:GOSUB 275:A=S+D+T+H:GOSUB 275:A=D:GOSUB 275:A=T:GOSUB 275:A=H:GOSUB 275:A=RBI:GOSUB 275
260 A=GW:GOSUB 275:A=BB:GOSUB 275:A=R:GOSUB 275:A=SB:GOSUB 275:A=SBA:GOSUB 275:A=SO:GOSUB 275:A=HIDP:GOSUB 275
265 ? #2;"":FPTR=FPTR+74:NEXT C:CLOSE #2:RETURN
270 REM ?NUM
275 IF A<10 THEN ? #2;" ";A;" ";:GOTO 290
280 IF A<100 THEN ? #2;" ";A;:GOTO 290
285 ? #2;A;
290 ? #2;" ";:RETURN
295 REM %
300 IF A<0 THEN ? #2;" ---- ";:GOTO 325
305 IF A<10 THEN ? #2;" .00";A;" ";:GOTO 325
310 IF A<100 THEN ? #2;" .0";A;" ";:GOTO 325
315 IF A<1000 THEN ? #2;" .";A;" ";:GOTO 325
320 FNAME$=STR$(A):? #2;FNAME$(1,1);".";FNAME$(2,4);" ";
325 RETURN
330 REM CALC
335 AVG=-1:SP=-1:IF OAB>0 THEN AVG=INT(1000*(S+D+T+H)/OAB+0.5):SP=INT(1000*(S+2*D+3*T+4*H)/OAB+0.5)
340 AWMO=-1:IF ABWMO>0 THEN AWMO=INT(1000*WMO/ABWMO+0.5)
345 LP=0:CP=0:RP=0:IF TH>0 THEN LP=INT(100*LH/TH+0.5):CP=INT(100*CH/TH+0.5):RP=INT(100*RH/TH+0.5)
350 OBP=-1:IF AB>0 THEN OBP=INT(1000*(S+D+T+H+BB+ETC)/AB+0.5)
355 RETURN
360 REM W/L RECORD
365 ? "↰Did this team win this game (Y or N)?":CLOSE #1:OPEN #1,4,0,"K:":GET #1,A:A$=CHR$(A)
370 IF A$="Y" THEN WIN=WIN+1:GOTO 385
375 IF A$="N" THEN LOSS=LOSS+1:GOTO 385
380 GOTO 365
385 RETURN
390 REM FILENAME CHECK
395 T$=FNAME$:IF T$(1,2)="D:" OR T$(1,3)="D1:" OR T$(1,3)="D2:" OR T$(1,3)="D3:" OR T$(1,3)="D4:" THEN 405
400 FNAME$(1,2)="D:":FNAME$(3)=T$
405 RETURN
410 REM LOAD FILE
415 ? "Load from what file";:INPUT FNAME$:GOSUB 395:OPEN #2,4,0,FNAME$:INPUT #2;NPIF:INPUT #2;WIN:INPUT #2;LOSS
420 L=1:TRAP 430
425 INPUT #2;CUR$:FILE$(L)=CUR$:L=L+74:GOTO 425
430 CLOSE #2:TRAP 175:RETURN
435 REM FIND PLAYER
440 FND=0:FPTR=1:IF NPIF=0 THEN 460
445 FOR C=1 TO NPIF:IF FILE$(FPTR,FPTR+1)=FIND$ THEN FND=1:GOTO 455
450 FPTR=FPTR+74
455 NEXT C
460 IF NOT FND THEN GOSUB 475
465 RETURN
470 REM NEW PLAYER
475 NPIF=NPIF+1:POSITION 2,22:? "↰Player #";BO(PTR);" is new. What is this player's name";:INPUT FNAME$
480 FILE$(FPTR,FPTR+1)=FIND$:FILE$(FPTR+2,FPTR+16)=" ":FILE$(FPTR+2,FPTR+16)=FNAME$
485 FOR C1=18 TO 72 STEP 3:FILE$(FPTR+C1-1,FPTR+C1+2)="0♥♥":NEXT C1:RETURN
490 REM TRANSFER DN
495 OAB=VAL(CUR$(18,20)):AB=VAL(CUR$(21,23)):S=VAL(CUR$(24,26)):D=VAL(CUR$(27,29)):T=VAL(CUR$(30,32))
500 H=VAL(CUR$(33,35)):BB=VAL(CUR$(36,38)):ETC=VAL(CUR$(39,41)):SB=VAL(CUR$(42,44)):SBA=VAL(CUR$(45,47))
505 SAC=VAL(CUR$(48,50)):RBI=VAL(CUR$(51,53)):SO=VAL(CUR$(54,56)):GW=VAL(CUR$(57,59)):HIDP=VAL(CUR$(60,62))
510 SH=VAL(CUR$(63,65)):WMO=VAL(CUR$(66,68)):R=VAL(CUR$(69,71)):ABWMO=VAL(CUR$(72,74)):RETURN
515 REM PRINT MENU
520 WM=0:HT=0:F1=0:F2=0:F3=0:F5=0:F6=0:? "↰INN:";INNING;" BATTER:";PTR;", #";VAL(CUR$(1,2));", ";CUR$(3,17)
525 ? "A)Single":? "B)Double":? "C)Triple":? "D)Home Run":? "E)Base on Balls":? "F)Hit batter,Interference"
530 ? "G)Reached on Error,CTRL G for FC":? "H)Out (CTRL H for Strikeout)":? "I)Sacrifice Out"
535 ? "J)Hit into Double Play"
540 ? "K)RBI's":? "L)Attempted Steal":? "M)Scored":? "N)Men on base":? "O)Next Batter":? "P)Next Inning"
545 ? "Q)Quit":? "R)Substitution":? "S)Append Lineup":? "T)Redo this frame":? "QUERY LINE:":RETURN
550 REM CHOICE
555 POSITION 0,Y:? ">"
560 IF PEEK(764)=255 THEN 560
565 KEY=PEEK(764):CLOSE #1:OPEN #1,4,0,"K:":GET #1,K
570 IF KEY=14 THEN POSITION 0,Y:? " ":Y=Y-1:IF Y=0 THEN Y=20
575 IF KEY=15 THEN POSITION 0,Y:? " ":Y=Y+1:IF Y=21 THEN Y=1
580 IF KEY=14 OR KEY=15 THEN POSITION 0,Y:? ">":GOTO 560
585 IF KEY=12 THEN K=64+Y:GOTO 605
590 IF K=8 THEN K=72:IF NOT F1 THEN SO=SO+1
595 IF (K>64 AND K<85) OR K=7 THEN 605
600 GOTO 560
605 K$=CHR$(K):POSITION 2,22:RETURN
610 REM HIT
615 HT=1:F1=1:IF K$="A" THEN S=S+1
620 IF K$="B" THEN D=D+1
625 IF K$="C" THEN T=T+1
630 IF K$="D" AND NOT F2 THEN F2=1:R=R+1:POSITION 1,13:? "*"
635 IF K$="D" THEN H=H+1:IF NOT F5 THEN GOSUB 655
640 IF WM THEN WMO=WMO+1
645 OAB=OAB+1:AB=AB+1:RETURN
650 REM RBI
655 GWF=1:F5=1:IF F7 THEN GWF=0
660 POSITION 2,22:? "How many RBI's (1-4";:IF GWF THEN ? ",G";
665 ? ")? ":CLOSE #1:OPEN #1,4,0,"K:":GET #1,A:A$=CHR$(A)
670 IF (ASC(A$)<49 OR ASC(A$)>52) AND A$<>"G" THEN 660
675 IF A$="G" AND NOT F6 AND NOT F7 THEN GWF=0:GW=GW+1:F6=1:GOTO 660
680 IF A$="G" AND NOT GWF THEN POSITION 2,22:? "↰":GOTO 660
685 A=VAL(A$):RBI=RBI+A:POSITION 2,22:? BK$:POSITION 1,11:? "*"
690 IF K$="D" AND A>1 AND NOT F3 THEN K$="N":POSITION 1,14:? "*":GOTO 700
695 IF NOT F3 AND K$<>"D" THEN K$="N":POSITION 1,14:? "*"
700 RETURN
705 REM SAC
710 POSITION 2,22:? "Sacrifice (H)it or (F)ly?":CLOSE #1:OPEN #1,4,0,"K:":GET #1,A:A$=CHR$(A)
715 IF A$<>"H" AND A$<>"F" THEN 710
720 IF A$="H" THEN SH=SH+1:GOTO 730
725 SAC=SAC+1
730 POSITION 2,22:? BK$:RETURN
735 REM STEAL
740 SBA=SBA+1
745 POSITION 2,22:? "Successful steal (Y or N)?":CLOSE #1:OPEN #1,4,0,"K:":GET #1,A:A$=CHR$(A)
750 IF A$="Y" THEN SB=SB+1:GOTO 760
755 IF A$<>"N" THEN 745
760 POSITION 2,22:? BK$
765 RETURN
770 REM FLAG CHECK
775 F4=0:IF F1 AND ASC(K$)>64 AND ASC(K$)<75 THEN F4=1
777 IF F1 AND K$="╲" THEN F4=1:? "↰":GOTO 800
780 IF F2 AND K$="M" THEN F4=1
785 IF F3 AND K$="N" THEN F4=1
790 IF F5 AND K$="K" THEN F4=1
795 IF F4 THEN POSITION 2,ASC(K$)-64:? "↰"
800 RETURN
805 REM TRANSFER UP
810 CUR$(18,20)=STR$(OAB):CUR$(21,23)=STR$(AB):CUR$(24,26)=STR$(S):CUR$(27,29)=STR$(D):CUR$(30,32)=STR$(T)
815 CUR$(33,35)=STR$(H):CUR$(36,38)=STR$(BB):CUR$(39,41)=STR$(ETC):CUR$(42,44)=STR$(SB):CUR$(45,47)=STR$(SBA)
820 CUR$(48,50)=STR$(SAC):CUR$(51,53)=STR$(RBI):CUR$(54,56)=STR$(SO):CUR$(57,59)=STR$(GW):CUR$(60,62)=STR$(HIDP)
825 CUR$(63,65)=STR$(SH):CUR$(66,68)=STR$(WMO):CUR$(69,71)=STR$(R):CUR$(72,74)=STR$(ABWMO)
830 FILE$(FPTR,FPTR+73)=CUR$:RETURN
835 REM ENTER A GAME
840 POSITION 2,11
845 ? "Is this the first game entered for this team (Y or N)?":CLOSE #1:OPEN #1,4,0,"K:":GET #1,A:A$=CHR$(A)
850 IF A$<>"Y" AND A$<>"N" THEN 840
855 IF A$="Y" THEN GOSUB 1200:GOTO 880
860 POSITION 2,13
865 ? "Is this team's file already loaded in (Y or N)?":CLOSE #1:OPEN #1,4,0,"K:":GET #1,A:A$=CHR$(A)
870 IF A$<>"Y" AND A$<>"N" THEN 860
875 IF A$="N" THEN GOSUB 415
880 ? "↰":? :? :? "How many players in the starting lineup";:INPUT NSP:FOR C=1 TO NSP:BO(C)=-1:NEXT C
885 ? "Enter the starting batting order by player numbers":FOR PTR=1 TO NSP
890 ? BK$:? "↑Batter #";PTR;:INPUT A
895 ? "↓";:GOSUB 65:IF ILF THEN ? "↑";BK$:? "↑↑";BK$:? "↑↑":GOTO 890
900 IF NOT ILF THEN ? "↑";
905 BO(PTR)=A:NEXT PTR:PTR=1:INNING=1
910 FIND$=STR$(BO(PTR)):IF LEN(FIND$)=1 THEN FIND$(2)="♥"
915 GOSUB 440:CUR$=FILE$(FPTR,FPTR+73):GOSUB 495
920 GOSUB 520:Y=1
925 GOSUB 555
930 GOSUB 775:IF F4 THEN 925
935 IF KEY=12 THEN POSITION 1,Y:? "*"
940 IF K>64 AND K<85 THEN POSITION 1,K-64:? "*"
942 IF K=7 THEN POSITION 1,7:? "*"
945 IF K$="T" THEN GOSUB 495:Y=1:GOSUB 520:POSITION 2,22:? "O.K., do it over":F1=0:F2=0:F3=0
950 IF K$="A" OR K$="B" OR K$="C" OR K$="D" THEN GOSUB 615
955 IF K$="E" THEN BB=BB+1:AB=AB+1:F1=1
960 IF K$="F" THEN ETC=ETC+1:AB=AB+1:F1=1
965 IF K$="G" THEN AB=AB+1:OAB=OAB+1:F1=1
967 IF K$="╲" THEN AB=AB+1:OAB=OAB+1:F1=1:IF NOT F3 THEN K$="N":POSITION 1,14:? "*"
970 IF K$="H" THEN OAB=OAB+1:AB=AB+1:F1=1
975 IF K$="I" THEN GOSUB 710:AB=AB+1:F1=1:IF NOT F3 THEN K$="N":POSITION 1,14:? "*"
980 IF K$="J" THEN HIDP=HIDP+1:AB=AB+1:OAB=OAB+1:F1=1:IF NOT F3 THEN K$="N":POSITION 1,14:? "*"
985 IF K$="K" THEN GOSUB 655
990 IF K$="L" THEN GOSUB 740
995 IF K$="M" THEN R=R+1:F2=1
1000 IF K$="R" THEN GOSUB 140
1005 IF K$="S" THEN GOSUB 100
1010 IF K$="N" THEN ABWMO=ABWMO+1:WM=1:F3=1:IF HT THEN WMO=WMO+1
1015 IF K$="O" OR K$="P" OR K$="Q" THEN GOSUB 810:PTR=PTR+1:IF PTR>NSP THEN PTR=1
1020 IF (K$="O" OR K$="P") AND F6 THEN F7=1
1025 IF K$="P" THEN INNING=INNING+1:GOTO 910
1030 IF K$="O" THEN 910
1035 IF K$="Q" THEN 1045
1040 GOTO 925
1045 GOSUB 365:IF FILE$<>"" THEN X=USR(ADR(SORT$),ADR(FILE$),74,INT(LEN(FILE$)/74),3,15,0)
1050 RETURN
1055 REM MAIN PROGRAM
1060 DIM SORT$(182),A$(1),FILE$(3500),TITLE$(40),BO(15),FIND$(2),FNAME$(15),CUR$(75),K$(1),BK$(35),T$(15)
1065 POKE 710,132:POKE 712,6:POKE 709,10:POKE 752,1:TRAP 175:WIN=0:LOSS=0:F7=0
1070 GOSUB 1150:BK$=" ":REM 35 BLANKS
1072 SORT$(1,65)="Xh8i┘┐Yh┐Lh┐Kh┐Wh┐Vh┐Rh┐Q"♥hh↓♥├hdYPv8%Qi▕┐Q%Ri♥┐R0l%Q┐S%R┐T%L┐N┐"
1073 SORT$(66,130)="P%K┐M┴eV┐O%PeW┐P ♥9♥├>▕├╱Z>├├HHH┤X(◢1MQOp▘%ZP┤♣♣0.♣,0◣HJPj$XDYPRF"
1074 SORT$(131,182)="S)▶ESP╱&Tp▝FT%P┐N%O┴♣,%Up┤╱UP●◆╱U ♥1M*1O┌M◣┌OHDVPqpK"
1075 TITLE$="********** BALLPARK FIGURES ********"
1080 ? "↰";TITLE$:? :? "MAIN MENU (select # of choice)":? :?
1085 ? "1) Print":? "2) Save File":? "3) Load file"
1086 ? "4) Enter a Game":? :CLOSE #1:OPEN #1,4,0,"K:":GET #1,A:A$=CHR$(A)
1090 IF A$<>"1" AND A$<>"2" AND A$<>"3" AND A$<>"4" THEN 1080
1095 A=VAL(A$)
1100 ON A GOSUB 205,85,415,840:GOTO 1080
1150 POKE 16,112:POKE 53774,112:RETURN
1200 WIN=0:LOSS=0
1210 FOR A=1 TO LEN(FILE$)-73 STEP 74
1220 FILE$(A+17,A+73)="0♥♥0♥♥0♥♥0♥♥0♥♥0♥♥0♥♥0♥♥0♥♥0♥♥0♥♥0♥♥0♥♥0♥♥0♥♥0♥♥0♥♥0♥♥0♥♥"
1230 NEXT A:RETURN
