The Envelope Maker (ENVELOPE.BAS)

The Envelope Maker by Todd R. Thedell, 55

Description

The Envelope Maker by Todd R. Thedell, 55

From the Antic disk of December 1987 (Vol. 6 No. 8).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 6.7 KB

Dialect
Atari BASIC
Lines
267
Variables
CS$, RETADR$, ADRS$, TEMP$, Q$, BL$, N$, LINE$, CUT$, DOT$, STAMP$, TOP$, DE, J, I, LR, LA, S, SP, F, START, W, FINSH, C1, C2, C3, L
BASIC listing (267 lines)
10 REM THE ENVELOPE MAKER
20 REM BY TODD R. THEDELL
30 REM (c)1987, ANTIC PUBLISHING
100 REM SETUP
110 DIM CS$(1),RETADR$(24*5),ADRS$(24*5),TEMP$(24*5),Q$(25),BL$(24*5),N$(25)
120 DIM LINE$(8),DOT$(1),STAMP$(8),TOP$(8)
130 CS$=CHR$(125):REM CLEAR SCREEN
140 BL$=" ":BL$(24*5)=BL$:BL$(2)=BL$
150 TEMP$=BL$
160 LINE$=" . . . ."
180 DOT$="."
190 TOP$=" ------ "
200 STAMP$="|      |"
210 DATA Antic Magazine
220 DATA 544 Second Street
230 DATA San Francisco, CA 94107
240 GOSUB 270:REM SETBG
250 GOTO 2700:REM MAIN PROGRAM
260 REM SETBG
270 SETCOLOR 2,(RND(0)*16),0:RETURN
280 REM CAPS
290 POKE 702,(PEEK(702)=0)*64:RETURN
300 REM CURSOR
310 POKE 752,(PEEK(752)=0)*1:RETURN
320 REM WELCOME
330 ? CS$
340 POSITION 7,2:POKE 82,7
350 GOSUB 310:REM ->CURSOR OFF
360 ? "            ."
370 ? "         .      ."
380 ? "     .              ."
390 ? " .                      ."
400 ? "┌────────────────────────┐"
410 ? "|                        |"
420 ? "|  ┌──────────────────┐  |"
430 ? "|  |                  |  |"
440 ? "|  |       THE        |  |"
445 ? "|  |   PRINT SHOP     |  |"
450 ? "|  |    ENVELOPE      |  |"
460 ? "|  |      MAKER       |  |"
470 ? "|  | by Todd Thedell  |  |"
480 ? "|  |                  |  |"
490 ? "|  └──────────────────┘  |"
500 ? "|                        |"
510 ? "└────────────────────────┘"
520 FOR DE=1 TO 100:NEXT DE
530 POKE 82,2
540 RETURN
550 REM CONVERT
560 FOR J=1 TO LEN(Q$)
570 Q$(J,J)=CHR$(ASC(Q$(J,J))+128)
580 NEXT J
590 RETURN
600 REM SENDER
610 FOR I=0 TO 2
620 READ Q$
630 GOSUB 560
640 RETADR$(I*24+1)=Q$
650 LR=LEN(RETADR$)
660 RETADR$(LR+1)=BL$
670 NEXT I
680 ? CS$:GOSUB 270:REM SETBG
690 LR=LEN(RETADR$)
700 FOR I=0 TO INT(LR/24)-1
710 POSITION 2,I+5
720 ? RETADR$(I*24+1,I*24+24)
730 NEXT I
740 GOSUB 310:REM ->CURSOR ON
750 POSITION 3,2:GOSUB 270:REM SETBG
760 ? "Do you want this return address? Y←";:INPUT #16;Q$
770 IF Q$="Y" OR Q$="y" THEN RETURN
780 ? CS$:GOSUB 270:REM SETBG
790 POSITION 3,2:? "ENTER RETURN ADDRESS"
800 I=0
810 GOSUB 290:REM LOWERCASE
820 POSITION 2,I+5:? I+1;"->";
830 INPUT #16;Q$
840 IF LEN(Q$)=0 THEN 910
850 RETADR$(I*24+1)=Q$
860 LR=LEN(RETADR$)
870 RETADR$(LR+1)=BL$
880 I=I+1
890 IF I>3 THEN 910
900 GOTO 820
910 GOSUB 310:REM CURSOR OFF
920 GOSUB 290:REM UPPERCASE
930 IF I=0 THEN RETADR$=BL$
940 GOTO 680
950 REM SENT2
960 ? CS$:POSITION 3,2
970 GOSUB 270:REM SETBG
980 ? "ENTER THE ADDRESS"
990 I=0
1000 GOSUB 290:REM LOWERCASE
1010 POSITION 14,13+I:? TEMP$(I*24+1,I*24+24)
1020 POSITION 11,13+I:? I+1;"->";
1030 INPUT #16;Q$
1040 IF LEN(Q$)=0 THEN 1110
1050 ADRS$(I*24+1)=Q$
1060 LA=LEN(ADRS$)
1070 ADRS$(LA+1)=BL$
1080 I=I+1
1090 IF I>3 THEN 1110
1100 GOTO 1010
1110 GOSUB 290:REM UPPERCASE
1120 IF I=0 THEN ADRS$=BL$
1130 ? CS$
1140 GOSUB 310:REM CURSOR OFF
1150 LA=LEN(ADRS$)
1160 FOR I=0 TO INT(LA/24)-1
1170 POSITION 16,13+I
1180 ? ADRS$(I*24+1,I*24+24)
1190 NEXT I
1200 POSITION 3,2
1210 GOSUB 310:REM CURSOR ON
1220 ? "Do you want this address? Y←";:INPUT #16;Q$
1230 IF Q$="N" OR Q$="n" THEN TEMP$=ADRS$:GOTO 960
1240 RETURN
1250 REM CHECK
1260 ? CS$
1270 GOSUB 270
1280 GOSUB 310
1290 POSITION 8,5:POKE 82,8:REM L. MARGIN
1300 ? "◢                      ◣"
1310 ? "  SET PAPER TO THE TOP  "
1320 ? "  LINE ON THE PRINTER   "
1330 ? "           &            "
1340 ? "     PRESS <RETURN>     "
1350 ? "◣                      ◢"
1360 TRAP 1600:REM ERROR CHECK
1370 POKE 82,2:REM L. MARGIN
1380 INPUT #16;Q$
1385 CLOSE #1:OPEN #1,8,0,"P:"
1390 ? CS$
1400 FOR I=0 TO INT(LR/24)-1
1410 POSITION 2,5+I
1420 ? RETADR$(I*24+1,I*24+24)
1430 NEXT I
1440 FOR I=0 TO INT(LA/24)-1
1450 POSITION 16,13+I
1460 ? ADRS$(I*24+1,I*24+24)
1470 NEXT I
1480 GOSUB 1550:REM POSTAGE
1490 POSITION 2,2
1500 ? "       PRINTING THIS ENVELOPE      "
1510 POSITION 2,20
1520 ? "   PRESS <BREAK> TO STOP PRINTING  "
1530 RETURN
1540 REM POSTAGE
1550 POSITION 30,5:? "┌───┐"
1560 POSITION 30,6:? "|   |"
1570 POSITION 30,7:? "|   |"
1580 POSITION 30,8:? "└───┘"
1590 RETURN
1600 ? CS$;" -> -> -> ->CHECK YOUR PRINTER!!!!"
1610 ? :? "        TURN ON YOUR PRINTER  ":GOTO 1290
1620 REM SPACES
1630 FOR S=1 TO SP
1640 ? #1;" ";
1650 NEXT S
1660 ? #1;DOT$;
1670 RETURN
1680 REM SIDES
1690 SP=8:GOSUB 1620:REM ->SPACES
1700 SP=64:GOSUB 1620:REM ->SPACES
1710 ? #1
1720 RETURN
1730 REM FOLD
1740 FOR F=1 TO 21
1750 ? #1;"  ";DOT$;
1760 NEXT F
1770 RETURN
1780 REM BEGIN
1790 START=W*24+1
1800 FINSH=W*24+24
1810 W=W+1
1820 RETURN
1830 REM BEGIN
1840 GOSUB 1790
1850 ? #1;BL$(1,34);ADRS$(START,FINSH)
1860 RETURN
1870 REM PRINT IT
1880 REM (BEGIN)
1890 REM SETBG
1900 GOSUB 270
1910 SP=39:GOSUB 1620:? #1
1920 REM
1930 C1=28:C2=5:C3=29
1940 FOR L=2 TO 14 STEP 3
1950 ? #1;"        ";
1960 SP=C1:GOSUB 1620
1970 SP=C2:GOSUB 1620
1980 REM SP=C3:GOSUB 1620
1990 ? #1:? #1
2000 C1=C1-7
2010 C2=C2+14
2020 C3=C3-7
2030 NEXT L
2040 REM
2050 GOSUB 1690
2060 ? #1
2070 REM
2080 ? #1;"  .  .";
2090 GOSUB 1740:? #1;" .  .  .  ."
2100 REM
2110 ? #1;BL$(1,64);TOP$
2120 ? #1;BL$(1,12);:W=0:GOSUB 1790:? #1;RETADR$(START,FINSH);:N$=RETADR$(START,FINSH)
2130 ? #1;BL$(1,64-(12+LEN(N$)));STAMP$
2140 REM
2150 SP=8:GOSUB 1620:GOSUB 1790
2160 ? #1;"   ";RETADR$(START,FINSH);
2170 ? #1;BL$(1,64-(12+LEN(N$)));STAMP$;" ";DOT$
2180 ? #1;BL$(1,12);:GOSUB 1790:? #1;RETADR$(START,FINSH);:N$=RETADR$(START,FINSH)
2190 ? #1;BL$(1,64-(12+LEN(N$)));STAMP$
2200 GOSUB 1790:IF RETADR$(START)=BL$(START) THEN 2230
2210 ? #1;RETADR$(START);:N$=RETADR$(START)
2220 ? #1;BL$(1,64-(12+LEN(N$)));:GOTO 2240
2230 ? #1;BL$(1,64);
2240 ? #1;TOP$
2250 GOSUB 1690:? #1
2260 REM
2270 GOSUB 1690:? #1:? #1
2310 REM
2320 GOSUB 1690
2330 W=0
2340 GOSUB 1840
2350 ? #1
2360 SP=8:GOSUB 1620:GOSUB 1790:? #1;BL$(10,34);ADRS$(START,FINSH);:N$=ADRS$(START,FINSH)
2370 ? #1;BL$(36+LEN(N$),74);DOT$:REM #36
2380 ? #1
2390 GOSUB 1840
2400 GOSUB 1690
2410 GOSUB 1840
2420 GOSUB 1690:? #1:? #1
2430 GOSUB 1690:? #1:? #1
2440 GOSUB 1680
2450 REM
2460 ? #1;" ";LINE$;
2470 GOSUB 1740
2480 ? #1;LINE$
2490 ? #1:? #1
2500 REM
2510 FOR L=51 TO 78 STEP 3
2520 GOSUB 1690:? #1
2540 NEXT L
2550 GOSUB 1690
2560 GOSUB 310:REM CURSOR ON
2570 RETURN
2580 REM MORE???
2590 ? CS$:GOSUB 270
2600 POSITION 5,10
2610 ? " DO YOU WANT TO DO ANOTHER? N←";:INPUT #16;Q$
2620 IF Q$="N" OR Q$="n" THEN 2680
2630 POP
2640 ? :? " DO YOU WANT THE SAME ADDRESSES? N←";:INPUT #16;Q$
2650 IF Q$="N" OR Q$="n" THEN 2700
2660 GOTO 2730:REM ? IT AGAIN
2670 GOSUB 2590:REM SAY WHAT?
2680 ? CS$:RETURN :REM GOODBY.
2690 REM MAIN PROGRAM
2700 GOSUB 330:REM -->WELCOME
2710 GOSUB 610:REM -->SENDER
2720 GOSUB 960:REM -->SENT2
2730 GOSUB 1260:REM ->CHECK
2740 GOSUB 1900:REM ->PRINTIT
2750 GOSUB 2590:REM ->MORE?
2760 END