Dungeon Arcade (DUNGEON.BAS)
Dungeon Arcade, game by Nadav Gur, 149
Description
Dungeon Arcade, game by Nadav Gur, 149
From the Antic disk of December 1987 (Vol. 6 No. 8).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 18.1 KB
- Dialect
- Atari BASIC
- Lines
- 391
- Variables
HS,LIVE,AC,CS,FREEZ,LINE$,MX,PX,MY,PY,L,A,CH$,HP,DIST,SP,BX,XINC,Z,FB,LXI,LYI,MXINC,MYINC,T,OK,MHS,HD,AR,SH,MON$,D,DMG,DMD,CONF,YINC,X,BOW,ARROWS,MON,MISC,ROOM,FDL,NUM,BUF$,I,PRICE,PRICEADJ,GP,DIR,HT,MDMG,MSD,SET,MONN,MIS,XP,WALLS,WALLX,WALLY,TRPS,Y,SHOP,DN,THING,X2,Y2,SHOP$,TREASURE,TXT,PL,SCORE,NAME$,FL,KEY$,CSET$,FOODL,MOV,LIN,BRK,BRKKY
BASIC listing (391 lines)
10 REM DUNGEON ARCADE
20 REM BY NADAV GUR
30 REM (c)1987, ANTIC PUBLISHING
40 BRK=PEEK(53279)<>5
90 GOTO 30000
95 POKE 77,0:IF BRK THEN POKE 16,112:POKE 53774,112
98 RETURN
100 HS=INT(RND(0)*35)+1:LIVE=0
110 HS=HS-AC-10:IF CS>0 THEN LIVE=1
115 IF FREEZ THEN HS=ABS(HS):GOTO 130
120 IF HS<1 THEN LINE$="You missed!":GOTO 1200
130 IF ABS(MX-PX)<>1 OR MY<>PY THEN LINE$="No use hitting that...":GOTO 1200
140 FOR L=1 TO 5:FOR A=1 TO 3:SOUND 0,A*L,4,3
150 CH$=CHR$(15+A)
160 POSITION MX,MY:? CH$;:POSITION 12,0:? INT(RND(0)*30);:NEXT A:NEXT L:IF HP>500 THEN HS=HS+HP-500
170 POSITION 12,0:? " ←←";HS;:POSITION MX,MY:? "▎";:SOUND 0,0,0,0
180 CS=CS-HS:IF HS<10 THEN LINE$="Lousy ":GOTO 200
190 IF HS<20 THEN LINE$="Good ":GOTO 200
195 IF HS<30 THEN LINE$="Stunning ":GOTO 200
197 LINE$="Super "
200 LINE$(LEN(LINE$)+1)="hit":IF (CS<1) AND (LIVE) THEN 24000
210 GOTO 1200
300 DIST=SQR((PX-MX)*(PX-MX)+(PY-MY)*(PY-MY)):IF DIST>10 THEN LINE$="Not in range!":GOTO 1200
320 COLOR 12:PLOT PX,PY:DRAWTO MX,MY
330 FOR A=0 TO 20:SOUND 0,A,0,10:NEXT A:FOR A=19 TO 0 STEP -1:SOUND 0,A,0,10:NEXT A:SOUND 0,0,0,0
340 COLOR 32:PLOT MX,MY:DRAWTO PX,PY
350 POSITION PX,PY:? "▔";:POSITION MX,MY:? "▎";:SP=0:POSITION 22,1:? " ";:FREEZ=1
360 GOTO 1200
450 POSITION 37,0:? " ";:FOR BX=PX+XINC TO PX+10*XINC STEP XINC
460 LOCATE BX,PY,Z:POSITION BX,PY:? "┐";
470 IF Z<>32 OR BX=3 OR BX=38 THEN POSITION BX,PY:? CHR$(Z);:POP :GOTO 490
480 SOUND 0,BX,0,10:FOR A=1 TO 5:NEXT A:POSITION BX,PY:? " ";:NEXT BX
490 IF BX<38 AND BX>2 THEN GOSUB 590:GOSUB 23000
500 FOR A=1 TO 3
510 IF PY-A>2 AND BX+A<38 AND BX-A>2 THEN LOCATE BX,PY-A,Z:POSITION BX,PY-A:? "┐";:GOSUB 590
520 IF PY+A<22 AND BX+A<38 AND BX-A>2 THEN LOCATE BX,PY+A,Z:POSITION BX,PY+A:? "┐";:GOSUB 590
530 IF BX+A<38 THEN LOCATE BX+A,PY,Z:POSITION BX+A,PY:? "┐";:GOSUB 590
540 IF BX-A>2 THEN LOCATE BX-A,PY,Z:POSITION BX-A,PY:? "┐";:GOSUB 590
550 SOUND 0,A*10,0,10:FOR L=1 TO 10:NEXT L:NEXT A
560 SOUND 0,0,0,0:FB=0:FOR A=1 TO 3:IF PY-A>2 AND BX+A<38 AND BX-A>2 THEN POSITION BX,PY-A:? " ";
570 IF PY+A<22 AND BX+A<38 AND BX-A>2 THEN POSITION BX,PY+A:? " ";
580 IF BX-A>2 THEN POSITION BX-A,PY:? " ";
582 IF BX+A<38 THEN POSITION BX+A,PY:? " ";
585 NEXT A:GOTO 1200
590 IF Z=22 THEN CS=CS-INT(RND(0)*80)
591 IF Z=13 THEN HP=HP-INT(RND(0)*80)
595 RETURN
600 LOCATE MX+LXI,MY+LYI,Z:POSITION MX+LXI,MY+LYI:? CHR$(Z);
610 IF (Z=32) OR (Z>1 AND Z<9) THEN MXINC=LXI:MYINC=LYI:GOTO 1400
620 IF Z=15 THEN CS=CS-INT(RND(0)*10):GOTO 1400
700 IF MXINC=0 OR RND(0)<0.3 THEN 730
710 T=MXINC:MXINC=0:GOSUB 800:IF OK THEN 1400
720 MXINC=T
730 IF MYINC=0 THEN 760
740 T=MYINC:MYINC=0:GOSUB 800:IF OK THEN 1400
750 MYINC=T
760 MYINC=-MYINC:MXINC=-MXINC:GOSUB 800:IF OK THEN 1400
770 GOTO 1410
800 LOCATE MX+MXINC,MY+MYINC,Z:OK=0:IF Z=32 OR Z=15 OR (Z>1 AND Z<9) THEN OK=1
810 IF Z=15 THEN CS=CS-INT(RND(0)*10)
820 POSITION MX+MXINC,MY+MYINC:? CHR$(Z);:RETURN
900 MHS=INT(RND(0)*30)+HD*2:IF AR THEN MHS=MHS-10
910 IF SH THEN MHS=MHS-5
920 LINE$="The ":LINE$(LEN(LINE$)+1)=MON$
925 FOR A=15 TO 20:SOUND 0,A,4,5:FOR D=1 TO 4:NEXT D:NEXT A:SOUND 0,0,0,0:SOUND 1,0,0,0
930 IF MHS>10 THEN LINE$(LEN(LINE$)+1)=" hits":DMG=0:FOR A=1 TO DMD:DMG=DMG+INT(RND(0)*6)+1:NEXT A:GOTO 950
940 LINE$(LEN(LINE$)+1)=" misses":GOTO 1500
950 FOR A=1 TO 10:POSITION PX,PY:? "▎";:POSITION PX,PY:? "▔";:NEXT A:HP=HP-DMG
960 GOTO 1500
1000 REM MAIN
1005 POSITION PX,PY:? "▔";:IF CONF THEN XINC=INT(RND(0)*3)-1:YINC=INT(RND(0)*3)-1:GOTO 1120
1010 X=PEEK(764):IF X=255 AND PEEK(632)=15 THEN 1210
1012 IF PEEK(632)=14 THEN X=11:REM UP
1014 IF PEEK(632)=13 THEN X=37:REM DOWN
1016 IF PEEK(632)=11 THEN X=57:REM LEFT
1018 IF PEEK(632)=7 THEN X=5:REM RIGHT
1019 IF PEEK(644)=0 THEN X=1
1020 IF X=1 THEN 100
1030 IF X=35 AND SP THEN 300
1040 IF X=32 AND FB THEN 450
1050 IF X=28 THEN 17000
1055 IF X=13 AND BOW AND ARROWS THEN 3000
1060 IF X<>11 AND X<>5 AND X<>57 AND X<>37 THEN 1200
1070 XINC=0:YINC=XINC
1080 IF X=11 THEN YINC=-1
1090 IF X=37 THEN YINC=1
1100 IF X=57 THEN XINC=-1
1110 IF X=5 THEN XINC=1
1120 LOCATE PX+XINC,PY+YINC,Z:POSITION PX+XINC,PY+YINC:? CHR$(Z);
1130 IF Z=32 THEN 1190
1140 IF Z=1 THEN LINE$="You bumped into a wall":HP=HP-10:IF CONF THEN CONF=0:LINE$="Confuse potion ended."
1145 IF Z=1 THEN 1200
1150 IF Z=15 THEN LINE$="A trap!!!":HP=HP-INT(RND(0)*10):GOTO 1190
1160 IF (Z>1 AND Z<9) OR Z=10 THEN 7000
1170 IF Z=9 THEN 8000
1180 IF Z=22 AND MON THEN 9000
1185 IF Z=11 THEN 13000
1190 POSITION PX,PY:? " ":PX=PX+XINC:PY=PY+YINC:POSITION PX,PY:? "▔";
1200 POKE 764,255
1210 IF (CS<1) OR (FREEZ) THEN 1500
1215 MXINC=0:MYINC=0:IF PEEK(53770)<35 THEN 1410
1220 MXINC=1*(PX>MX)-1*(PX<MX)
1230 MYINC=1*(PY>MY)-1*(PY<MY)
1260 LOCATE MX+MXINC,MY+MYINC,Z:POSITION MX+MXINC,MY+MYINC:? CHR$(Z);
1270 IF (Z=32) OR (Z>1 AND Z<9) THEN 1400
1280 IF Z=1 OR Z=11 OR Z=9 THEN 600
1290 IF Z=15 THEN IF RND(0)>0.5 THEN CS=CS-INT(RND(0)*10):GOTO 1400
1310 IF Z=13 AND RND(0)<0.3 THEN 900
1320 IF Z=13 THEN 1410
1400 LXI=MXINC:LYI=MYINC:POSITION MX,MY:? " ";:MX=MX+MXINC:MY=MY+MYINC:POSITION MX,MY:? "▎";
1410 IF MISC AND RND(0)>(0.1*ROOM/3) AND PY=MY AND ABS(PX-MX)>3 THEN GOSUB 14000:MISC=MISC-1
1500 FDL=FDL-1:IF FDL=100 THEN LINE$="You are getting hungry."
1510 IF FDL=50 THEN LINE$="You are very hungry."
1520 IF FDL=0 THEN LINE$="You are starving.":IF FDL/10=INT(FDL/10) THEN HP=HP-1
1530 IF MON AND CS<1 THEN MON=0:POSITION 18,0:? "───";
1550 IF CONF AND RND(0)<0.05 THEN CONF=0:LINE$="Confuse potion ended"
1560 IF FREEZ AND (RND(0)<3E-03*HD) THEN FREEZ=0:LINE$="Spell ended."
1570 IF RND(0)<2E-03 THEN GOSUB 6000
1580 IF HP<1 THEN 26000
1800 POSITION 5,0:? " ←←←";HP:IF MON THEN POSITION 18,0:? " ←←←";CS
1810 IF LINE$="" AND RND(0)<5E-03 THEN GOSUB 2000
1820 IF LINE$<>"" THEN POSITION 2,23:? " ";:POSITION 2,23:? LINE$;:LINE$=""
1900 GOTO 1000
2000 NUM=INT(RND(0)*18):RESTORE 2500+NUM*10:READ LINE$:FOR A=1 TO LEN(LINE$)
2010 IF LINE$(A,A)<>" " AND LINE$(A,A)<>"!" THEN LINE$(A,A)=CHR$(ASC(LINE$(A,A))+1)
2020 NEXT A:RETURN
2500 DATA @ unhbd ltssdqr9 Trd sgd Enqbd!
2510 DATA Rlhkd+ xnt&qd ◆klnrs cd◆c!
2520 DATA L◆jd ◆ kdes stqm ◆s @katptdqptd
2530 DATA Atx ◆s Rstloor enq adrs ldqbg◆mchrd!
2540 DATA Ehqda◆kkr ◆qd udqx c◆mfdqntr
2550 DATA Xnt&kk mdudq fds nts ne gdqd ◆khud
2560 DATA Lnud hs !
2570 DATA Cnm&s xnt vhrg xnt vdqd gnld>
2580 DATA Sghr hr sgd ohsr!
2590 DATA Fhud to-----------
2600 DATA Ok◆x Ctmfdnm @qb◆cd!
2610 DATA @ vhy◆qc nmbd r◆hc9 &Trd SXON HH&
2620 DATA V◆sbg nts enq ctbjr---
2630 DATA &Ots ghl hm Sgd Bnlex Bg◆hq!!!&
2640 DATA Sgd k◆rs ne sgd adrs-
2650 DATA Rtodq Rnesv◆qd eqnl @MSHB! X◆gnn!
2660 DATA --H jmnv xnt ◆qd+ ats vg◆s ◆l H >
2670 DATA @ unhbd r◆xr9 H&l rn Gnqmx!
3000 ARROWS=ARROWS-1:POSITION 19,1:? " ←←";ARROWS;:FOR A=PX+XINC TO PX+15*XINC STEP XINC
3010 LOCATE A,PY,Z:POSITION A,PY:? CHR$(Z);
3020 IF (Z<>32 AND Z<>22) OR A=38 OR A=3 THEN POP :SOUND 0,0,0,0:GOTO 1200
3030 POSITION A,PY:? "-";:IF Z=22 THEN POP :GOTO 3070
3040 SOUND 0,A/3,0,2:FOR L=1 TO 5:NEXT L:POSITION A,PY:? " ";:NEXT A
3050 SOUND 0,0,0,0:GOTO 1200
3070 SOUND 0,0,0,0:IF INT(RND(0)*10)>AC THEN CS=CS-INT(RND(0)*15)
3080 GOTO 1200
6000 ON INT(RND(0)*4)+1 GOTO 6010,6030,6050,6070
6010 IF SP THEN LINE$="Your scroll disappeared.":SP=0:POSITION 22,1:? " ";
6020 RETURN
6030 IF AR THEN LINE$="Your mail broke up!":AR=0:POSITION 9,1:? " ";
6040 RETURN
6050 IF FB THEN LINE$="Your fireball scroll caught fire!":FB=0:POSITION 37,0:? " ";
6060 RETURN
6070 IF SH THEN LINE$="Your shield cracked!":SH=0:POSITION 2,1:? " ";
6080 RETURN
7000 FOR A=30 TO 23 STEP -1:SOUND 0,A,10,10:NEXT A:SOUND 0,0,0,0
7005 IF Z=2 THEN SP=1:LINE$="You found a scroll":POSITION 22,1:? "Freeze":GOTO 1190
7010 IF Z=3 THEN 7500
7020 IF Z=4 THEN BOW=1:ARROWS=ARROWS+INT(RND(0)*21):POSITION 15,1:? "Bow:";ARROWS;:GOTO 1190
7030 IF Z=5 THEN LINE$="A fireball!":FB=1:POSITION 37,0:? "fb";:GOTO 1190
7040 IF Z=7 THEN SH=1:POSITION 2,1:? "Shield";:LINE$="A shield!":GOTO 1190
7050 IF Z=8 THEN HP=HP+INT(RND(0)*30):LINE$="You feel better":GOTO 1190
7060 IF Z=10 THEN LINE$="Armor !":POSITION 9,1:? LINE$(1,5);:AR=1:GOTO 1190
7070 X=INT(RND(0)*3)+1:ON X GOTO 7080,7090,7100
7080 LINE$="A healing potion":HP=HP+INT(RND(0)*30):GOTO 1190
7090 LINE$="Confuse Potion!":CONF=1:GOTO 1190
7100 LINE$="It blew up in your face!":HP=HP-INT(RND(0)*21):GOTO 1190
7500 LINE$="You found ":RESTORE 7550+INT(RND(0)*5)*10:READ BUF$:LINE$(LEN(LINE$)+1)=BUF$:FDL=500:GOTO 1190
7550 DATA a burger
7560 DATA a bag of beans
7570 DATA chop-suey
7580 DATA a pizza
7590 DATA a hot dog
8000 REM NEW ROOM
8010 ROOM=ROOM+1:IF ROOM=41 THEN 25000
8020 ? "↰";
8100 GOTO 20000
9000 A=INT(RND(0)*2)+1:ON A GOTO 9010,9050
9010 X=INT(RND(0)*4):I=1:IF RND(0)<0.5 THEN I=-1
9015 IF PX+X*I<3 OR PX+X*I>38 THEN 1500
9020 X=X*I:LOCATE PX+X,PY,Z:POSITION PX+X,PY:? CHR$(Z);
9030 IF Z<>32 THEN 1220
9040 POSITION PX,PY:? " ";:PX=PX+X:POSITION PX,PY:? "▔";:GOTO 1190
9050 X=INT(RND(0)*4):I=1:IF RND(0)<0.5 THEN I=-1
9055 IF MX+X*I<3 OR MX+X*I>38 THEN 1500
9060 X=X*I:LOCATE MX+X,MY,Z:POSITION MX+X,MY:? CHR$(Z);
9070 IF Z<>32 THEN 1220
9080 POSITION MX,MY:? " ";:MX=MX+X:POSITION MX,MY:? "▎";:GOTO 1500
13000 IF PY<>11 THEN LINE$="Broke into my store, eh?":HP=HP-INT(RND(0)*70):GOTO 1200
13010 LOCATE PX,9,Z:POSITION PX,9:? CHR$(Z);
13020 PRICE=100*(Z=2)+50*(Z=3)+150*(Z=4)+250*(Z=5)+200*(Z=7)+120*(Z=8)+300*(Z=10)
13030 PRICE=INT(PRICE*PRICEADJ)
13040 IF PRICE>GP THEN LINE$=STR$(GP):LINE$(LEN(LINE$)+1)=" g.p. is not enough!":GOTO 1200
13050 POSITION PX,12:? CHR$(Z);:GP=GP-PRICE:LINE$="You have "
13055 LINE$(10)=STR$(GP):LINE$(LEN(LINE$)+1)=" g.p. left."
13060 GOTO 1200
14000 DIR=1*(PX>MX)-1*(PX<MX)
14010 FOR A=MX+DIR TO PX-DIR STEP DIR
14020 LOCATE A,MY,Z:POSITION A,MY:? CHR$(Z);
14030 IF Z<>32 THEN POP :SOUND 0,0,0,0:RETURN
14040 POSITION A,MY:? "┼";:FOR L=0 TO 0:NEXT L:POSITION A,MY:? "●";:FOR L=0 TO 0:POSITION A,MY:? "▄";
14045 SOUND 0,A+10,0,5:SOUND 0,A+5,0,5
14050 POSITION A,MY:? " ";:NEXT A:SOUND 0,0,0,0
14055 HT=INT(RND(0)*10)+HD:IF HT<7 THEN RETURN
14060 POSITION PX,PY:? "▄";:POSITION PX,PY:? "▔";:MDMG=0:FOR A=1 TO MSD:DMG=DMG+INT(RND(0)*8):NEXT A:HP=HP-DMG
14070 RETURN
17000 POKE 764,255
17020 IF PEEK(764)=255 OR PEEK(764)=28 THEN 17020
17030 GOTO 1000
17999 END
20000 REM INIT NEW ROOM
20005 GRAPHICS 0:A=INT(RND(0)*16):SETCOLOR 2,A,0:SETCOLOR 1,A,12:POKE 752,1:POKE 756,SET/256
20010 GOSUB 95:MONN=INT(RND(0)*14)+INT(RND(0)*ROOM):IF MONN>27 THEN 20010
20015 IF MONN=0 THEN MONN=1
20020 RESTORE 20500+MONN*10-10:POKE 752,1:MISC=0
20030 READ MON$,HD,DMD,AC,MIS,MSD:IF MIS THEN MISC=INT(RND(0)*4)
20040 CS=0:FOR A=1 TO HD:CS=CS+INT(RND(0)*30):NEXT A
20050 FOR A=SET+688 TO SET+695:READ L:POKE A,L:NEXT A
20055 FREEZ=0:CONF=0
20060 ? "↰Hp:";HP:POSITION 9,0:? "Hs:":POSITION 15,0:? "Cs:";CS:POSITION 22,0:? "Xp:";XP:POSITION 29,0:? "Room:";
20070 ? ROOM:POSITION 29,1:? MON$
20080 IF FB THEN POSITION 37,0:? "fb"
20090 IF SH THEN POSITION 2,1:? "Shield"
20100 IF AR THEN POSITION 9,1:? "Armor"
20110 IF BOW THEN POSITION 15,1:? "Bow:";ARROWS
20120 IF SP THEN POSITION 22,1:? "Freeze"
20123 POSITION 2,2:? "├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├"
20125 COLOR 1:PLOT 38,2:DRAWTO 38,22:DRAWTO 2,22:DRAWTO 2,2
20130 WALLS=INT(RND(0)*4)
20135 IF WALLS<1 THEN 20210
20140 FOR A=1 TO WALLS:WALLX=INT(RND(0)*33)+4:WALLY=RND(0)
20150 IF WALLY>0.5 THEN WALLY=3
20160 IF WALLY<0.5 THEN WALLY=21
20170 IF WALLY=21 THEN PLOT WALLX,WALLY:DRAWTO WALLX,14
20180 IF WALLY=3 THEN PLOT WALLX,WALLY:DRAWTO WALLX,11
20190 NEXT A
20210 TRPS=INT(RND(0)*30)+ROOM/2
20220 FOR A=1 TO TRPS
20230 X=INT(RND(0)*35)+3:Y=INT(RND(0)*20)+2:LOCATE X,Y,Z:IF Z=32 THEN POSITION X,Y:? "▖";
20240 NEXT A
20245 SHOP=INT(RND(0)*6):IF SHOP=2 THEN GOSUB 22000
20250 DN=RND(0):IF DN<0.3 THEN 20330
20260 DN=INT(RND(0)*(ROOM/10)):DN=DN+INT(RND(0)*2)+1
20270 FOR A=1 TO DN
20280 THING=INT(RND(0)*12)+1
20290 RESTORE 20295:FOR I=1 TO THING:READ CH$:NEXT I
20292 IF CH$="╱" AND INT(RND(0)<0.3) THEN CH$="◣"
20295 DATA ┘,┘,▕,┤,┤,▕,◢,╱,┐,╱,╲,◢
20300 X=INT(RND(0)*35)+3:Y=INT(RND(0)*20)+2:LOCATE X,Y,Z:IF Z<>32 THEN 20300
20310 POSITION X,Y:? CH$;
20320 NEXT A
20330 IF PX=37 THEN PX=3:PY=11:GOTO 20370
20340 IF PY=21 THEN PY=3:PX=20:GOTO 20370
20350 IF PY=3 THEN PY=21:PX=20:GOTO 20370
20360 PY=11:PX=37
20370 POSITION PX,PY:? "▔";
20380 MX=INT(RND(0)*36)+3:MY=INT(RND(0)*20)+3:LOCATE MX,MY,Z:IF Z<>32 THEN 20380
20385 IF SHOP=2 AND MX>12 AND MX<28 AND MY>6 AND MY<15 THEN 20380
20390 POSITION MX,MY:? "▎";
20400 X=INT(RND(0)*4)+1
20410 RESTORE 20450+X*10-10:READ X,Y,X2,Y2
20420 COLOR 9:PLOT X,Y:DRAWTO X2,Y2:POSITION X2,Y2:? "├";
20430 MON=1
20440 GOTO 1000
20450 DATA 2,13,2,10
20460 DATA 38,10,38,13
20470 DATA 19,2,23,2
20480 DATA 19,22,23,22
20499 GOTO 20499
20500 DATA Worm,2,1,1,0,0,0,6,3,55,126,230,112,0
20510 DATA Rat,3,2,2,0,0,0,0,0,120,244,254,120,84
20520 DATA Gnome,3,2,3,1,1,16,56,16,125,186,16,40,108
20530 DATA Orc,3,3,2,0,0,24,60,25,3,126,24,102,102
20540 DATA Spider,3,3,2,0,0,0,24,60,24,126,189,165,165
20550 DATA Eagle,4,3,3,0,0,0,153,211,126,60,24,36,0
20560 DATA Manticore,4,3,3,1,2,0,0,102,143,255,124,54,85
20570 DATA Human,5,4,3,1,1,24,25,1,127,153,60,102,102
20580 DATA Wolf,5,3,2,0,0,0,12,134,143,124,124,68,170
20590 DATA Ghost,4,3,5,0,0,24,60,106,126,126,60,28,56
20600 DATA Worg,6,4,4,0,0,0,12,134,143,124,124,68,170
20610 DATA Minotaur,8,4,4,0,0,60,25,1,127,153,24,102,102
20620 DATA Jelly,2,5,1,0,0,0,0,0,0,12,62,127,173
20630 DATA Hydra,7,5,5,0,0,80,218,83,126,56,124,84,198
20640 DATA Giant,7,5,4,0,0,56,57,147,255,61,57,109,108
20650 DATA Firecreep,2,5,7,0,0,12,24,56,104,92,92,56,16
20660 DATA Troll,8,5,5,0,0,12,12,24,62,57,28,102,99
20670 DATA G.Scorpion,3,6,6,0,0,0,98,147,132,125,63,100,170
20680 DATA Dragon,9,4,5,1,4,16,50,59,186,158,126,60,20
20690 DATA Droid,7,6,8,0,0,24,36,60,126,255,189,36,102
20700 DATA Blob,10,5,7,0,0,24,36,60,118,223,247,124,231
20710 DATA Demon,12,6,6,1,2,24,24,195,126,60,24,36,36
20720 DATA Snake,6,8,3,0,0,0,0,120,100,5,57,66,60
20730 DATA Warrior,8,6,6,1,2,27,27,1,127,153,60,102,102
20740 DATA Eye,4,6,7,0,0,0,24,102,153,153,102,24,0
20750 DATA Wierd One,6,8,4,1,2,153,102,60,255,90,24,60,102
20760 DATA Dark one,7,7,6,0,0,24,219,102,60,24,36,102,0
22000 POSITION 12,6:? " ":POSITION 12,7:? " ├├├├├├├├├├├├├├├ ":POSITION 12,8:? " ├ ├ "
22010 POSITION 12,9:? " ├┘ ▕ ┤ ╲ ┐ ◣ ◢├ ":POSITION 12,10
22015 ? " ├▝├▝├▝├▝├▝├▝├▝├ ":POSITION 12,11:? " ├ ├ ├ ├ ├ ├ ├ ├"
22020 POSITION 13,12:? "├ ├ ├ ├ ├ ├ ├ ├":POSITION 13,13:? "├ ├":POSITION 12,14:? " ├├├├├├ ├├├├├├├ "
22030 POSITION 13,15:? " "
22040 RESTORE 22500+(INT(RND(0)*11))*10:READ SHOP$:POSITION 14,8:? SHOP$
22050 PRICEADJ=0.5+RND(0):RETURN
22500 DATA CATALOGSHOP 1
22510 DATA CRAZY ORLIC'S
22520 DATA SUPERMARKET V
22530 DATA >SWORDS R US<
22540 DATA ┐ DRAGONSDEN┐
22550 DATA PIRATES COVE
22560 DATA ╲LAST SHOP!!◢
22570 DATA ─ STUMPP'S ♣
22580 DATA MEDIEVAL MALL
22590 DATA CHEAP ARMOR ◣
22600 DATA KNIGHTDELIGHT
22999 END
23000 POSITION BX,PY:? "┐";:FOR L=0 TO 9:SOUND 0,L,0,10:NEXT L:POSITION BX,PY:? " ":RETURN
24000 POSITION 2,23:? "You killed the ";MON$;:POSITION 18,0:? "♣♣♣";
24010 TREASURE=INT(RND(0)*HD*50)
24020 GP=GP+TREASURE:MON=0:XP=XP+HD:TXT=INT(RND(0)*8):RESTORE 24100+TXT*10:READ LINE$,PL
24030 LINE$(PL,PL+LEN(STR$(TREASURE))-1)=STR$(TREASURE)
24040 FOR A=1 TO 100:NEXT A:GOTO 1500
24100 DATA In its guts you found g.p,23
24110 DATA It had a check of g.p.,19
24120 DATA In its pocket it had g.p.,22
24130 DATA You found g.p.,11
24140 DATA You recovered g.p.,15
24150 DATA x gold piece were in its bag,1
24160 DATA Under it you found g.p.,20
24170 DATA It had gems worth g.p.,19
25000 SCORE=XP*10+GP
25010 SCORE=SCORE+200*AR+100*SP+5*ARROWS+150*FB+100*SH
25020 GRAPHICS 0:POKE 710,0:POKE 752,1:POKE 756,SET/256:? :?
25030 ? " Congratulations, brave ":? "▶─ ";NAME$;" ♣"
25040 ? :? " You have shown much courage,"
25045 ? " skill and wisdom, and survived ▶▶←←← DUNGEON ARCADE"
25050 ? " You have scored ";XP;" fame points,":? " and ";SCORE-10*XP;" fortune points, which rate ":? " you as"
25060 IF SCORE<5000 THEN LINE$="An average knight.":GOTO 25100
25070 IF SCORE<7000 THEN LINE$="A hero.":GOTO 25100
25080 IF SCORE<8000 THEN LINE$="A super hero.":GOTO 25100
25090 IF SCORE<9000 THEN LINE$="A supreme lord!":GOTO 25100
25095 LINE$="A true overlord of might!"
25100 ? :? " ";LINE$
25110 ? :? :? "├ ├ ├":? "├├├├├├":? "├├├├├▗":? "├├├├├▗ ▔":? "├├├├├├├├├├├├"
25120 ? :? "Would you like to play again ";:INPUT LINE$
25130 IF LINE$(1,1)<>"Y" AND LINE$(1,1)<>"y" THEN END
25140 GOTO 29000
26000 SCORE=XP*10+GP
26010 SCORE=SCORE+200*AR+100*SP+5*ARROWS+150*FB+100*SH
26020 GRAPHICS 0:POKE 710,0:POKE 752,1:POKE 756,SET/256:? :GOSUB 95
26025 ? " ┌▔ ▎":? "├├├├├├":?
26030 ? :? " ";NAME$:? :? "You have perished on your quest for"
26040 ? "▶▶←←←fame & fortune"
26050 ? :? "May you rest well in your grave."
26060 ? :? "Overall, you acquired :":? " ";XP;" Fame points,"
26070 ? " ";SCORE-10*XP;" Fortune points, a sum of :":? " ";SCORE;" game points."
26080 ? :? :? :? "Do you want to try again ";:INPUT LINE$
26090 IF LINE$(1,1)<>"Y" AND LINE$(1,1)<>"y" THEN GRAPHICS 0:END
29000 ? "↰"
29010 ? :? :? :?
29020 ? " ├├├├├├ ├├├├├"
29030 ? " ├├ ├├ ├├ ├├"
29040 ? " ├├ ├├ ├├ ├├"
29050 ? " ├├ ├├ ├├ ├├"
29060 ? " ├├ ├├ ├├├├├├├"
29070 ? " ├├ ├├ ├├ ├├"
29080 ? " ├├ ├├ ├├ ├├"
29085 ? " ├├├├├├ UNGEON ├├ ├├RCADE"
29090 ? :? :? :? "▶An Underground Adventure!"
29100 ? :? "(c) 1987 Antic Publishing"
29110 ? "Enter your name, O' Brave adventurer -->";:INPUT #16;NAME$
29120 ? "Welcome to Dungeon Arcade, ";NAME$
29130 FOR A=1 TO 100:NEXT A
29140 XP=0:HP=400:GP=0:BOW=0:SH=0:SP=0:FB=0:FL=500:ROOM=1:ARROWS=0:AR=0
29500 GOTO 20000
29999 END
30000 DIM LINE$(60),BUF$(60),NAME$(15),MON$(10),SHOP$(15),KEY$(1),CH$(1),CSET$(168)
30010 XP=0:HP=400:GP=0:BOW=0:SH=0:SP=0:FB=0:FOODL=30:ROOM=1:ARROWS=0
30020 MOV=ADR("hh┐qh┐ph┐Uh┐Th┐oh┐n ♥1p┌TfTP▕fUfpP▕fqFnPjFo♣f◆")
30030 CSET$(1,84)="[[♥mm♥66♥♥$◀U◀$♥♥<Bf◀◀◀<▖└└22└└▖♥$Z<<Z$♥<fN↑┴♥┴┴♥┴$ZZ$┴♥♥┴┴┴$Zf<fZf◀ZfZ◀┴<gCff<<♥♥♥▶"
30040 CSET$(85,168)="▶├◀◀♥♥♥┌*D♥♥┴▌├▶▌<ff8l┘↑Cp6q♥◀fZZf◀♥♥@ ▎◢●─♥♥♥@ ◀ @♥♥─●◢▎ @♥♥┴┴<<┴┴♥♥ |<<>┤♥♥┤><<| ♥"
30050 POKE 106,PEEK(740):POKE 559,0
30060 SET=PEEK(106)-8:POKE 106,SET-2:SET=SET*256:A=USR(MOV,57344,SET,1024)
30070 GRAPHICS 0:POKE 710,0:POKE 756,SET/256:GOSUB 95
30080 A=USR(MOV,ADR(CSET$),SET+520,168):POKE 559,34
30090 GOTO 29000
