Meg-Animator, graphics utility (BLKED.BAS)

Meg-Animator, graphics utility by Jacob Donham, 148

Description

Meg-Animator, graphics utility by Jacob Donham, 148

From the Antic disk of February 1988 (Vol. 6 No. 10).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 6.2 KB

Dialect
Atari BASIC
Lines
112
Variables
PM, CH, PMB, CHB, A, B, I, BT(, PW(, PL(, A$, F$, FN$, K, DL, DM, J, ZM, ZMH, ZML, X, Y, CHR, OY, P0, ST, P1, OX, IN, BT, OT, M, N, P2, P3
BASIC listing (112 lines)
10 REM MEG-ANIMATOR, LISTING ONE
11 REM BLKED.BAS
20 REM BY JACOB DONHAM
30 REM (c)1987, ANTIC PUBLISHING
50 POKE 106,152:PM=152:CH=156:GRAPHICS 0:POKE 710,0:POKE 752,1:PMB=PM*256:CHB=CH*256
60 A=PEEK(89):B=PEEK(88):POKE 88,0:FOR I=152 TO 160:POKE 89,I:? "↰":NEXT I:POKE 89,A:POKE 88,B
70 DIM BT(8),PW(7),PL(7),A$(17),F$(8),FN$(15):FOR I=0 TO 7:READ A:PW(I)=A:NEXT I:DATA 1,2,4,8,16,32,64,128
80 GOSUB 3000
90 OPEN #3,4,0,"K:"
100 ? "            Block Editor  "
105 ?
110 ? "          1 Edit Block Set"
120 ? "          2 Load Block Set"
130 ? "          3 Save Block Set"
140 ? "          4 Quit"
150 GET #3,K:TRAP 210
160 IF K=ASC("1") THEN 1000
170 IF K=ASC("2") THEN 2000
180 IF K=ASC("3") THEN 2500
190 IF K=ASC("4") THEN RUN "D:MEGMATOR.BAS"
200 GOTO 150
210 POSITION 12,7:PRINT "  Disk Error!  "
220 GET #3,K:POSITION 12,7:? "               ":GOTO 150
1000 ? "↰":GOSUB 3050:DL=PEEK(560)+256*PEEK(561):POKE DL+27,65:POKE DL+28,32:POKE DL+29,156
1001 POKE DL+3,71:POKE DL+6,7:POKE DL+7,7:POKE DL+8,135
1005 POKE 756,CH:POKE 53277,3
1010 POKE 54286,192:DM=PEEK(DL+4)+256*PEEK(DL+5):FOR I=0 TO 3:FOR J=0 TO 15:POKE DM+(I*20)+J+2,I*16+J:NEXT J
1020 NEXT I:ZM=DM+80:ZMH=INT(ZM/256):ZML=ZM-256*ZMH:POKE 88,ZML:POKE 89,ZMH
1025 ? #6;"  ┌────────┐"
1030 ? #6;"  |        |    1 Edit Block"
1040 ? #6;"  |        |    2 Clear Block"
1050 ? #6;"  |        |    3 Reverse Block"
1060 ? #6;"  |        |    4 Scroll Up"
1070 ? #6;"  |        |    5 Scroll Down"
1080 ? #6;"  |        |    6 Scroll Right"
1090 ? #6;"  |        |    7 Scroll Left"
1100 ? #6;"  |        |    8 Return"
1110 ? #6;"  └────────┘"
1120 GET #3,K
1130 IF K>56 OR K<49 THEN 1120
1140 ON K-48 GOTO 1200,1700,1750,1800,1850,1900,1950,1390
1150 ON K-48 GOTO 1200,1700,1750,1800,1850,1900,1950
1200 X=64:Y=16:CHR=0:OY=16:POKE 53277,3
1210 POKE 53248,X:IF Y<>OY THEN FOR I=OY TO OY+7:POKE P0+I,0:NEXT I
1220 FOR I=Y TO Y+7:POKE P0+I,PL(I-Y):NEXT I
1230 OY=Y:ST=STICK(0):IF ST=14 AND Y>23 THEN Y=Y-8:CHR=CHR-16
1240 IF ST=13 AND Y<33 THEN Y=Y+8:CHR=CHR+16
1250 IF ST=11 AND X>71 THEN X=X-8:CHR=CHR-1
1260 IF ST=7 AND X<177 THEN X=X+8:CHR=CHR+1
1270 IF STRIG(0)=1 THEN 1210
1275 FOR I=OY TO OY+7:POKE P0+I,0:NEXT I
1280 POKE 53249,68:FOR I=0 TO 7:FOR J=0 TO 3:POKE P1+56+(I*4)+J,PEEK(CHB+(CHR*8)+I):NEXT J:NEXT I
1290 X=5:Y=2:OX=5:OY=2
1300 IF OX<>X OR OY<>Y THEN POSITION OX,OY:? " "
1305 POSITION X,Y:? "+":FOR I=0 TO 6:NEXT I
1310 OX=X:OY=Y:ST=STICK(0):IF ST=14 AND Y>2 THEN Y=Y-1
1320 IF ST=13 AND Y<9 THEN Y=Y+1
1330 IF ST=11 AND X>5 THEN X=X-1
1340 IF ST=7 AND X<12 THEN X=X+1
1350 IF PEEK(764)<>255 THEN POSITION X,Y:? " ":GOTO 1120
1360 IF STRIG(0)=1 THEN 1300
1370 IN=PEEK(CHB+(CHR*8)+(Y-2)):BT=X-4:GOSUB 1650:POKE CHB+(CHR*8)+(Y-2),OT:FOR I=0 TO 3
1380 POKE P1+60+((Y-3)*4)+I,OT:NEXT I:GOTO 1300
1390 GRAPHICS 0:POKE 752,1:POKE 710,0:POKE 53248,0:POKE 53249,0:GOTO 100
1650 FOR I=1 TO 8:BT(I)=0:NEXT I
1652 A=IN:FOR I=1 TO 8:M=8-I:N=PW(M):IF A>N-1 THEN BT(I)=1:A=A-N
1653 NEXT I
1654 IF BT(BT)=1 THEN BT(BT)=0:GOTO 1658
1656 IF BT(BT)=0 THEN BT(BT)=1
1658 FOR I=1 TO 8:M=8-I:N=PW(M):A=A+BT(I)*N:NEXT I:OT=A:RETURN
1700 FOR I=0 TO 7:POKE CHB+(CHR*8)+I,0:NEXT I:GOTO 1280
1750 FOR I=0 TO 7:POKE CHB+(CHR*8)+I,255-PEEK(CHB+(CHR*8)+I):NEXT I:GOTO 1280
1800 FOR I=0 TO 6:POKE CHB+(CHR*8)+I,PEEK(CHB+(CHR*8)+I+1):NEXT I:POKE CHB+(CHR*8)+7,0:GOTO 1280
1850 FOR I=7 TO 0 STEP -1:POKE CHB+(CHR*8)+I,PEEK(CHB+(CHR*8)+I-1):NEXT I:POKE CHB+(CHR*8),0:GOTO 1280
1900 FOR I=0 TO 7:POKE CHB+(CHR*8)+I,INT(PEEK(CHB+(CHR*8)+I)/2):NEXT I:GOTO 1280
1950 FOR I=0 TO 7:J=PEEK(CHB+(CHR*8)+I)*2:IF J>255 THEN J=J-255
1960 POKE CHB+(CHR*8)+I,J:NEXT I:GOTO 1280
2000 ? "↰":? :? :? "          1 Directory":? "          2 Load Block Set":? "          3 Return"
2010 GET #3,K
2020 IF K=ASC("1") THEN GOSUB 2060:GOTO 2000
2030 IF K=ASC("2") THEN 2100
2040 IF K=ASC("3") THEN ? "↰":GOTO 100
2050 GOTO 2010
2060 ? "↰":? "              Directory    ":OPEN #2,6,0,"D:*.SET":TRAP 2080
2070 INPUT #2,A$:? "          ";A$:GOTO 2070
2080 CLOSE #2:GET #3,K:RETURN
2100 F$="        ":FN$="D:":TRAP 2110
2110 ? "↰":? :? :? "        File to Load";:INPUT F$:FN$(3,LEN(F$)+2)=F$:FN$(LEN(F$)+3,LEN(F$)+6)=".SET"
2120 TRAP 2140:OPEN #1,4,0,FN$:POKE 852,0:POKE 853,CH:POKE 856,0:POKE 857,2:POKE 850,7
2130 A=USR(ADR("hhh*LVd"),16):CLOSE #1:GOSUB 3000:GOTO 2000
2140 CLOSE #1:? :? "        Disk Error- ";PEEK(195):GET #3,K:GOSUB 3000:GOTO 2000
2500 ? "↰":? :? :? "          1 Directory":? "          2 Save Block Set":? "          3 Return"
2510 GET #3,K
2520 IF K=ASC("1") THEN GOSUB 2060:GOTO 2500
2530 IF K=ASC("2") THEN 2600
2540 IF K=ASC("3") THEN ? "↰":GOTO 100
2550 GOTO 2510
2600 F$="        ":FN$="D:":TRAP 2610
2610 ? "↰":? :? :? "        File to Save";:INPUT F$:FN$(3,LEN(F$)+2)=F$:FN$(LEN(F$)+3,LEN(F$)+6)=".SET"
2620 TRAP 2640:OPEN #1,8,0,FN$:POKE 852,0:POKE 853,CH:POKE 856,0:POKE 857,2:POKE 850,11
2630 A=USR(ADR("hhh*LVd"),16):CLOSE #1:GOSUB 3000:GOTO 2500
2640 CLOSE #1:? :? "        Disk Error- ";PEEK(195):GET #3,K:GOSUB 3000:GOTO 2500
2999 END
3000 RESTORE 3015
3010 FOR I=0 TO 10:READ J:POKE 1536+I,J:NEXT I:POKE 512,0:POKE 513,6
3015 DATA 72,169,224,141,10,212,141,9,212,104,64
3020 RETURN
3050 POKE 54279,PM:POKE 559,46:POKE 53256,0:POKE 53257,3:POKE 53258,1:POKE 704,26:POKE 705,20:POKE 706,0
3060 POKE 707,0:POKE 53259,1:P0=PMB+512:P1=PMB+640:P2=PMB+768:P3=PMB+896:POKE 53277,0
3080 RESTORE 3085:FOR I=0 TO 7:READ J:PL(I)=J:NEXT I
3085 DATA 255,129,129,129,129,129,129,255
3090 RETURN