Roman Numeral Converter (ROMAN.BAS)
Roman Numeral Converter by David Stone, 18
Description
Roman Numeral Converter by David Stone, 18
From the Antic disk of March 1988 (Vol. 6 No. 11).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.1 KB
- Dialect
- Atari BASIC
- Lines
- 41
- Variables
ORIG$,ROMAN$,WORK$,CHAR$,F9$,F5$,F4$,F1$,N,M,F,X,ARABIC,DONE,CHAR,HIVAL,LOVAL,D,Q,Q9
BASIC listing (41 lines)
2 REM ROMAN NUMERAL CONVERTER
4 REM BY DAVID STONE
6 REM (c) 1987, ANTIC PUBLISHING
10 DIM ORIG$(20),ROMAN$(20),WORK$(20),CHAR$(1),F9$(2),F5$(1),F4$(2),F1$(1)
20 GRAPHICS 0:POKE 710,12:POKE 712,12:POKE 709,12:GOTO 500
50 ROMAN$(LEN(ROMAN$)+1)=WORK$:N=N-M*F:X=INT(N/F):RETURN
100 ROMAN$=ORIG$:ARABIC=0:DONE=0:RESTORE 600:FOR CHAR=1 TO 7:READ CHAR$,HIVAL,LOVAL
110 FOR N=LEN(ORIG$) TO 1 STEP -1:IF ORIG$(N,N)<>CHAR$ THEN 160
120 IF N=LEN(ORIG$) THEN DONE=1
130 WORK$=ORIG$(1,N):IF N<LEN(ORIG$) THEN ORIG$=ORIG$(N+1):N=LEN(ORIG$)
140 FOR M=1 TO LEN(WORK$):IF WORK$(M,M)<>CHAR$ THEN ARABIC=ARABIC+HIVAL-LOVAL:POP :GOTO 160
150 ARABIC=ARABIC+HIVAL:NEXT M
160 IF DONE THEN POP :GOTO 180
170 NEXT N
180 NEXT CHAR:RETURN
200 N=VAL(ORIG$):ARABIC=N:ROMAN$="":RESTORE 610
210 N=N-1000:IF N>=0 THEN ROMAN$(LEN(ROMAN$)+1)="M":GOTO 210
220 N=N+1000:F=1000
230 F=F/10:READ F9$,F5$,F4$,F1$:X=INT(N/F):M=X
240 IF X=9 THEN WORK$=F9$:GOSUB 50:GOTO 280
250 IF X>=5 THEN WORK$=F5$:M=5:GOSUB 50:GOTO 270
260 IF X=4 THEN WORK$=F4$:GOSUB 50:GOTO 280
270 IF X>=1 THEN WORK$=F1$:M=1:GOSUB 50:GOTO 270
280 IF F>1 THEN 230
290 RETURN
500 TRAP 500:? "↰":POKE 752,0:POSITION 1,9:? "Numeral to convert: ?";:GOSUB 590
505 INPUT #16;ORIG$:POKE 752,1:? :GOSUB 580
507 ON (ASC(ORIG$)<65)+1 GOSUB 100,200
510 ? "↰":POSITION 1,7:? "┌────────┬──────────────────────────┐"
511 POSITION 1,8:? "| Roman | ";ROMAN$
512 POSITION 1,9:? "├────────┼──────────────────────────┤"
513 POSITION 1,10:? "| Arabic | ";ARABIC
514 POSITION 1,11:? "└────────┴──────────────────────────┘"
515 POSITION 37,8:? "|":POSITION 37,10:? "|":POKE 752,1
516 POSITION 5,22:? "(Press any key to continue)";:POKE 764,255:GOSUB 590
520 IF PEEK(764)=255 THEN 520
530 POKE 764,255:GOSUB 580:? "↰":GOTO 500
580 FOR Q=0 TO 12:POKE 709,Q:NEXT Q:RETURN
590 FOR Q=12 TO 0 STEP -0.5:POKE 709,Q:NEXT Q:RETURN
600 DATA M,1000,100,D,500,100,C,100,10,L,50,10,X,10,1,V,5,1,I,1,1
610 DATA CM,D,CD,C,XC,L,XL,X,IX,V,IV,I
