Large-Letter Screen Titles (BIGTEXT.BAS)
Large-Letter Screen Titles by Jerry Vanden Bosch, 75
Description
Large-Letter Screen Titles by Jerry Vanden Bosch, 75
From the Antic disk of March 1988 (Vol. 6 No. 11).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 9.1 KB
- Dialect
- Atari BASIC
- Lines
- 157
- Variables
BRK,L,ROW,COL,M,MD,LINE$,TEXT$,N,LTR,T,TMP$,Q,I,Z$,R,CJ,Y,X,LOC
BASIC listing (157 lines)
10 REM LARGE-LETTER SCREEN TITLES
20 REM BY JERRY VANDEN BOSCH
30 REM (c)1987, ANTIC PUBLISHING
35 REM (DO NOT RENUMBER THIS PROGRAM!)
40 BRK=(PEEK(53279)<>5):L=10000:CLOSE #1:OPEN #1,4,0,"K:"
50 GOSUB 1290:GOSUB 530
60 GOSUB 90
70 ROW=ROW+1:COL=M+1:IF ROW>29-MD*6 THEN ROW=MD*6-6
80 GOTO 60
90 LINE$=TEXT$(1+20*(ROW+6-6*MD),20*(ROW+7-(6*MD))):N=0
100 POKE 752,1:POSITION COL,ROW
110 GOSUB 1480:IF ASC(LINE$(COL-M,COL-M))>127 THEN ? CHR$(ASC(LINE$(COL-M,COL-M))-128);:GOTO 130
120 ? CHR$(ASC(LINE$(COL-M,COL-M))+128);
130 POKE 764,255:GET #1,LTR
140 IF LTR>31 AND LTR<125 THEN 410
150 IF LTR>159 AND LTR<253 THEN 410
160 IF LTR=30 THEN POSITION COL,ROW:? LINE$(COL-M,COL-M);:IF COL>M+1 THEN COL=COL-1:GOTO 100
170 IF LTR=30 THEN COL=M+20:GOTO 100
180 IF LTR=31 THEN POSITION COL,ROW:? LINE$(COL-M,COL-M);:IF COL<M+20 THEN COL=COL+1:GOTO 100
190 IF LTR=31 THEN COL=M+1:GOTO 100
200 IF LTR=28 THEN POSITION COL,ROW:? LINE$(COL-M,COL-M);:GOSUB 510:IF ROW>6*MD-6 THEN ROW=ROW-1:GOTO 90
210 IF LTR=28 THEN ROW=29-6*MD:GOTO 90
220 IF LTR=29 THEN POSITION COL,ROW:? LINE$(COL-M,COL-M);:GOSUB 510:IF ROW<29-MD*6 THEN ROW=ROW+1:GOTO 90
230 IF LTR=29 THEN ROW=MD*6-6:GOTO 90
240 IF LTR=126 AND COL>M+1 THEN POSITION COL,ROW:? LINE$(COL-M,COL-M);:COL=COL-1:LINE$(COL-M,COL-M)=" ":GOTO 100
250 IF LTR=155 THEN POSITION COL,ROW:? LINE$(COL-M,COL-M);:T=T+1:GOSUB 510:RETURN
260 IF LTR=254 AND COL<M+20 THEN TMP$=LINE$(COL-(M-1),20):LINE$(COL-M,19)=TMP$:LINE$(20,20)=" "
270 IF LTR=255 AND COL<M+20 THEN TMP$=LINE$(COL-M,19):LINE$(COL-(M-1),20)=TMP$:LINE$(COL-M,COL-M)=" "
280 IF LTR>253 AND COL<M+20 THEN POSITION COL,ROW:? LINE$(COL-M,20);:GOTO 100
290 GOSUB 510
300 IF LTR=156 AND ROW+6-MD*6<T-1 THEN T=T-1
310 IF LTR=156 THEN 450
320 IF LTR=157 AND ROW<29-MD*6 THEN T=T+1:GOTO 450
330 IF LTR>128 THEN LTR=LTR-128
340 IF LTR=125 THEN N=0:GOSUB 1290:GOSUB 540:GOTO 90
350 IF LTR=3 AND MD=1 THEN MD=2:M=15:N=0:GOTO 550
360 IF LTR=3 AND MD=2 THEN MD=1:M=18:N=0:GOTO 550
370 IF LTR=7 THEN 900
380 IF LTR=13 THEN 1120
390 IF LTR=18 THEN Q=9900:GOSUB 1410:GOSUB 550:GOTO 60
400 GOTO 100
410 LINE$(COL-M,COL-M)=CHR$(LTR):POSITION COL,ROW:? CHR$(LTR);
420 IF COL=M+20 THEN GOSUB 510:T=T+1:RETURN
430 COL=COL+1:GOTO 100
440 REM INSERT/DELETE LINE AT CURSOR ROUTINE
450 I=ROW+6-MD*6
460 IF LTR=157 THEN TMP$=TEXT$(1+I*20,460):TEXT$(21+I*20,480)=TMP$:TEXT$(1+I*20,20+I*20)=Z$(1,20):GOTO 490
470 IF I=23 THEN TEXT$(461,480)=Z$(1,20):GOTO 490
480 TMP$=TEXT$(21+I*20,480):TEXT$(1+I*20,460)=TMP$:TEXT$(461,480)=Z$(1,20)
490 GOSUB 520+MD*140:COL=M+1:GOTO 90
500 REM INCORPORATE INPUT/REVISION INTO APPROPRIATE STRING
510 IF ROW+6-MD*6>=T THEN T=ROW+7-MD*6
520 TEXT$(1+20*(ROW+6-6*MD),20*(ROW+7-6*MD))=LINE$:RETURN
530 DIM LINE$(20),Z$(80),TEXT$(480),TMP$(480):Z$=" ":Z$(80)=Z$:Z$(2)=Z$
540 TEXT$=" ":TEXT$(480)=TEXT$:TEXT$(2)=TEXT$
550 GRAPHICS 0:GOSUB 1480:POKE 710,0:POKE 752,1:ROW=6*MD-6:IF MD=2 THEN 720
560 REM INPUT/EDIT WINDOW DISPLAY FOR MODES 1 & 17
570 COL=19:ROW=0:? "▎MODES 1 & 17▕"
580 POSITION 3,2:? "CAPS=ORANGE":POSITION 4,3:? "lower=AQUA":POSITION 3,4:? "INV CAPS=BLUE"
590 POSITION 4,5:? "inv lwr=RED":POSITION 1,8:? "SHIFT&<=CLEAR":POSITION 1,10:? "CTRL&R=REVIEW"
600 POSITION 1,12:? "CTRL&C=MODE 2":POSITION 1,14:? "CTRL&M=MEMORY"
610 POSITION 7,16:? "┌GR.1,":POSITION 1,17:? "CTRL&G┤ GR.17":POSITION 7,18:? "└DISPLAY"
620 POSITION 15,20:? "┌":POSITION 1,21:? " TEXT WINDOW ─┤"
630 POKE 752,1:POSITION 1,22:? "FOR GRAPHICS 1┤":POSITION 15,23:? "└";
640 FOR I=0 TO 9:POSITION 17,I:? I;"| ";:NEXT I:FOR I=10 TO 23:POSITION 16,I:? I;"|";:NEXT I
650 COLOR 124:PLOT 39,0:DRAWTO 39,23
660 IF T<23 THEN FOR I=ROW TO T:GOTO 680
670 FOR I=ROW TO 23
680 POSITION 19,I:? TEXT$(1+20*I,20*(1+I));:NEXT I:IF LTR=156 OR LTR=157 THEN RETURN
690 IF LTR=3 THEN 90
700 RETURN
710 REM INPUT/EDIT WINDOW DISPLAY FOR MODES 2 & 18
720 COL=16:ROW=6:? " GRAPHICS MODES 2 AND 18 "
730 POSITION 2,3:? "CAPS=":POSITION 26,3:? "1111111111":POSITION 4,4:? "ORANGE"
740 POSITION 16,4:? "01234567890123456789"
750 POSITION 2,6:? "lower=":POSITION 4,7:? "AQUA":POSITION 1,9:? "▕INV CAP=":POSITION 4,10:? "BLUE"
760 POSITION 1,12:? "▕inv lwr=":POSITION 4,13:? "RED"
770 POSITION 15,5:? "┌────────────────────┐"
780 FOR I=0 TO 9:POSITION 14,6+I:? I;"|":POSITION 36,6+I:? "|":NEXT I
790 FOR I=10 TO 11:POSITION 13,6+I:? I;"|":POSITION 36,6+I:? "|":NEXT I:IF COL<16 THEN 830
800 IF T<11 THEN FOR I=ROW-6 TO T:GOTO 820
810 FOR I=ROW-6 TO 11
820 POSITION 16,I+6:? TEXT$(1+20*I,20*(1+I)):NEXT I:IF LTR=156 OR LTR=157 THEN RETURN
830 POSITION 2,16:? "TEXT WINDOW":POSITION 3,17:? " FOR GR.2 "
840 POSITION 15,18:? "└────────────────────┘":POSITION 5,19:? "▕CTRL▎& ▕G▎FOR GRAPHICS DISPLAY"
850 POSITION 6,20:? "▕CTRL▎&▕M▎FOR WORK TO MEMORY":POSITION 3,21:? "CTRL&R TO REVIEW, CTRL&C FOR MODE 1"
860 POSITION 4,22:? "▕CTRL▎OR▕SHIFT▎&▕<▎TO START OVER"
870 IF LTR=3 THEN 90
880 RETURN
890 REM VIEW WORK IN GRAPHICS MODE 1, 2, 17 OR 18 DISPLAY
900 IF N>48 AND N<51 THEN GRAPHICS MD:GOTO 1000
910 IF N>54 AND N<57 THEN GRAPHICS 16+MD:GOTO 1020
920 ? "↰":POSITION 3,6:? "FOR GRAPHICS ";MD;" (WITH TEXT WINDOW),":POSITION 6,7:? "TYPE ";CHR$(MD+176);" NOW"
930 POSITION 3,9:? "FOR GRAPHICS ";MD+16;" (NO TEXT WINDOW),":POSITION 6,10:? "TYPE ";CHR$(182+MD);" NOW"
940 POSITION 4,13:? "AFTER VIEWING GRAPHICS ";MD;" OR ";MD+16:POSITION 6,14:? "DISPLAY, PRESS▕ANY KEY▎TO"
950 POSITION 5,15:? "RETURN TO INPUT/EDIT WINDOW":POSITION 15,16:? "DISPLAY"
960 POKE 764,255:GET #1,N:IF N>176 THEN N=N-128
970 IF MD=1 AND (N=49 OR N=55) THEN 900
980 IF MD=2 AND (N=50 OR N=56) THEN 900
990 GOTO 960
1000 IF (MD=2 AND TEXT$(201,240)=Z$(1,40)) OR (MD=1 AND TEXT$(401,480)=Z$) THEN 1020
1010 GRAPHICS MD+16:N=N+6
1020 GOSUB 1480:? #6;TEXT$(1,200);:IF MD=2 THEN 1050
1030 ? #6;TEXT$(201,400);
1040 IF N=55 AND MD=1 THEN ? #6;TEXT$(401,480);:GOTO 1070
1050 IF N=56 AND MD=2 THEN ? #6;TEXT$(201,240);:GOTO 1070
1060 POKE 752,1:? :? " TO CHANGE TO GRAPHICS ";MD+16;" (NO TEXT WINDOW), TYPE▕SHIFT▎& ";CHR$(MD+182)
1070 POKE 752,1:GET #1,LTR:IF LTR>166 THEN LTR=LTR-128
1080 IF LTR=39 AND N=49 THEN N=55:GRAPHICS 17:GOTO 1020
1090 IF LTR=64 AND N=50 THEN N=56:GRAPHICS 18:GOTO 1020
1100 GOSUB 550:GOTO 60
1101 REM
1110 REM FORCED READ ROUTINE
1111 REM
1120 ? "↰":? :? L;" GRAPHICS ";:IF N>50 THEN 1140
1130 IF (MD=2 AND TEXT$(201,240)=Z$(1,40)) OR (MD=1 AND TEXT$(401,480)=Z$) THEN ? MD;:GOTO 1145
1140 ? MD+16;
1145 ? ":SE.0,2,8:SE.1,12,10:SE.2,9,4:SE.3,4,6:SE.4,0,0"
1150 GOSUB 1190:FOR ROW=0 TO 36-MD*12
1160 IF ROW=36-MD*12 THEN ? "↰":? :? L+R+1;" RETURN":R=0:GOSUB 1190:L=L+100:GOSUB 550:GOTO 60
1170 GOSUB 1220
1180 IF LEN(LINE$)=0 THEN 1185
1181 FOR CJ=1 TO LEN(LINE$):IF LINE$(CJ,CJ)=CHR$(34) THEN LINE$(CJ,CJ)=CHR$(162)
1182 NEXT CJ
1185 R=R+1:? "↰":? :? L+R;" POSITION ";Y;",";ROW;":PRINT #6;";CHR$(34);LINE$;CHR$(34);";"
1190 ? :? :? "CONT":POSITION 0,0:POKE 842,13:STOP
1200 POKE 842,12:? "↰":POSITION 16,10:? "WORKING":IF R=0 THEN RETURN
1210 NEXT ROW
1220 X=20:Y=0:LINE$=TEXT$(1+20*ROW,20*(ROW+1))
1230 IF ASC(LINE$(X,X))<>32 AND ASC(LINE$(X,X))<>160 THEN 1260
1240 X=X-1:IF X>0 THEN LINE$=LINE$(1,X):GOTO 1230
1250 POP :NEXT ROW
1260 IF ASC(LINE$(1,1))<>32 AND ASC(LINE$(1,1))<>160 THEN RETURN
1270 LINE$=LINE$(2):Y=Y+1:GOTO 1260
1280 REM INTRO DISPLAY/MODE SELECT ROUTINE
1290 GRAPHICS 0:GOSUB 1480:T=1:IF PEEK(1536)=112 THEN 1320
1300 DATA 112,112,112,70,64,156,6,6,6,6,6,6,6,6,6,6,6,7,7,7,7,7,7,65,0,6
1310 FOR LOC=1536 TO 1561:READ X:POKE LOC,X:NEXT LOC
1320 POKE 559,0:POKE 560,0:POKE 561,6:POKE 559,34:POKE 87,1
1330 POSITION 2,3:? #6;"THIS IS GRAPHICS":POSITION 1,4:? #6;"MODES 1 OR 17 TEXT"
1340 POSITION 3,6:? #6;"TYPE ";CHR$(34);"1";CHR$(34);" NOW":POSITION 0,7:? #6;"TO WORK IN THIS MODE"
1350 POSITION 2,13:? #6;"THIS IS GRAPHICS":POSITION 1,14:? #6;"MODES 2 OR 18 TEXT":POSITION 3,15
1360 ? #6;"TYPE ";CHR$(34);"2";CHR$(34);" NOW":POSITION 0,16:? #6;"TO WORK IN THIS MODE":POKE 694,0:POKE 702,64
1365 GOSUB 1480
1370 GET #1,MD:MD=MD-48:IF MD=1 THEN M=18:RETURN
1380 IF MD=2 THEN M=15:RETURN
1390 GOTO 1370
1400 REM REVIEW ROUTINE
1410 ? "↰":POSITION 4,5:? "REVIEW YOUR WORK IN SEQUENCE,":POSITION 10,6:? "AT YOUR OWN PACE"
1420 ? :? :? :? " START TO BEGIN":? :? " START AGAIN TO ADVANCE"
1430 ? :? " SELECT TO SEE PRECEEDING PAGE":? :? " OPTION RETURNS TO INPUT/EDIT WINDOW"
1440 IF PEEK(53279)=6 AND Q+100<L+R THEN Q=Q+100:GOSUB Q:FOR I=0 TO 25:NEXT I
1450 IF PEEK(53279)=5 AND Q>10000 THEN Q=Q-100:GOSUB Q:FOR I=0 TO 25:NEXT I
1460 IF PEEK(53279)=3 THEN RETURN
1470 GOTO 1440
1480 POKE 77,0:IF BRK THEN POKE 16,112:POKE 53774,112
1490 RETURN
