Biorhythms At Your Keyboard (BIO.BAS)
Biorhythms At Your Keyboard by Tom Bohmbach, 90
Description
Biorhythms At Your Keyboard by Tom Bohmbach, 90
From the Antic disk of January 1988 (Vol. 6 No. 9).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 10.9 KB
- Dialect
- Atari BASIC
- Lines
- 244
- Variables
BRKK,K,MON(,P(,E(,I(,YN$,NA$,MO$,F$,NA1$,NA2$,A$,TR,MO,DA,YR,ER,EMO,EYR,XX,YY,MO1,DAY1,MO2,DAY2,DAYS,PHY,EM,ITL,A,ADJ,H,B,X,AD,Y,PADJ,EADJ,IADJ,D,M1,D1,Y1,M2,D2,Y2,P,E,I
BASIC listing (244 lines)
1 REM BIORHYTHMS AT YOUR KEYBOARD
2 REM BY TOM BOHMBACH
3 REM (c) 1987, ANTIC PUBLISHING
9 OPEN #1,4,0,"K:":BRKK=PEEK(53279)<>5
10 GRAPHICS 2:POKE 710,0:POSITION 5,1:? #6;"BIORHYTHMS":POSITION 9,2:? #6;"AT"
11 POSITION 8,3:? #6;"YOUR":POSITION 6,4:? #6;"KEYBOARD":GOSUB 1075
15 POSITION 9,7:? #6;"by":POSITION 4,8:? #6;"tom bohmbach"
30 POKE 752,1:? :? " (Press any key to begin)":GET #1,K
100 DIM MON(12),P(62),E(62),I(62)
110 DIM YN$(1),NA$(10),MO$(10),F$(100),NA1$(10),NA2$(10),A$(5)
120 MON(1)=31:MON(3)=31:MON(4)=30:MON(5)=31:MON(6)=30:MON(7)=31:MON(8)=31:MON(9)=30:MON(10)=31
130 MON(11)=30:MON(12)=31
198 REM CHOOSE BIORHYTHMS OR COMPATIBILITY PROFILE
199 GRAPHICS 0:POKE 710,0
1020 ? "↰":POKE 752,1:POSITION 14,6:? "Do you want:":POSITION 14,7:? "▔▔▔▔▔▔▔▔▔▔▔▔"
1030 POSITION 15,8:? "Biorhythms":POSITION 19,10:? "or":POSITION 10,12:? "Compatibility Profile"
1040 GOSUB 1075:POKE 702,64:POKE 694,0:GET #1,K:IF K=66 THEN 2000:REM GOTO BIORHYTHMS
1050 IF K<>67 THEN 1020
1060 GOTO 6000:REM GOTO COMPAT.
1075 POKE 77,0:IF BRKK THEN POKE 16,112:POKE 53774,112
1076 RETURN
2000 ? "↰":? " Please enter your name"
2010 GOSUB 8000
2130 ? "↰":POSITION 2,8:TR=2130:TRAP 5000
2131 ? "Please enter your birthdate":? :? "(M,D,Y i.e. 1,31,1987)";:INPUT MO,DA,YR
2140 TR=0:GOSUB 9000
2150 IF ER=1 THEN 2130
2160 ? "↰":POSITION 2,6:? "Is this your correct birthday (Y/N)?":EMO=MO:GOSUB 4000
2170 POSITION 12,9:? MO$;" ";DA;", ";YR
2180 POSITION 38,6:GOSUB 7000
2190 IF YN$="N" THEN 2130
2200 ? "↰":POSITION 2,9:? "Please enter the month and year you would like to examine"
2205 ? :? "(M,Y i.e. 1,1987)";
2210 TR=2200:TRAP 5000:INPUT EMO,EYR
2215 TR=0
2220 ER=0:IF EMO<1 OR EMO>12 OR EMO<>INT(EMO) OR EYR<1900 OR EYR>2100 OR EYR<>INT(EYR) THEN ER=1
2230 IF ER=0 THEN 2232
2231 ? :? " BAD DATE":FOR XX=1 TO 100:NEXT XX:GOTO 2200
2232 IF EMO=2 AND EYR/4=INT(EYR/4) AND EYR/400<>INT(EYR/400) THEN MON(2)=29:GOTO 2240
2233 MON(2)=28
2234 GOSUB 4000
2239 REM COMPUTE THE # OF DAYS BETWEEN BIRTHDAY AND THE 1st OF EXAMINATION MONTH
2240 IF MO=1 OR MO=2 THEN YY=YR-1:MO1=MO+13:GOTO 2260
2250 MO1=MO+1:YY=YR
2260 DAY1=INT(365.25*YY)+INT(30.6001*MO1)+DA
2270 IF EMO=1 OR EMO=2 THEN YY=EYR-1:MO2=EMO+13:GOTO 2290
2280 MO2=EMO+1:YY=EYR
2290 DAY2=INT(365.25*YY)+INT(30.6001*MO2)
2300 DAYS=(DAY2-DAY1)+1
2400 REM COMPUTE THE # OF DAYS INTO EACH CYCLE
2500 PHY=INT(DAYS/23):EM=INT(DAYS/28):ITL=INT(DAYS/33)
2510 PHY=PHY*23:EM=EM*28:ITL=ITL*33
2520 PHY=DAYS-PHY:EM=DAYS-EM:ITL=DAYS-ITL
2521 IF PHY=23 THEN PHY=0
2522 IF EM=28 THEN EM=0
2523 IF ITL=33 THEN ITL=0
2559 REM INIT. SCREEN
2560 GRAPHICS 7:COLOR 2:POKE 708,106:GOSUB 1075
2570 PLOT 7,39:DRAWTO 159,39:PLOT 0,0:DRAWTO 159,0:DRAWTO 159,79:DRAWTO 0,79:DRAWTO 0,0
2580 FOR A=7 TO 159 STEP 4
2590 PLOT A,0:DRAWTO A,79
2600 NEXT A
2610 PLOT 2,8:DRAWTO 2,11:PLOT 5,8:DRAWTO 5,11:PLOT 2,9:DRAWTO 5,9
2620 PLOT 2,68:DRAWTO 2,71:PLOT 2,71:DRAWTO 4,71
2625 PLOT 2,38:DRAWTO 2,39:PLOT 3,37:DRAWTO 4,37:PLOT 3,40:DRAWTO 4,40
2630 POKE 752,1:? "1234567891111111111222222222233":? " DAYS 0123456789012345678901"
2640 ? " PRESS ANY KEY TO CONTINUE"
2650 ? "NAME:";NA$;" ";MO$;"/";EYR;
2659 REM COMPUTE AND GRAPH CYCLE FUNCTIONS - BLUE=PHYSICAL - RED=EMOTIONAL - GREEN=INTELLECTUAL
2660 DEG :COLOR 3:ADJ=360/96
2670 H=30:A=0:B=MON(EMO)*4:X=7:AD=PHY*4:GOSUB 2671:GOTO 2730
2671 Y=SIN(ADJ*AD)*H:Y=39-Y
2672 PLOT X,Y
2680 FOR X=A TO B
2690 Y=SIN(ADJ*(X+AD))*H:Y=39-Y
2700 DRAWTO X+7,Y
2710 NEXT X
2720 RETURN
2730 COLOR 1:ADJ=360/116
2740 X=7:AD=EM*4:GOSUB 2671
2750 COLOR 2:ADJ=360/136
2760 X=7:AD=ITL*4:GOSUB 2671
2770 GET #1,K:GRAPHICS 0:POKE 710,0
2999 REM MENU
3000 ? "↰":? " MENU ":? :? " Go ahead one month":? :? " Print this month":?
3005 ? " See another month":? :? " Enter another birthday"
3006 ? :? " Use Compatibility Profile"
3010 ? :? " Quit":? :? :POKE 752,1:? " Please Choose One":GOSUB 1075
3020 POKE 702,64:POKE 694,0:GET #1,K
3030 IF K=71 THEN 11000
3040 IF K=83 THEN 2200
3050 IF K=69 THEN 2000
3055 IF K=85 THEN 6000
3060 IF K=81 THEN GRAPHICS 0:END
3070 IF K<>80 THEN 3020
3079 REM PRINTER OPTION
3080 ? "↰":POSITION 2,10:? " PLEASE MAKE SURE PRINTER IS READY":? " THEN PRESS A KEY":GET #1,K
3090 TR=3080:TRAP 5100:OPEN #2,8,0,"P:"
3095 TR=0
3099 REM SET UP PRINTER
3100 ? #2:? #2:? #2;"NAME:";NA$;" ";MO$;"/";EYR
3101 ? #2:? #2:? #2:? #2;" DAYS"
3102 ? #2;" 1 2 3 4 5 6 7 8 9 1 1 1 1 1 1 1 1 1 1 2 2 2 2 2 2 2 2 2 2 3 3"
3103 ? #2;" 0 1 2 3 4 5 6 7 8 9 0 1 2 3 4 5 6 7 8 9 0 1"
3110 ? #2;"---------------------------------------------------------------"
3119 REM COMPUTE VALUES
3120 PADJ=360/48:EADJ=360/58:IADJ=360/68:GRAPHICS 4:POKE 710,0:POKE 752,1:? ," Thinking"
3125 COLOR 1:PLOT 10,20:DRAWTO MON(EMO)*2+10,20:GOSUB 1075
3130 COLOR 0:PLOT 10,20:FOR A=1 TO MON(EMO)*2
3131 DRAWTO A+10,20
3140 P(A)=INT(SIN(PADJ*(A+(PHY*2)))*20)
3150 E(A)=INT(SIN(EADJ*(A+(EM*2)))*20)
3160 I(A)=INT(SIN(IADJ*(A+(ITL*2)))*20)
3170 NEXT A:? "↰":? ," Printing"
3179 REM PRINT IT
3180 FOR H=19 TO -20 STEP -1
3190 FOR D=1 TO MON(EMO)*2
3200 IF P(D)=H THEN F$(D,D)="*":NEXT D:GOTO 3241
3210 IF E(D)=H THEN F$(D,D)="+":NEXT D:GOTO 3241
3220 IF I(D)=H THEN F$(D,D)="#":NEXT D:GOTO 3241
3230 F$(D,D)=" "
3240 NEXT D
3241 IF H=19 THEN ? #2;"H";:? #2;F$:NEXT H
3242 IF H=0 THEN ? #2;"C---------------------------------------------------------------":NEXT H
3243 IF H=-20 THEN ? #2;"L";:? #2;F$:GOTO 3245
3244 ? #2;"|";F$:NEXT H
3245 ? #2;"---------------------------------------------------------------"
3290 ? #2;" 1 2 3 4 5 6 7 8 9 1 1 1 1 1 1 1 1 1 1 2 2 2 2 2 2 2 2 2 2 3 3"
3300 ? #2;" 0 1 2 3 4 5 6 7 8 9 0 1 2 3 4 5 6 7 8 9 0 1"
3310 ? #2;" DAYS"
3320 ? #2:? #2:? #2;" *=PHYSICAL +=EMOTIONAL #=INTELLECTUAL"
3330 CLOSE #2
3340 GRAPHICS 0:POKE 752,1:POKE 710,0:GOTO 3000
3999 REM MONTH NAME
4000 ON EMO GOTO 4010,4020,4030,4040,4050,4060,4070,4080,4090,4100,4110,4120
4010 MO$="JANUARY":RETURN
4020 MO$="FEBUARY":RETURN
4030 MO$="MARCH":RETURN
4040 MO$="APRIL":RETURN
4050 MO$="MAY":RETURN
4060 MO$="JUNE":RETURN
4070 MO$="JULY":RETURN
4080 MO$="AUGUST":RETURN
4090 MO$="SEPTEMBER":RETURN
4100 MO$="OCTOBER":RETURN
4110 MO$="NOVEMBER":RETURN
4120 MO$="DECEMBER":RETURN
4999 REM ERRORS ROUTINES
5000 TRAP 40000:? :? " ERROR↰":FOR XX=1 TO 500:NEXT XX:GOTO TR
5100 CLOSE #2:GOTO 5000
5998 REM COMPATIBILITY PROFILE
5999 REM 1ST NAME
6000 ? "↰":POKE 752,1:? " Please enter 1st person's name"
6010 GOSUB 8000:NA1$=NA$
6019 REM 1ST BIRTHDAY
6020 ? "↰":POSITION 2,9
6021 TR=6020:TRAP 5000:? "Please enter 1st person's birthdate (M,D,Y i.e. 1,31,1987)";:INPUT MO,DA,YR
6030 GOSUB 9000:TR=0
6040 IF ER=1 THEN GOTO 6020
6045 M1=MO:D1=DA:Y1=YR
6050 ? "↰":POSITION 2,6:? "Is this the correct birthday (Y/N)?":EMO=MO:GOSUB 4000
6060 POSITION 12,9:? MO$;" ";D1;", ";Y1
6070 POSITION 38,6:GOSUB 7000
6080 IF YN$="N" THEN 6020
6099 REM ENTER 2ND NAME
6100 ? "↰":POKE 752,1:? " Please enter 2nd person's name"
6110 GOSUB 8000:NA2$=NA$
6119 REM ENTER 2ND BIRTHDAY
6120 ? "↰":POSITION 2,9
6121 TR=6120:TRAP 5000:? "Please enter 2nd person's birthdate (M,D,Y i.e. 1,31,1987)";:INPUT MO,DA,YR
6130 GOSUB 9000:TR=0
6140 IF ER=1 THEN GOTO 6120
6145 M2=MO:D2=DA:Y2=YR
6150 ? "↰":POSITION 2,6:? "Is this the correct birthday (Y/N)?":EMO=MO:GOSUB 4000
6160 POSITION 12,9:? MO$;" ";D2;", ";Y2
6170 POSITION 38,6:GOSUB 7000
6180 IF YN$="N" THEN 6120
6199 REM FIND # OF DAYS BETWEEN BIRTHDAYS
6200 IF M1=1 OR M1=2 THEN Y1=Y1-1:M1=M1+13:GOTO 6220
6210 M1=M1+1
6220 DAY1=INT(365.25*Y1)+INT(30.6001*M1)+D1
6230 IF M2=1 OR M2=2 THEN Y2=Y2-1:M2=M2+13:GOTO 6250
6240 M2=M2+1
6250 DAY2=INT(365.25*Y2)+INT(30.6001*M2)+D2
6260 DAYS=ABS(DAY2-DAY1)
6269 REM COMPUTE CYCLE DIFFERENCES
6270 PHY=INT(DAYS/23):PHY=PHY*23:PHY=DAYS-PHY:P=PHY
6280 EM=INT(DAYS/28):EM=EM*28:EM=DAYS-EM:E=EM
6290 ITL=INT(DAYS/33):ITL=ITL*33:ITL=DAYS-ITL:I=ITL
6299 REM COMPUTE COMPATIBILITY %'S
6300 PHY=ABS(11.5-PHY):PHY=PHY/23*2:A$=STR$(PHY)
6320 GOSUB 10000:PHY=VAL(A$)
6370 EM=ABS(14-EM):EM=EM/28*2:A$=STR$(EM)
6400 GOSUB 10000:EM=VAL(A$)
6410 ITL=ABS(16.5-ITL):ITL=ITL/33*2:A$=STR$(ITL)
6440 GOSUB 10000:ITL=VAL(A$)
6445 PHY=PHY*100:EM=EM*100:ITL=ITL*100
6448 REM PRINT %'S
6449 GRAPHICS 2:? #6;" COMPATIBILITY":? #6;" PERCENTAGES":? #6;"--------------------"
6450 ? #6;" PHYSICAL=";PHY;"%":? #6:? #6;" emotional=";EM;"%":? #6
6460 ? #6;" intellectual=";ITL;"%":GOSUB 1075
6461 ? "↰ FOR":A=INT((39-(LEN(NA1$)+LEN(NA2$)+3))/2)
6462 FOR B=1 TO A:? " ";:NEXT B
6463 ? NA1$;" & ";NA2$
6470 POKE 752,1:? :? " PRESS ANY KEY TO CONTINUE";
6480 GET #1,K:GOTO 199
6999 REM (Y)ES OR (N)O
7000 POKE 702,64:POKE 694,0:GET #1,K:YN$=CHR$(K):IF YN$<>"Y" AND YN$<>"N" THEN 200
7010 RETURN
7999 REM ENTER NAMES
8000 ? :? " Use BACKSPACE to erase typos"
8010 ? :? " Press RETURN when finished":? :? :? " __________"
8030 POSITION 15,8
8040 NA$="":A=1
8050 POKE 702,64:POKE 694,0:GET #1,K:IF K=155 THEN 8120
8060 IF K=126 AND A>1 THEN ? CHR$(K);"_";CHR$(30);:A=A-1:NA$(A,A)=" ":GOTO 8050
8070 IF K<32 OR K>95 THEN 8050
8080 NA$(A,A)=CHR$(K):? CHR$(K);:A=A+1
8090 IF A<>11 THEN 8050
8100 GET #1,K:IF K<>126 AND K<>155 THEN 8100
8110 IF K=126 THEN 8060
8120 RETURN
8999 REM CHECK DATES
9000 ER=0:IF MO<1 OR MO>12 OR MO<>INT(MO) THEN ER=1
9005 IF MO=2 THEN MON(2)=29:GOTO 9010
9006 MON(2)=28
9010 IF DA<1 OR DA>MON(MO) OR DA<>INT(DA) THEN ER=1
9030 IF YR<1900 OR YR>2100 OR YR<>INT(YR) THEN ER=1
9040 IF ER=0 THEN 9060
9050 ? :? :? " BAD DATE↰":FOR XX=1 TO 500:NEXT XX
9060 RETURN
9999 REM ROUND OFF %'S
10000 IF LEN(A$)<5 THEN RETURN
10010 A=VAL(A$(5,5)):B=VAL(A$(4,4))
10020 IF A>4 THEN B=B+1
10030 A$(4,4)=STR$(B):A$(5,5)="0"
10040 RETURN
10999 REM COMPUTE NEXT MONTH CYCLES
11000 PHY=PHY+MON(EMO):EM=EM+MON(EMO):ITL=ITL+MON(EMO)
11010 IF PHY>23 THEN PHY=PHY-23:GOTO 11010
11020 IF EM>28 THEN EM=EM-28:GOTO 11020
11030 IF ITL>33 THEN ITL=ITL-33:GOTO 11030
11040 EMO=EMO+1:IF EMO=13 THEN EMO=1:EYR=EYR+1
11050 GOSUB 4000:GOTO 2560
