Antic Publisher (ANTICPUB.BAS)
Antic Publisher by Nadav Gur, 188 (BASIC, text)
Description
Antic Publisher by Nadav Gur, 188 (BASIC, text)
From the Antic disk of December 1987 (Vol. 6 No. 8).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 15.1 KB
- Dialect
- Atari BASIC
- Lines
- 261
- Variables
BRK,WA,FONTST,C710,C709,CASE,PX,LX,PY,LY,NZ1,NZ2,NZ3,NZ4,Z1,Z2,Z3,Z4,L,R,SWAP$,S,Z,HEB,A,ADDR,BYTES,FONTADR,SIGNS,X,TYPE$,FWIDTH,FHEIGHT,TEMP,BS,Y,TXT$,DUMP$,GRAF$,MOV,ESIGN,RX,TY,BY,WIN,BIN$,STIK,KEY,EXT,LINE1$,WD,I,DEC$,FROM,SEC,TEMP$,FN$,FN,OPT,LINE2$,LN,B,C,INV$,MAX,LINE3$,HT,Y1,Y2,FLAG,LINE,KEY$,SC
BASIC listing (261 lines)
10 REM ANTIC PUBLISHER
20 REM BY NADAV GUR
30 REM (c)1987, ANTIC PUBLISHING
40 BRK=PEEK(53279)<>5:POKE 106,PEEK(740):GOTO 32000
50 FOR WA=0 TO 0 STEP 0:WA= NOT STRIG(0):NEXT WA:RETURN
100 POKE 77,0:IF BRK THEN POKE 16,112:POKE 53774,112
110 RETURN
1000 POKE 106,FONTST:GRAPHICS 56:OPEN #1,4,0,"K:":POKE 710,C710:POKE 709,C709:CASE=0
1010 PX=1:LX=PX:PY=1:LY=PY
1020 GOSUB 2000:GOSUB 100
1050 COLOR NZ1:PLOT PX,PY:COLOR NZ2:PLOT PX+1,PY:COLOR NZ3:PLOT PX,PY+1:COLOR NZ4:PLOT PX+1,PY+1
1055 COLOR Z1:PLOT PX,PY:COLOR Z2:PLOT PX+1,PY:COLOR Z3:PLOT PX,PY+1:COLOR Z4:PLOT PX+1,PY+1
1060 IF STICK(0)<>15 THEN 1200
1070 IF NOT STRIG(0) THEN NZ1=Z1:Z1= NOT Z1:LX=PX:LY=PY:GOTO 1050
1080 L=PEEK(53279):IF L<>7 THEN 1300
1090 R=PEEK(764):IF R=205 THEN R=USR(ADR(SWAP$)):C710=PEEK(710):C709=PEEK(709):POKE 764,255:GOTO 1050
1097 IF R=255 THEN 1050
1100 GOSUB 1180:R=R-64:GOSUB 1180:R=R-64:GOSUB 1180:R=R-64:GOSUB 1180
1110 GOTO 1400
1180 IF R=39 OR R=60 THEN POP :POKE 766,255:GOTO 1050
1190 RETURN
1200 S=PEEK(632):PX=PX+1*((S=7 OR S=6 OR S=5) AND PX<319)-1*((S=11 OR S=9 OR S=10) AND PX>0)
1210 PY=PY+1*((S=13 OR S=9 OR S=5) AND PY<191)-1*((S=14 OR S=10 OR S=6) AND PY>0)
1220 GOSUB 2000:GOTO 1070
1300 IF L=6 THEN COLOR 1:PLOT LX,LY:DRAWTO PX,PY:LOCATE PX,PY,Z:LX=PX:LY=PY
1310 IF L=3 THEN POKE 106,FONTST-32:CLOSE #1:GRAPHICS 0:GOTO 20000
1320 IF L=5 THEN CASE= NOT CASE
1330 IF L=4 THEN HEB= NOT HEB
1350 IF PEEK(53279)<>7 THEN 1330
1360 GOTO 1050
1400 GET #1,A:A=A+CASE*32:IF (A<38 OR A>122) AND (A<28 OR A>32) AND A-32*CASE<>155 THEN 1050
1405 IF A-CASE*32=32 THEN 1500
1406 IF A-CASE*32=155 THEN 1600
1407 IF A-32*CASE>27 AND A-32*CASE<32 THEN A=A-32*CASE:GOTO 1450
1410 A=A-38:ADDR=A*BYTES+FONTADR:IF A>SIGNS THEN 1050
1420 X=USR(ADR(TYPE$),ADDR,FWIDTH/8,FHEIGHT,PX,PY)
1430 TEMP=PX-2*FWIDTH*HEB+FWIDTH-HEB+BS*(HEB=0):IF TEMP>0 AND TEMP<319 THEN PX=TEMP
1440 GOSUB 2000:GOTO 1050
1450 PX=PX+(FWIDTH+1)*(A=31 AND PX+FWIDTH+1<319)-(FWIDTH+1)*(A=30 AND PX-FWIDTH-1>-1)
1460 PY=PY+(FHEIGHT+1)*(A=29 AND PY+FHEIGHT+1<192)-(FHEIGHT+1)*(A=28 AND PY-FHEIGHT-1>-1)
1470 GOSUB 2000:GOTO 1050
1500 IF PX+FWIDTH-BS>319 THEN 1050
1510 IF PY+FHEIGHT+1>191 THEN 1050
1520 COLOR 0:FOR Y=PY TO PY+FHEIGHT+1:PLOT PX,Y:DRAWTO PX+FWIDTH,Y:NEXT Y:GOTO 1430
1600 IF PY+FHEIGHT+BS<191-FHEIGHT THEN PX=2:PY=PY+FHEIGHT+1:GOSUB 2000:GOTO 1050
1610 GOTO 1050
2000 LOCATE PX,PY,Z1:LOCATE PX+1,PY,Z2:LOCATE PX,PY+1,Z3:LOCATE PX+1,PY+1,Z4
2010 NZ1= NOT Z1:NZ2= NOT Z2:NZ3= NOT Z3:NZ4= NOT Z4:RETURN
12000 POKE 106,FONTST:GRAPHICS 56:POKE 710,C710:POKE 709,C709:L=0
12010 TRAP 12040:OPEN #1,8,0,"P:":TXT$=" ":TXT$(640)=" ":TXT$(2)=TXT$:? #1;"␛3┴"
12015 IF PEEK(710)<>0 THEN 12020
12016 R=PEEK(88)+PEEK(89)*256:GOSUB 12051:L=1
12020 FOR A=0 TO 188 STEP 4:X=USR(ADR(DUMP$),ADR(TXT$),A*40):? #1;GRAF$;TXT$:NEXT A
12030 GOSUB 12050:POKE 106,FONTST-32:GRAPHICS 0:GOTO 20000
12040 GOSUB 12050:POKE 106,FONTST-32:GRAPHICS 0:? "CHECK PRINTER !!!↰↰":GOTO 20000
12050 IF L=0 THEN RETURN
12051 POKE 559,0:A=USR(MOV,R,R,7680,255):A=USR(ADR(SWAP$)):POKE 559,34:RETURN
14000 TRAP 14000:POSITION 2,12:? "CURRENT BIT SPACING:";BS;" NEW:";
14010 INPUT X:IF ABS(X)>100 THEN ? "RANGE ERROR↰↰":GOTO 20000
14020 BS=X:GOTO 20000
15000 TRAP 15000:POSITION 2,12:? "EDIT SIGN #:";:INPUT ESIGN:ESIGN=INT(ESIGN)
15010 IF ESIGN>SIGNS THEN ? "ERROR:SIGN DOES NOT EXIST!↰":FOR A=1 TO 500:NEXT A:GOTO 20000
15020 ? "↰":LX=20-FWIDTH/2-1:RX=LX+FWIDTH+1:TY=0:BY=FHEIGHT+1:WIN=1:POKE 752,1
15030 TXT$="":FOR A=1 TO BYTES:TXT$(LEN(TXT$)+1)=" ":NEXT A
15040 FOR A=0 TO BYTES-1:X=USR(ADR(BIN$),PEEK(FONTADR+ESIGN*BYTES+A),ADR(TXT$)+A*8):NEXT A
15050 GOSUB 28000:POSITION 10,19:? "SIGN #:";ESIGN;" KEYPRESS: ←←";CHR$(ESIGN+38):?
15060 ? "COMPUTE KILL EXIT NEXT LAST MOVE"
15080 PX=LX+1:PY=1:POKE 752,1:LOCATE PX,PY,Z:R=0:IF Z=160 THEN R=1
15100 POSITION PX,PY:? "●";:POSITION PX,PY:? CHR$(Z)
15105 IF PEEK(764)<>255 THEN 15200
15110 IF NOT STRIG(0) THEN R= NOT R:Z=R*128+32:GOSUB 15300
15120 IF STICK(0)=15 THEN 15100
15130 STIK=STICK(0):PX=PX-1*((STIK=11 OR STIK=10 OR STIK=9) AND PX>LX+1)
15140 PX=PX+1*((STIK=7 OR STIK=5 OR STIK=6) AND PX<RX-1)
15150 PY=PY-1*((STIK=14 OR STIK=6 OR STIK=10) AND PY>1)+1*((STIK=13 OR STIK=5 OR STIK=9) AND PY<FHEIGHT)
15160 LOCATE PX,PY,Z:R=0:IF Z=160 THEN R=1
15170 GOTO 15100
15200 KEY=PEEK(764):POKE 764,255
15210 IF KEY=18 THEN 15500
15215 IF KEY=37 THEN 15600
15220 IF KEY=42 THEN 20000
15230 IF KEY=5 THEN FOR A=FONTADR+ESIGN*BYTES TO FONTADR+(ESIGN+1)*BYTES-1:POKE A,0:NEXT A:GOTO 15040
15235 IF KEY=0 AND ESIGN>0 THEN ESIGN=ESIGN-1:GOTO 15040
15240 IF KEY<>35 OR ESIGN=84 THEN 15100
15250 ESIGN=ESIGN+1
15260 IF ESIGN>SIGNS THEN SIGNS=SIGNS+1:FOR A=FONTADR+ESIGN*BYTES TO FONTADR+(ESIGN+1)*BYTES-1:POKE A,0:NEXT A
15270 GOTO 15040
15300 IF NOT STRIG(0) THEN 15300
15310 RETURN
15400 POSITION 2,12:? "CURRENT MAX. SIGN:";SIGNS;" EXTEND TO:";:INPUT EXT:EXT=INT(EXT)
15410 IF EXT<=SIGNS THEN ? "ERROR - SIGN ALREADY EXISTS!↰":FOR A=1 TO 500:NEXT A:GOTO 20000
15420 IF EXT>84 THEN ? "ERROR - OVER MAX. SIGN!↰":FOR A=1 TO 500:NEXT A:GOTO 20000
15430 FOR A=FONTADR+(SIGNS+1)*BYTES TO FONTADR+(EXT+1)*BYTES:POKE A,0:NEXT A
15440 SIGNS=EXT:GOTO 20000
15500 LINE1$=" ":WD=FWIDTH/8:FOR I=0 TO FHEIGHT-1:FOR A=0 TO WD-1
15510 FOR L=1 TO 8:LOCATE LX+A*8+L,I+1,Z:LINE1$(L,L)=CHR$(Z):NEXT L
15520 X=USR(ADR(DEC$),ADR(LINE1$)):POKE FONTADR+ESIGN*BYTES+WD*I+A,PEEK(203)
15530 NEXT A:NEXT I:POSITION 8,23:? "COMPUTING DONE!";:FOR A=1 TO 100:NEXT A:POSITION 8,23:? " ";
15540 GOTO 15100
15600 TRAP 15600:POSITION 10,19:? "↑↑↑FROM:";:INPUT FROM:? "TO:";:INPUT SEC
15610 IF SEC>SIGNS OR FROM>SIGNS OR FROM<>INT(FROM) OR SEC<>INT(SEC) OR FROM<0 OR SEC<0 THEN ? "↰":GOTO 15020
15620 FOR A=0 TO BYTES-1:POKE FONTADR+BYTES*SEC+A,PEEK(FONTADR+BYTES*FROM+A):NEXT A
15630 GOTO 15020
16000 POKE 106,FONTST:GRAPHICS 24:POKE 106,FONTST-32:GRAPHICS 0:GOTO 20000
16100 POSITION 2,12:? "Enter a filename":? "(8 char. or less)↑";:INPUT TEMP$
16110 IF LEN(TEMP$)>8 THEN 16100
16120 FN$="D:":FN$(3,3+LEN(TEMP$))=TEMP$:FN$(LEN(FN$)+1)=".PIC"
16130 CLOSE #1:TRAP 16170:OPEN #1,8,0,FN$
16135 POKE 106,FONTST:GRAPHICS 56
16140 X=USR(ADR("h)▝▔R┘)♥▔X┘)←▔Y┘%X▔T┘%Y▔U┘◆"))
16150 X=USR(ADR("hhh*LVd"),16):CLOSE #1
16160 POKE 106,FONTST-32:GRAPHICS 0:GOTO 20000
16170 POKE 106,FONTST-32:GRAPHICS 0:GOTO 19100
16200 TRAP 40100:OPEN #1,6,0,"D:*.PIC"
16210 FN=1:TXT$="":TXT$=" ":TXT$(48)=" ":TXT$(2)=TXT$:WIN=1:TY=10:LX=6:RX=15
16220 INPUT #1;FN$:IF FN$(2,2)<>" " THEN 16400
16230 TXT$((FN-1)*8+1,FN*8)=FN$(3,10):FN=FN+1:IF FN<6 THEN 16220
16240 TXT$(41,48)=" OTHER ":BY=17:GOSUB 28000:GOSUB 26000
16250 IF OPT=6 THEN GOSUB 27000:GOTO 16210
16260 FN$="D:":FN$(3,10)=TXT$((OPT-1)*8+1,OPT*8):FOR A=3 TO 10:IF FN$(A,A)=" " THEN POP :GOTO 16265
16263 NEXT A:A=11
16265 FN$(A,A+3)=".PIC"
16270 CLOSE #1:POKE 106,FONTST:GRAPHICS 56:POKE 710,C710:POKE 709,C709:TRAP 16310:OPEN #1,4,0,FN$
16280 X=USR(ADR("h)╲▔R┘)♥▔X┘)←▔Y┘%X▔T┘%Y▔U┘◆"))
16290 X=USR(ADR("hhh*LVd"),16):CLOSE #1
16300 POKE 106,FONTST-32:GRAPHICS 0:GOTO 20000
16310 POKE 106,FONTST-32:GRAPHICS 0:POKE 710,0:GOTO 19100
16320 FOR A=1 TO 500:NEXT A:GOTO 2000016320
16400 CLOSE #1:IF FN=1 THEN 20000
16410 TXT$((FN-1)*8+1,FN*8)=" EXIT ":BY=TY+FN+1:GOSUB 28000:GOSUB 26000:IF OPT=FN THEN 20000
16420 GOTO 16260
17000 POKE 752,1:TRAP 19100:TY=3:BY=14:LX=2:RX=20:WIN=1:OPEN #1,6,0,"D:*.*"
17010 FN=1:TXT$="":TXT$=" ":TXT$(136)=" ":TXT$(2)=TXT$
17030 INPUT #1;LINE1$:IF LINE1$(2,2)<>" " THEN 17060
17040 TXT$((FN-1)*17+1,FN*17)=LINE1$:FN=FN+1:IF FN<11 THEN 17030
17050 GOSUB 28000:GOSUB 50:GOTO 17010
17060 IF FN=1 THEN CLOSE #1:POKE 752,0:GOTO 20000
17070 GOSUB 27000:TXT$((FN-1)*17+1,FN*17)="END OF DIRECTORY ":BY=FN+TY+1:GOSUB 28000
17080 GOSUB 50:POKE 752,0:CLOSE #1:GOTO 20000
17100 TRAP 20000:POSITION 2,12:? "ENTER CURRENT FILENAME:";:INPUT FN$
17110 ? "ENTER TARGET FILENAME:";:INPUT LINE1$
17120 IF FN$(2,2)<>":" AND FN$(3,3)<>":" THEN LINE2$=FN$:FN$="D:":FN$(3)=LINE2$
17130 IF LINE1$(2,2)=":" THEN LINE1$=LINE1$(3,LEN(LINE1$))
17140 IF LINE1$(3,3)=":" THEN LINE1$=LINE1$(4,LEN(LINE1$))
17150 LINE2$=FN$:LINE2$(LEN(LINE2$)+1)=",":LINE2$(LEN(LINE2$)+1)=LINE1$
17160 XIO 32,#1,0,0,LINE2$
17170 GOTO 20000
17200 TRAP 20000:POSITION 2,12:? "ENTER FILE TO UNPROTECT:";:INPUT FN$
17210 IF FN$(2,2)<>":" AND FN$(3,3)<>":" THEN LINE1$=FN$:FN$="D:":FN$(3)=LINE1$
17220 XIO 36,#1,0,0,FN$:GOTO 20000
17300 TRAP 20000:POSITION 2,12:? "ENTER FILE TO PROTECT:";:INPUT FN$
17310 IF FN$(2,2)<>":" AND FN$(3,3)<>":" THEN LINE1$=FN$:FN$="D:":FN$(3)=LINE1$
17320 XIO 35,#1,0,0,FN$:GOTO 20000
19000 POSITION 2,12:? "Enter a filename":? "(8 char. or less)↑";:INPUT TEMP$
19010 IF LEN(TEMP$)>8 THEN GOTO 19000
19020 FN$="D:":FN$(3,3+LEN(TEMP$))=TEMP$:FN$(LEN(FN$)+1)=".FIT"
19030 TRAP 19100:OPEN #1,8,0,FN$
19040 PUT #1,FHEIGHT:PUT #1,FWIDTH:PUT #1,SIGNS
19070 POKE 850,11:POKE 852,0:POKE 853,FONTST:LN=SIGNS*(BYTES+1):POKE 857,INT(LN/256):POKE 856,LN-256*PEEK(857)
19080 X=USR(ADR("hhh*LVd"),16):CLOSE #1:GOTO 20000
19100 ? "↰ERROR - ";PEEK(195);" @ ";PEEK(186)+PEEK(187)*256:FOR A=1 TO 500:NEXT A:CLOSE #1:GOTO 20000
19200 POKE 752,1:TRAP 19100:OPEN #1,6,0,"D:*.FIT"
19210 FN=1:TXT$="":TXT$=" ":TXT$(48)=" ":TXT$(2)=TXT$:WIN=1:TY=10:LX=6:RX=15
19220 INPUT #1;FN$:IF FN$(2,2)<>" " THEN 19400
19230 TXT$((FN-1)*8+1,FN*8)=FN$(3,10):FN=FN+1:IF FN<6 THEN 19220
19240 TXT$(41,48)=" OTHER ":BY=17:GOSUB 28000:GOSUB 26000
19250 IF OPT=6 THEN GOSUB 27000:GOTO 19210
19260 FN$="D:":FN$(3,10)=TXT$((OPT-1)*8+1,OPT*8):FOR A=3 TO 10:IF FN$(A,A)=" " THEN POP :GOTO 19265
19263 NEXT A:A=11
19265 FN$(A,A+3)=".FIT"
19270 CLOSE #1:OPEN #1,4,0,FN$:GET #1,A:GET #1,B:GET #1,C
19275 L=A+B
19280 IF L<16 OR L>40 OR L/8<>INT(L/8) OR C>84 THEN POSITION 3,18:? "ERROR - NOT A FONT!↰↰↰":GOTO 20000
19285 FHEIGHT=A:FWIDTH=B:SIGNS=C
19290 BYTES=FWIDTH/8*FHEIGHT:LN=BYTES*(SIGNS+1):POKE 850,7:POKE 852,0:POKE 853,FONTST:POKE 857,INT(LN/256)
19300 POKE 856,LN-256*PEEK(857):X=USR(ADR("hhh*LVd"),16):CLOSE #1:GOTO 20000
19400 CLOSE #1:IF FN=1 THEN 20000
19410 TXT$((FN-1)*8+1,FN*8)=" EXIT ":BY=TY+FN+1:GOSUB 28000:GOSUB 26000:IF OPT=FN THEN 20000
19420 GOTO 19260
19500 TY=10:BY=16:LX=5:RX=11:WIN=1:TXT$="8x8 8x16 16x1624x16EXIT ":GOSUB 28000:GOSUB 26000
19510 IF OPT=5 THEN 20000
19520 FWIDTH=8:FHEIGHT=8:IF OPT>1 THEN FHEIGHT=16:IF OPT>2 THEN FWIDTH=16:IF OPT=4 THEN FWIDTH=24
19530 BYTES=FWIDTH/8*FHEIGHT:FOR A=FONTST*256 TO FONTST*256+BYTES-1:POKE A,0:NEXT A
19540 SIGNS=0:GOTO 20000
19600 TY=10:BY=14:LX=2:RX=12:WIN=1:TXT$="SIGNS: WIDTH: HEIGHT: ":TXT$(7)=STR$(SIGNS):TXT$(16)=STR$(FWIDTH)
19610 TXT$(26)=STR$(FHEIGHT):IF LEN(TXT$)<27 THEN TXT$(27)=" "
19620 POKE 752,1:GOSUB 28000:GOSUB 50:GOSUB 27000:GOTO 20000
20000 POKE 766,0:TXT$=" FONT GRAPHICS DOS EXIT ":? "↰":POKE 710,0:POKE 709,0:OPT=1
20005 POKE 752,1:GOSUB 20085:WIN=0
20010 CLOSE #1:TRAP 40000:LINE1$=TXT$
20020 X=USR(ADR(INV$),ADR(LINE1$)-1+(OPT-1)*10,10)
20030 POSITION 0,0:? LINE1$;:POKE 709,202
20040 GOSUB 100:IF NOT STRIG(0) THEN POSITION 0,0:? TXT$:GOTO OPT*200+19900
20050 IF STICK(0)<>11 AND STICK(0)<>7 THEN 20040
20060 IF STICK(0)=7 THEN OPT=OPT+1:IF OPT=5 THEN OPT=1
20070 IF STICK(0)=11 THEN OPT=OPT-1:IF OPT=0 THEN OPT=4
20080 POSITION 0,0:? TXT$:GOTO 20010
20085 POSITION 7,17:? "Antic Publishing presents:":POSITION 11,19:? "▌ANTIC PUBLISHER▌"
20090 POSITION 14,21:? "by Nadav Gur":RETURN
20100 LX=1:RX=8:TY=1:BY=8:TXT$=" EDIT EXTEND LOAD SAVE CREATESTATUS EXIT "
20110 GOSUB 28000:GOSUB 26000
20120 ON OPT GOTO 15000,15400,19200,19000,19500,19600,20000
20300 LX=11:RX=19:TY=1:BY=8:TXT$=" EDIT ERASE LOAD SAVE PRINT SPACE EXIT "
20310 GOSUB 28000:GOSUB 26000
20320 ON OPT GOTO 1000,16000,16200,16100,12000,14000,20000
20500 LX=21:RX=31:TY=1:BY=6:TXT$="DIRECTORY RENAME UNPROTECT PROTECT EXIT "
20510 GOSUB 28000:GOSUB 26000:ON OPT GOTO 17000,17100,17200,17300,20000
20700 TY=1:BY=3:LX=30:RX=39:TXT$="CONTINUE STOP ":R=PEEK(88)+PEEK(89)*256
20705 L=USR(MOV,ADR("|#/.4).5%|"),R+70,10,0):FOR L=1 TO 7:NEXT L:L=USR(MOV,ADR("|♥♥34/0♥♥|"),R+110,10,0)
20706 FOR L=1 TO 7:NEXT L:L=USR(MOV,ADR("ZRRRRRRRRC"),R+150,10,0)
20710 GOSUB 26000:IF OPT=2 THEN POKE 106,PEEK(740):GRAPHICS 0:END
20720 GOTO 20000
20999 END
26000 POKE 752,1:LN=RX-LX-1:OPT=1:MAX=BY-TY-WIN
26010 LINE1$=TXT$((OPT-1)*LN+1,OPT*LN)
26020 X=USR(ADR(INV$),ADR(LINE1$)-1,LEN(LINE1$))
26030 POSITION LX+1,TY+OPT-1+WIN:? LINE1$
26040 IF NOT STRIG(0) THEN POKE 752,0:RETURN
26050 IF STICK(0)=15 THEN 26040
26060 IF STICK(0)=14 AND OPT>1 THEN POSITION LX+1,TY+OPT+WIN-1:? TXT$((OPT-1)*LN+1,OPT*LN):OPT=OPT-1:GOTO 26010
26070 IF STICK(0)=13 AND OPT<MAX THEN POSITION LX+1,TY+OPT+WIN-1:? TXT$((OPT-1)*LN+1,OPT*LN):OPT=OPT+1:GOTO 26010
26080 GOTO 26040
27000 POKE 752,1
27010 LINE3$="":LN=RX-LX+1:FOR A=1 TO LN:LINE3$(A,A)=" ":NEXT A:FOR A=TY TO BY:POSITION LX,A:? LINE3$:NEXT A
27020 RETURN
28000 LN=RX-LX-1:LINE1$="":LINE2$="":LINE1$(1)="┌":LINE1$(LN+2,LN+2)="┐":LINE2$(1)="└":LINE2$(LN+2,LN+2)="┘"
28010 FOR A=2 TO LN+1:LINE1$(A,A)="─":LINE2$(A,A)="─":NEXT A:LINE3$="":LINE3$(1,1)="|":LINE3$(LN+2,LN+2)="|"
28020 HT=BY-TY-1
28030 IF NOT WIN THEN 28100
28040 Y1=INT((BY+TY)/2):Y2=Y1+1
28050 POSITION LX,Y1:? LINE1$:POSITION LX,Y2:? LINE2$
28060 FLAG=0:IF Y1>TY THEN LINE=Y1-TY:GOSUB 28500:Y1=Y1-1:POSITION LX,Y1:? LINE1$:POSITION LX,Y1+1:? LINE3$:FLAG=1
28070 IF Y2<BY THEN LINE=Y2-TY:GOSUB 28500:Y2=Y2+1:POSITION LX,Y2:? LINE2$:POSITION LX,Y2-1:? LINE3$:FLAG=1
28080 IF FLAG THEN 28060
28090 RETURN
28100 FOR Y=TY TO BY-1
28110 LINE=Y-TY+1:GOSUB 28500:POSITION LX,Y:? LINE3$:POSITION LX,Y+1:? LINE2$:NEXT Y
28120 RETURN
28499 END
28500 LINE3$(2,1+LN)=TXT$((LINE-1)*LN+1,(LINE-1)*LN+LN):RETURN
29900 REM WINDOWS: 28000 OPEN - PARAMETERS: WIN:1=WINDOW 0=MENU,LX- LEFT X,TY-TOP Y,RX - RIGHT X,BY-BOT. Y
29910 REM
29920 REM
31999 END
32000 DIM FN$(15),TXT$(640),INV$(24),LINE1$(40),LINE2$(40),LINE3$(40),TEMP$(10),KEY$(1),BIN$(34),TYPE$(202)
32005 DIM SWAP$(14):SWAP$="h.F▕,E▕▂E▕▘F▕◆"
32010 POKE 106,PEEK(106)-16:FONTST=PEEK(106):GRAPHICS 24:POKE 710,0:SC=PEEK(88)+256*PEEK(89)
32015 POKE 106,PEEK(106)-32:MOV=ADR("hh┐qh┐ph┐Uh┐Th┐oh┐nhh┐Q ♥1pEQ┌TfTP▕fUfpP▕fqFnPhFo♣d◆")
32020 FONTADR=FONTST*256:C710=14:C709=0
32030 FWIDTH=8:FHEIGHT=8:SIGNS=84:A=USR(MOV,57392,FONTADR,464,0)
32040 A=USR(MOV,58112,FONTADR+464,216,0)
32050 BYTES=8:DIM DUMP$(105),GRAF$(5):GRAF$="␛*┤♥▕":BS=1:REM 640 COLS.
32100 TYPE$="Xhh┐Lh┐Khh▔p╱hh▔q╱h▔s╱h▔r╱hh┐O-r╱)╲▔t╱┴Ns╱nr╱Nr╱Nr╱┴%Xmr╱┐M)♥eY┐N)♥▔u╱$O@▕♣┌◢┴%Mi(┐M)♥eN┐N"
32110 TYPE$(91,180)="◢Pp ♥1K▌v╱HLp╱Pu)♥▌v╱,t╱p┬"├Nv╱◢(◀v╱◢hlp╱♣ups(◢Pi┴%Mi(┐M)♥eN┐N ♥9v╱┌M┌MHLp╱♣spq┴%Kmp╱┐K)♥e"
32120 TYPE$(181)="L┐Lnu╱-u╱Mq╱p╲┴eOI@♣●◆"
32130 DUMP$="hh┐Nh┐Mh┐Lh┐K%X┴eK┐K%YeL┐L)(┐Q ├┤P ♥┤R1K$P◣◢P|◢&O(&O%R┴i(I p┐┐R(Pd%O┌MH┌M)▕┴eM┐M"
32140 DUMP$(81,105)=")♥eN┐NfP%PI▗PDfKP▕fLFQP6◆"
32170 DIM DEC$(37):DEC$="hh┐Mh┐L)♥┐K)♥┐N ♥1LI p╱%K┐N┐KFNH@◢Pm◆"
32180 BIN$="hhh┐Mh┐Lh┐K ♥┴╱M♣╱) ┌K0┤) ┌KH@◢Pf◆"
32190 INV$="hh┐Lh┐Khh(1KI p┤I♥┌K◢Ps◆"
32200 GOTO 20000
