Sierpinski Curves, graphics demo (SIERPIN.BAS)
Sierpinski Curves, graphics demo by Allan Sharpe, 15
Description
Sierpinski Curves, graphics demo by Allan Sharpe, 15
From the Antic disk of February 1988 (Vol. 6 No. 10).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 1.7 KB
- Dialect
- Atari BASIC
- Lines
- 54
- Variables
ST(,F,Z,C,H0,I,X,H,Y,PS,A,B,TP,SP,LINE$,ANS,D,CODE,HCODE,LCODE
BASIC listing (54 lines)
4 REM SIERPINSKI CURVES
8 REM BY ALLAN SHARPE
11 REM FROM PAGE 6 MAGAZINE
15 DIM ST(5):F=0
45 GRAPHICS 7+16:POKE 708,56
50 FOR Z=1 TO 4
55 C=C+1:IF C>3 THEN C=1
56 COLOR C
57 IF F=1 THEN COLOR 0
61 GOSUB 100
62 NEXT Z
70 IF F=0 THEN COLOR 0:F=1:GOTO 50
90 END
100 H0=96:H=H0/4:X=3.3*H:Y=3*H:I=0
110 I=I+1:X=X-H:H=H/2:Y=Y+H
120 IF I<Z THEN GOTO 110
130 PS=I:GOSUB 600
140 GOSUB 200:A=H:B=-H:GOSUB 800
150 GOSUB 300:A=-H:B=-H:GOSUB 800
160 GOSUB 400:A=-H:B=H:GOSUB 800
170 GOSUB 500:A=H:B=H:GOSUB 800
180 GOSUB 700:RETURN
200 IF TP<=0 THEN RETURN
220 PS=TP-1:GOSUB 600
230 GOSUB 200:A=H:B=-H:GOSUB 800
240 GOSUB 300:A=2*H:B=0:GOSUB 800
250 GOSUB 500:A=H:B=H:GOSUB 800
260 GOSUB 200
270 GOSUB 700:RETURN
300 IF TP<=0 THEN RETURN
320 PS=TP-1:GOSUB 600
330 GOSUB 300:A=-H:B=-H:GOSUB 800
340 GOSUB 400:A=0:B=-2*H:GOSUB 800
350 GOSUB 200:A=H:B=-H:GOSUB 800
360 GOSUB 300
370 GOSUB 700:RETURN
400 IF TP<=0 THEN RETURN
420 PS=TP-1:GOSUB 600
430 GOSUB 400:A=-H:B=H:GOSUB 800
440 GOSUB 500:A=-2*H:B=0:GOSUB 800
450 GOSUB 300:A=-H:B=-H:GOSUB 800
460 GOSUB 400
470 GOSUB 700:RETURN
500 IF TP<=0 THEN RETURN
520 PS=TP-1:GOSUB 600
530 GOSUB 500:A=H:B=H:GOSUB 800
540 GOSUB 200:A=0:B=2*H:GOSUB 800
550 GOSUB 400:A=-H:B=H:GOSUB 800
560 GOSUB 500
570 GOSUB 700:RETURN
600 SP=SP+1:ST(SP)=PS:TP=PS:RETURN
700 SP=SP-1:TP=ST(SP):RETURN
800 PLOT X,Y:DRAWTO X+A,Y+B
820 X=X+A:Y=Y+B:RETURN
