Entrepreneur Jungle (ENTRE.BAS)
Entrepreneur Jungle by William Austin, 318
Description
Entrepreneur Jungle by William Austin, 318
From the Antic disk of March 1988 (Vol. 6 No. 11).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 31.3 KB
- Dialect
- Atari BASIC
- Lines
- 750
- Variables
UD$,A$,B$,K$,L$,C$,E$,F$,H$,I$,T$,IT$,J$,ASA,BSA,CSA,DSA,ESA,FSA,GSA,MSA,ASV,BSV,CSV,DSV,ESV,FSV,GSV,MSV,A,CASH,OTNW,X,XX,SEC,TNW,BI,YEAR,MONTH,PATENT,CRIME,PD,LIMITB,LIMITM,START,CRASH,BOOM,ATIP,ACON,SV,SA,SO,ASO,AJAX,LP,AP,FAIL,SW,PP,SS,BSO,BEER,BP,CTIP,CCON,CSO,CRAT,CP,DSO,DEHR,DP,ESO,EASY,EP,LIMITA,FTIP,FXTIP,FCON,FSO,FOX,FP,LIMITE,GSO,GOLD,GP,LIMITC,INV,OINV,LIMITD,SHOW,SCOST,A1,B1,C1,BO,LENGTH,L,LL,MBO,TBO,MSO,SPEC,UD,Y,MULT,SKIP,DI,Z,NSV,GAMBLE,RISK,SHARE,MININ,FIX,DEV,LIMITF,MP,LIMITP,AGE
BASIC listing (750 lines)
1 REM ENTREPRENEUR
2 REM BY WILLIAM A. AUSTIN
3 REM (c)1987, ANTIC PUBLISHING
5 GRAPHICS 0:POKE 752,1:POKE 710,195
10 POKE 16,112:POKE 53774,112
50 DIM UD$(10),A$(13),B$(18),K$(27),L$(25)
52 DIM C$(14),E$(13),F$(21),H$(27),I$(23),T$(10),IT$(14),J$(24)
100 UD$="THE STOCK ":T$="THANK YOU.":IT$="INSIDERS TIP: ":L$="You don't have that many."
120 A$="Stock Value: ":B$="Shares Available: ":C$="Shares Owned: ":E$="Total Value: "
122 F$="Your Cash Reserves: $":J$="Not that much available."
124 H$="How many shares do you want":I$="How many shares to sell":K$="You don't have enough cash."
200 ASA=150:BSA=50:CSA=125:DSA=100:ESA=5000:FSA=250:GSA=500:MSA=1000
300 ASV=INT(10*RND(1))+25:BSV=INT(10*RND(1))+5:CSV=INT(25*RND(1))+25
310 DSV=INT(25*RND(1))+10:ESV=INT(10*RND(1))+5:FSV=INT(100*RND(1))+100:GSV=INT(200*RND(1))+200
312 MSV=INT(500*RND(1))+500
805 POSITION 2,10:? "Is this a new game?"
807 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
810 IF A=89 THEN CASH=100:OTNW=100:GOTO 820
812 GOTO 900
820 ? "↰":POSITION 2,8:? "You have $100.":? :? "Do you wish to make a deposit":? :? "in a Swiss bank at this time?"
821 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
822 IF A<>89 THEN 1000
824 ? "↰":? :? F$;CASH:? :? "How much do you wish to deposit";:INPUT X
826 IF X>CASH THEN ? :? "You don't have that much cash.":XX=1:GOTO 912
828 CASH=CASH-X:SEC=SEC+X:GOTO 1000
900 POSITION 2,8:? "What is your net worth";:INPUT CASH:TNW=CASH:OTNW=TNW:IF TNW>1000000000 THEN BI=1
902 ? :? "What year is this";:INPUT YEAR:? :? "What month is this";:INPUT MONTH
904 ? :? "Value of patents";:INPUT PATENT:CASH=CASH-PATENT
905 ? :? "Number of Grand Jury files";:INPUT CRIME:? :? "Amount of political donations";:INPUT PD:IF PD>99 THEN LIMITB=1
906 IF PD>5000 THEN LIMITM=1
908 X=INT(3*RND(1))+2:ASV=ASV*X:BSV=BSV*X:CSV=CSV*X:DSV=DSV*X:ESV=ESV*X:FSV=FSV*X:GSV=GSV*X:MSV=MSV*X
909 X=INT(3*RND(1))+2:ASA=ASA*X:BSA=BSA*X:CSA=CSA*X:DSA=DSA*X:ESA=ESA*X:FSA=FSA*X:GSA=GSA*X:MSA=MSA*X
910 ? "↰":POSITION 2,8:? :? "Do you wish to make a deposit":? :? "in a Swiss bank at this time?"
912 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
914 IF XX=1 THEN XX=0:GOTO 1000
920 IF A<>89 THEN 1000
930 ? "↰":? :? F$;CASH:? :? "How much do you wish to deposit";:INPUT X
940 IF X>CASH THEN ? :? "You don't have that much cash.":XX=1:GOTO 912
950 CASH=CASH-X:SEC=SEC+X
1000 ? "↰":REM AJAX
1050 IF START=0 THEN START=1:GOTO 1100
1075 GOTO 20000:? "↰"
1100 ? "↰":? " AJax Mfg. Corp."
1102 IF CRASH=3 THEN CRASH=0
1104 IF CRASH>0 THEN CRASH=CRASH+1
1105 IF BOOM=3 THEN BOOM=0
1107 IF BOOM>0 THEN BOOM=BOOM+1
1112 IF ATIP>0 THEN ATIP=ATIP+1
1114 IF ACON=1 THEN ACON=2
1125 SV=ASV:SA=ASA:SO=ASO:AJAX=1:LP=AP
1150 GOSUB 10100:ASV=SV:ASA=SA:ASO=SO:AJAX=0
1500 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
1502 IF FAIL=1 THEN FAIL=0:ASV=INT(10*RND(1))+25:GOTO 2000
1510 IF XX=1 THEN XX=0:GOTO 2000
1520 IF A=66 THEN 1600
1530 IF A=83 THEN 1700
1599 GOTO 2000
1600 ? "↰":? :? :? B$;SA
1625 ? :? A$;SV:? :? F$;CASH
1650 ? :? H$;:INPUT SW
1655 IF SW=0 THEN 2000
1660 IF SW>SA THEN ? :? :? J$:XX=1:GOTO 1500
1670 PP=SW*SV:IF PP>CASH THEN ? :? :? K$:XX=1:GOTO 1500
1680 CASH=CASH-PP:ASA=ASA-SW:ASO=ASO+SW:AP=SV
1699 GOTO 2000
1700 ? "↰":? :? :? C$;ASO
1725 ? :? A$;SV:? :? F$;CASH
1750 ? :? I$;:INPUT SS
1755 IF SS=0 THEN XX=1:GOTO 1500
1760 IF SS>ASO THEN ? :? :? L$:XX=1:GOTO 1500
1770 PP=SS*ASV
1780 CASH=CASH+PP:ASA=ASA+SS:ASO=ASO-SS
1799 GOTO 2000
2000 ? "↰":REM BEAR
2100 ? " Bear Breath Brewery Co."
2125 SV=BSV:SA=BSA:SO=BSO:BEER=1:LP=BP
2150 GOSUB 10100:BSV=SV:BSA=SA:BSO=SO:BEER=0
2500 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
2502 IF FAIL=1 THEN FAIL=0:BSV=INT(10*RND(1))+5:GOTO 3000
2510 IF XX=1 THEN XX=0:GOTO 3000
2520 IF A=66 THEN 2600
2530 IF A=83 THEN 2700
2599 GOTO 3000
2600 ? "↰":? :? :? B$;BSA
2625 ? :? A$;SV:? :? F$;CASH
2650 ? :? H$;:INPUT SW
2655 IF SW=0 THEN GOTO 3000
2660 IF SW>BSA THEN ? :? :? J$:XX=1:GOTO 2500
2670 PP=SW*SV:IF PP>CASH THEN ? :? :? K$:XX=1:GOTO 2500
2680 CASH=CASH-PP:BSA=BSA-SW:BSO=BSO+SW:BP=SV
2699 GOTO 3000
2700 ? "↰":? :? :? C$;BSO
2725 ? :? A$;SV:? :? F$;CASH
2750 ? :? I$;:INPUT SS
2755 IF SS=0 THEN XX=1:GOTO 2500
2760 IF SS>BSO THEN ? :? :? L$:XX=1:GOTO 2500
2770 PP=SS*BSV
2780 CASH=CASH+PP:BSA=BSA+SS:BSO=BSO-SS
2799 GOTO 3000
3000 ? "↰":REM CRATER
3100 ? " Crater Tech Inc."
3112 IF CTIP>0 THEN CTIP=CTIP+1
3114 IF CCON=1 THEN CCON=2
3125 SV=CSV:SA=CSA:SO=CSO:CRAT=1:LP=CP
3150 GOSUB 10100:CSV=SV:CSA=SA:CSO=SO:CRAT=0
3500 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
3502 IF FAIL=1 THEN FAIL=0:CSV=INT(25*RND(1))+25:GOTO 4000
3510 IF XX=1 THEN XX=0:GOTO 4000
3520 IF A=66 THEN 3600
3530 IF A=83 THEN 3700
3599 GOTO 4000
3600 ? "↰":? :? :? B$;SA
3625 ? :? A$;SV:? :? F$;CASH
3650 ? :? H$;:INPUT SW
3655 IF SW=0 THEN 4000
3660 IF SW>SA THEN ? :? :? J$:XX=1:GOTO 3500
3670 PP=SW*SV:IF PP>CASH THEN ? :? :? K$:XX=1:GOTO 3500
3680 CASH=CASH-PP:CSA=CSA-SW:CSO=CSO+SW:CP=SV
3699 GOTO 4000
3700 ? "↰":? :? :? C$;CSO
3725 ? :? A$;SV:? :? F$;CASH
3750 ? :? I$;:INPUT SS
3755 IF SS=0 THEN XX=1:GOTO 3500
3760 IF SS>CSO THEN ? :? :? L$:XX=1:GOTO 3500
3770 PP=SS*CSV
3780 CASH=CASH+PP:CSA=CSA+SS:CSO=CSO-SS
3799 GOTO 4000
4000 ? "↰":REM DEHRING
4100 ? " Dehring Investments"
4125 SV=DSV:SA=DSA:SO=DSO:DEHR=1:LP=DP
4150 GOSUB 10100:DSV=SV:DSA=SA:DSO=SO:DEHR=0
4500 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
4502 IF FAIL=1 THEN FAIL=0:DSV=INT(25*RND(1))+10:GOTO 5000
4510 IF XX=1 THEN XX=0:GOTO 5000
4520 IF A=66 THEN 4600
4530 IF A=83 THEN 4700
4599 GOTO 5000
4600 ? "↰":? :? :? B$;SA
4625 ? :? A$;SV:? :? F$;CASH
4650 ? :? H$;:INPUT SW
4655 IF SW=0 THEN 5000
4660 IF SW>SA THEN ? :? :? J$:XX=1:GOTO 4500
4670 PP=SW*SV:IF PP>CASH THEN ? :? :? K$:XX=1:GOTO 4500
4680 CASH=CASH-PP:DSA=DSA-SW:DSO=DSO+SW:DP=SV
4699 GOTO 5000
4700 ? "↰":? :? :? C$;DSO
4725 ? :? A$;SV:? :? F$;CASH
4750 ? :? I$;:INPUT SS
4755 IF SS=0 THEN XX=1:GOTO 4500
4760 IF SS>DSO THEN ? :? :? L$:XX=1:GOTO 4500
4770 PP=SS*DSV
4780 CASH=CASH+PP:DSA=DSA+SS:DSO=DSO-SS
4799 GOTO 5000
5000 ? "↰":REM EASY
5100 ? " Easy Bond & Trust"
5125 SV=ESV:SA=ESA:SO=ESO:EASY=1:LP=EP
5150 GOSUB 10100:ESV=SV:ESA=SA:ESO=SO:EASY=0
5500 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
5502 IF FAIL=1 THEN FAIL=0:ESV=INT(10*RND(1))+5:GOTO 6000
5510 IF XX=1 THEN XX=0:GOTO 6000
5520 IF A=66 THEN 5600
5530 IF A=83 THEN 5700
5599 GOTO 6000
5600 ? "↰":? :? :? B$;SA
5625 ? :? A$;SV:? :? F$;CASH
5650 ? :? H$;:INPUT SW
5655 IF SW=0 THEN 6000
5660 IF SW>SA THEN ? :? :? J$:XX=1:GOTO 5500
5670 PP=SW*SV:IF PP>CASH THEN ? :? :? K$:XX=1:GOTO 5500
5680 CASH=CASH-PP:ESA=ESA-SW:ESO=ESO+SW:EP=SV
5699 GOTO 6000
5700 ? "↰":? :? :? C$;ESO
5725 ? :? A$;SV:? :? F$;CASH
5750 ? :? I$;:INPUT SS
5755 IF SS=0 THEN GOTO 6000
5760 IF SS>ESO THEN ? :? :? L$:XX=1:GOTO 5500
5770 PP=SS*ESV
5780 CASH=CASH+PP:ESA=ESA+SS:ESO=ESO-SS
5799 GOTO 6000
6000 ? "↰":REM FOX
6010 IF TNW>200 THEN LIMITA=1
6012 IF LIMITA=0 THEN 7000
6100 ? " Flying Fox Airlines"
6104 IF FTIP>0 THEN FTIP=FTIP+1
6108 IF FXTIP>0 THEN FXTIP=FXTIP+1
6110 IF FCON=1 THEN FCON=2
6125 SV=FSV:SA=FSA:SO=FSO:FOX=1:LP=FP
6150 GOSUB 10100:FSV=SV:FSA=SA:FSO=SO:FOX=0
6500 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
6502 IF FAIL=1 THEN FAIL=0:FSV=INT(100*RND(1))+100:GOTO 7000
6510 IF XX=1 THEN XX=0:GOTO 7000
6520 IF A=66 THEN 6600
6530 IF A=83 THEN 6700
6599 GOTO 7000
6600 ? "↰":? :? :? B$;SA
6625 ? :? A$;SV:? :? F$;CASH
6650 ? :? H$;:INPUT SW
6655 IF SW=0 THEN 7000
6660 IF SW>SA THEN ? :? :? J$:XX=1:GOTO 5500
6670 PP=SW*SV:IF PP>CASH THEN ? :? :? K$:XX=1:GOTO 6500
6680 CASH=CASH-PP:FSA=FSA-SW:FSO=FSO+SW:FP=SV
6699 GOTO 7000
6700 ? "↰":? :? :? C$;FSO
6725 ? :? A$;SV:? :? F$;CASH
6750 ? :? I$;:INPUT SS
6755 IF SS=0 THEN 7000
6760 IF SS>FSO THEN ? :? :? L$:XX=1:GOTO 6500
6770 PP=SS*FSV
6780 CASH=CASH+PP:FSA=FSA+SS:FSO=FSO-SS
6799 GOTO 7000
7000 ? "↰":REM GOLD
7005 IF TNW>1000 THEN LIMITE=1
7010 IF LIMITE=0 THEN 13000
7100 ? " Grande Gold Mines"
7125 SV=GSV:SA=GSA:SO=GSO:GOLD=1:LP=GP
7150 GOSUB 10100:GSV=SV:GSA=SA:GSO=SO:GOLD=0
7500 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
7502 IF FAIL=1 THEN FAIL=0:GSV=INT(200*RND(1))+200:GOTO 13000
7510 IF XX=1 THEN XX=0:GOTO 13000
7520 IF A=66 THEN 7600
7530 IF A=83 THEN 7700
7599 GOTO 13000
7600 ? "↰":? :? :? B$;SA
7625 ? :? A$;SV:? :? F$;CASH
7650 ? :? H$;:INPUT SW
7655 IF SW=0 THEN 13000
7660 IF SW>SA THEN ? :? :? J$:XX=1:GOTO 7500
7670 PP=SW*SV:IF PP>CASH THEN ? :? :? K$:XX=1:GOTO 7500
7680 CASH=CASH-PP:GSA=GSA-SW:GSO=GSO+SW:GP=SV
7699 GOTO 13000
7700 ? "↰":? :? :? C$;GSO
7725 ? :? A$;SV:? :? F$;CASH
7750 ? :? I$;:INPUT SS
7755 IF SS=0 THEN 13000
7760 IF SS>GSO THEN ? :? :? L$:XX=1:GOTO 7500
7770 PP=SS*GSV
7780 CASH=CASH+PP:GSA=GSA+SS:GSO=GSO-SS
7799 GOTO 13000
8000 ? "↰":REM RISK
8010 IF TNW>2000 THEN LIMITC=1
8012 IF LIMITC=0 THEN 9000
8100 ? " Risque Futures, Inc"
8110 IF INV=0 THEN 8200
8120 OINV=INV:X=INT(3*RND(1))+1:IF X<>1 THEN INV=INT(INV/2*RND(1))+5:CASH=CASH+INV:GOTO 8150
8130 X=INT(4*RND(1))+3:INV=INV*X:CASH=CASH+INV
8150 ? :? "YOUR INVESTMENT WAS $";OINV:? :? "YOUR RETURN IS $";INV
8200 GOSUB 25000
9000 ? "↰":REM SHOW
9005 IF TNW>5000 THEN LIMITD=1
9007 IF LIMITD=0 THEN 11000
9010 ? " Bi Coastal Theater Productions, Ltd."
9020 IF SHOW=0 THEN 9100
9022 IF SHOW=1 THEN 9200
9024 IF SHOW=2 THEN 9300
9026 IF SHOW=3 THEN 9400
9090 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
9095 GOTO 11000
9100 ? :? "A PRODUCER IS PLANNING A NEW":?
9105 X=INT(4*RND(1))+1:IF X=1 THEN ? "MUSICAL."
9107 IF X=2 THEN ? "MUSICAL COMEDY."
9109 IF X=3 THEN ? "COMEDY."
9111 IF X=4 THEN ? "DRAMA."
9120 X=INT(23*RND(1))+3:SCOST=X*100
9125 ? :? :? "BASIC PARTICIPATION WILL COST $";SCOST;"."
9127 ? :? "DO YOU WISH TO INVEST IN THIS?":? :? "YOUR CASH RESERVE IS $";CASH
9150 OPEN #5,4,0,"K":GET #5,A:CLOSE #5
9152 IF A<>89 THEN 11000
9153 GOSUB 9500
9154 IF CASH<SCOST THEN ? :? "YOU DON'T HAVE ENOUGH MONEY.":GOTO 9090
9160 A1=INT(10*RND(1))+3:B1=INT(10*RND(1))+3:C1=INT(10*RND(1))+3:BO=SCOST/2
9162 LENGTH=A1+B1:IF A1>9 THEN IF B1>9 THEN LENGTH=LENGTH+C1
9164 CASH=CASH-SCOST:SHOW=1:GOTO 11000
9200 X=INT(2*RND(1))+1:IF X=1 THEN ? :? :? "THE SHOW IS IN REHEARSAL.":SHOW=2:GOTO 9090
9210 ? :? :? "THE SHOW CLOSED IN REHEARSAL.":? :? "YOU LOST YOUR INVESTMENT OF $";SCOST;".":SHOW=0:GOTO 9090
9300 L=L+12:? :? "THE SHOW IS IN WEEK ";L;".":LL=L/12:IF LL>LENGTH THEN SHOW=3
9310 MBO=INT(BO*RND(1))+5:TBO=TBO+MBO:CASH=CASH+MBO
9320 ? :? :? "QUARTERLY BOX OFFICE: $";MBO
9322 ? :? :? "BOX OFFICE TO DATE: $";TBO
9324 ? :? :? "YOUR INVESTMENT: $";SCOST
9326 ? :? :? "CASH RESERVE: $";CASH
9349 GOTO 9090
9400 ? :? :? "THE SHOW CLOSED AFTER ";L;" WEEKS."
9410 ? :? :? "YOUR INVESTMENT WAS $";SCOST
9420 ? :? :? "YOUR RETURN WAS $";TBO
9430 LENGTH=0:SHOW=0:SCOST=0:L=0:TBO=0
9449 GOTO 9090
9500 REM OPTIONS
9510 ? "↰":? "AT WHAT LEVEL DO YOU WISH TO INVEST?"
9520 ? :? :? :? " (1) $";SCOST
9530 ? :? " (2) $";SCOST*3
9540 ? :? " (3) $";SCOST*5
9560 ? :? " (4) $";SCOST*7
9570 ? :? " (5) $";SCOST*9
9580 ? :? :? :? "YOUR CASH RESERVE IS $";CASH;"."
9600 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
9610 IF A=50 THEN SCOST=SCOST*3
9612 IF A=51 THEN SCOST=SCOST*5
9614 IF A=52 THEN SCOST=SCOST*7
9616 IF A=53 THEN SCOST=SCOST*9
9649 RETURN
10000 REM TNW
10020 TNW=CASH+SEC+ASO*ASV+BSO*BSV+CSO*CSV+DSO*DSV+ESO*ESV+FSO*FSV+GSO*GSV+PATENT+MSO*MSV
10099 RETURN
10100 IF FTIP=3 THEN FTIP=0:GOTO 16000:REM UP/DOWN
10101 IF ACON=2 THEN ACON=0:GOTO 16600
10102 IF CRASH=3 THEN 10600
10103 IF BOOM=3 THEN 16100
10104 IF CCON=2 THEN CCON=0:GOTO 16600
10105 IF CTIP=3 THEN CTIP=0:GOTO 16000
10106 IF FXTIP=3 THEN FXTIP=0:GOTO 10600
10107 IF ATIP=3 THEN ATIP=0:GOTO 16000
10108 IF FCON=2 THEN FCON=0:GOTO 16600
10109 SPEC=INT(33*RND(1))+1:IF SPEC=1 THEN 16000
10110 X=INT(20*RND(1))+1:IF X=1 THEN ? :? "THE MARKET REMAINS STABLE.":GOTO 10270
10111 X=INT(20*RND(1))+1
10112 UD=1:IF X>10 THEN UD=2:IF X=20 THEN 10500
10120 Y=10:IF AJAX=1 THEN IF SV>700 THEN 10640
10121 IF BEER=1 THEN Y=5:IF SV>300 THEN 10640
10122 IF CRAT=1 THEN Y=20:IF SV>1000 THEN 10640
10124 IF DEHR=1 THEN IF SV>10 THEN Y=SV:IF SV>2500 THEN 10640
10126 IF EASY=1 THEN Y=3:UD=1:IF SV>500 THEN 10640
10128 IF GOLD=1 THEN Y=100:IF SV>10000 THEN 10640
10130 IF FOX=1 THEN Y=50:IF SV>3000 THEN 10640
10132 IF MULT=1 THEN Y=200:IF SV>25000 THEN 10640
10140 IF SO>SA THEN Y=Y*2:IF SA=0 THEN Y=Y*2
10200 X=INT(Y*RND(1))+1:IF SKIP=1 THEN SKIP=0:GOTO 10210
10205 DI=INT(5*RND(1))+1:IF DI=1 THEN GOSUB 10900
10210 ? :IF UD=1 THEN SV=SV+X
10212 IF UD=2 THEN SV=SV-X:IF SV<1 THEN 10600
10250 IF UD=1 THEN ? UD$;"ROSE ";X
10260 IF UD=2 THEN ? UD$;"FELL ";X
10270 ? :? A$;SV:? :? B$;SA:? :? :? C$;SO:? :? E$;SO*SV
10272 ? :? "Last Price Paid: $";LP
10280 ? :? :? F$;CASH
10299 RETURN
10500 REM UNUSUAL
10502 X=INT(28*RND(1))+1:SKIP=1
10510 IF X=1 THEN 10600
10512 IF X=2 THEN 10620
10514 IF X=3 THEN 10630
10520 IF X=4 THEN 10660
10522 IF X=5 THEN 10670
10524 IF X=6 THEN 10680
10526 IF X=7 THEN 10690
10528 IF X=8 THEN 10700
10530 IF X=9 THEN 10710
10532 IF X=10 THEN 10720
10534 IF X=11 THEN 10730
10536 IF X=12 THEN 10740
10538 IF X=13 THEN 10750
10540 IF X=14 THEN 10760
10550 IF X=15 THEN 10770
10552 IF X=16 THEN 10780
10554 IF X=17 THEN 10790
10556 IF X=18 THEN 10800
10558 IF X=19 THEN 10810
10560 IF X=20 THEN 10820
10562 IF X=21 THEN 10850
10564 IF X=22 THEN 10860
10566 IF X=23 THEN 10870
10568 IF X=24 THEN CRASH=3:GOTO 10102
10570 IF X=25 THEN BOOM=3:GOTO 10103
10572 IF X=26 THEN ATIP=2:UD=1:Y=20:GOTO 10200
10574 IF X=27 THEN ATIP=2:CTIP=2:FTIP=2:UD=1:Y=20:GOTO 10200
10576 IF X=28 THEN IF AJAX=1 THEN 16410
10578 IF X=28 THEN IF CRAT=1 THEN 16410
10580 IF X=28 THEN IF FOX=1 THEN 16410
10582 IF X=28 THEN UD=1:Y=20:GOTO 10200
10600 IF MULT=1 THEN 10950
10602 ? :? "The firm has gone bankrupt!":? :SA=SA+SO:SO=0:FAIL=1:RETURN
10620 ? :? "Comptroller indicted for fraud!":IF SV=1 THEN 10600
10624 X=SV-1:UD=2:GOTO 10210
10630 ? :? "Cash lost in Bank Failure!!!":CASH=0:UD=1:GOTO 10120
10640 X=INT(4*RND(1))+1:IF X<3 THEN 10140
10642 IF X=3 THEN 10650
10644 ? :? "2 for 1 stock split!":SA=SA*2:SO=SO*2:SV=SV/2:SV=INT(SV):IF SV<1 THEN SV=1
10646 UD=1:GOTO 10210
10650 ? :? "3 for 1 stock split!":SA=SA*3:SO=SO*3:SV=SV/3:SV=INT(SV):IF SV<1 THEN SV=1
10652 UD=1:GOTO 10210
10660 ? :? "Successful merger!!":UD=1:X=GSV:SA=SA+GSO+GSA:GOTO 10210
10670 ? :? "Unsuccessful merger attempt!!":UD=2:Y=100:SKIP=1:GOTO 10140
10680 IF SO=0 THEN 10111
10682 ? :? "IMPROPER STOCK REGISTRATION!":SA=SA+SO:SO=0:UD=1:GOTO 10120
10690 IF SO=0 THEN 10111
10692 ? :? "FRIENDLY TAKEOVER!!":Z=SO*SV:Y=Z*3:X=INT(Y*RND(1))+Z:SA=SA+SO:SO=0:FAIL=1
10694 ? :? "YOU RECEIVE $";X;" FOR YOUR STOCK.":CASH=CASH+X:RETURN
10700 IF SO=0 THEN 10111
10702 ? :? "HOSTILE TAKEOVER!!":Z=SO*SV:X=INT(Z*RND(1))+1:SA=SA+SO:SO=0:FAIL=1
10704 ? :? "YOU RECEIVE $";X;" FOR YOUR STOCK.":CASH=CASH+X:RETURN
10710 ? :? "EXPANSION SUCCEEDS, NEW STOCK ISSUED!":SA=SA+SO:SA=SA*2:SA=SA-SO:UD=1:Y=100:GOTO 10200
10720 ? :? "EXPANSION PLANS FAIL!":UD=2:Y=50:GOTO 10200
10730 ? :? "SALES DOUBLE!!":X=SV*2:UD=1:GOTO 10210
10740 ? :? "SALES TREBLE!!":X=SV*3:UD=1:GOTO 10210
10750 ? :? "BANK COMPUTER MALFUNCTION!":IF CASH<25 THEN CASH=25
10752 X=INT(3*RND(1))+2:CASH=CASH*X:UD=1:GOTO 10210
10760 IF CASH<1 THEN 10770
10762 ? :? "CASH SEIZED IN TAX AUDIT!":CASH=0:UD=1:Y=10:GOTO 10200
10770 IF SO=0 THEN 10111
10772 ? :? "STOCK SEIZED IN TAX AUDIT!":SA=SA+SO:SO=0:UD=1:Y=10:GOTO 10200
10780 Z=INT(20*RND(1))+1:X=Z:Z=Z*10:? :? "COMPUTER ERROR ISSUES YOU ";Z;" SHARES!":SO=SO+Z:UD=1:Y=5:GOTO 10210
10790 ? :? "$";SV;" PROFIT SHARING PAID!":CASH=CASH+SV*SO:X=INT(10*RND(1))+1:UD=1:GOTO 10210
10800 Y=INT(20*RND(1))+1:Y=Y*5:? :? "$";Y;" PER SHARE BONUS PAID!":CASH=CASH+Y*SO
10802 UD=1:X=INT(Y*RND(1))+Y:GOTO 10210
10810 IF SV<11 THEN 10600
10812 ? :? "LABOR UNION STRIKES! STOCKS TUMBLE!":X=SV-10:UD=2:GOTO 10210
10820 ? :? "CREDITORS FORCE REORGANIZATION!"
10824 IF AJAX=1 THEN Y=10:Z=25
10825 IF BEER=1 THEN Y=10:Z=5
10826 IF CRAT=1 THEN Y=25:Z=25
10827 IF DEHR=1 THEN Y=25:Z=10
10828 IF EASY=1 THEN Y=10:Z=5
10829 IF FOX=1 THEN Y=100:Z=100
10830 IF GOLD=1 THEN Y=200:Z=200
10831 IF MULT=1 THEN Y=500:Z=500
10835 NSV=INT(Y*RND(1))+Z:IF NSV=SV THEN NSV=NSV+1
10837 IF NSV>SV THEN X=NSV-SV:UD=1:GOTO 10210
10839 IF SV>NSV THEN X=SV-NSV:UD=2:GOTO 10210
10850 ? :? "FAVORABLE UNION CONTRACT SIGNED!"
10852 X=INT(SV*RND(1))+SV/2:X=INT(X):IF X<5 THEN X=5
10854 UD=1:GOTO 10210
10860 ? :? "MERGER RUMOR CAUSES STOCK TO JUMP!"
10862 Y=INT(3*RND(1))+2:X=SV*Y:UD=1:GOTO 10210
10870 IF SV<101 THEN 10860
10872 ? :? "TAX AUDIT RUMOR! STOCKS GO DOWN!"
10874 X=SV-100:UD=2:GOTO 10210
10900 REM DIV
10910 IF AJAX=1 THEN Y=8:Z=3
10912 IF BEER=1 THEN Y=5:Z=1
10914 IF CRAT=1 THEN Y=10:Z=5
10916 IF DEHR=1 THEN Y=10:Z=10
10918 IF EASY=1 THEN Y=3:Z=1
10920 IF FOX=1 THEN Y=20:Z=5
10922 IF GOLD=1 THEN Y=25:Z=25
10924 IF MULT=1 THEN Y=50:Z=50
10930 DI=INT(Y*RND(1))+Z:X=X+DI:UD=1
10940 ? :? "$";DI;" PER SHARE DIVIDEND PAID!":CASH=CASH+DI*SO
10949 RETURN
10950 ? :? "A foreign financial cartel intervenes":? :? "to prevent bankruptcy! Firm is being":? :? "reorganized!"
10955 SA=SA+500:SV=INT(500*RND(1))+500:FAIL=1
10959 RETURN
11000 REM ILLEGAL
11010 IF LIMITB=0 THEN 12000
11012 ? "↰":? " Darkside Ventures, Inc."
11020 IF GAMBLE=0 THEN 11100
11022 IF GAMBLE=1 THEN GAMBLE=0:GOTO 11500
11050 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
11070 GOTO 12000
11100 REM SET-UP
11110 X=INT(9*RND(1))+1
11120 ? :? :? "VENTURE CAPITAL IS BEING SOUGHT FOR":?
11130 IF X=1 THEN ? "IMPORTING AGRICULTURAL PRODUCTS":? :? "FROM COLOMBIA."
11132 IF X=2 THEN ? "IMPORTING FLORAL ARRANGEMENTS":? :? "FROM LAOS."
11134 IF X=3 THEN ? "IMPORTING PHARMACEUTICAL PRODUCTS":? :? "FROM MARSEILLES."
11136 IF X=4 THEN ? "EXPORTING ELECTRONIC PRODUCTS":? :? "TO RUSSIA."
11138 IF X=5 THEN ? "EXPORTING FARM IMPLEMENTS":? :? "TO THE MIDDLE EAST."
11140 IF X=6 THEN ? "MAKING POLITICAL CONTRIBUTIONS":? :? "IN CENTRAL AMERICA."
11142 IF X=7 THEN ? "IMPORTING OLIVE OIL FROM SICILY"
11144 IF X=8 THEN ? "FINANCING A STABLE OF PONIES":? :? "IN ATLANTIC CITY."
11146 IF X=9 THEN ? "FINANCING A SOCIAL CLUB":? :? "IN LAS VEGAS."
11200 RISK=INT(4*RND(1))+2
11210 ? :? :? "THIS IS A ";
11212 IF RISK=2 THEN ? "LOW";
11214 IF RISK=3 THEN ? "MODERATE";
11216 IF RISK=4 THEN ? "HIGH";
11218 IF RISK=5 THEN ? "VERY HIGH";
11230 ? " RISK VENTURE."
11300 X=6-RISK:SHARE=X*100
11310 ? :? :? "SHARES ARE $";SHARE
11320 ? :? :? "DO YOU WISH TO PARTICIPATE?"
11330 ? :? :? F$;CASH
11400 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
11410 IF A<>89 THEN 12000
11420 ? "↰":? :? F$;CASH:? :? "SHARES COST $";SHARE
11430 ? :? :? "HOW MANY DO YOU WISH TO PURCHASE";:INPUT X:MININ=X*SHARE
11440 IF MININ>CASH THEN ? :? :? "YOU DON'T HAVE ENOUGH CASH.":GOTO 11050
11450 CASH=CASH-MININ:GAMBLE=1:GOTO 12000
11500 REM RESULT
11510 CRIME=CRIME+1:X=INT(100*RND(1))+1:IF X<=CRIME THEN 11600
11520 X=INT(RISK*RND(1))+1:IF X=1 THEN 11550
11530 ? :? "THE VENTURE FAILED."
11532 OPEN #5,4,0,"K":GET #5,A:CLOSE #5
11534 GOTO 11000
11550 ? :? "THE VENTURE SUCCEEDED!"
11560 X=RISK*3:Y=MININ*X:X=MININ/2:X=X+MININ:X=INT(X):Z=INT(Y*RND(1))+X
11570 ? :? :? "YOUR ORIGINAL INVESTMENT: $";MININ:? :? :? "YOUR RETURN: $";Z:CASH=CASH+Z
11575 GOTO 11532
11600 REM INDICT
11610 ? :? "YOU HAVE BEEN INDICTED BY THE GRAND":? :? "JURY FOR RACKETEERING!"
11612 X=INT(3*RND(1))+1:IF X<>1 THEN 11650
11614 IF FIX=1 THEN FIX=0:GOTO 11650
11615 ? :? :? "ALL OF YOUR ASSETS HAVE BEEN SEIZED!"
11620 CASH=0:ASA=ASA+ASO:ASO=0:BSA=BSA+BSO:BSO=0:CSA=CSA+CSO:CSO=0:DSA=DSA+DSO:DSO=0:ESA=ESA+ESO:ESO=0
11622 FSA=FSA+FSO:FSO=0:GSA=GSA+GSO:GSO=0:SHOW=0:INV=0:L=0:SCOST=0:PATENT=0:DEV=0:TBO=0:MSA=MSA+MSO:MSO=0
11625 GOTO 11050
11650 ? :? :? "YOU HAVE BEEN FOUND INNOCENT!":CRIME=0:? :? :GOTO 11550
12000 ? "↰":REM PATENT
12005 IF TNW>10000 THEN LIMITF=1
12006 IF LIMITF=0 THEN 15000
12010 ? "↰":? " Experitech R&D Inc."
12020 IF DEV=0 THEN 12100
12030 ? :X=INT(2*RND(1))+1:IF X=1 THEN ? "THE PROJECT FAILED.":DEV=0:GOTO 12100
12032 ? "THE PATENT HAS BEEN GRANTED.":PATENT=PATENT+DEV:DEV=0
12100 IF PATENT=0 THEN 12200
12110 Y=PATENT/4:X=INT(Y*RND(1))+1:? :? :? "QUARTERLY ROYALTIES: $";X:CASH=CASH+X
12200 X=INT(6*RND(1))+1:? :?
12210 ? "A ";:IF X=1 THEN ? "PHARMACIST";
12212 IF X=2 THEN ? "MECHANICAL ENGINEER";
12214 IF X=3 THEN ? "CHEMICAL ENGINEER";
12216 IF X=4 THEN ? "NUCLEAR PHYSICIST";
12220 IF X=5 THEN ? "WEAPONS SPECIALIST";
12222 IF X=6 THEN ? "MEDICAL RESEARCHER";
12238 X=INT(CASH*RND(1))+100:IF X>5000000 THEN X=5000000
12240 ? " IS SEEKING ":? :? "$";X;" FUNDING FOR A NEW PROJECT."
12245 ? :? "ARE YOU INTERESTED?":? :? F$;CASH
12250 OPEN #5,4,0,"K":GET #5,A:CLOSE #5
12255 IF XX=1 THEN XX=0:GOTO 15000
12260 IF A<>89 THEN IF A<>83 THEN 15000
12262 IF A=83 THEN 12275
12264 IF CASH<X THEN ? :? "YOU DON'T HAVE ENOUGH MONEY.":XX=1:GOTO 12250
12270 DEV=X:CASH=CASH-X:GOTO 15000
12275 IF PATENT=0 THEN ? :? "YOU HAVE NO PATENTS TO SELL.":XX=1:GOTO 12250
12276 ? "↰":? :? "YOUR PATENTS ARE VALUED AT $";PATENT
12277 Y=PATENT:Z=PATENT/2:Z=INT(Z):X=INT(Y*RND(1))+Z
12280 ? :? :? "YOU HAVE BEEN OFFERED $";X:? :? "FOR YOUR RIGHTS.":? :? :? "ARE YOU INTERESTED?"
12285 OPEN #5,4,0,"K":GET #5,A:CLOSE #5
12287 IF A<>89 THEN 15000
12288 CASH=CASH+X:PATENT=0:GOTO 15000
13000 ? "↰":REM MULTI
13010 IF LIMITM=0 THEN 8000
13100 ? " Multinational Arms Corp."
13125 SV=MSV:SA=MSA:SO=MSO:MULT=1:LP=MP
13150 GOSUB 10100:MSV=SV:MSA=SA:MSO=SO:MULT=0
13500 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
13502 IF FAIL=1 THEN FAIL=0:GOTO 8000
13510 IF XX=1 THEN XX=0:GOTO 8000
13520 IF A=66 THEN 13600
13530 IF A=83 THEN 13700
13599 GOTO 8000
13600 ? "↰":? :? :? B$;SA
13625 ? :? A$;SV:? :? F$;CASH
13650 ? :? H$;:INPUT SW
13655 IF SW=0 THEN 8000
13660 IF SW>SA THEN ? :? :? J$:XX=1:GOTO 13500
13670 PP=SW*SV:IF PP>CASH THEN ? :? :? K$:XX=1:GOTO 13500
13680 CASH=CASH-PP:MSA=MSA-SW:MSO=MSO+SW:MP=SV
13699 GOTO 8000
13700 ? "↰":? :? :? C$;MSO
13725 ? :? A$;SV:? :? F$;CASH
13750 ? :? I$;:INPUT SS
13755 IF SS=0 THEN 8000
13760 IF SS>MSO THEN ? :? :? L$:XX=1:GOTO 13500
13770 PP=SS*MSV
13780 CASH=CASH+PP:MSA=MSA+SS:MSO=MSO-SS
13799 GOTO 8000
15000 REM POLIT
15008 IF TNW>100 THEN LIMITP=1
15010 IF CASH=0 THEN 1000
15012 IF LIMITP=0 THEN 1000
15020 ? "↰":? " Party War Chest Foundation"
15030 ? :? :? "WOULD YOU LIKE TO MAKE A POLITICAL":? :? "DONATION?"
15040 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
15045 IF A<>89 THEN 1000
15050 ? :? F$;CASH:? :? "HOW MUCH DO YOU WISH TO CONTRIBUTE";:INPUT X
15055 IF X>CASH THEN ? :? "YOU DON'T HAVE THAT MUCH MONEY.":GOTO 15400
15060 CASH=CASH-X:PD=PD+X
15070 IF LIMITB=0 THEN 15500
15080 IF LIMITM=0 THEN IF PD>5000 THEN 15550
15100 X=YEAR*2000:IF X<2000 THEN X=2000
15102 Y=INT(X*RND(1))+1:IF Y>PD THEN ? :? T$:GOTO 15400
15200 X=INT(32*RND(1))+1
15206 IF BOOM>0 THEN ? :? T$:GOTO 15400
15208 IF CRASH>0 THEN ? :? T$:GOTO 15400
15210 IF X=1 THEN IF CRIME=0 THEN ? :? T$:GOTO 15400
15212 IF X=1 THEN IF CRIME>0 THEN ? :? "YOUR GRAND JURY FILES HAVE VANISHED!":CRIME=0
15220 IF X=2 THEN 15600
15230 IF X>2 THEN IF X<15 THEN X=INT(12*RND(1))+1:Y=INT(5*RND(1))+1:Z=INT(4*RND(1))+1:GOTO 15700
15240 IF X=15 THEN IF FIX=1 THEN ? :? T$:GOTO 15400
15242 IF X=15 THEN FIX=1:? :? "A LETTER HAS BEEN WRITTEN TO THE":? :? "GRAND JURY."
15250 IF X=16 THEN CASH=CASH*3:? :? "THERE HAS BEEN A BANK ERROR IN YOUR":? :? "FAVOR!":IF CASH<100 THEN CASH=100
15260 IF X=17 THEN Z=PD/4:Z=INT(Z):SEC=SEC+Z
15262 IF X=17 THEN ? :? "$";Z;" HAS BEEN DEPOSITED IN":? :? "YOUR SWISS BANK ACCOUNT!":GOTO 15400
15290 IF X>17 THEN IF X<30 THEN ? :? T$
15310 IF X=30 THEN 15650
15320 IF X=31 THEN 15680
15322 IF X=32 THEN 15800
15400 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
15402 GOTO 1000
15500 X=INT(100*RND(1))+1:IF PD>X THEN GOTO 15510
15502 GOTO 15100
15510 ? :? "YOU ARE GIVEN A LETTER OF INTRODUCTION":? "TO Darkside INVESTORS."
15512 LIMITB=1:GOTO 15400
15550 LIMITM=1:? :? "YOU ARE INTRODUCED TO THE DIRECTORS":? :? "OF Multinational Arms Corp."
15552 GOTO 15400
15600 Z=INT(3*RND(1))+1
15602 Y=INT(20*RND(1))+1:Y=Y*10
15610 ? :? Y;" NEW SHARES OF ";
15612 IF Z=1 THEN ? "AJAX":ASO=ASO+Y
15614 IF Z=2 THEN ? "CRATER":CSO=CSO+Y
15616 IF Z=3 THEN ? "FOX":FSO=FSO+Y
15618 ? :? "ARE IN YOUR PORTFOLIO!!":GOTO 15400
15650 ? :? "FOREIGN CAPITAL SEEKING OPORTUNTIES!":? :? "WHERE WOULD YOU SUGGEST THEY INVEST?"
15660 ? :? "AJAX, CRATER OR FOX?"
15665 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
15670 IF A=65 THEN ACON=1
15672 IF A=67 THEN CCON=1
15674 IF A=70 THEN FCON=1
15679 GOTO 1000
15680 Z=INT(3*RND(1))+1
15682 IF Z=1 THEN ? :? "AJAX";:X=ASV*10
15684 IF Z=2 THEN ? :? "CRATER";:X=CSV*10
15686 IF Z=3 THEN ? :? "FOX";:X=FSV*10
15688 IF X<100 THEN X=100+X
15689 ? " PAYS YOU A SECRET BONUS OF":? :? "$";X;"!":CASH=CASH+X:GOTO 15400
15700 IF Z=1 THEN ? :? "RUMOR MILL: ";:Z=3:GOTO 15710
15702 ? :? IT$;:Z=1
15710 IF X=1 THEN ? "BUY AJAX!":IF Y>Z THEN ATIP=1
15712 IF X=2 THEN ? "SELL FOX!":IF Y>Z THEN FXTIP=1
15714 IF X=3 THEN ? "BUY FOX!":IF Y>Z THEN FTIP=1
15716 IF X=4 THEN ? "BUY CRATER!":IF Y>Z THEN CTIP=1
15718 IF X=5 THEN ? "BOOM TIMES!!":IF Y>Z THEN BOOM=1
15720 IF X=6 THEN ? "THE CRASH IS COMING!":IF Y>Z THEN CRASH=1
15722 IF X=7 THEN ? "BUY AJAX AND CRATER!":IF Y>Z THEN ATIP=1:CTIP=1
15724 IF X=8 THEN ? "BUY AJAX AND FOX!":IF Y>Z THEN ATIP=1:FTIP=1
15726 IF X=9 THEN ? "BUY CRATER AND FOX!":IF Y>Z THEN CTIP=1:FTIP=1
15728 IF X=10 THEN ? "BUY CRATER AND SELL FOX!":IF Y>Z THEN CTIP=1:FXTIP=1
15730 IF X=11 THEN ? "BUY AJAX AND SELL FOX!":IF Y>Z THEN ATIP=1:FXTIP=1
15732 IF X=12 THEN ? "BUY AJAX, CRATER AND FOX":IF Y>Z THEN ATIP=1:FTIP=1:CTIP=1
15799 GOTO 15400
15800 ? :? "Darkside IS SEEKING A LEGITIMATE FIRM":? :? "TO 'LAUNDER' FUNDS. WHERE SHOULD":? :? "THEY INVEST?"
15802 ? :? :? "THE BREWERY, DEHRING OR EASY?"
15810 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:X=INT(2*RND(1))+2:IF A=66 THEN BSV=BSV*X:BSA=BSA+50
15812 IF A=68 THEN DSV=DSV*X:DSA=DSA+100
15814 IF A=69 THEN ESV=ESV*X:ESA=ESA+5000
15819 GOTO 1000
16000 REM SPECIAL
16010 X=INT(4*RND(1))+1:IF X=1 THEN 16400
16100 ? :IF AJAX=1 THEN ? "A GOVERNMENT CONTRACT GRANTED!"
16110 IF BEER=1 THEN ? "HOLIDAY BEER SALES JUMP!!"
16120 IF CRAT=1 THEN ? "NEW RESEARCH CONTRACT GRANTED!"
16130 IF DEHR=1 THEN ? "HIGH RISK INVESTMENT SUCCEEDS!"
16140 IF EASY=1 THEN ? "PROPERTY VALUES RISE SHARPLY!!"
16150 IF FOX=1 THEN ? "GOVERNMENT FREIGHT LINE GRANTED!!"
16160 IF GOLD=1 THEN ? "NEW MOTHER LODE DISCOVERED!!"
16170 IF MULT=1 THEN ? "FOREIGN CONTRACT SIGNED!!"
16200 Y=SV*3:IF Y<75 THEN Y=75
16210 X=INT(Y*RND(1))+SV
16220 UD=1:GOTO 10210
16400 REM SPECIAL LOSS
16408 Z=INT(3*RND(1))+1:IF Z=1 THEN 16600
16410 IF SV<6 THEN 16100
16500 ? :IF AJAX=1 THEN ? "GOVERNMENT CONTRACT CANCELED!"
16510 IF BEER=1 THEN ? "COLD WEATHER: BEER SALES DROP!"
16520 IF CRAT=1 THEN ? "RESEARCH PROJECT FAILS!"
16530 IF DEHR=1 THEN ? "HIGH RISK INVESTMENTS FAIL!"
16540 IF EASY=1 THEN ? "PROPERTY VALUES DROP SHARPLY!!"
16550 IF FOX=1 THEN ? "SAFETY VIOLATIONS CITED!!"
16560 IF GOLD=1 THEN ? "NEW MINE YIELDS FOOL'S GOLD!"
16570 IF MULT=1 THEN ? "FOREIGN CONTRACT CANCELED!"
16590 ? :X=SV-5:UD=2:GOTO 10212
16600 ? :? "FOREIGN INVESTORS CAUSE EXPANSION!"
16610 X=SV*2:IF X<100 THEN X=100+SV*2
16620 Y=SA+SO:SA=SA+Y
16630 UD=1:GOTO 10210
20000 REM REPORT
20010 MONTH=MONTH+3:IF MONTH=12 THEN MONTH=0:YEAR=YEAR+1
20020 IF YEAR>43 THEN X=INT(4*RND(1))+1:IF X=1 THEN 20500
20100 ? "↰":? " Quarterly Report"
20110 ? :? " YEAR ";YEAR;" MONTH ";MONTH:? :?
20120 X=INT(5*RND(1))+1
20122 ? "CURRENT SWISS ACCOUNT: $";SEC
20126 ? :? X;"% INTEREST PAID: $";:Y=SEC*X:Y=Y/100:Y=INT(Y):SEC=SEC+Y:? Y
20150 ? :? :GOSUB 10000:IF TNW=OTNW THEN ? "YOUR NET WORTH HAS NOT CHANGED."
20152 IF TNW>OTNW THEN X=TNW-OTNW:? "YOUR NET WORTH INCREASED $";X
20154 IF OTNW>TNW THEN X=OTNW-TNW:? "YOUR NET WORTH DECREASED $";X
20156 OTNW=TNW
20160 ? :? :? "YOUR CURRENT NET WORTH IS $";TNW:? :? F$;CASH
20200 OPEN #5,4,0,"K":GET #5,A:CLOSE #5
20202 IF BI=0 THEN IF TNW>1000000000 THEN BI=1:GOTO 20600
20206 IF A=86 THEN 20400
20208 IF A<>87 THEN IF A<>68 THEN 1100
20210 IF A=87 THEN 20300
20212 IF A=68 THEN 20350
20300 ? "↰":? :? "YOUR CURRENT DEPOSIT IS $";SEC:? :? "HOW MUCH DO YOU WANT TO WITHDRAW";:INPUT X
20310 IF X>SEC THEN ? :? "YOU DON'T HAVE THAT MUCH.":GOTO 20200
20312 SEC=SEC-X:CASH=CASH+X:GOTO 1100
20350 ? "↰":? F$;CASH:? :? "HOW MUCH DO YOU WANT TO DEPOSIT";:INPUT X
20352 IF X>CASH THEN ? :? "YOU DON'T HAVE THAT MUCH CASH.":GOTO 20200
20354 SEC=SEC+X:CASH=CASH-X:GOTO 1100
20400 ? "↰":? " Vacation Time!!"
20410 ? :? :? "YOUR NET WORTH IS $";TNW
20420 ? :? "THIS IS MONTH ";MONTH;", OF YEAR ";YEAR;"."
20425 ? :? "VALUE OF PATENT RIGHTS: $";PATENT
20430 ? :? :? "GRAND JURY FILES: ";CRIME
20440 ? :? :? "POLITICAL DONATIONS: $";PD
20450 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:RUN
20500 ? "↰":? " Retirement Time!!"
20502 GOSUB 10000:AGE=21+YEAR
20510 POSITION 2,6:? "At the age of ";AGE;" you have achieved":? :? "a personal net worth of $";TNW;"!"
20512 ? :? :? "Congratulations on your skills as an":? :? "entrepreneur!!"
20550 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:RUN
20600 ? "↰":POSITION 2,3:? "Congratulations!!":? :? "At the age of ";YEAR+21;" you have become a":? :? "Billionaire!"
20610 ? :? :? "You're an Entrepreneur Extraordinaire!"
20620 ? :? "Would you like to Retire, take a":? :? "Vacation, Continue your career or":? :? "Start a new game?"
20650 OPEN #5,4,0,"K":GET #5,A:CLOSE #5
20652 IF A=86 THEN 20400
20654 IF A=67 THEN 20000
20656 IF A=82 THEN 20500
20658 IF A=83 THEN RUN
20659 GOTO 20650
24999 RETURN
25000 REM FUTURES
25010 X=INT(13*RND(1))+1
25050 ? :? "THERE IS AN INVESTMENT OPPORTUNITY IN":?
25100 IF X=1 THEN ? "OLD COMIC BOOKS.":Y=10:Z=25
25110 IF X=2 THEN ? "THE MEXICAN PESO.":Y=25:Z=50
25120 IF X=3 THEN ? "THE JAPANESE YEN.":Y=500:Z=250
25130 IF X=4 THEN ? "THE AMERICAN DOLLAR.":Y=150:Z=75
25140 IF X=5 THEN ? "PORKBELLY FUTURES.":Y=150:Z=150
25150 IF X=6 THEN ? "STRATEGIC METALS.":Y=300:Z=200
25160 IF X=7 THEN ? "RARE METALS.":Y=500:Z=250
25170 IF X=8 THEN ? "GEM STONES.":Y=1000:Z=500
25180 IF X=9 THEN ? "INDUSTRIAL ZONED REAL ESTATE.":Y=5000:Z=5000
25182 IF X=10 THEN ? "ACQUISITION AND RESALE OF ART.":Y=25000:Z=10000
25184 IF X=11 THEN ? "BASEBALL TRADING CARDS.":Y=250:Z=100
25188 IF X=12 THEN ? "SOYBEAN FUTURES.":Y=1500:Z=100
25190 IF X=13 THEN ? "RESORT HOTEL DEVELOPMENT.":Y=50000:Z=25000
25200 INV=INT(Y*RND(1))+Z
25210 ? :? "REQUIRED INVESTMENT IS $";INV:? :? :? "DO YOU WISH TO PARTICIPATE?"
25212 ? :? F$;CASH
25300 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
25305 IF XX=1 THEN XX=0:RETURN
25310 IF A<>89 THEN INV=0:RETURN
25312 GOTO 25400
25320 IF INV>CASH THEN ? :? "YOU DON'T HAVE ENOUGH CASH TO INVEST.":XX=1:GOTO 25300
25340 CASH=CASH-INV:RETURN
25400 REM FUT OPTIONS
25410 ? "↰":? "AT WHAT LEVEL DO YOU WISH TO INVEST?"
25420 ? :? :? :? " (1) $";INV
25430 ? :? " (2) $";INV*7
25440 ? :? " (3) $";INV*14
25460 ? :? " (4) $";INV*21
25470 ? :? " (5) $";INV*28
25480 ? :? :? :? "YOUR CASH RESERVE IS $";CASH;"."
25500 OPEN #5,4,0,"K":GET #5,A:CLOSE #5:? "↰"
25510 IF A=50 THEN INV=INV*7
25512 IF A=51 THEN INV=INV*14
25514 IF A=52 THEN INV=INV*21
25516 IF A=53 THEN INV=INV*28
25529 GOTO 25320
30000 CLOSE #5:POKE 752,1:GOTO 20000
