WYSIWYG, print utility (WYSIWYG.BAS)
WYSIWYG, print utility by Chet Walters, 94
Description
WYSIWYG, print utility by Chet Walters, 94
From the Antic disk of November 1987 (Vol. 6 No. 7).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 11.4 KB
- Dialect
- Atari BASIC
- Lines
- 180
- Variables
K,P84,P85,A,B,J,PBF$,E$,PSET$,I,X,Q,AHI,ALO,DL,SIDE,A$,B$,CHSET,BIAS,DB,ROTCHAR,MV,TOPWIRE,CHAR,JKT,PBF,INV,C,EOR,NCR,P$,CIO$,MV$,R$,F$,EOR$,NCR$,JKT$,PRNTRS,CIO,VNTP,VVTP,SWAP,OFFSET,TEMPA,TEMPB
BASIC listing (180 lines)
2 REM WYSIWYG
4 REM BY CHET WALTERS
6 REM (c)1986, ANTIC PUBLISHING
10 GOTO 2000
15 GET #2,K:P84=PEEK(84):P85=PEEK(85):IF K=19 THEN GOSUB 340:GOTO 15
20 IF K=4 THEN GOSUB 480:GOTO 15
25 IF K=2 THEN GOSUB 430:GOTO 15
30 IF K=3 THEN GOSUB 130:K=155
35 IF K>253 OR K=156 OR K=157 OR K=125 THEN IF PEEK(93)<>82 THEN GOSUB 130:GOTO 15
40 IF K=27 THEN GOSUB 340:POKE 752,1:? "→";:GOTO 3000
45 IF K=1 THEN POKE 85,1:? "→";:GOTO 15
50 IF K=26 THEN POKE 85,27:? "←";:GOTO 15
55 IF K=127 THEN IF PEEK(85)<23 THEN GOTO 115
60 IF K=20 THEN A=B:P84=0:POKE 85,2:K=28:GOTO 110
65 IF K=5 THEN POKE 84,22:K=155:POKE 764,12:A=B+240:GOTO 95
70 IF K=155 AND P84<>23 THEN GOTO 95
75 IF K>31 THEN IF PEEK(93)=82 THEN GOSUB 320:GOTO 15
80 IF P84=23 AND K=29 THEN GOSUB 320:GOTO 15
85 IF K=6 THEN GOSUB 400:GOTO 15
90 IF K<28 OR K>126 THEN GOSUB 320:GOTO 15
95 IF P85=2 AND K=30 THEN POKE 85,27:GOTO 115
100 IF P85=26 AND K=31 THEN POKE 85,1
105 IF P85=27 AND K<>155 AND K<>126 THEN GOSUB 320:K=30
110 IF P84=0 AND K=28 THEN A=A-40*(A<>B):GOSUB 300:POKE 84,0:? "→←";:GOTO 15
115 ? CHR$(K);:IF PEEK(84)<>23 THEN GOTO 15
120 IF A<B+280 THEN POKE 84,22:A=A+40:GOSUB 300
125 GOTO 15:REM END EDITOR LOOP
129 REM CENTER/INSERT/DELETE
130 POKE 752,1:POKE 85,0:? "→";:J=A-B+P84*40+3:PBF$=E$(J,J+24):PSET$="♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥":IF K>3 THEN 160
140 FOR I=25 TO 1 STEP -1:IF PBF$(I,I)<>"♥" THEN POP :X=INT(I/2):PSET$(13-X)=PBF$:GOTO 290
150 NEXT I
160 IF K<254 THEN 210
170 Q=P85-1:POKE 85,Q:IF Q=26 THEN GOSUB 320:PSET$=PBF$:GOTO 290
180 IF Q=25 THEN PSET$=PBF$:PSET$(25,25)="♥":POKE 85,25:GOTO 290
190 IF K=255 THEN PSET$(1,Q)=PBF$:PSET$(Q+1,25)=PBF$(Q,25):PSET$(Q,Q)="♥":GOTO 290
200 PSET$(1,Q)=PBF$:PSET$(Q,Q+24)=PBF$(Q+1,25):GOTO 290
210 IF K<156 THEN 290
220 IF J=843 OR J=883 THEN GOSUB 320:PSET$=PBF$:GOTO 290
230 PBF$=PSET$:PSET$=E$:X=J:Q=J+40:FOR I=J TO 1242 STEP 40:IF I=763 THEN Q=Q+160
240 IF I=803 THEN J=J+160:I=I+160
250 IF K=156 THEN E$(J,J+24)=PSET$(Q,Q+24)
260 IF K=157 THEN PSET$(Q,Q+24)=E$(J,J+24)
270 J=J+40:Q=Q+40:NEXT I:PSET$(J)=PBF$:IF K=157 THEN E$=PSET$:J=X
280 PSET$=PBF$
290 E$(J,J+24)=PSET$:POKE 752,0:? "→";:RETURN
299 REM SCROLL EDITOR
300 AHI=INT(A/256):ALO=A-AHI*256:POKE DL,ALO:POKE DL+1,AHI:POKE 88,ALO:POKE 89,AHI:RETURN
319 REM SIGNAL - CAN'T TYPE
320 POKE 712,50:POKE 53247,50:FOR I=1 TO 5:NEXT I:POKE 694,0:POKE 712,0:RETURN
339 REM FLIP SIDES
340 J=PEEK(85):POKE 85,0:POKE 752,1:? "→";:IF NOT SIDE THEN A$=E$:POKE 710,140
350 IF SIDE THEN B$=E$:POKE 710,124
360 E$=A$:SIDE=(SIDE=0):IF SIDE THEN E$=B$
370 POKE 85,J+1:POKE 752,0:? "←";:POKE 709,0:RETURN
399 REM TOGGLE C-SET
400 IF PEEK(756)=224 THEN POKE 756,CHSET/256:RETURN
410 POKE 756,224:RETURN
429 REM TOGGLE BIAS
430 BIAS=(BIAS+1)*(BIAS<2):IF BIAS=0 THEN E$(478,479)="./"
440 IF BIAS=1 THEN E$(478,479)="#r"
450 IF BIAS=2 THEN E$(478,479)="-4"
460 RETURN
479 REM TOGGLE DOLBY
480 DB=(DB+1)*(DB<3):E$(439,439)=CHR$(34+(DB=2)+6*(DB=3)+12*(DB=0)):RETURN
499 REM MAKE NEW JACKET FORM
500 E$="♥":E$(1300)=E$:E$(2)=E$:A=ADR(E$):B=A:POKE 752,1:POKE 709,0:POKE 710,124:SIDE=0:POKE 756,CHSET/256
510 ? "↑/-/-/ WIPING JACKET FORM /-/-/";:J=1:FOR I=1 TO 1279 STEP 40:PBF$=" ":PBF$(1+(J<10),2)=STR$(J)
520 FOR Q=1 TO 2:PBF$(Q,Q)=CHR$(ASC(PBF$(Q,Q))+96):NEXT Q:X=USR(ROTCHAR,CHSET+104,3)
540 E$(I,I+1)=PBF$:J=J+(I<761 OR I>920):E$(I+2,I+26)="♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥":NEXT I:GOSUB 300
550 POKE 82,0:POKE 84,19:? :? "--─────────────────────────------------":? "->":? "->"
560 ? "--─────────────────────────------------";:POKE 82,27:POKE 84,20:? :? "<---TITLE":? "<-GOES HERE"
570 RESTORE 570:FOR I=0 TO 19:READ PBF$:POSITION 28,I:? PBF$;:NEXT I:DB=1:BIAS=1
580 DATA ->SIDE A<-,,CONTROL, T->TOF, E->EOF, A->BOL, Z->EOL, F->FONT, S->SIDE, C->CENTER
590 DATA D->DOLBY B, B->BIAS Cr,,SHIFT/CLEAR,ERASE LINE,, ESC FOR , MAIN MENU ,,->SIDE A<-
600 POKE 82,2:A$=E$:B$=E$:POKE 752,0:POKE 764,173
610 B$(31,36)="3)$%♥"":B$(791,796)=B$(31,36):RETURN
999 REM PRINT JACKET
1000 POKE 756,CHSET/256:POSITION 2,19:? "USE DISPLAYED FONT TO PRINT Y←";:GET #2,K:IF K=78 THEN POKE 756,224
1010 POSITION 2,19:? " PREPARE PRINTER AND PRESS ANY KEY ":POKE 752,1:? ,"ESCAPE TO ABORT"
1020 I=USR(MV,PEEK(756)*256,ADR(PSET$),1024):FOR J=0 TO 2*(TOPWIRE=128):I=USR(ROTCHAR,ADR(PSET$),128):NEXT J
1030 GET #2,K:IF K=27 THEN 3000
1040 TRAP 1010:CLOSE #1:OPEN #1,8,0,"P:":POSITION 1,19:? "↑":TRAP 3000
1050 CHAR=255:GOSUB 1400:GOSUB 1600:CHAR=0:GOSUB 1200:E$(2,8)="3)$%♥!♥":E$(53,59)="♥3)$%♥"":E$(12,18)=A$(433,439)
1060 E$(21,27)=A$(473,479):E$(34,40)=B$(433,439):E$(43,49)=B$(473,479):E$(17,17)="♥":E$(25,25)="♥"
1070 E$(39,39)="♥":E$(47,47)="♥":GOSUB 1400:GOSUB 1500:GOSUB 1600
1080 CHAR=0:GOSUB 1400:GOSUB 1700:GOSUB 1600
1090 FOR JKT=0 TO 19:GOSUB 1200:GOSUB 1300:GOSUB 1400:GOSUB 1500:GOSUB 1600:NEXT JKT
1100 CHAR=(TOPWIRE=1)+3+188*(TOPWIRE=1):GOSUB 1400:GOSUB 1700:GOSUB 1600
1110 CHAR=0:GOSUB 1400:GOSUB 1700:GOSUB 1600
1120 FOR JKT=21 TO 22:GOSUB 1200:GOSUB 1300:GOSUB 1400:GOSUB 1500:GOSUB 1600:NEXT JKT
1130 CHAR=0:GOSUB 1400:GOSUB 1700:GOSUB 1600
1140 CHAR=24:GOSUB 1400:GOSUB 1700:GOSUB 1600
1150 FOR JKT=24 TO 30:GOSUB 1200:GOSUB 1300:GOSUB 1400:GOSUB 1500:GOSUB 1600:NEXT JKT
1160 CHAR=255:GOSUB 1400:GOSUB 1600:? #1:CLOSE #1:GOTO 3000
1200 E$="♥":E$(59)=E$:E$(2)=E$:E$(1,1)="♥":E$(30,30)="|":E$(60,60)="♥":RETURN
1300 E$(4,28)=A$(40*JKT+3,40*JKT+27):E$(33,57)=B$(40*JKT+3,40*JKT+27):RETURN
1400 PBF$=CHR$(CHAR):PBF$(479)=PBF$:PBF$(2)=PBF$:RETURN
1500 PBF=ADR(PBF$):FOR X=1 TO 60:INV=0:C=ASC(E$(X,X)):IF C>127 THEN C=C-128:INV=255
1510 I=USR(EOR,PBF,ADR(PSET$)+8*C,INV):PBF=PBF+8:NEXT X:RETURN
1600 I=USR(NCR,ADR(PBF$),480,155):? #1;P$;PBF$:IF PEEK(764)=28 THEN POP :POKE 764,255:? #1:CLOSE #1:GOTO 3000
1610 RETURN
1700 FOR I=1 TO 8:PBF$(I,I)=CHR$(255):NEXT I:PBF$(473,480)=PBF$(1,8):PBF$(236,237)=PBF$(1,2):RETURN
1999 REM INITS. & CHOOSE PRINTER
2000 GRAPHICS 0:POKE 731,255:DL=PEEK(560)+256*PEEK(561)+4:CHSET=(PEEK(89)-8)*256:OPEN #3,12,0,"E:"
2010 OPEN #2,4,0,"K:":DIM A$(1300),B$(1300),E$(1300),PBF$(500),PSET$(1400),CIO$(30),MV$(57),R$(96),F$(30),P$(20)
2020 DIM EOR$(45),NCR$(60),JKT$(14):GOSUB 9000:GOSUB 5000:I=USR(MV,57344,CHSET,1024):JKT$="NONE"
2030 POKE 710,146:? "↰":RESTORE 2040:PRNTRS=2:FOR I=1 TO PRNTRS:READ P$:? I;"->";P$:? :NEXT I
2040 DATA EPSON,PROWRITER
2041 REM -----------------------------
2042 REM TO ADD PRINTERS TO THE ABOVE LIST, CHANGE THE >PRNTRS=2< IN 2030 TO THE # OF PRINTERS ON
2044 REM YOUR LIST, AND ADD THE NAMES TO THE ABOVE DATA STATEMENTS. THEN ADD DATA STATEMENTS NUMBERED
2045 REM BY ONES) AFTER 2102 WITH THE APPROPRIATE PRINTER CONTROL CODES
2046 REM (IN DECIMAL).
2047 REM -----------------------------
2050 ? "CHOOSE PRINTER->";:GET #2,K:K=K-48:P$="":J=1:RESTORE 2100+K:IF K<1 OR K>PRNTRS THEN 2030
2060 READ A:IF A<0 THEN TOPWIRE=ABS(A):GOSUB 5000:GOTO 3000
2070 P$(J,J)=CHR$(A):J=J+1:GOTO 2060
2098 REM -----------------------------
2099 REM LINEFEED=8 DOTS, HI-RES GRAPHICS=480 BYTE/LINE & USE NEGATIVE MSB OR LSB FOR TOP WIRE
2100 REM -----------------------------
2101 DATA 27,65,8,27,76,224,1,-128
2102 DATA 27,62,27,84,49,54,27,81,27,83,48,52,56,48,-1
2999 REM MAIN MENU
3000 TRAP 3000:CLOSE #1:GRAPHICS 0:POKE 710,0:POKE 756,CHSET/256:POKE 82,4:POKE 702,64:POKE 16,64:POKE 53774,64
3010 RESTORE 3000:FOR I=1 TO 10:READ PSET$:? PSET$:? :NEXT I:POKE 82,2:?
3020 DATA , WYSIWYG! CASSETTE JACKETS , ↑by Chet Walters
3030 DATA ,C-> CREATE NEW JACKET,E-> EDIT,S-> SAVE JACKET,L-> LOAD JACKET,P-> PRINT JACKET,F-> LOAD FONT
3040 POSITION 13,9:? JKT$:POSITION 2,20:? "↑↑↑↑ CHOICE->";:GET #2,K:IF K=96 THEN I=USR(MV,57344,CHSET,1024)
3050 IF JKT$="NONE" THEN IF K=69 OR K=83 OR K=80 THEN GOSUB 320:GOTO 3040
3100 IF K=67 THEN I=7:GOSUB 4400:GOSUB 4000:JKT$="JACKET":GOSUB 500:GOTO 15
3200 IF K=69 THEN J=32:A=B:SIDE=(SIDE=0):GOSUB 360:GOSUB 340:GOSUB 300:POKE 764,173:GOTO 15
3300 IF K<>83 THEN 3400
3310 I=11:GOSUB 4400:GOSUB 4100:TRAP 3000:GOSUB 4300:OPEN #1,8,0,F$:? #1;"JACKET"
3320 I=USR(CIO,16,11,ADR(A$),1300):I=USR(CIO,16,11,ADR(B$),1300):CLOSE #1:JKT$=F$(4):GOTO 3000
3400 IF K<>76 THEN 3500
3410 I=13:GOSUB 4400:GOSUB 4000:GOSUB 4100:GOSUB 4300:TRAP 3000:OPEN #1,4,0,F$:? "↑↑↑↑↑↑↑";
3420 INPUT #1;PBF$:IF PBF$<>"JACKET" THEN GOTO 3000
3430 GOSUB 500:I=USR(CIO,16,7,ADR(A$),1300):I=USR(CIO,16,7,ADR(B$),1300):JKT$=F$(4):E$=A$:GOTO 15
3500 IF K=80 THEN I=15:GOSUB 4400:GOTO 1000
3600 IF K<>70 THEN GOSUB 320:GOTO 3040
3610 I=17:GOSUB 4400:GOSUB 4100:OPEN #1,4,0,F$:POKE 756,CHSET/256:I=USR(CIO,16,7,CHSET,1024):CLOSE #1:GOTO 3000
4000 IF JKT$="NONE" THEN RETURN
4010 ? "WIPE CURRENT FORM? N←";:GET #2,K:IF K<>89 THEN POP :GOTO 3000
4020 RETURN
4100 POSITION 2,20:? " RETURN=MENU 1-9=DIRECTORY ":? "ENTER FILENAME->";
4110 INPUT #3;PBF$:IF PBF$="" THEN POP :GOTO 3000
4120 IF PBF$>"0" AND PBF$<":" THEN GOSUB 4200:GOTO 4100
4125 FOR I=1 TO LEN(PBF$):IF PBF$(I,I)=":" THEN F$=PBF$:POP :GOTO 4140
4130 NEXT I:F$="D1:":F$(4)=PBF$
4140 RETURN
4200 POKE 82,0:? "↰";:F$="D":F$(2)=PBF$:F$(3)=":*.*":? F$(1,3):TRAP 4230:CLOSE #1:OPEN #1,6,0,F$:TRAP 4220
4210 INPUT #1;F$:? F$,:GOTO 4210
4220 TRAP 4220:CLOSE #1
4230 POKE 82,2:? :RETURN
4300 F$(LEN(F$)+1)=".JKT":? F$;:RETURN
4400 POSITION 5,I:? "-->":POKE 84,20:? "↑";:RETURN
5000 NCR$="hh┐Oh┐Nh┐Mh┐Lh(h┐P1NEPP┤)└P╱I▔P▕)▘┌N┴%Ni├┐N%Oi♥┐OFLP]FM♣Y◆":NCR=ADR(NCR$)
5010 MV$="hh┐Lh┐Kh┐Nh┐Mh┐Ph┐O ♥&Pp▂1K┌M◢PyfLfNJPr$Op▘◢1K┌M◢Py1K┌M◆":MV=ADR(MV$)
5020 CIO$="hhh*hh↓B┘h↓E┘h↓D┘h↓I┘h↓H┘LVd":CIO=ADR(CIO$)
5030 R$="hh┐Mh┐Lhh┐N)├┐P"╲ ╲)♥┐O)♥┐Q1L%Pp╱%Q┐O┐O◢FQPo%O▄RJ╱PP\"╲ ╲5R┌L◢J♣x)◢┴eL┐L)♥eM┐MFNP9◆":ROTCHAR=ADR(R$)
5040 EOR=ADR(EOR$):IF TOPWIRE=1 THEN EOR$="hh┐Mh┐Lh┐Oh┐Nhh┐P ╲1NEP┌L◢♣w◆":RETURN
5050 EOR$="hh┐Mh┐Lh┐Oh┐Nh┐Qh┐P ╲┤R$Q1NEP$R┌LfQFR◢♣o◆":RETURN
9000 VNTP=PEEK(130)+PEEK(131)*256
9001 VVTP=PEEK(134)+PEEK(135)*256
9003 SWAP=1
9004 IF INT(ADR(A$)/2048)=INT((959+ADR(A$))/2048) THEN SWAP=65
9005 IF INT(ADR(B$)/2048)=INT((959+ADR(B$))/2048) THEN SWAP=66
9006 IF SWAP=1 THEN 9039
9007 POKE 710,0
9010 X=1:OFFSET=0:A=0:B=0
9015 IF PEEK(X+VNTP-1)<128 THEN 9030
9016 OFFSET=OFFSET+1
9020 IF A=0 AND PEEK(X+VNTP)=69 AND PEEK(X+VNTP+1)=164 THEN A=OFFSET:X=X+1
9025 IF B=0 AND PEEK(X+VNTP)=SWAP AND PEEK(X+VNTP+1)=164 THEN B=OFFSET:X=X+1
9030 IF X<100 THEN X=X+1:GOTO 9015
9031 REM
9032 TEMPA=PEEK(VVTP+(A*8)+2):TEMPB=PEEK(VVTP+(A*8)+3)
9033 POKE VVTP+(A*8)+2,PEEK((VVTP+(B*8)+2)):POKE VVTP+(A*8)+3,PEEK((VVTP+(B*8)+3))
9034 POKE VVTP+(B*8)+2,TEMPA:POKE VVTP+(B*8)+3,TEMPB
9039 RETURN
