Smoothy programming demo (SMOOTHY.BAS)
Smoothy programming demo by Kenneth Kaye, 88 (BASIC, MAC/65 source)
Description
Smoothy programming demo by Kenneth Kaye, 88 (BASIC, MAC/65 source)
From the Antic disk of March 1988 (Vol. 6 No. 11).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 5.0 KB
- Dialect
- Atari BASIC
- Lines
- 87
- Variables
BGN,LD$,MS$,CL$,PR$,TPC$,TPR$,CRY$,POS(,INP(,SPT(,ANS(,DMA,X,A,Q,MODE,SPEED,COL,ROW,WLEN,COLR,DC,DR,D,GNB,VAR,CVAL,MODL,N,Y,A$
BASIC listing (87 lines)
2 REM SMOOTHY DEMO
4 REM BY KENNETH KAYE
6 REM (c)1987, ANTIC PUBLISHING
10 GOSUB 400:POKE 106,PEEK(740)
20 IF PEEK(106)<>160 THEN ? "Not enough RAM to continue.":END
30 GOSUB 31000:REM INITIALIZE SCROLLO ROUTINE
40 DIM CL$(6),PR$(101),TPC$(12),TPR$(12),POS(14),INP(16),SPT(14),ANS(11)
45 DIM A$(40):A$="************** Mr.Smoothy **************"
70 FOR X=1 TO 14:READ A:POS(X)=A:NEXT X
80 FOR X=1 TO 14:READ A:INP(X)=A:NEXT X
90 FOR X=1 TO 14:READ A:SPT(X)=A:NEXT X
100 PR$="GRAPHICS MODE (3-15)SPEED (0-15)COLUMNROWWINDOW (1-40)COLOR#(1-4)MESSAGE (DEFAULT-PRESS RETURN)"
110 CL$=" "
130 MS$="MR.SMOOTHY * SMOOTH SCROLLING TEXT WINDOWS IN ALL MAP MODES. BY KEN KAYE":MODE=3
140 SPEED=10:COL=0:ROW=8:WLEN=10:COLR=4:DC=39:DR=23:POKE 559,DMA:CRY$=STR$(11):GOTO 1010
150 GRAPHICS 0:POKE 709,206:POKE 710,4:POKE 752,1:MS$=""
152 ? "↰":FOR X=39 TO 0 STEP -3:POSITION X,0:? A$(1,40-X):SOUND 1,6*X,14,14:NEXT X
160 FOR X=1 TO 14 STEP 2:POSITION POS(X),POS(X+1):? PR$(SPT(X),SPT(X+1)):NEXT X
165 TRAP 150
170 POSITION POS(1)-6,POS(2):? "ENTER":POSITION INP(1),INP(2):INPUT MODE:GOSUB 500
180 POSITION POS(5)+7,POS(6):? TPC$:POSITION POS(7)+4,POS(8):? TPR$
190 TRAP 150:POSITION POS(1)-6,POS(2):? CL$
200 FOR X=3 TO 11 STEP 2:POSITION POS(X)-6,POS(X+1):? "ENTER":POSITION INP(X),INP(X+1):INPUT A:ANS(X)=A
210 POSITION POS(X)-6,POS(X+1):? CL$
212 IF X=5 OR X=9 THEN GOSUB 250
216 NEXT X:POKE 82,0
220 POSITION POS(X)-6,POS(X+1):? "ENTER":POSITION INP(X),INP(X+1):INPUT MS$:POKE 82,2
230 IF MS$<>"" THEN 1000
240 MS$="THIS IS GRAPHICS MODE ":MS$(LEN(MS$)+1)=STR$(MODE):GOTO 1000
250 CVAL=VAL(TPC$(4,5))-ANS(5)
260 IF CVAL<=0 THEN POSITION 0,18:? "WINDOW VALUE WILL EXCEED MAX.":FOR D=1 TO 500:NEXT D:POP :GOTO 150
270 IF X=9 AND CVAL+1<ANS(9) THEN CVAL=0:GOTO 260
280 POSITION 15,12:? CL$
290 POSITION 15,12:? "(1-";STR$(CVAL+1);")"
300 RETURN
400 MODL=800:TRAP 410:POKE 559,0:GRAPHICS 15:MODL=130
410 GRAPHICS 0:POKE 559,34:RETURN
500 TRAP 535
520 IF MODE>15 THEN MODE=MODE-16
525 IF MODL=800 AND MODE>13 THEN POP :? "↰Illegal mode on 400/800 systems.":FOR D=1 TO 500:NEXT D:GOTO 150
530 ON MODE GOTO 535,535,540,550,555,560,565,570,580,590,600,535,535,610,620
535 POP :? "↰":? "ILLEGAL MODE":? :? "NOTE: MODES 12 & 13 ARE TEXT MODES":FOR D=1 TO 500:NEXT D:GOTO 150
540 TPC$="(0-09)":TPR$="(0-16)":DC=39:DR=23:CRY$="11":RETURN
550 TPC$="(0-09)":TPR$="(0-40)":DC=79:DR=47:CRY$="11":RETURN
555 TPC$="(0-19)":TPR$="(0-40)":DC=79:DR=47:CRY$="11":RETURN
560 TPC$="(0-19)":TPR$="(0-88)":DC=159:DR=95:CRY$="11":RETURN
565 TPC$="(0-39)":TPR$="(0-88)":DC=159:DR=95:CRY$="12":RETURN
570 TPC$="(0-39)":TPR$="(0-184)":DC=319:DR=191:CRY$="2":RETURN
580 TPC$="(0-39)":TPR$="(0-184)":DC=79:DR=191:CRY$="350017":RETURN
590 TPC$="(0-39)":TPR$="(0-184)":DC=79:DR=191:CRY$="300608":RETURN
600 TPC$="(0-39)":TPR$="(0-184)":DC=79:DR=191:CRY$="300617":RETURN
610 TPC$="(0-19)":TPR$="(0-184)":DC=159:DR=191:CRY$="11":RETURN
620 TPC$="(0-39)":TPR$="(0-184)":DC=159:DR=191:CRY$="12":RETURN
1000 SPEED=ANS(3):COL=ANS(5):ROW=ANS(7):WLEN=ANS(9):COLR=ANS(11)
1010 GNB=VAL(CRY$(1,1))
1020 ON GNB GOSUB 2000,2100,2200
1030 GOSUB 31500
1040 FOR D=1 TO 500:NEXT D:GOTO 150
2000 GRAPHICS MODE+16:A=1
2010 FOR X=0 TO DR/2 STEP VAL(CRY$(2,2))
2020 COLOR A:PLOT X,X:DRAWTO DC-X,X:DRAWTO DC-X,DR-X:DRAWTO X,DR-X:DRAWTO X,X
2030 A=A+1:IF A=4 THEN A=1
2040 NEXT X
2050 RETURN
2100 GRAPHICS 8+16:SETCOLOR 1,0,14:SETCOLOR 2,0,0:COLOR 1
2110 FOR X=0 TO 191 STEP 4:PLOT 159,0:DRAWTO 319,X:PLOT 159,0:DRAWTO 0,191-X:NEXT X
2120 FOR X=319 TO 0 STEP -4:PLOT 159,0:DRAWTO X,191:NEXT X
2130 RETURN
2200 GRAPHICS MODE:SETCOLOR 4,VAL(CRY$(2,3)),VAL(CRY$(4,4)):VAR=VAL(CRY$(5,6)):A=0
2210 FOR X=0 TO DC-1:COLOR A:PLOT X,X:DRAWTO DC-X,X:DRAWTO DC-X,DR-X:DRAWTO X,DR-X:DRAWTO X,X
2220 A=A+1:IF A=VAR THEN A=0
2230 NEXT X:RETURN
5020 DATA 8,4,8,6,8,8,8,10,8,12,8,14,8,16
5030 DATA 29,4,21,6,22,8,20,10,22,12,21,14,0,18
5040 DATA 1,20,21,32,33,38,39,41,42,54,55,65,66,95
31000 BGN=152:POKE 106,BGN-8:GRAPHICS 0
31010 DIM MS$(120),CRY$(6)
31020 DMA=PEEK(559):POKE 559,0
31030 OPEN #1,4,0,"D:SMOOTHY.DAT":POKE 850,7:POKE 852,0:POKE 853,152:POKE 856,244:POKE 857,3
31040 Q=USR(ADR("hhh*LVd"),16):CLOSE #1
31045 RETURN :REM END OF INIT. ROUTINE
31500 REM MS$="MR.SMOOTHY * SMOOTH SCROLLING TEXT WINDOWS IN ALL MAP MODES. BY KEN KAYE":MODE=7
31510 REM SPEED=10:COL=0:ROW=44:WLEN=40:COLR=4:POKE 559,DMA:CRY$=STR$(11)
31520 REM GRAPHICS 7+16:COLOR 2:PLOT 0,0:DRAWTO 159,95:DRAWTO 159,0:DRAWTO 0,95:DRAWTO 0,0
31530 Q=USR(38912,ADR(MS$),SPEED,LEN(MS$),COL,ROW,WLEN,COLR)
31540 IF Q<>0 THEN GRAPHICS 0:? "USR ERROR#";Q
31550 RETURN
