games (ROLLOUT.BAS)

games by Robert "Rassilon" Patton, 76

Description

games by Robert "Rassilon" Patton, 76

From the Antic disk of January 1988 (Vol. 6 No. 9).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 3.9 KB

Dialect
Atari BASIC
Lines
78
Variables
T, T1, T2, N, D1, D2, NSUM, TROLLS, ROLL, AVG, GAME, MAX, YY, XX, DICE(, SUM, CARD, X, CARD(, MEAN, COL, STK, INC, WAIT, N(, DIE$, ZAP$, Y
BASIC listing (78 lines)
5 REM ROLLOUT
10 REM BY ROBERT PATTON
20 REM (c)1987, ANTIC PUBLISHING
30 GOSUB 600
40 GOSUB 120:POKE 77,0:T=0:T1=0:T2=0:N=0:D1=0:D2=0
50 IF NSUM=0 THEN GOSUB 590:TROLLS=TROLLS+ROLL:ROLL=0:AVG=TROLLS/GAME:GAME=GAME+1:NSUM=55
60 AVG=(INT(AVG*1000))/1000:IF GAME>MAX THEN GOSUB 750
70 GOTO 40
80 POSITION 10,11:POKE 82,10
90 FOR YY=1 TO 6:FOR XX=1 TO 6:? " ";DICE(XX,YY);" ";:NEXT XX:? :? :NEXT YY:POKE 82,0:SUM=0:CARD=0
100 FOR X=2 TO 12:POSITION 30,9+X:? CARD(X);" of ";X;"'s";:SUM=SUM+(X*CARD(X)):CARD=CARD+CARD(X):NEXT X
110 MEAN=SUM/CARD:MEAN=(INT(MEAN*100))/100:POSITION 30,9:? "Mean=";MEAN;:RETURN
120 GOSUB 280
130 POSITION COL,4:? "   ";:GOSUB 270:GOSUB 320:COL=3*(D1+D2):IF COL>30 THEN COL=30
140 STK=STICK(0):INC=0
150 IF STK=7 THEN INC=3
160 IF STK=11 THEN INC=-3
170 IF INC THEN POSITION COL,4:? "   ";:GOSUB 260:COL=COL+INC
180 IF COL<3 THEN COL=30
190 IF COL>31 THEN COL=3
200 POSITION COL,4:? "◢^◣";
210 IF (STK=15 AND STRIG(0)=0) THEN GOSUB 430
220 FOR WAIT=1 TO 10:NEXT WAIT
230 IF (D1+D2=0 OR NSUM=0) THEN 250
240 GOTO 140
250 RETURN
260 SOUND 0,28,10,2:FOR WAIT=1 TO 10:NEXT WAIT:SOUND 0,0,0,0:RETURN
270 POSITION 5,1:? "ROLL ";ROLL;"  GAME #";GAME;"  AVG=";AVG;"     ";:RETURN
280 POSITION 3,3:FOR X=1 TO 10
290 IF N(X,0)<>0 THEN ? " ";N(X,0);" ";
300 IF N(X,0)=0 THEN ? "   ";
310 NEXT X:? :? :RETURN
320 ROLL=ROLL+1:POSITION 5,1:? "ROLL ";ROLL;" ";
330 FOR X=0 TO 6
340 D1=INT(RND(0)*7):IF D1=0 THEN 340
350 D2=INT(RND(0)*7):IF D2=0 THEN 350
360 POSITION 14,6:? DIE$((D1-1)*27+1,(D1-1)*27+27)
370 POSITION 20,6:? DIE$((D2-1)*27+1,(D2-1)*27+27)
380 NEXT X
390 CARD(D1+D2)=CARD(D1+D2)+1
400 DICE(D1,D2)=DICE(D1,D2)+1
410 GOSUB 80
420 RETURN
430 POSITION COL,4:? "   ";
440 FOR X=1 TO 10
450 IF N(X,1)=COL THEN T=N(X,0)
460 NEXT X
470 T2=T
480 IF N=0 THEN T1=T
490 N=N+T:IF N>D1+D2 THEN N=0:RETURN
500 IF N=0 THEN POP :GOTO 130
510 IF N=D1 THEN D1=0:POSITION 14,6:? ZAP$:GOSUB 580
520 IF N=D2 THEN D2=0:POSITION 20,6:? ZAP$:GOSUB 580
530 IF (N=D1+D2 AND D1+D2<>0) THEN 550
540 GOTO 560
550 POSITION 14,6:? ZAP$:POSITION 20,6:? ZAP$:N=T1:GOSUB 580:N=T2:GOSUB 580:D1=0:D2=0
560 GOSUB 280
570 RETURN
580 N(N,0)=0:NSUM=0:SOUND 3,33,14,3:FOR X=1 TO 10:NSUM=NSUM+N(X,0):NEXT X:SOUND 3,0,0,0:N=0:RETURN
590 FOR X=1 TO 10:N(X,0)=X:N(X,1)=X*3:NEXT X:RETURN
600 DIM DIE$(162),ZAP$(27),N(10,1),DICE(6,6),CARD(12)
610 GRAPHICS 0:POKE 752,1:POKE 82,0:POKE 710,98:POKE 712,98:POKE 709,106
620 FOR X=0 TO 12:CARD(X)=0:NEXT X:FOR X=0 TO 6:FOR Y=0 TO 6:DICE(X,Y)=0:NEXT Y:NEXT X:GAME=1:NSUM=55
630 DIE$(1,27)="▕   ▎↓←←←←←▕ ◆ ▎↓←←←←←▕   ▎"
640 DIE$(28,54)="▕◆  ▎↓←←←←←▕   ▎↓←←←←←▕  ◆▎"
650 DIE$(55,81)="▕◆  ▎↓←←←←←▕ ◆ ▎↓←←←←←▕  ◆▎"
660 DIE$(82,108)="▕◆ ◆▎↓←←←←←▕   ▎↓←←←←←▕◆ ◆▎"
670 DIE$(109,135)="▕◆ ◆▎↓←←←←←▕ ◆ ▎↓←←←←←▕◆ ◆▎"
680 DIE$(136,162)="▕◆ ◆▎↓←←←←←▕◆ ◆▎↓←←←←←▕◆ ◆▎"
690 ZAP$="     ↓←←←←←     ↓←←←←←     "
700 POSITION 0,7:? "RASSILON'S":? :? " ROLLOUT":POSITION 9,10:? "┌──────────────────┐"
710 POSITION 9,22:? "└──────────────────┘→↓DIE 1";
720 FOR X=11 TO 21:POSITION 9,X:? "|";:POSITION 28,X:? "|";:NEXT X
730 FOR X=1 TO 6:POSITION 7,9+(X*2):? X;:POSITION 8+(X*3),23:? X;:NEXT X
740 POSITION 0,16:? "DIE 2";:POSITION 29,7:? " Dice Sums";:GOSUB 590
750 GOSUB 270:POSITION 3,3:? "  How many games do we play    ←←←←";:INPUT MAX:GAME=1:IF MAX=0 THEN END
760 IF MAX>10 THEN MAX=10
770 RETURN