Travel Planner (TRAVEL.BAS)

Travel Planner by J. Summers, 71 (BASIC, sample data)

Description

Travel Planner by J. Summers, 71 (BASIC, sample data)

From the Antic disk of November 1987 (Vol. 6 No. 7).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 7.9 KB

Dialect
Atari BASIC
Lines
168
Variables
PCOL, PROW, EXT, X, RECIP, DDIRECT, R$, I, VALUE, CL$, HEAD$, RONOFF$, LEFTCOL, LOC$, LINE$, NLOC, J, TABLE(, BRK, RPOS, LCOL, LROW, ADL, KEY$, COL, ROW, SLOC, ELOC, VLOC, VISIT(, CURTOT, V(, TOT, INDEX, K, FTRIP(, SP$, OPTION, DLIST, SCRMEM, LM, RM, UM, BM, Y
BASIC listing (168 lines)
10 REM TRAVEL PLANNER
20 REM BY J. SUMMERS
30 REM (c)1987, ANTIC PUBLISHING
98 GOSUB 20000
99 GOTO 10000
100 REM GETNUM
110 GOSUB 300:POKE 752,1:POSITION PCOL,PROW:? CHR$(30);CHR$(31);:EXT=0
115 POKE 752,0:? " ";
120 GET #1,X:IF X=155 THEN 230
122 IF X=126 THEN 160
124 IF X=82 THEN RECIP= NOT RECIP:GOTO 110
126 IF X=69 OR X=27 THEN EXT=1:RETURN
128 IF X>57 THEN 120
130 IF (X>47) OR (X=46) THEN 160
132 IF X=32 THEN 160
134 IF X>31 THEN 120
136 IF X<28 THEN 120
140 ON X-27 GOTO 190,200,210,220
150 STOP
160 ? CHR$(X);:GOTO 120
190 DDIRECT=4:GOTO 230
200 DDIRECT=2:GOTO 230
210 DDIRECT=3:GOTO 230
220 DDIRECT=1
230 POKE 752,1:R$="        ":FOR I=0 TO 7:LOCATE PCOL+I,PROW,X:IF X>127 THEN X=X-128
235 R$(I+1)=CHR$(X):NEXT I
240 VALUE=VAL(R$):RETURN
300 REM DISPLAY
310 ? CL$;HEAD$;RONOFF$(1+5*RECIP,5+5*RECIP)
320 ? ,:FOR I=LEFTCOL TO LEFTCOL+2:? LOC$((I-1)*8+1,I*8),:NEXT I
330 POSITION 2,2:? LINE$
340 FOR I=1 TO NLOC:POSITION 2,I+3:? LOC$(8*(I-1)+1,8*I),
350 FOR J=LEFTCOL TO LEFTCOL+2:? TABLE(J,I),:NEXT J:NEXT I
360 RETURN
500 IF  NOT BRK THEN POKE 16,112:POKE 53774,112
510 RETURN
800 CLOSE #5:OPEN #5,6,0,"D:*.*":? CL$;"    directory"
810 TRAP 850
820 GET #5,X:IF X=155 THEN ? "  ";:GOTO 820
830 PUT #16,X:GOTO 820
850 CLOSE #5:? :? "Press any key for menu"
860 GET #1,X:GOTO 10025
1000 REM CREATE TABLE
1005 TRAP 1005:GRAPHICS 0:POKE 710,2:POKE 709,188:GOSUB 500
1010 POSITION 5,10:? "Enter number of locations: ";:INPUT #16,NLOC
1020 IF NLOC<3 OR NLOC>20 THEN 1010
1025 FOR I=1 TO NLOC:FOR J=1 TO NLOC:TABLE(I,J)=0:NEXT J:NEXT I
1030 FOR I=1 TO NLOC:? "Enter name of location":? "8 characters max ________←←←←←←←←";
1040 RPOS=1
1041 GET #1,X:IF X=155 THEN 1050
1042 IF X=126 AND RPOS>1 THEN RPOS=RPOS-1:PUT #16,X:GOTO 1041
1045 R$(RPOS)=CHR$(X):PUT #16,X:RPOS=RPOS+1:IF RPOS<9 THEN 1041
1050 ? :IF LEN(R$)<8 THEN R$(LEN(R$)+1)="        "
1060 LOC$(8*(I-1)+1,8*I)=R$:NEXT I
1070 LEFTCOL=1:LCOL=1:LROW=1:PCOL=10:PROW=4:RECIP=1
1075 IF NLOC=0 THEN 4005
1080 DDIRECT=1
1090 GOSUB 100:IF EXT THEN GOTO 10025
1100 TABLE(LCOL,LROW)=VALUE:IF RECIP THEN TABLE(LROW,LCOL)=VALUE
1110 ON DDIRECT GOTO 1120,1130,1140,1150
1120 LCOL=LCOL+1:IF LCOL>NLOC THEN LCOL=NLOC:GOTO 1090
1122 IF LCOL>LEFTCOL+2 THEN LEFTCOL=LEFTCOL+1:GOTO 1090
1125 PCOL=PCOL+10:GOTO 1090
1130 LROW=LROW+1:IF LROW>NLOC THEN LROW=NLOC:GOTO 1090
1135 PROW=PROW+1:GOTO 1090
1140 LCOL=LCOL-1:IF LCOL<1 THEN LCOL=1:GOTO 1090
1142 IF LCOL<LEFTCOL THEN LEFTCOL=LEFTCOL-1:GOTO 1090
1145 PCOL=PCOL-10:GOTO 1090
1150 LROW=LROW-1:IF LROW<1 THEN LROW=1:GOTO 1090
1155 PROW=PROW-1:GOTO 1090
2000 POKE 752,0:POKE ADL+6,7:REM LOAD TABLE
2010 ? CL$;"     load                TABLE":POSITION 3,10:? "Enter filename to load using format"
2020 ? "       <dev>:<filename>.<ext> ":? :? "          ┌───────────────┐"
2021 ? "          |               |":? "          └───────────────┘"
2022 POSITION 4,18:? "(or press [RETURN] for directory)":POSITION 13,14:? "←→";
2023 POKE 752,1:INPUT #16,R$
2024 IF R$(1,2)="  " THEN 800
2030 TRAP 2900:CLOSE #2:OPEN #2,4,0,R$
2040 TRAP 2950:INPUT #2,R$:IF R$<>KEY$ THEN 2950
2050 INPUT #2,NLOC:LOC$(1)=" ":LOC$(160)=" ":LOC$(2)=LOC$(1):FOR I=1 TO NLOC
2060 INPUT #2,R$:LOC$(8*(I-1)+1,8*(I-1)+LEN(R$))=R$
2070 NEXT I:FOR COL=1 TO NLOC:FOR ROW=1 TO NLOC:INPUT #2,X:TABLE(COL,ROW)=X:NEXT ROW:NEXT COL
2090 CLOSE #2:GOTO 10025
2900 TRAP 2960:POKE 710,52:? :? "Error on opening file":CLOSE #2:GOTO 2960
2950 POKE 710,52:? :? "File not compatable with this program":CLOSE #2
2960 ? "Press any key for menu";:GET #1,X:GOTO 10025
3000 POKE 752,0:POKE ADL+6,7:REM SAVE TABLE
3009 IF NLOC=0 THEN 4005
3010 ? CL$;"     save                TABLE":POSITION 3,10:? "Enter filename to load using format"
3020 ? "       <dev>:<filename>.<ext> ":? :? "          ┌───────────────┐"
3021 ? "          |               |":? "          └───────────────┘"
3022 POSITION 4,18:? "(or press [RETURN] for directory)":POSITION 13,14:? "←→";
3023 POKE 752,1:INPUT #16,R$
3024 IF R$(1,2)="  " THEN 800
3030 TRAP 2900:CLOSE #2:OPEN #2,8,0,R$:? #2;KEY$:? #2;NLOC
3031 FOR I=1 TO NLOC:? #2;LOC$(8*(I-1)+1,8*I)
3040 NEXT I:FOR COL=1 TO NLOC:FOR ROW=1 TO NLOC:? #2;TABLE(COL,ROW):NEXT ROW:NEXT COL
3050 CLOSE #2:GOTO 10025
3500 REM EDIT TABLE
3505 TRAP 3505:GRAPHICS 0:POKE 710,2:POKE 709,188:GOSUB 500
3510 GOTO 1070
4000 REM SOLVE TABLE, PLAN THE TRIP
4005 IF NLOC=0 THEN POKE 710,52:? "No table in memory":GOTO 2960
4010 ? CL$;"  plan the trip":?
4020 FOR I=1 TO NLOC:? ,I;"   ";LOC$(8*(I-1)+1,8*I):NEXT I
4030 TRAP 4030:POSITION 2,21:? "Enter number of starting location: "
4032 INPUT #16,SLOC:IF SLOC<0 OR SLOC>NLOC THEN 4030
4034 POSITION 8,SLOC+1:? "S"
4035 TRAP 4035:POSITION 2,21:? "Enter number of final location:    "
4040 INPUT #16,ELOC:I=1:IF ELOC<0 OR ELOC>NLOC THEN 4035
4041 POSITION 9,ELOC+1:? "E"
4042 TRAP 4042:POSITION 1,20:? " Enter number of location to visit,"
4050 ? "end with 0:                    ":? "  ";:POSITION 15,21:? "→←";
4060 INPUT #16,VLOC:IF VLOC<0 OR VLOC>NLOC THEN 4042
4065 VISIT(I)=VLOC:I=I+1:IF I>NLOC THEN 4100
4066 POSITION 10,VLOC+1:? "●"
4070 IF VLOC>0 THEN 4042
4100 ? CL$;:POSITION 1,0:? "optimal trip route":POKE 710,22
4110 IF SLOC THEN ? "Start at    ";LOC$(8*(SLOC-1)+1,8*SLOC)
4115 IF I<=2 THEN CURTOT=TABLE(SLOC,ELOC):GOTO 4411
4119 FOR J=1 TO 10:V(J)=0:NEXT J:I=I-2:CURTOT=999999999:FOR J=1 TO I:V(J)=I-J+1:NEXT J
4200 TRAP 40000
4219 TOT=0:FOR J=1 TO I-1:TOT=TOT+TABLE(VISIT(V(J)),VISIT(V(J+1))):NEXT J
4220 TOT=TOT+TABLE(SLOC,VISIT(V(1)))+TABLE(VISIT(V(I)),ELOC)
4222 IF PEEK(764)=33 THEN POKE 559,34-PEEK(559):POKE 764,255
4225 IF TOT<CURTOT THEN 4500
4230 INDEX=1
4235 V(INDEX)=V(INDEX)+1:IF V(INDEX)>I THEN V(INDEX)=1:INDEX=INDEX+1:GOTO 4235
4240 IF INDEX>I THEN 4400
4250 FOR J=1 TO I
4260 FOR K=1 TO I:IF (K<>J) AND (V(K)=V(J)) THEN POP :POP :GOTO 4230
4270 NEXT K:NEXT J
4280 GOTO 4219
4400 FOR J=1 TO I:? "go to","  ";LOC$(8*(VISIT(FTRIP(J))-1)+1,8*VISIT(FTRIP(J)))
4410 NEXT J
4411 IF ELOC THEN ? "End at      ";LOC$(8*(ELOC-1)+1,8*ELOC)
4415 ? "Total mileage: ";CURTOT
4420 POKE 710,2:? "Press any key for menu"
4425 POKE 559,34:FOR X=75 TO 20 STEP -1:SOUND 0,X,14,14:NEXT X:SOUND 0,0,0,0:POKE 764,255
4430 GET #1,X:GOTO 10025
4500 FOR J=0 TO 9:FTRIP(J)=V(J):NEXT J:CURTOT=TOT
4510 GOTO 4230
9999 STOP
10000 DIM TABLE(20,20),LOC$(160),HEAD$(30),RONOFF$(10),LINE$(37),R$(30),CL$(1),KEY$(16)
10005 SOUND 0,0,0,0
10010 DIM FTRIP(10),V(10),VISIT(20),SP$(10)
10011 CL$=CHR$(125):LINE$(1)="-":LINE$(37)="-":LINE$(2)=LINE$(1):LOC$(1)=" ":LOC$(160)=" ":LOC$(2)=LOC$(1)
10012 RONOFF$="R OFFR  ON":HEAD$="Travel Planner by J. Summers ":KEY$="\SUMMERS\TRAVEL\"
10013 SP$="      "
10015 POKE 559,34:BRK=0:IF PEEK(53279)=5 THEN BRK=1
10020 CLOSE #1:OPEN #1,4,0,"K:":CLOSE #2
10025 GRAPHICS 0:POKE 710,2:POKE 709,188:PRINT CL$;
10026 GOSUB 500:ADL=PEEK(560)+256*PEEK(561):POKE ADL+3,PEEK(ADL+3)+5:POKE ADL+6,6
10027 ? "  travel planner      BY J. SUMMERS"
10030 ? :? SP$;"Select option by number":?
10040 ? SP$;"0 - Exit":? SP$;"1 - Create table":? SP$;"2 - Load a table"
10045 ? SP$;"3 - Save current table"
10050 ? SP$;"4 - Edit current table":? SP$;"5 - Find shortest trip":? :? SP$;"Select: ";
10060 TRAP 10025:INPUT #16,OPTION
10065 TRAP 40000
10070 IF OPTION=0 THEN GRAPHICS 0:END
10080 IF OPTION>5 THEN 10025
10090 ON OPTION GOTO 1000,2000,3000,3500,4000
20000 GRAPHICS 7+16:DLIST=PEEK(560)+256*PEEK(561):POKE DLIST+3,71:POKE DLIST+6,6
20005 SCRMEM=PEEK(88)+256*PEEK(89)
20030 LM=0:RM=159:UM=3:BM=90
20040 X=RM/2:Y=BM/2
20100 RETURN