Iconverter, graphics utility (ICONVERT.BAS)
Iconverter, graphics utility by Jim Johnson, 60
Description
Iconverter, graphics utility by Jim Johnson, 60
From the Antic disk of December 1987 (Vol. 6 No. 8).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 7.3 KB
- Dialect
- Atari BASIC
- Lines
- 173
- Variables
C0,C1,C2,C3,C4,C5,C8,GNAME$,X,SRADR,BADR,B$,SECTR,I,G$,MODE,FULLSCREEN,C6,L,SCRMEM,MOV,Y,NOCLEAR,KEY,CLEAR,CHAR,CELL$,CELL,DD$,CELL2$,SCREEN$,CHAR$,LINE,TOP,W,C9,OFF,FILENAME$,TEMP$,C7,C16,BL$,CC$,D$,MOV$,P$,PG$,PT$,SR$,T$,K
BASIC listing (173 lines)
10 REM ICONVERTER
20 REM BY JIM JOHNSON
30 REM (c)1987, ANTIC PUBLISHING
1000 GOSUB 1890:TRAP 1010
1010 GRAPHICS C0:POKE 710,C0:POKE 709,C0:POKE 752,C1
1020 POSITION C0,C0:? "▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂"
1030 POSITION C0,C1:? "▗▄▄▖ ▄▄ ▄▄ ▗▖▗▖▗▖▗▖▗▄▄▖▗▄▄ ▗▄▄▖▗▄▄▖▗▄▄ "
1040 POSITION C0,C2:? " ▌▌ ▌▌▝▘▌▌▌▌▌ ▘▌▌▌▌▌▌▝▖ ▌▌▌▌ ▌▌ ▌▝▄ ▌▌▌▌"
1050 POSITION C0,C3:? " ▌▌ ▌▌▗▖▌▌▌▌▌▗ ▌▝▝▘▘▌▌ ▌▗ ▌▌ ▌▌ ▌▗ "
1060 POSITION C0,C4:? "▝▄▄▘ ▄▄ ▄▄ ▝▘▝▘ ▝▘ ▝▄▄▘▝▘▝▘ ▝▘ ▝▄▄▘▝▘▝▘"
1070 POSITION C0,C5:? "▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔"
1080 POSITION C2,10
1090 ? " A utility to convert PrintShop"
1100 ? " icons to ATASCII format."
1110 POKE 703,C4
1120 ? "↰ Load which icon?"
1130 ? " ( RETURN for directory)"
1140 ? :POKE 709,C8:POKE 752,C0:INPUT GNAME$:POKE 709,C0
1150 IF GNAME$="" THEN GOSUB 2050:GOSUB 2130:GOTO 1110
1160 REM GET ICON
1170 X=USR(SRADR,BADR,361,C1,C3):IF B$(C1,15)<>"PRINT SHOP:CLK!" THEN GOSUB 2510:GOTO 1120
1180 FOR SECTR=362 TO 393:X=USR(SRADR,BADR,SECTR,C1,C3)
1190 FOR I=C0 TO 96 STEP 32:IF B$(I+C1,I+LEN(GNAME$))=GNAME$ THEN POP :POP :GOTO 1220
1200 NEXT I:NEXT SECTR:GOSUB 2540:GOTO 1120
1210 GOSUB 2200:GOTO 2300
1220 SECTR=ASC(B$(I+17,I+17))+256*ASC(B$(I+18,I+18))
1230 FOR I=C0 TO 378 STEP 126:X=USR(SRADR,BADR,SECTR,C1,C3)
1240 G$(I+C1,I+126)=B$(C1,126):SECTR=ASC(B$(127,127))+256*ASC(B$(128,128)):NEXT I
1250 X=USR(SRADR,BADR,SECTR,C1,C3):G$(505,572)=B$(C1,68)
1260 REM DISPLAY ICON
1270 GRAPHICS MODE+FULLSCREEN
1280 COLOR C1:PLOT 30,C6:DRAWTO 121,C6:DRAWTO 121,61:DRAWTO 30,61:DRAWTO 30,C6
1290 L=ADR(G$):SCRMEM=PEEK(88)+PEEK(89)*256:SCRMEM=SCRMEM+C8*20+C4
1300 FOR X=SCRMEM TO 1020+SCRMEM STEP 20:I=USR(MOV,L,X,11):L=L+11:NEXT X
1310 COLOR C0:PLOT 35,C8:DRAWTO 35,59:COLOR C1:PLOT 34,C6:DRAWTO 34,61
1320 COLOR C0:FOR Y=C6 TO 61:PLOT 30,Y:DRAWTO 33,Y:NEXT Y
1330 COLOR C0:PLOT 116,C8:DRAWTO 116,59:COLOR C1:PLOT 117,C6:DRAWTO 117,61
1340 COLOR C0:FOR Y=C6 TO 61:PLOT 118,Y:DRAWTO 121,Y:NEXT Y
1350 GRAPHICS MODE+NOCLEAR:POKE 710,C0:POKE 752,C1
1360 ? "↰ RETURN to convert ":? " ESC to load new icon "
1370 ? :POKE 709,202:POKE 752,C1
1380 GOSUB 2680:IF KEY=155 THEN 1410
1390 IF KEY=27 THEN 1110
1400 GOTO 1380
1410 REM CONVERT
1420 ? "↰ Converting to ATASCII.":? " Please wait...."
1430 TRAP CLEAR:CHAR=C1:COLOR C1
1440 FOR Y=C8 TO 58 STEP C2:PLOT 32,Y
1450 FOR X=36 TO 114 STEP C2
1460 CELL$="0000"
1470 LOCATE X+C0,Y+C0,CELL:IF CELL THEN CELL$(C1,C1)="1"
1480 LOCATE X+C1,Y+C0,CELL:IF CELL THEN CELL$(C2,C2)="1"
1490 LOCATE X+C0,Y+C1,CELL:IF CELL THEN CELL$(C3,C3)="1"
1500 LOCATE X+C1,Y+C1,CELL:IF CELL THEN CELL$(C4,C4)="1"
1510 I=USR(ADR(DD$),ADR(CELL$),ADR(CELL2$),LEN(CELL2$))
1520 SCREEN$(CHAR,CHAR)=CHAR$(I,I):CHAR=CHAR+C1
1530 NEXT X
1540 NEXT Y
1550 REM PRINT ATASCII SCREEN
1560 GRAPHICS C0:POKE 710,C0:POKE 752,C1:? "↰";
1570 FOR LINE=C0 TO 22:POSITION C0,LINE
1580 ? SCREEN$(C1+(LINE+C2*TOP)*40,40+(LINE+C2*TOP)*40);
1590 NEXT LINE
1600 POSITION C0,LINE:? SCREEN$(C1+(LINE+C2*TOP)*40,39+(LINE+C2*TOP)*40);:IF NOT W THEN 1650
1610 POSITION C8,20:? "┌─────────────────────┐";
1620 POSITION C8,21:? "|RETURN to save screen|";
1630 POSITION C8,22:? "| ESC to exit |";
1640 POSITION C8,23:? "└─────────────────────┘";
1650 GOSUB 2680:IF KEY=155 THEN 1760
1660 IF KEY=27 THEN RUN
1670 IF KEY=32 THEN 1710
1680 IF KEY=45 AND TOP=0 THEN TOP=1:GOTO 1570
1690 IF KEY=61 AND TOP=1 THEN TOP=0:GOTO 1570
1700 GOTO 1650
1710 W= NOT W:IF W THEN 1610
1720 FOR L=20 TO 23
1730 POSITION C8,L:? SCREEN$(C9+(L+C2*TOP)*40,31+(L+C2*TOP)*40);
1740 NEXT L:GOTO 1650
1750 POSITION C8,23:? SCREEN$(C9+23*40,31+23*40);:GOTO 1650
1760 REM SAVE ATASCII FILE
1770 POKE 703,C4:TRAP OFF:TRAP 2600
1780 ? "↰ Filename to save?"
1790 ? " ( RETURN for directory)"
1800 POKE 752,C0:INPUT FILENAME$
1810 IF FILENAME$="" THEN GOSUB 2320:GOTO 1760
1820 X=USR(SRADR,BADR,361,C1,C3):IF B$(C1,15)="PRINT SHOP:CLK!" THEN GOSUB 2570:GOTO 1780
1830 TEMP$="D1:":TEMP$(C4)=FILENAME$:FILENAME$=TEMP$
1840 CLOSE #C1:OPEN #C1,C8,C0,FILENAME$
1850 FOR LINE=C0 TO 25
1860 ? #C1;SCREEN$(C1+LINE*40,40+LINE*40)
1870 NEXT LINE:CLOSE #C1:TRAP OFF
1880 GOTO 1560
1890 REM INIT
1900 C0=0:C1=1:C2=2:C3=3:C4=4:C5=5:C6=6:C7=7:C8=8:C9=9:C16=16
1910 MODE=C6:FULLSCREEN=C16:NOCLEAR=C2*C16:W=C1:OFF=40000
1920 DIM CELL$(C4),CELL2$(C4*C16),SCREEN$(1040),CHAR$(C16),FILENAME$(20),TEMP$(20)
1930 DIM B$(128),BL$(40),CC$(140),D$(2048),G$(616),GNAME$(16),MOV$(46),P$(1456),PG$(616)
1940 DIM PT$(1456),SR$(55),T$(183),DD$(72)
1950 SR$(C1)="hh▔┐┘h▔┤┘h▔▝┘h▔◣┘hh▔├┘hh*)R▔▕┘ SdJ-┘┘I├p┤◆♥Pq)♥┐U-┘┘┐T◆"
1960 MOV$="hh┐qh┐ph┐Uh┐Th┐oh┐n ♥1p┌TfTP▕fUfpP▕fqFnPjFo♣f◆":MOV=ADR(MOV$)
1970 DD$="hh┐Lh┐Kh┐Nh┐Mhh┐O"♥▂▶╱╱Uh ♥1KQMP◢H@┤Pu╱T◆-▶╱┴i┤EOp♣▔▶╱%M┴i┤┐M♣YfN0U▔♥┐T◆"
1980 P$(C1)="♥":P$(1456)="♥":P$(C2)=P$:B$(C1,128)=P$(C1,128):G$(C1,616)=P$(C1,616):PG$(C1,616)=P$(C1,616)
1990 PT$(C1,1456)=P$(C1,1456):T$(C1)=" ":T$(182)=" ":T$(C2)=T$:BL$(C1,40)=T$(C1,40)
2000 GNAME$(C1,C16)=T$(C1,C16)
2010 SRADR=ADR(SR$):BADR=ADR(B$):MOV=ADR(MOV$)
2020 CELL2$="0000000100100011010001010110011110001001101010111100110111101111"
2030 CHAR$=" ▗▖▄▝▌▘▘▘▝▌▝▄▖▗ "
2040 RETURN
2050 REM PRINT SHOP DIRECTORY
2060 GRAPHICS C0:POKE 710,C0:POKE 709,C0:POKE 752,255
2070 POSITION C0,C0:? "▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂▂"
2080 POSITION C0,C1:? "▗▄▖ ▗▄▄▖▗▄▄ ▗▄▄▖ ▄▄ ▗▄▄▖ ▄▄ ▗▄▄ ▗▖▗▖ "
2090 POSITION C0,C2:? "▌▌▖▖ ▌▌ ▌▌▌▌▌▝▄ ▌▌▝▘ ▌▌ ▌▌▌▌▌▌▌▌▝▝▘▘ ▌▌ "
2100 POSITION C0,C3:? "▌▌▘▘ ▌▌ ▌▗ ▌▌ ▌▌▗▖ ▌▌ ▌▌▌▌▌▗ ▌▌ ▗▖ "
2110 POSITION C0,C4:? "▝▄▘ ▝▄▄▘▝▘▝▘▝▄▄▘ ▄▄ ▝▘ ▄▄ ▝▘▝▘ ▝▘ ▝▘ "
2120 POSITION C0,C5:? "▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔":POKE 709,C8:RETURN
2130 D$(C1)=" ":D$(2048)=" ":D$(C2)=D$:K=C0:L=C0:POKE 54286,64
2140 X=USR(SRADR,BADR,361,C1,C3):IF B$(C1,15)<>"PRINT SHOP:CLK!" THEN GOSUB 2510:RETURN
2150 POSITION C4,C7:? "Reading Directory...wait......";
2160 FOR SECTR=362 TO 393:X=USR(SRADR,BADR,SECTR,C1,C3)
2170 FOR X=C0 TO 96 STEP 32:IF B$(X+20,X+20)<>"X" AND B$(X+20,X+20)<>"x" THEN 2190
2180 D$(C16*K+C1,C16*K+C16)=B$(X+C1,X+C16):K=K+1
2190 NEXT X:NEXT SECTR:POSITION C0,C6:? BL$(C1,39)
2200 FOR I=C0 TO 11:POSITION C3,C7+I:? D$(C16*(L+I)+C1,C16*(L+I)+C16);" ";D$(C16*(L+I+12)+C1,C16*(L+I+12)+C16)
2210 NEXT I
2220 IF K<25 THEN RETURN
2230 POSITION C9,20:? "RETURN for more "
2240 POSITION C9,21:? " ESC to load icon"
2250 GOSUB 2680:IF KEY=155 THEN 2280
2260 IF KEY=27 THEN RETURN
2270 GOTO 2250
2280 IF L+25>K THEN L=C0:GOTO 2200
2290 L=L+24:GOTO 2200
2300 IF L-24<0 THEN L=K-24:GOTO 2200
2310 L=L-24:GOTO 2200
2320 REM DOS DIRECTORY
2330 GOSUB 2060
2340 D$(C1)=" ":D$(2048)=" ":D$(C2)=D$:K=C0:L=C0
2350 CLOSE #C1:OPEN #C1,C6,C0,"D1:*.*"
2360 INPUT #C1,FILENAME$
2370 IF FILENAME$(C4,11)="SHOP:CLK" THEN GOSUB 2570:RETURN
2380 IF FILENAME$(C5,C8)="FREE" THEN CLOSE #C1:GOTO 2410
2390 D$(17*K+C1,17*K+LEN(FILENAME$))=FILENAME$:K=K+C1
2400 GOTO 2360
2410 FOR I=C0 TO C8:POSITION C1,C7+I:? D$(17*(L+I)+C1,17*(L+I)+17);" ";D$(17*(L+I+C9)+C1,17*(L+I+C9)+17)
2420 NEXT I:? :? FILENAME$
2430 IF K<18 THEN RETURN
2440 POSITION C9,20:? "RETURN for more "
2450 POSITION C9,21:? " ESC to save file"
2460 GOSUB 2680:IF KEY=155 THEN 2490
2470 IF KEY=27 THEN RETURN
2480 GOTO 2460
2490 IF L+18>K THEN L=C0:GOTO 2410
2500 L=L+18:GOTO 2410
2510 GOSUB 2660
2520 ? "↰ Not a PrintShop data disk."
2530 GOSUB 2670:RETURN
2540 GOSUB 2660
2550 ? "↰ ";CHR$(34);GNAME$;CHR$(34);" not on this disk."
2560 GOSUB 2670:RETURN
2570 GOSUB 2660
2580 ? "↰ Not a DOS II format disk."
2590 GOSUB 2670:RETURN
2600 POKE 703,C4:POKE 709,C8:POKE 752,C1
2610 ? "↰ ┌─────────────────────────────┐"
2620 ? " | *** DISK ERROR *** Insert |"
2630 ? " |DOS II data disk-Press RETURN|"
2640 ? " └─────────────────────────────┘↰";
2650 GOSUB 2680:GOTO 1770
2660 POKE 703,C4:POKE 709,C8:POKE 752,C1:RETURN
2670 ? " Insert data disk-Press RETURN↰"
2680 CLOSE #C1:OPEN #C1,C4,C0,"K:":GET #C1,KEY:CLOSE #C1:RETURN
2690 GOSUB 2660
