database (TOPSHELF.BAS)

database by Lester Block, 130

Description

database by Lester Block, 130

From the Antic disk of January 1988 (Vol. 6 No. 9).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 15.8 KB

Dialect
Atari BASIC
Lines
289
Variables
BL$, ELEM, INP, TOP, MENU, F, FLD, OFFSET, COL, ROW, CUR$, DLAY, ILEN, MODE, CK, K, C, R, DL, X, A$, CL$, B$, FIELD$, Z, I, SEC, START, ST(, LLEN(, OK, BEEP, S, NUM, D, FIND$, BUFFER$, RECLEN, RECORD$, MEM, LNG, DELAY, TYPE(, FUN$, FILE$, DAT$, DEC(, SPACE, ADDR, EOL$, OP, TMP, RLEN, RL, A, ED(, IOCB, CMD, IOCBX, ICCOM, ICSTA, ICBAL, ICBAH, ICBLL, ICBLH, LO, HI, CIO$, STAT, V, SORT$, DEC, DC, L, ZERO$, FC, CN, B, TOT, FNO, T, MOV$, C$
BASIC listing (289 lines)
10 REM TOPSHELF
12 REM BY LESTER BLOCK
14 REM (c)1987, ANTIC PUBLISHING
20 GOTO 5000
25 POKE 77,0:POKE 16,112:POKE 53774,112:RETURN
30 POSITION 1,0:? BL$:POSITION 1,0:RETURN
40 POSITION 1,1:? BL$:POSITION 1,1:RETURN
50 IF  NOT ELEM THEN GOSUB INP:GOSUB TOP:? "NO DATA ON FILE":GOTO MENU
60 RETURN
70 FOR F=1 TO FLD*(FLD>0)+23*(FLD=0):POKE OFFSET+F*2+2,12:NEXT F:RETURN
80 FOR F=FLD+1 TO 23:POKE OFFSET+F*2+2,6:NEXT F:RETURN
99 REM INPUT ROUTINE
100 CLOSE #2:OPEN #2,4,0,"K:":COL=PEEK(85):ROW=PEEK(84)
110 ? CUR$;:FOR DLAY=1 TO 15
115 GOSUB 25:IF PEEK(85)=ILEN+COL AND MODE=1 THEN ? CUR$(1,1);
117 IF PEEK(764)<>255 THEN 130
120 NEXT DLAY:CK=(CK=0):POKE 752,CK:GOTO 110
130 GET #2,K:IF K<>16 THEN 145
135 TRAP 140:C=PEEK(85):R=PEEK(84):FOR DL=3 TO 22:POSITION 1,X:INPUT #5,A$:LPRINT A$:NEXT DL
140 TRAP 1015:POSITION C,R:GOTO 120
145 IF K=27 THEN GOSUB 70:? CL$:GOTO MENU
148 IF  NOT MODE THEN RETURN
150 IF K=155 THEN POSITION COL,ROW:INPUT #5;B$:GOTO 170
155 IF K=29 OR K=28 OR K=254 THEN 120
160 ? CHR$(K);:GOTO 120
170 IF LEN(B$)=0 THEN B$=BL$(1,25)
180 RETURN
199 REM OK
200 GOSUB TOP:? "IS THIS CORRECT (Y/N) ";:MODE=0:GOSUB INP
210 IF K<>78 AND K<>89 THEN 200
220 RETURN
230 FOR DLAY=1 TO 500:NEXT DLAY:RETURN
239 REM SHOW TITLES
240 GOSUB 70:POKE 752,1:POKE 82,1:? CL$:POSITION 1,3:FOR X=1 TO FLD:? FIELD$(X*8-7,X*8);":":NEXT X:RETURN
250 SOUND 0,50,10,10:Z=2^2:SOUND 0,0,0,0:RETURN
260 I=1:MODE=0
265 GOSUB SEC:? FIELD$(I*8-7,I*8);":";:POKE OFFSET+I*2+2,44:GOSUB INP
270 C=(K=43)-(K=45):IF K=155 THEN POKE OFFSET+I*2+2,12:RETURN
280 POKE OFFSET+I*2+2,12:I=I+C:IF I<1 OR I>FLD THEN C=-C:I=I+C
290 GOTO 265
299 REM SEE NAMES
300 GOSUB 50:GOSUB 240:GOSUB TOP:? "LOOK FOR..:+:-:RETURN ENTERS"
310 GOSUB 260
320 POKE OFFSET+I*2+2,88:START=ST(I):GOSUB TOP:? "ENTER NAME TO FIND ";
325 GOSUB SEC:? FIELD$(I*8-7,I*8);":";:MODE=1:ILEN=LLEN(I):GOSUB INP:GOSUB OK:IF K=78 THEN 300
330 GOSUB 70:R=LEN(B$):IF R<1 THEN GOSUB BEEP:GOTO 330
335 IF B$(R,R)=CHR$(34) THEN B$(R)="  ":B$=B$(2)
340 GOSUB SEC:? "LOOKING FOR ";B$;:S=1:NUM=0
345 D=USR(ADR(FIND$),ADR(BUFFER$)+S*RECLEN-RECLEN+START-1,R,ELEM,S-1,ADR(B$),RECLEN)
350 S=PEEK(1786)+256*PEEK(1787)
360 IF S<=ELEM THEN RECORD$=BUFFER$(S*RECLEN-RECLEN+1):NUM=NUM+1:GOSUB 1100:S=S+1:GOTO 345
370 GOSUB TOP:IF NUM THEN ? "END OF DATA":GOTO MENU
380 GOSUB TOP:IF  NOT NUM THEN ? "NO DATA FOUND":GOTO MENU
399 REM ADD DATA
400 ? CL$:IF  NOT FLD THEN GOSUB BEEP:GOSUB TOP:? "FILE NOT CREATED":GOTO MENU
402 R=INT((MEM-LNG)/RECLEN):IF R<3 THEN GOSUB BEEP:GOSUB TOP:? "IMPORTANT!..ROOM FOR ";R;" MORE FILES";
403 GOSUB DELAY
404 S=ELEM+1:GOSUB 240:FOR I=1 TO FLD:IF TYPE(I)=2 THEN 430
405 IF TYPE(I)=3 THEN B$=FUN$(I*20-19,I*20):GOTO 425
408 GOSUB TOP:? "ENTER DATA FOR ";FIELD$(I*8-7,I*8);:IF TYPE(I)=1 THEN ? " NUMBERS ONLY"
410 POKE OFFSET+I*2+2,44:MODE=1
420 GOSUB SEC:? FIELD$(I*8-7,I*8);":";BL$(1,LLEN(I));":";:POSITION 10,1:ILEN=LLEN(I):GOSUB INP
425 POSITION 10,I+2:? B$
430 POKE OFFSET+I*2+2,12:NEXT I:GOSUB OK:IF K=78 THEN 600
440 GOSUB 1700:BUFFER$(LNG)=RECORD$:ELEM=ELEM+1:LNG=LNG+RECLEN
450 GOSUB TOP:? "DATA ENTERED":GOTO MENU
460 BUFFER$(LNG)=RECORD$:ELEM=ELEM+1:LNG=LNG+RECLEN:GOTO MENU
499 REM SAVE
500 GOSUB TOP:? "NAME OF FILE":GOSUB SEC:? "SAVE>";FILE$;:POKE 85,6:MODE=1:ILEN=15:GOSUB INP
505 FOR X=1 TO FLD:DAT$(X*3-2)=CHR$(LLEN(X))
507 DAT$(X*3-1)=CHR$(DEC(X)):DAT$(X*3)=CHR$(TYPE(X)):NEXT X
510 A$="D:":A$(3)=B$:GOSUB SEC:? "SAVE>";A$:GOSUB OK:IF K=78 THEN 500
512 TRAP 520:CLOSE #2:OPEN #2,4,0,A$:CLOSE #2:GOSUB BEEP:GOSUB BEEP:GOSUB SEC:? "REPLACE>>";A$:GOSUB OK
515 IF K=78 THEN GOSUB TOP:? A$;" NOT SAVED":GOTO MENU
520 TRAP 1015:SPACE=LNG+500:CLOSE #2:OPEN #2,8,0,A$:FILE$=B$:ADDR=ADR(DAT$)
530 ? #2;ELEM;EOL$;LNG;EOL$;RECLEN;EOL$;FLD;EOL$;FIELD$
550 OP=8:GOSUB 900:GOSUB TOP:? "FILE SAVED":GOTO MENU
559 REM ERASE FILE
560 ? CL$:GOSUB SEC:? "ERASE CURRENT FILE!":GOSUB OK:IF K=78 THEN GOSUB TOP:? "FILE INTACT":GOTO MENU
570 LNG=1:ELEM=0:GOSUB TOP:? "FILE ERASED FROM MEMORY":GOTO MENU
600 GOSUB TOP:? "CORRECT ENTRIES:+:-:RETURN ENTERS"
610 GOSUB 260:POKE OFFSET+I*2+2,88
630 POSITION 10,I+2:INPUT #5,B$:IF TYPE(I)=1 THEN GOSUB 1800
633 POSITION 10,I+2:? BL$(1,25):GOSUB SEC
635 ? FIELD$(I*8-7,I*8);":";B$:GOSUB TOP:? "MAKE CORRECTION":POSITION 10,1
640 ILEN=LLEN(I):MODE=1:GOSUB INP:B$(LEN(B$)+1)=BL$:B$=B$(1,LLEN(I)):POKE OFFSET+(I*2-2),12
650 TMP=I:POSITION 10,I+2:? B$:GOSUB OK:IF K=78 THEN GOSUB 70:GOTO 600
660 GOSUB 1700:BUFFER$(S*RECLEN-RECLEN+1,S*RECLEN)=RECORD$(1,RECLEN)
665 POKE OFFSET+TMP*2+2,12:IF S>ELEM THEN ELEM=S:LNG=LNG+RECLEN
670 GOSUB TOP:? "CORRECTIONS MADE, DATA ENTERED":GOTO MENU
699 REM EXIT
700 GOSUB SEC:? "EXIT...ARE YOU SURE":GOSUB OK:IF K=78 THEN ? CL$:GOTO MENU
710 GRAPHICS 0:END
749 REM BROWSE
750 GOSUB 50:GOSUB 240:GOSUB TOP:? "BROWSE":GOSUB SEC:? "FIRST:LAST:MIDDLE..SELECT ONE";:MODE=0:F=1
760 GOSUB INP:C=(K=70)+ELEM*(K=76)+INT(ELEM/2)*(K=77):IF  NOT C THEN GOSUB BEEP:GOTO 760
770 S=C:IF C=ELEM THEN F=-F
775 RECORD$=BUFFER$(S*RECLEN-RECLEN+1)
780 GOSUB 1100:S=S+F:IF S>ELEM OR S<1 THEN 370
790 GOTO 775
799 REM LOAD
800 A$="D:":GOSUB TOP:? "Enter Filename":GOSUB SEC:? "LOAD>";:COL=PEEK(85):? FILE$;:POKE 85,COL
810 MODE=1:ILEN=15:GOSUB INP:A$(3)=B$:GOSUB SEC:? "LOAD>";A$:GOSUB OK:IF K=78 THEN 800
820 FILE$=B$:OP=4:ADDR=ADR(DAT$):TRAP 1015:CLOSE #2:OPEN #2,4,0,A$:SPACE=MEM:RLEN=1
830 INPUT #2,ELEM,LNG,RECLEN,FLD,FIELD$
840 GOSUB 900:RL=1:FOR X=1 TO FLD:ST(X)=RL:A=ASC(DAT$(X*3-2)):LLEN(X)=A:RL=RL+A:ED(X)=RL-1
850 DEC(X)=ASC(DAT$(X*3-1)):TYPE(X)=ASC(DAT$(X*3)):NEXT X
860 GOSUB TOP:? "File Loaded":GOSUB 80:GOSUB 70:GOTO MENU
900 REM
960 IOCB=2:CMD=7*(OP=4)+11*(OP=8):IOCBX=IOCB*16
970 ICCOM=834+IOCBX:ICSTA=835+IOCBX:ICBAL=836+IOCBX:ICBAH=837+IOCBX
975 ICBLL=840+IOCBX:ICBLH=841+IOCBX:TMP=ADDR:GOSUB 1020
985 IF OP=4 THEN BUFFER$=BL$:BUFFER$(MEM)=BUFFER$:BUFFER$(2)=BUFFER$:DAT$=BUFFER$:FUN$=BUFFER$
990 POKE ICBAL,LO:POKE ICBAH,HI:TMP=SPACE:GOSUB 1020
995 POKE ICBLL,LO:POKE ICBLH,HI:POKE ICCOM,CMD:D=USR(ADR(CIO$),IOCBX)
1000 CLOSE #2:? CL$:STAT=PEEK(ICSTA):IF STAT<>1 AND STAT<>136 THEN POKE 195,STAT:GOTO 1015
1010 RETURN
1015 GOSUB BEEP:GOSUB TOP:? "I/O ERROR #";PEEK(195);:GOTO MENU
1020 HI=INT(TMP/256):LO=TMP-HI*256:RETURN
1099 REM SHOW DATA
1100 POKE 82,10:POKE 752,1:POSITION 10,3:FOR X=1 TO FLD:? RECORD$(ST(X),ED(X)):NEXT X
1110 POKE 82,1:GOSUB TOP:? "SELECT ITEM":GOSUB SEC:? "CORRECT:ERASE:+:-:SPACE CONT:ESC";
1120 MODE=0:GOSUB INP:C=(K=67)+2*(K=69)+3*(K=43)+4*(K=45)+5*(K=32):IF  NOT C THEN GOSUB BEEP:GOTO 1120
1130 ON C GOTO 600,1140,1250,1250,1290
1140 GOSUB SEC:? "ERASE THIS RECORD":GOSUB OK:IF K=78 THEN GOSUB TOP:? "RECORD NOT ERASED":GOTO MENU
1150 BUFFER$(S*RECLEN-RECLEN+1)=BUFFER$(S*RECLEN+1)
1160 LNG=LNG-RECLEN:ELEM=ELEM-1
1170 GOSUB TOP:? "RECORD ERASED":GOTO MENU
1249 REM VERT
1250 V=(C=3)-(C=4):S=S+V
1260 IF S>ELEM THEN S=ELEM:GOSUB BEEP:GOSUB TOP:? "TOP OF FILE";:GOTO 1120
1270 IF S<1 THEN S=1:GOSUB BEEP:GOSUB TOP:? "BOTTOM OF FILE";:GOTO 1120
1280 RECORD$=BUFFER$(S*RECLEN-RECLEN+1):GOTO 1100
1290 RETURN
1299 REM SORT
1300 GOSUB 50:GOSUB 240:GOSUB TOP:? "SORT USING FIELD (+:-:RETURN ENTERS)":GOSUB 260:POKE OFFSET+I*2+2,88
1310 START=ST(I):GOSUB SEC:? "SORT ON ";FIELD$(I*8-7,I*8):GOSUB OK:IF K<>89 THEN 1300
1320 GOSUB 70:? CL$:GOSUB SEC:? "SORTING":? :?
1330 FOR X=1 TO ELEM-1:D=USR(ADR(SORT$),ADR(BUFFER$)+X*RECLEN-RECLEN+START-1,LLEN(I),X,ELEM,RECLEN)
1340 S=PEEK(1788)+256*PEEK(1789):IF S>ELEM THEN 1380
1350 RECORD$=BUFFER$(S*RECLEN-RECLEN+1,S*RECLEN)
1360 BUFFER$(S*RECLEN-RECLEN+1,S*RECLEN)=BUFFER$(X*RECLEN-RECLEN+1,X*RECLEN)
1370 BUFFER$(X*RECLEN-RECLEN+1,X*RECLEN)=RECORD$
1380 ? ".";:NEXT X:? CL$:GOSUB TOP:? "Sort Complete":GOTO MENU
1390 GOTO 1360
1399 REM FIND
1400 GOSUB 50:GOSUB 240:GOSUB TOP:? "FIND..+:-:RETURN ENTERS":GOSUB 260
1410 GOSUB TOP:? "Enter name to look for":GOSUB SEC:? FIELD$(I*8-7,I*8);":";
1420 MODE=1:ILEN=LLEN(I):GOSUB INP:GOSUB OK:IF K=78 THEN 1400
1425 START=ST(I):R=LEN(B$):IF B$(R,R)=CHR$(34) THEN B$(R)="  ":B$=B$(2)
1430 GOSUB TOP:? "Looking for ";B$;:NUM=0:ADDR=ADR(DAT$):S=1
1440 D=USR(ADR(FIND$),ADR(BUFFER$)+S*RECLEN-RECLEN+START-1,R,ELEM,S-1,ADR(B$),RECLEN)
1445 S=PEEK(1786)+256*PEEK(1787):IF S>ELEM THEN 1455
1450 TMP=S:GOSUB 1020:POKE ADDR+NUM,LO:POKE ADDR+NUM+1,HI:NUM=NUM+2:S=S+1:GOTO 1440
1455 ? CL$:IF  NOT NUM THEN GOSUB TOP:? "No Matching Data Found":GOTO MENU
1460 GOSUB 240:GOSUB TOP:? NUM/2;" Files found. Enter disposition":GOSUB SEC
1470 ? "Display to: Screen:Printer:Disk";:MODE=0:GOSUB INP:TRAP 1015
1480 C=(K=83)+2*(K=80)+3*(K=68):IF  NOT C THEN GOSUB BEEP:GOTO 1460
1490 IF C<>3 THEN 1530
1500 GOSUB TOP:? "Enter filename":GOSUB SEC:? "FILENAME:":POSITION 10,1:MODE=1:A$="D:"
1505 ILEN=15:GOSUB INP:GOSUB OK:IF K=78 THEN 1460
1508 A$(3)=B$
1510 GOSUB TOP:? "ENTER TYPE OF TRANSFER":GOSUB SEC:? "MOVE AS:DATA:TEXT>";:MODE=1:ILEN=1:GOSUB INP
1512 GOSUB OK:IF K=78 THEN 1500
1515 TRAP 1015:CLOSE #3:OPEN #3,8,0,A$:IF B$="T" THEN 1530
1520 RECORD$=DAT$:FOR X=1 TO FLD:DAT$(X*3-2)=CHR$(LLEN(X)):DAT$(X*3-1)=CHR$(DEC(X))
1523 DAT$(X*3)=CHR$(TYPE(X)):NEXT X
1524 IF LEN(DAT$)<100 THEN DAT$(LEN(DAT$)+1)=BL$:GOTO 1524
1525 IF LEN(FUN$)<400 THEN FUN$(LEN(FUN$)+1)=FUN$:GOTO 1525
1527 ? #3;NUM/2;EOL$;(NUM/2)*RECLEN+1;EOL$;RECLEN;EOL$;FLD;EOL$;FIELD$;EOL$;DAT$;
1529 ? #3;FUN$;:DAT$=RECORD$
1530 FOR X=0 TO NUM-2 STEP 2:S=PEEK(ADDR+X)+256*PEEK(ADDR+X+1)
1535 RECORD$=BUFFER$(S*RECLEN-RECLEN+1):FOR D=1 TO FLD:POSITION 10,D+2:? RECORD$(ST(D),ED(D))
1540 IF C=3 THEN ? #3;RECORD$(ST(D),ED(D))
1550 IF C=2 THEN LPRINT FIELD$(D*8-7,D*8);":";RECORD$(ST(D),ED(D))
1560 NEXT D:IF C=2 THEN LPRINT
1570 NEXT X:CLOSE #3:GOSUB TOP:? "DISPOSITION OF DATA COMPLETE":GOTO MENU
1599 REM DIRECTORY
1600 ? CL$:GOSUB TOP:? "DIRECTORY":GOSUB SEC:? "DRIVE #:";
1610 MODE=0:GOSUB INP:TRAP 1015:A=K-48
1620 A$="D":A$(2)=STR$(A):A$(3)=":*.*"
1640 POKE 752,1:CLOSE #2:OPEN #2,6,0,A$:V=0:TRAP 1670
1650 INPUT #2;A$:POSITION 1+19*(V/2=INT(V/2)),4+INT(V/2):? A$
1660 V=V+1:GOTO 1650
1670 GOSUB TOP:? "All Files Listed":TRAP 1015:GOTO MENU
1680 TRAP 40000:GOSUB TOP:? "Disk Files Listed":GOTO MENU
1699 REM PUT DATA INTO RECORD$
1700 POKE 752,1:FOR I=1 TO FLD:POSITION 10,I+2:INPUT #5,B$
1702 DEC=DEC(I):DC=1:IF  NOT DEC THEN 1710
1705 FOR X=1 TO DEC:DC=DC*10:NEXT X
1710 IF TYPE(I)=0 OR TYPE(I)=3 THEN 1900
1720 IF TYPE(I)=2 THEN 1750
1730 TRAP 1735:A=VAL(B$):TRAP 40000:GOTO 1740
1735 A=0:GOTO 1745
1740 IF DEC(I)=0 THEN A=INT(A+0.5):POSITION 10,I+2:? A:GOTO 1900
1742 B$=STR$(A*DC):L=LEN(B$)
1745 IF A=0 THEN B$=ZERO$(1,DEC+1):L=LEN(B$)
1748 GOSUB 1820:GOTO 1895
1750 A$=FUN$(I*20-19):FC=0:F=1:CN=0:POSITION 10,I+2:? BL$(1,28)
1760 IF A$(F,F)<="9" AND A$(F,F)>="0" THEN CN=CN*10+VAL(A$(F,F)):F=F+1:GOTO 1760
1765 TRAP 1767:IF CN THEN B$=RECORD$(ST(CN),ED(CN)):GOSUB 1800:A=VAL(B$):IF  NOT FC THEN B=A
1766 IF CN THEN 1770
1767 GOSUB BEEP:POSITION 10,I+2:? "error":GOTO 1900
1770 FC=FC+1:IF FC=2 THEN ON C GOSUB 1880,1881,1882,1883:B=TOT:FC=1
1780 C=(A$(F,F)="+")+2*(A$(F,F)="-")+3*(A$(F,F)="*")+4*(A$(F,F)="/"):IF  NOT C THEN 1890
1790 F=F+1:CN=0:GOTO 1760
1800 FOR Z=1 TO LEN(B$):IF B$(Z,Z)=" " THEN NEXT Z:RETURN
1810 POP :B$=B$(Z):RETURN
1820 IF L>LLEN(I) THEN RETURN
1825 A$=BL$:L=LEN(B$):A$(LLEN(I)-L)=B$:B$=A$:L=LEN(B$):RETURN
1880 TOT=B+A:RETURN
1881 TOT=B-A:RETURN
1882 TOT=B*A:RETURN
1883 TOT=B/A:RETURN
1890 B$=STR$(INT(B*DC)):L=LEN(B$):IF VAL(B$)=0 THEN B$=ZERO$(1,DEC+1):L=DEC+1
1892 IF L<DEC+1 THEN A$=ZERO$:A$(2)=B$:B$=A$:L=L+1:GOTO 1892
1895 POSITION 10,I+2:? B$(1,L-DEC);:IF DEC THEN ? ".";B$(L-DEC+1);
1897 IF L>LLEN(I) THEN ? "*"
1900 POSITION 10,I+2:INPUT #5,B$:IF LEN(B$)<LLEN(I) THEN B$(LEN(B$)+1)=BL$
1910 RECORD$(ST(I),ED(I))=B$(1,LLEN(I)):NEXT I:RETURN
2099 REM CREATE FILE
2100 TMP=FLD:FLD=0:GOSUB 80:FLD=TMP:FNO=0:? CL$:IF  NOT FLD THEN 2115
2102 FOR X=1 TO FLD:POSITION 1,X+2:? X:POSITION 5,X+2:B$=FIELD$(X*8-7,X*8)
2103 GOSUB 1800
2104 ? B$:POSITION 16,X+2:? LLEN(X)-DEC(X)-(DEC(X)>0)
2105 POSITION 27,X+2:C=TYPE(X):IF  NOT C THEN ? "C":GOTO 2109
2106 IF C=1 THEN ? "N":GOTO 2109
2107 IF C=2 THEN ? "F":GOTO 2109
2108 ? "S"
2109 POSITION 37,X+2:IF C=1 OR C=2 THEN ? DEC(X)
2110 NEXT X
2115 MODE=1:GOSUB SEC:? "NO..TITLE...LENGTH..TYPE(C/N/F/S)..DEC"
2120 GOSUB TOP:? "Enter blank title to end"
2130 POSITION 1,FNO+3:? FNO+1;:POSITION 5,FNO+3:ILEN=8:GOSUB INP:IF LEN(B$)=1 THEN B$(2)=" "
2135 GOSUB TOP:IF B$(1,2)="  " THEN 2170
2140 POSITION 16,FNO+3:ILEN=2:GOSUB INP:POSITION 27,FNO+3:ILEN=1:GOSUB INP
2150 IF B$(1,1)<>"C" AND B$(1,1)<>"S" THEN POSITION 37,FNO+3:GOSUB INP
2160 FNO=FNO+1:IF FNO<20 THEN 2120
2170 GOSUB SEC:? FNO;" FIELDS CREATED"
2180 GOSUB OK:IF K=78 THEN GOSUB TOP:? "CORRECT AND RE-ENTER":GOSUB DELAY:FNO=0:GOTO 2115
2190 RLEN=1:FOR X=1 TO FNO:POKE OFFSET+X*2+2,44:POSITION 5,X+2:INPUT #5,B$:A$=B$(1,8):FOR D=8 TO 1 STEP -1
2195 IF A$(D,D)=" " THEN NEXT D
2197 POP :A$=A$(1,D):FIELD$(X*8-7)=BL$:FIELD$(X*8-7+(8-LEN(A$)))=A$:FIELD$(LEN(FIELD$)+1)=BL$
2200 V=0:TRAP 2210:A=VAL(B$(12,13)):A$=B$(23,23):IF A$="F" OR A$="N" THEN TRAP 2290:V=VAL(B$(33,33)):A=A+V+1
2203 IF A>25 THEN GOSUB BEEP:GOSUB TOP:? "FIELD LENGTH NO MORE THAN 25 TOTAL":GOSUB DELAY:FNO=X-1:GOTO 2115
2205 ST(X)=RLEN:LLEN(X)=A:RLEN=RLEN+A:ED(X)=RLEN-1:DEC(X)=V:TRAP 40000:GOTO 2220
2210 GOSUB BEEP:GOSUB SEC:? "ERROR IN LENGTH OF FIELD..RE-ENTER";:FNO=X-1:MODE=1:GOSUB DELAY:GOTO 2115
2220 T=(B$(23,23)="C")+2*(B$(23,23)="N")+3*(B$(23,23)="F")+4*(B$(23,23)="S"):IF T THEN 2240
2230 GOSUB BEEP:GOSUB SEC:? "UNABLE TO INTERPRET TYPE..RE-ENTER";:GOSUB DELAY:FNO=X-1:GOTO 2115
2240 T=T-1:TYPE(X)=T:IF T=1 THEN 2350
2245 IF T<>2 THEN 2300
2247 POKE OFFSET+X*2+2,88
2250 POSITION 27,X+2:? CHR$(198):GOSUB TOP:? "ENTER FUNCTION FOR FIELD # ";X:GOSUB SEC:? "FUNCTION:>";
2260 MODE=1:ILEN=20:GOSUB INP:GOSUB OK:IF K=78 THEN 2250
2265 FUN$(X*20-19)=B$:FUN$(LEN(FUN$)+1)=BL$:GOTO 2350
2290 GOSUB BEEP:GOSUB SEC:? "ERROR IN DECIMAL..RE-ENTER":GOSUB DELAY:FNO=X-1:GOTO 2115
2300 IF T<>3 THEN 2350
2310 POSITION 27,X+2:? CHR$(211):GOSUB TOP:? "ENTER STATEMENT FOR FIELD # ";X
2320 GOSUB SEC:? "STATEMENT>";:MODE=1:ILEN=20:GOSUB INP:GOSUB OK:IF K=78 THEN 2310
2330 FUN$(X*20-19)=B$:FUN$(LEN(FUN$)+1)=BL$
2350 POKE OFFSET+X*2+2,12:NEXT X:FLD=0:GOSUB 70:FLD=FNO:RECLEN=ED(FLD):? CL$:GOSUB TOP
2360 ? "NEW FILE CREATED":GOSUB 80:GOTO MENU
4000 REM
5000 DIM A$(40),B$(40),BL$(38),CL$(1),CUR$(2),LLEN(20),ST(20),ED(20),FILE$(15),FIELD$(200),MOV$(46),ZERO$(10)
5005 ZERO$="0000000000"
5010 BL$=" ":BL$(38)=BL$:BL$(2)=BL$:CL$="↰":CUR$="←→"
5015 DIM RECORD$(400),C$(20),TYPE(20),DEC(20),EOL$(1),FIND$(110),SORT$(142):EOL$=CHR$(155)
5020 DIM CIO$(7):CIO$="hhh*LVd":RESTORE 5020
5025 CLOSE #5:OPEN #5,13,0,"E:":POKE 752,1:?
5030 READ OFFSET,INP,OK,BEEP,MENU,TOP,SEC,DELAY:DATA 1700,100,200,250,5120,30,40,230
5035 FOR X=1 TO 45 STEP 2:POKE OFFSET+X,0:POKE OFFSET+X+1,12:NEXT X:POKE 512,114:POKE 513,6:POKE OFFSET,1
5040 FIND$(1,55)="hh┐Lh┐Khh┐Qh▔▶╱h▔◀╱h▔↰╱h▔|╱h┐Nh┐Mh┐Ph┐O-|╱▔z╱-↰╱▔♠╱nz╱P"
5042 FIND$(56,110)="┘n♠╱-▶╱M♠╱p┘♣▗◆-◀╱Mz╱0w ♥&Q1KQMP╱HJPvpg%K┴eO┐K%LeP┐L┴♣E"
5050 SORT$(1,70)="hh┐Lh┐Khh┐Oh▔↰╱h▔|╱h▔y╱h▔x╱h▔♠╱h▔z╱-|╱▔◀╱-↰╱▔▶╱%K┐M%L┐Nn◀╱P┘n▶╱%M┴mz╱┐"
5052 SORT$(71,142)="M%Nm♠╱┐N-▶╱My╱p┘0▝◆-◀╱Mx╱p▕♣u&O ♥1MQK0◣p▕♣FHJPrp@-◀╱▔|╱-▶╱▔↰╱%M┐K%N┐L┴♣)"
5060 MOV$="hh┐qh┐ph┐Uh┐Th┐oh┐n ♥1p┌TfTP▕fUfpP▕fqFnPjFo♣f◆"
5070 MEM=FRE(0)-800:DIM DAT$(100),FUN$(400),BUFFER$(MEM)
5075 LNG=1:ELEM=0:RESTORE 4051
5076 X=USR(ADR(MOV$),ADR("H◣H.$╱=$╱▔◣T▔┬Ph=$╱▔┴P▔└Ph-▝TIn0▕"├▂$╱h*h@"),1650,42)
5080 DL=PEEK(560)+256*PEEK(561)+5
5090 FOR X=1 TO 23:POKE DL+X,130:NEXT X:POKE 54286,192:POKE 710,8:POKE 709,0:POKE 712,8
5110 ? CL$:GOSUB TOP:? "TOPSHELF by LESTER BLOCK"
5120 TRAP 5130:POP :POP :POP :POP :POP :POP :POP :POP :POP :POP
5130 TRAP 40000:GOSUB SEC:? "VIEW:BROWSE:ADD:SAVE:LOAD:MORE:EXIT";
5150 MODE=0:GOSUB INP:C=(K=86)+2*(K=66)+3*(K=65)+4*(K=83)+5*(K=76)+6*(K=77)+7*(K=69):IF  NOT C THEN 5150
5170 ON C GOTO 300,750,400,500,800,5180,700
5180 GOSUB SEC:? "SORT:FIND:ERASE:DIRECORY:CREATE";:GOSUB INP
5190 C=(K=83)+2*(K=70)+3*(K=69)+4*(K=68)+5*(K=67):IF  NOT C THEN 5180
5200 ON C GOTO 1300,1400,560,1600,2100