Science Helper, educational (SCIHELP.BAS)
Science Helper, educational by Robert Witzofsky, 98
Description
Science Helper, educational by Robert Witzofsky, 98
From the Antic disk of December 1987 (Vol. 6 No. 8).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 11.9 KB
- Dialect
- Atari BASIC
- Lines
- 332
- Variables
FATX,X,X1,X2,LINE$,NUMDIV,K,H,EST,I,FX0,FX1,FX2,DATPT,OPT,R(,N,Y,Y(,X(,SX,MX,MY,AX,AY,SY,A,B,R,TEMP,XMAX,XMIN,ADD,NUMX,YMIN,YMAX,NUMY,D,C,MLPRINT,PRINT$,TEMP$,A$,PRNT$,GRAF$,KLR$,LPR$,DUMP$,PRNTER,A1,B1,C1,START,J,DUMP,SLOC,N1,T,MENU
BASIC listing (332 lines)
1 REM SCIENCE HELPER
2 REM BY ROBERT WITZOFSKY
3 REM (c)1987, ANTIC PUBLISHING
10 GRAPHICS 0:GOTO 13000
20 REM RETURNS VALUE OF FATX FOR CURRENT VALUE OF X
30 FATX=X*SIN(X)
40 RETURN
100 REM SIMPSON FUNCTION CALCULATES VALUE OF INTEGRAL
110 IF X1=X2 OR LINE$="" THEN ? "↰":? "ERROR: Current inputs not valid":GOSUB 17000:RETURN
120 ? "↰":? :? "To evaluate the integral it must be"
130 ? "split into n divisions. This value"
140 ? "determines the accuracy of the"
150 ? "answer and the amount of time"
160 ? "needed to determine it"
170 ? :? "↑Value for n";:TRAP 400:INPUT NUMDIV:IF NUMDIV>5000 THEN NUMDIV=5000
180 NUMDIV=INT(NUMDIV/20)*20:IF NUMDIV<20 THEN NUMDIV=20
185 TRAP 500
190 ? "↰":? :? "┌t"
200 ? "| ";LINE$;" = ?"
210 ? "┘";X1:? :?
220 K=1
230 H=(X2-X1)/NUMDIV
240 X=X1
250 EST=0
260 FOR I=1 TO NUMDIV/2
270 GOSUB 30:FX0=FATX:X=X+H
280 GOSUB 30:FX1=FATX:X=X+H
290 GOSUB 30:FX2=FATX
300 EST=EST+FX0+4*FX1+FX2
310 IF I*2/NUMDIV=K/10 THEN ? "for t=";INT(X*10000)/10000;" ?=";H/3*EST:K=K+1
320 NEXT I
330 GOSUB 17000
340 RETURN
400 TRAP 400:GOTO 170
500 ? "↰ERROR: can't integrate current function":GOSUB 17000:RETURN
2000 REM ANALYZE DATA
2005 TRAP 2700
2010 ? "↰":IF NOT DATPT THEN OPT=1:GOTO 2100
2020 ? " TYPE OF ANALYSIS":?
2030 ? " 1. x vs y"
2040 ? " 2. ln x vs. y"
2050 ? " 3. x vs. ln y"
2060 ? " 4. ln x vs. ln y":? " "
2070 ? "Which type?";
2080 GET #2,OPT:OPT=OPT-48:IF OPT>4 OR OPT<1 THEN 2080
2090 ? "↰↓ STATISTICS":?
2100 FOR I=1 TO 5:R(I)=0:NEXT I
2200 FOR I=1 TO N:Y=Y(I):X=X(I)
2210 IF OPT=2 OR OPT=4 THEN X=LOG(X)
2220 IF OPT=3 OR OPT=4 THEN Y=LOG(Y)
2230 R(1)=X+R(1):R(2)=X*X+R(2)
2240 IF DATPT THEN R(3)=Y+R(3):R(4)=Y*Y+R(4):R(5)=Y*X+R(5)
2250 NEXT I
2300 SX=SQR((N*R(2)-R(1)*R(1))/(N*(N-1)))
2310 MX=R(1)/N:MY=R(3)/N
2320 AX=0:AY=0
2330 FOR I=1 TO N
2340 AX=ABS(MX-X(I))+AX:AY=ABS(MY-Y(I))+AY
2350 NEXT I
2360 AX=AX/N:AY=AY/N
2370 IF DATPT THEN 2400
2380 ? " _"
2381 ? " x = ";INT(MX*100000)/100000
2385 ? :? :? "Avg deviation:":? :? " of x ";INT(AX*10000)/10000;" Precision ";INT(AX/MX*10000)/100;"%"
2390 ? :? :? "Standard deviation:":? :? " of x ";INT(SX*10000)/10000;" error ";INT(SX/SQR(N)*1000)/1000
2395 GOSUB 17000:RETURN
2400 SY=SQR((N*R(4)-R(3)*R(3))/(N*(N-1)))
2410 ? " _ _"
2420 ? " x=";INT(100000*MX)/100000:POSITION 19,4:? "y=";INT(100000*MY)/100000
2430 POKE 82,2:? :? "Avg deviation:"
2440 ? " of x ";INT(AX*10000)/10000;" precision ";INT(AX/MX*10000)/100;"%"
2450 ? " of y ";INT(AY*10000)/10000;" precision ";INT(AY/MY*10000)/100;"%"
2460 ? :? "Standard deviation:"
2470 ? " of x ";INT(SX*10000)/10000;" error ";INT(SX/SQR(N)*1000)/1000
2480 ? " of y ";INT(SY*10000)/10000;" error ";INT(SY/SQR(N)*1000)/1000
2490 ? :? "y as a function of x":?
2495 TRAP 2610
2496 A=(N*R(5)-R(1)*R(3))/(N*R(2)-R(1)*R(1))
2497 B=(R(3)*R(2)-R(1)*R(5))/(N*R(2)-R(1)*R(1))
2500 R=0:FOR I=1 TO N
2510 IF OPT=1 THEN TEMP=ABS((A*X(I)+B)/Y(I))
2520 IF OPT=3 THEN TEMP=ABS((EXP(B)*EXP(A*X(I)))/Y(I))
2530 IF OPT=2 THEN TEMP=ABS((B+A*LOG(X(I)))/Y(I))
2540 IF OPT=4 THEN TEMP=ABS((EXP(B)*X(I)^A)/Y(I))
2545 IF TEMP>1 THEN TEMP=1/TEMP
2550 R=R+TEMP:NEXT I:R=R/N
2555 A=INT(A*100000)/100000:IF OPT=3 OR OPT=4 THEN B=EXP(B)
2556 B=INT(B*100000)/100000
2560 IF OPT=1 THEN ? " y= ";A;"*x + ";B
2570 IF OPT=3 THEN ? " y= ";B;"*exp(";A;"*x)"
2580 IF OPT=2 THEN ? " y= ";B;" + ";A;"*ln(x)"
2590 IF OPT=4 THEN ? " y= ";B;"*x↑";A:?
2600 ? :? " corr. co-ef. R: ";INT(R*100000)/100000
2610 GOSUB 17000
2620 RETURN
2700 ? "↰":? "ERROR: Can't evaluate the given data"
2710 ? " MATH ERROR!"
2720 GOSUB 17000:RETURN
3000 REM PLOT FUNCTION 'F' OVER INTERVAL X1 -> X2
3003 TRAP 3300
3005 ? "↰":POSITION 2,10:? "Thinking..."
3010 XMAX=X2
3020 XMIN=X1
3030 ADD=(XMAX-XMIN)/(NUMX)
3040 X=XMIN:GOSUB 30:YMIN=FATX
3050 YMAX=YMIN
3060 FOR I=0 TO NUMX
3080 GOSUB 30:Y=FATX
3085 X(I)=X:Y(I)=Y
3090 IF Y>YMAX THEN YMAX=Y
3100 IF Y<YMIN THEN YMIN=Y
3101 X=X+ADD
3103 NEXT I
3105 GRAPHICS 8+16
3106 POKE 710,0:POKE 709,14:COLOR 1
3110 GOSUB 5000
3115 PLOT INT((X(0)-B)/A-0.5),INT(NUMY-(Y(0)-D)/C+1.5)
3120 FOR I=1 TO NUMX
3140 DRAWTO INT((X(I)-B)/A-0.5),INT(NUMY-(Y(I)-D)/C+1.5)
3160 NEXT I
3165 GOSUB 3500:REM PAXIS
3167 GOSUB 17000
3170 RETURN
3300 GRAPHICS 0:? "ERROR: can't graph this function":? :GOSUB 17000
3310 RETURN
3500 REM DRAW RELATIVE POSITION OF X & Y AXIS
3501 REM (USE WORLD CONVERSION FACTORS)
3510 IF XMAX>0 AND XMIN<0 THEN X=INT(-0.5-B/A)
3520 IF YMAX>0 AND YMIN<0 THEN Y=INT(NUMY+1.5+D/C)
3530 IF YMAX<0 THEN Y=0
3540 IF YMIN>0 THEN Y=NUMY
3550 IF XMAX<0 THEN X=NUMX
3560 IF XMIN>0 THEN X=0
3570 REM DRAW LINES
3580 PLOT 0,Y:DRAWTO NUMX,Y
3590 PLOT X,0:DRAWTO X,NUMY
3600 REM DISPLAY RANGE
3610 X=INT(X/8):IF X>=35 THEN X=35
3620 Y=INT(Y/8)
3630 MLPRINT=ADR(PRINT$)
3640 TEMP$=" ":TEMP$=STR$(YMAX):A=USR(MLPRINT,X,0,ADR(TEMP$),4)
3650 TEMP$=" ":TEMP$=STR$(YMIN):A=USR(MLPRINT,X,23,ADR(TEMP$),4)
3660 TEMP$=" ":TEMP$=STR$(XMIN):A=USR(MLPRINT,0,Y,ADR(TEMP$),4)
3670 TEMP$=" ":TEMP$=STR$(XMAX):A=USR(MLPRINT,35,Y,ADR(TEMP$),4)
3700 RETURN
4000 REM GET A FUNCTION OF X
4005 CLOSE #3:OPEN #3,4,0,"E:"
4010 ? "↰":POSITION 2,5:? "Enter a function"
4015 ? " 'FATX = ' your function"
4020 TRAP 4100
4030 POSITION 2,10:? "30 FATX = ";
4040 INPUT #3;LINE$
4045 POSITION 2,14:? "CONT"
4050 POSITION 1,8:? " ";
4060 POKE 842,13:STOP
4070 POKE 842,12
4071 X=0:GOSUB 30
4075 ? "↰":POSITION 2,10:? "Function is:":? " F(x)=";LINE$
4080 RETURN
4100 ? "↰ERROR: Function is incorrect"
4110 TRAP 4100:GOTO 4020
4999 REM DETERMINE CONVERSION FACTORS FOR PLOT
5000 A=(XMAX-XMIN)/NUMX
5010 C=(YMAX-YMIN)/NUMY
5020 B=XMIN-A
5030 D=YMIN-C
5040 RETURN
6000 REM GET LIMITS OF INTERVAL
6010 ? "↰"
6020 POSITION 2,10:? "Enter limits of the interval:"
6030 TRAP 6100
6040 ? "x1 = ";:INPUT X1
6050 ? "x2 = ";:INPUT X2
6060 IF X1>X2 THEN TEMP=X1:X1=X2:X2=TEMP
6070 ? :? "x1 = ";X1;", x2 = ";X2
6080 GOSUB 17000
6090 RETURN
6100 TRAP 6100:? "↰ERROR: limits incorrect"
6110 GOTO 6020
7000 REM HELP
7010 ? "↰":? " HELP":?
7020 ? "F input a function: by entering a":? " function of x at the prompt FATX"
7025 ? " remember to enter it as you"
7030 ? " would a line in a basic program":? " (capitalize everything)"
7040 ? :? "L limits of the interval: enter":? " x1 and x2 the bounds for the ":? " integration and the graph"
7050 ? :? "I numerical integration of the":? " entered function using Simpson's":? " algorithm (you select n)"
7060 ? :? "G graph the entered function from":? " x1 to x2"
7070 GOSUB 17000
7080 ? "↰":? "D enter data: this data can be":? " either x or (x,y) and can then":? " be analyzed or plotted"
7090 ? :? "A analysis of entered data: data":? " pts. can be analyzed in several"
7095 ? " ways by taking the ln of the"
7100 ? " data and then fitting a curve to":? " the pts. Values of R close to 1"
7110 ? " indicate a good fit while values":? " near 0 indicate a poor one"
7120 ? " standard and average deviations":? " are also calculated as well as":? " errors based on them "
7130 ? :? "P plot the entered data points"
7140 ? :? "to print out a screen hit esc at":? " the continue prompt or at a":? " graphics screen "
7150 GOSUB 17000
7160 RETURN
8000 REM GET DATA POINTS
8010 ? "↰":? "Do you wish to enter:"
8020 ? " 1. data"
8030 ? " 2. data points (x,y)"
8040 GET #2,OPT:IF OPT<>49 AND OPT<>50 THEN 8040
8045 DATPT=0:IF OPT=50 THEN DATPT=1
8050 TRAP 8050:POSITION 2,6:? "↑Number of data points";:INPUT N
8060 ? :? "Enter data x or x,y at the prompt"
8070 ? "To make a correction: enter the ":? "remaining data then make the":? "correction at the end"
8080 ? :TRAP 8300:Y=0
8090 FOR I=1 TO N
8100 ? "Pt. #";I;" ";:IF DATPT THEN INPUT X,Y:GOTO 8120
8110 INPUT X
8120 X(I)=X:Y(I)=Y:NEXT I:? "↰":? "This is the entered data:"
8130 IF DATPT THEN 8150
8140 FOR I=1 TO N:? "#";I;" ";X(I):GOTO 8160
8150 FOR I=1 TO N:? "#";I;" (";X(I);", ";Y(I);")"
8160 NEXT I:? :? "Make corrections (Y/N)?";
8165 GET #2,OPT:IF OPT<>89 AND OPT<>121 THEN GOSUB 17000:RETURN
8170 TRAP 8170:? :? "Correct which data point";:INPUT I
8180 ? "New data";:IF DATPT THEN INPUT X,Y:X(I)=X:Y(I)=Y:GOTO 8200
8190 INPUT X:X(I)=X
8200 ? "More corrections (Y/N)?";:GOTO 8165
8300 ? "ERROR: input incorrect--try again":TRAP 8300:GOTO 8100
9000 REM PLOT
9005 TRAP 9200
9010 YMIN=Y(1):YMAX=Y(1)
9020 XMIN=X(1):XMAX=X(1)
9030 FOR I=1 TO N
9040 IF Y(I)<YMIN THEN YMIN=Y(I)
9050 IF Y(I)>YMAX THEN YMAX=Y(I)
9060 IF X(I)<XMIN THEN XMIN=X(I)
9070 IF X(I)>XMAX THEN XMAX=X(I)
9075 NEXT I
9080 K=(YMAX-YMIN)*0.05:YMAX=YMAX+K:YMIN=YMIN-K
9090 K=(XMAX-XMIN)*0.05:XMAX=XMAX+K:XMIN=XMIN-K
9100 GOSUB 5000
9110 GRAPHICS 8+16
9120 POKE 710,0:POKE 709,14:COLOR 1
9130 FOR I=1 TO N
9140 X=INT((X(I)-B)/A-0.5):Y=INT(NUMY-(Y(I)-D)/C+1.5)
9150 PLOT X,Y:PLOT X+1,Y:PLOT X+1,Y+1:PLOT X,Y+1
9160 NEXT I
9170 GOSUB 3500
9180 GOSUB 17000
9190 RETURN
9200 GRAPHICS 0:? "ERROR: data for plot not valid":? :GOSUB 17000
9210 RETURN
13000 REM INITIALIZE
13005 CLOSE #2:OPEN #2,4,0,"K:"
13050 DIM A$(81),PRNT$(192),GRAF$(6),KLR$(6),LPR$(10),DUMP$(40)
13055 DIM X(320),Y(320),LINE$(128),PRINT$(167),TEMP$(5),R(5)
13056 LINE$=""
13060 RAD :NUMX=319:NUMY=191:N=NUMX:X1=0:X2=1
13110 ? "↰":POSITION 2,6
13115 ? " SCIENCE HELPER"
13116 ? " by Robert Witzofsky":?
13120 ? "This program lets you evaluate"
13130 ? "math functions or data sets."
13150 ? :? "For Help, press H at the"
13160 ? "menu prompt "
13170 GOSUB 17000
13180 ? "↰"
14000 REM ML ROUTINE TO PUT TEXT ON A GR. 8 SCREEN
14002 LET PRINT$(1,56)="hI┤p▗*p┐hhJP♠◆h┐Wh┐Vhh(h┐Yh┐Xhhpl┐T┴%VeX┐V%YeW┐W┴p▖%Vi@┐"
14003 LET PRINT$(57,112)="V%Wi├┐W◢Pq┤] ♥┤\1X ♥*♣├◢┤U◣)◆P┤)@♣▂I P┤)♥♣╱I@P▕) ┐Z◣)→┐Z"
14004 LET PRINT$(113,167)="┐Z)♥"┘╱Z*JPzmt▕┐[$]1ZEU$\┌VH┤\DTP6┴%Vi(┐V♣▕fWf])◢E]P→◆O"
15000 REM INIT. PRINTER
15140 A$="hh┐Lh┐Kh┐Nh┐M ♥┤Ohh┐P ♥1KI♥P▕)└I▔P▕)▘$O┌MH┤O@@p %PI▕0▔8%Ki(┐K0VFL♣R┴%Ki(┐K♣IfL0E◆"
15150 A$(27,27)=CHR$(155):PRNT$="♥":PRNT$(192)=PRNT$:PRNT$(2)=PRNT$
15155 ? "↰":PRNTER=1
15160 POSITION 2,9:? "WHICH PRINTER?":? :? "1. Epson/Gemini":? "2. Nec 8023":? "3. Prowriter 8510"
15165 ? "4. No printer"
15170 GET #2,OPT:OPT=OPT-48:IF OPT>4 OR OPT<1 THEN ? "↰ERROR: input not 1 through 4":GOTO 15160
15180 ON OPT GOSUB 15601,15602,15603,15604
15190 GOTO 18000
15600 REM PRINTER CODES
15601 GRAF$="␛K@♥":LPR$="␛A◢":KLR$="␛@":A1=0:B1=39:C1=1:START=7640:RETURN
15602 GRAF$="␛S0192":LPR$="␛>␛T16␛N":KLR$="␛<␛A␛N":A1=39:B1=0:C1=-1:START=0:RETURN
15603 GRAF$="␛S0192":LPR$="␛[␛T16␛N":KLR$="␛]␛A␛N":A1=39:B1=0:C1=-1:START=0:RETURN
15604 PRNTER=0:RETURN
15900 REM EXIT
15910 ? "↰":POSITION 4,10:? "QUIT (Y/N)?";
15920 GET #2,OPT
15930 IF OPT=89 OR OPT=121 THEN ? "↰":END
15940 RETURN
16000 REM PRINT SCREEN
16005 TRAP 16200:CLOSE #1:OPEN #1,8,0,"P:"
16010 IF PEEK(87)=8 THEN 16100
16011 REM DUMP GR.0 SCREEN
16020 ? #1,KLR$
16030 FOR J=0 TO 23:FOR I=0 TO 39:LOCATE I,J,DUMP:DUMP$(I+1)=CHR$(DUMP):NEXT I
16040 ? #1;DUMP$:NEXT J
16050 RETURN
16100 REM DUMP GR.8 SCREEN
16110 SLOC=PEEK(88)+PEEK(89)*256+START
16120 ? #1,LPR$
16130 FOR N1=A1 TO B1 STEP C1:X=USR(ADR(A$),SLOC+N1,ADR(PRNT$),T):? #1;GRAF$;PRNT$:NEXT N1
16140 ? #1,KLR$:CLOSE #1:RETURN
16200 POP :GOTO 17000
16999 REM WAIT FOR KEYPRESS
17000 IF PEEK(87)=0 THEN ? :? "Press any key to continue":? :? " ( [ESC] to print the screen)";
17010 GET #2,OPT:IF OPT=27 AND PRNTER THEN GOSUB 16000
17020 RETURN
18000 REM GET MENU CHOICE
18010 GRAPHICS 0
18020 POSITION 13,5:? "OPTION MENU"
18030 POKE 82,8:?
18040 ? "H-elp"
18050 ? "F-unction to input"
18060 ? "L-imits of interval"
18070 ? "I-integrate the function"
18080 ? "G-raph the function"
18090 ? "D-ata points to input"
18100 ? "A-nalysis of data"
18110 ? "P-lot data points"
18120 ? "Q-uit"
18130 ? " "
18140 ? "Your choice?";
18150 GET #2,OPT:IF OPT>96 AND OPT<120 THEN OPT=OPT-32
18160 MENU=0
18170 IF OPT=72 THEN MENU=1
18180 IF OPT=70 THEN MENU=2
18190 IF OPT=76 THEN MENU=3
18200 IF OPT=73 THEN MENU=4
18210 IF OPT=71 THEN MENU=5
18220 IF OPT=68 THEN MENU=6
18230 IF OPT=65 THEN MENU=7
18240 IF OPT=80 THEN MENU=8
18250 IF OPT=81 THEN MENU=9
18260 IF MENU=0 THEN 18150
18270 POKE 82,2
18280 ON MENU GOSUB 7000,4000,6000,100,3000,8000,2000,9000,15900
18290 GOTO 18000
