Morse Master (MORSE8.BAS)
Morse Master by Patrick Bass, 16
Description
Morse Master by Patrick Bass, 16
From the Antic disk of December 1987 (Vol. 6 No. 8).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 1.8 KB
- Dialect
- Atari BASIC
- Lines
- 88
- Variables
TRUE,OFF,FALSE,EOF,KEYBOARD,DISK,READ,WRITE,BELL$,X$,FILENAME$,M$,Z$,LETTER,INDEX,LOOP,NOT,C,CHARACTER,KEYSTROKE,CH,P1,P2,X,DELAY,D
BASIC listing (88 lines)
100 REM
110 REM ATARI BASIC MORSE MASTER
120 REM (c) 1987 ANTIC PUBLISHING
130 REM Written by Patrick Bass
140 REM Version 090287
150 REM
152 REM - - - - - - - - - - - - - - -
160 LET TRUE=1:LET OFF=40000
170 LET FALSE= NOT TRUE
171 LET EOF=340
172 LET KEYBOARD=1:LET DISK=2
174 LET READ=4:LET WRITE=8
176 OPEN #KEYBOARD,READ,0,"K:"
180 DIM BELL$(1),X$(40),FILENAME$(40)
181 DIM M$(1000),Z$(100)
182 FOR LETTER=0 TO 26
183 READ X$
184 LET INDEX=(LETTER*5)
185 LET M$(INDEX+1)=X$
186 NEXT LETTER
187 REM
188 DATA 0122,1000,1010,1002,0222
189 DATA 0010,1102,0000,0022,0111
190 DATA 1012,0100,1122,1022,1112
191 DATA 0110,1101,0102,0002,1222
192 DATA 0012,0001,0112,1001,1011
193 DATA 1100,END
194 REM
199 LET BELL$=CHR$(253)
200 REM
210 FOR LOOP=FALSE TO TRUE STEP NOT
220 REM
222 PRINT "↰"
224 PRINT " MORSE MASTER!"
225 PRINT
226 TRAP EOF
230 PRINT " Filename: D1:←←←←";
250 INPUT FILENAME$
260 OPEN #DISK,READ,0,FILENAME$
270 REM
280 TRAP EOF
290 FOR C=FALSE TO TRUE STEP NOT
300 GET #DISK,CHARACTER
310 GOSUB 450
320 NEXT C
330 REM
340 CLOSE #DISK
350 REM
352 PRINT
360 PRINT "↓↓↓ Read another File? ";
370 GET #KEYBOARD,KEYSTROKE
380 LET X$=CHR$(KEYSTROKE)
390 IF X$="N" THEN LOOP=(TRUE+TRUE)
400 REM
410 NEXT LOOP
414 END
420 REM
430 REM ----------------------------
440 REM EMIT CHARACTER
450 LET CH=CHARACTER
452 IF CH>96 THEN CH=(CH-32)
454 LET CHARACTER=CH
460 LET X$=CHR$(CHARACTER)
470 LET P1=FALSE:LET P2=FALSE
480 IF X$>="A" THEN LET P1=TRUE
482 IF X$<="Z" THEN LET P2=TRUE
490 IF (P1 AND P2) THEN GOSUB 500
492 RETURN
494 REM
500 REM -----------------------------
510 LET INDEX=((CHARACTER-65)*5)
512 PRINT CHR$(CHARACTER);
520 LET X$=M$(INDEX+1,INDEX+5)
530 FOR X=1 TO 4
540 LET Z$=X$(X,X)
545 LET DELAY=0
550 IF Z$="0" THEN DELAY=10
560 IF Z$="1" THEN DELAY=25
565 IF DELAY THEN GOSUB 600
570 NEXT X
580 RETURN
590 REM
600 REM -----------------------------
610 SOUND 1,10,10,15
620 FOR D=0 TO DELAY:NEXT D
630 SOUND 1,0,0,0
640 FOR D=0 TO 15:NEXT D
690 RETURN
