Meg-Animator, graphics utility (FRMED.BAS)

Meg-Animator, graphics utility by Jacob Donham, 148

Description

Meg-Animator, graphics utility by Jacob Donham, 148

From the Antic disk of February 1988 (Vol. 6 No. 10).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 7.8 KB

Dialect
Atari BASIC
Lines
152
Variables
PM, CH, SB, PMB, CHB, A, B, I, PL(, CT(, A$, F$, FN$, X, K, DL, DM, J, ZM, ZMH, ZML, SC, Y, CHR, OY, P0, ST, C, S, TN, CL, BS, P1, P2, P3
BASIC listing (152 lines)
10 REM MEG-ANIMATOR, LISTING TWO
11 REM FRMED.BAS
20 REM BY JACOB DONHAM
30 REM (c)1987, ANTIC PUBLISHING
50 POKE 106,88:PM=88:CH=92:SB=96:GRAPHICS 0:POKE 710,0:POKE 752,1:PMB=PM*256:CHB=CH*256
60 A=PEEK(89):B=PEEK(88):POKE 88,0:FOR I=88 TO 160:POKE 89,I:? "↰":NEXT I:POKE 89,A:POKE 88,B
70 DIM PL(7),CT(19,11),A$(17),F$(8),FN$(15)
75 FOR I=96 TO 160:X=I*256+244:POKE X+5,10:NEXT I
80 GOSUB 3000
90 OPEN #3,4,0,"K:"
100 ? "            Frame Editor  "
105 ?
110 ? "          1 Edit Frames"
120 ? "          2 Load Frames"
130 ? "          3 Save Frames"
140 ? "          4 Load Block Set"
145 ? "          5 Quit"
150 GET #3,K
160 IF K=ASC("1") THEN 1000
170 IF K=ASC("2") THEN 2500
180 IF K=ASC("3") THEN 2800
185 IF K=ASC("4") THEN 2000
190 IF K=ASC("5") THEN RUN "D:MEGMATOR.BAS"
200 GOTO 150
210 POSITION 12,7:? "  Disk Error!  "
220 GET #3,K:POSITION 12,7:? "               ":GOTO 150
1000 ? "↰":GOSUB 3050:DL=PEEK(560)+256*PEEK(561):POKE DL+27,65:POKE DL+28,32:POKE DL+29,156
1001 POKE DL+3,71:POKE DL+6,7:POKE DL+7,7:POKE DL+8,135
1005 POKE 756,CH:POKE 53277,3
1010 POKE 54286,192:DM=PEEK(DL+4)+256*PEEK(DL+5):FOR I=0 TO 3:FOR J=0 TO 15:POKE DM+(I*20)+J+2,I*16+J:NEXT J
1020 NEXT I:ZM=DM+80:ZMH=INT(ZM/256):ZML=ZM-256*ZMH:POKE 88,ZML:POKE 89,ZMH
1030 ? #6;"          1 Change Frame"
1040 ? #6;"  Frame   2 Clear Frame"
1050 ? #6;"          3 Color"
1060 ? #6;"    ";SC,"4 Copy From"
1070 ? #6;"          5 Parameters"
1075 ? #6;"          6 Return"
1080 GOTO 1200
1120 GET #3,K
1130 IF K>54 OR K<49 THEN 1200
1140 ON K-48 GOTO 1510,1530,1540,1600,1700,1390
1200 X=64:Y=16:CHR=0:OY=16:POKE 53277,3
1210 POKE 53248,X:IF Y<>OY THEN FOR I=OY TO OY+7:POKE P0+I,0:NEXT I
1220 FOR I=Y TO Y+7:POKE P0+I,PL(I-Y):NEXT I
1230 OY=Y:ST=STICK(0):IF ST=14 AND Y>23 THEN Y=Y-8:CHR=CHR-16
1240 IF ST=13 AND Y<33 THEN Y=Y+8:CHR=CHR+16
1250 IF ST=11 AND X>71 THEN X=X-8:CHR=CHR-1
1260 IF ST=7 AND X<177 THEN X=X+8:CHR=CHR+1
1265 IF PEEK(764)<>255 THEN FOR I=Y TO Y+7:POKE P0+I,0:NEXT I:GOTO 1120
1270 IF STRIG(0)=1 THEN 1210
1275 FOR I=OY TO OY+7:POKE P0+I,0:NEXT I
1290 GRAPHICS 18:GOSUB 3050:POKE 756,CH:POKE 53277,3:POKE 53249,0:POKE 53250,0:POKE 53251,0
1293 POKE 88,0:POKE 89,SB+SC:DL=PEEK(560)+256*PEEK(561):POKE DL+4,0:POKE DL+5,SB+SC
1295 X=48:Y=16:B=0:OY=16
1300 IF OY<>Y THEN FOR I=OY TO OY+7:POKE P0+I,0:NEXT I
1305 POKE 53248,X:FOR I=Y TO Y+7:POKE P0+I,PL(I-Y):NEXT I
1310 OY=Y:ST=STICK(0):IF ST=14 AND Y>23 THEN Y=Y-8:B=B-20
1320 IF ST=13 AND Y<97 THEN Y=Y+8:B=B+20
1330 IF ST=11 AND X>55 THEN X=X-8:B=B-1
1340 IF ST=7 AND X<193 THEN X=X+8:B=B+1
1350 IF PEEK(764)<>255 THEN GET #3,K:GOTO 1400
1360 IF STRIG(0)=1 THEN 1300
1370 POKE (SC+SB)*256+B,CHR+C:GOTO 1300
1390 GRAPHICS 0:POKE 752,1:POKE 710,0:POKE 53248,0:GOTO 100
1400 GRAPHICS 0:POKE 752,1:POKE 710,0:FOR I=Y TO Y+7:POKE P0+I,0:NEXT I:GOTO 1000
1510 GRAPHICS 0:POKE 752,1:POKE 710,0:POKE 53248,0
1520 ? "↰":? :? :? "        Which Frame";:TRAP 1000:INPUT S:IF S>-1 AND S<64 THEN SC=S:GOTO 1000
1530 GRAPHICS 18:POKE 88,0:POKE 89,SB+SC:PRINT #6;"↰":GOTO 1290
1540 GRAPHICS 0:POKE 53277,0:POKE 752,1:POKE 710,0:? :? :? "        Which Color";:TRAP 1000:INPUT C
1550 IF C<1 OR C>4 THEN 1540
1560 C=(C-1)*64:GOTO 1000
1600 GRAPHICS 0:POKE 752,1:POKE 710,0:POKE 53248,0:? :? :? "          Frame to Copy From";:TRAP 1000
1605 INPUT S
1610 IF S>-1 AND S<64 THEN ? :? "      Copying Frame ";S;" to Frame ";SC
1620 FOR I=0 TO 239:POKE (SB+SC)*256+I,PEEK((SB+S)*256+I):NEXT I:GOTO 1000
1700 GRAPHICS 0:POKE 752,1:POKE 710,0:POKE 53248,0
1710 ? :? :? "          1 Sound"
1730 ? "          2 Block Set"
1740 ? "          3 Delay"
1750 ? "          4 Return"
1760 GET #3,K
1770 IF K=ASC("1") THEN 1820
1790 IF K=ASC("2") THEN 1880
1800 IF K=ASC("3") THEN 1900
1810 IF K=ASC("4") THEN 1000
1815 GOTO 1760
1820 ? "↰":? :FOR I=0 TO 3
1825 ? "        Tone For Voice ";I+1;:TRAP 1825:INPUT TN:IF TN<0 OR TN>255 THEN 1825
1830 POKE (SB+SC)*256+240+I,TN:NEXT I:GOTO 1700
1850 ? "↰":? :FOR I=0 TO 3
1855 ? "        Color ";I+1;:TRAP 1855:INPUT CL:IF CL<0 OR CL>255 THEN 1855
1860 POKE (SB+SC)*256+244+I,CL:NEXT I:GOTO 1700
1880 ? "↰":?
1885 ? "        Block Set";:TRAP 1885:INPUT BS:IF BS<1 OR BS>8 THEN 1885
1890 POKE (SB+SC)*256+248,BS-1:GOTO 1700
1900 ? "↰":?
1915 ? "        Delay";:TRAP 1915:INPUT DL:IF DL<0 OR DL>255 THEN 1915
1920 POKE (SB+SC)*256+249,DL:GOTO 1700
1999 END
2000 ? "↰":? :? :? "          1 Directory":? "          2 Load Block Set":? "          3 Return"
2010 GET #3,K
2020 IF K=ASC("1") THEN GOSUB 2060:GOTO 2000
2030 IF K=ASC("2") THEN 2100
2040 IF K=ASC("3") THEN ? "↰":GOTO 100
2050 GOTO 2010
2060 ? "↰":? "              Directory    ":OPEN #2,6,0,"D:*.SET":TRAP 2080
2070 INPUT #2,A$:? "          ";A$:GOTO 2070
2080 CLOSE #2:GET #3,K:RETURN
2100 F$="        ":FN$="D:":GOSUB 3100:TRAP 2110
2110 ? "↰":? :? :? "        File to Load";:INPUT F$:FN$(3,LEN(F$)+2)=F$:FN$(LEN(F$)+3,LEN(F$)+6)=".SET"
2120 TRAP 2140:OPEN #1,4,0,FN$:POKE 852,0:POKE 853,CH:POKE 856,0:POKE 857,2:POKE 850,7:A=USR(1536,16)
2130 CLOSE #1:GOSUB 3000:GOTO 2000
2140 CLOSE #1:? :? "        Disk Error- ";PEEK(195):GET #3,K:GOSUB 3000:GOTO 2000
2500 ? "↰":? :? :? "          1 Directory":? "          2 Load Frames":? "          3 Return"
2510 GET #3,K
2520 IF K=ASC("1") THEN GOSUB 2560:GOTO 2500
2530 IF K=ASC("2") THEN 2600
2540 IF K=ASC("3") THEN ? CHR$(125):GOTO 100
2550 GOTO 2510
2560 ? CHR$(125):? "              Directory    ":OPEN #2,6,0,"D:*.FRM":TRAP 2580
2570 INPUT #2,A$:? "          ";A$:GOTO 2070
2580 CLOSE #2:GET #3,K:RETURN
2600 F$="        ":FN$="D:":GOSUB 3100:TRAP 2610
2610 ? CHR$(125):? :? :? "        File to Load";:INPUT F$:FN$(3,LEN(F$)+2)=F$:FN$(LEN(F$)+3,LEN(F$)+6)=".FRM"
2620 TRAP 2640:OPEN #1,4,0,FN$:POKE 852,0:POKE 853,SB:POKE 856,0:POKE 857,64:POKE 850,7:A=USR(1536,16)
2630 CLOSE #1:GOSUB 3000:GOTO 2500
2640 CLOSE #1:? :? "        Disk Error- ";PEEK(195):GET #3,K:GOSUB 3000:GOTO 2500
2800 ? CHR$(125):? :? :? "          1 Directory":? "          2 Save Frames":? "          3 Return"
2810 GET #3,K
2820 IF K=ASC("1") THEN GOSUB 2560:GOTO 2800
2830 IF K=ASC("2") THEN 2900
2840 IF K=ASC("3") THEN ? CHR$(125):GOTO 100
2850 GOTO 2810
2900 F$="        ":FN$="D:":GOSUB 3100:TRAP 2910
2910 ? CHR$(125):? :? :? "        File to Save";:INPUT F$:FN$(3,LEN(F$)+2)=F$:FN$(LEN(F$)+3,LEN(F$)+6)=".FRM"
2920 TRAP 2940:OPEN #1,8,0,FN$:POKE 852,0:POKE 853,SB:POKE 856,0:POKE 857,64:POKE 850,11:A=USR(1536,16)
2930 CLOSE #1:GOSUB 3000:GOTO 2800
2940 CLOSE #1:? :? "        Disk Error- ";PEEK(195):GET #3,K:GOSUB 3000:GOTO 2800
2999 END
3000 RESTORE 3015
3010 FOR I=0 TO 10:READ J:POKE 1536+I,J:NEXT I:POKE 512,0:POKE 513,6
3015 DATA 72,169,224,141,10,212,141,9,212,104,64,0,0,0,0,0,0,0,0,0
3020 RETURN
3050 POKE 54279,PM:POKE 559,46:POKE 53256,0:POKE 53257,3:POKE 53258,1:POKE 704,26:POKE 705,20:POKE 706,0
3060 POKE 707,0:POKE 53259,1:P0=PMB+512:P1=PMB+640:P2=PMB+768:P3=PMB+896:POKE 53277,0
3080 RESTORE 3085:FOR I=0 TO 7:READ J:PL(I)=J:NEXT I
3085 DATA 255,129,129,129,129,129,129,255
3090 RETURN
3100 RESTORE 3115
3110 FOR I=0 TO 6:READ J:POKE 1536+I,J:NEXT I
3115 DATA 104,104,104,170,76,86,228
3120 RETURN