Hot and Cold (HOTCOLD.BAS)

Hot and Cold, game by Heidi Brumbaugh, 33

Description

Hot and Cold, game by Heidi Brumbaugh, 33

From the Antic disk of November 1987 (Vol. 6 No. 7).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 4.0 KB

Dialect
Atari BASIC
Lines
106
Variables
I, X, S$, C(, TURN, M, M$, PEG, GUESS$, WHITE, BLACK, D$, J, MASTER$, MOVE
BASIC listing (106 lines)
10 REM HOT AND COLD
20 REM BY HEIDI BRUMBAUGH
30 REM (c)1987, ANTIC PUBLISHING
100 GOSUB 10000:REM INITIALIZE
120 FOR I=1 TO 4:X=INT(RND(0)*6)+1:S$(I)=CHR$(C(X)):NEXT I:TURN=1:REM NEW GAME
130 GOSUB 5000:REM DRAW BOARD
132 REM GAME LOOP
135 M=1:POKE 709,14:POKE 711,96
137 POSITION 14,8:? #6;"select":POSITION 14,10:? #6;M$
140 POKE 77,0:FOR PEG=1 TO 4
150 GOSUB 6000:REM GET GUESS FOR EACH PEG
160 POSITION PEG+2,(TURN*2):? #6;CHR$(C(M))
165 GUESS$(PEG)=CHR$(C(M)):X=2^2
170 NEXT PEG
172 GOSUB 1100:REM ERASE SELECT MENU
180 REM CONFIRM GUESS
190 POSITION 15,8:? #6;"OKAY":POSITION 16,10:? #6;"??"
200 POKE 711,14:POKE 710,157
210 POSITION 14,12:? #6;"yes"
220 POSITION 18,12:? #6;"NO"
230 POKE 710,157:POKE 711,14
235 POSITION 14,13:? #6;"▶▶▶   "
240 IF STRIG(0)=0 THEN 400
250 POKE 77,0:IF STICK(0)<>7 THEN 240
260 POKE 710,14:POKE 711,157
265 POSITION 14,13:? #6;"    __"
270 POKE 77,0:IF STRIG(0)=0 THEN 300
280 IF STICK(0)<>11 THEN 270
290 GOTO 230
300 POSITION 3,(TURN*2):? #6;"    ":GOSUB 1000:X=2^2:GOTO 135
400 GOSUB 1000:REM ERASE CONFIRM MSG.
410 GOSUB 2000:REM EVALUATE GUESS
420 POSITION 8,(TURN*2):? #6;WHITE;" ";BLACK
430 IF BLACK=4 THEN 600:REM CHECK FOR WIN
440 IF TURN<10 THEN TURN=TURN+1:GOTO 135:REM CHECK FOR LOSS
500 REM LOST
510 POSITION 14,2:? #6;"better"
520 POSITION 15,4:? #6;"luck"
530 POSITION 15,6:? #6;"next"
540 POSITION 15,8:? #6;"time"
545 POSITION 0,23:? #6;"the answer was ";S$
550 GOSUB 3000
560 POSITION 14,2:? #6;"      "
570 POSITION 15,4:? #6;"    "
580 POSITION 15,6:? #6;"    "
590 POSITION 15,8:? #6;"    "
592 POSITION 0,23:? #6;"                   "
595 GOTO 120
600 REM WON
605 POSITION 15,3:? #6;"good"
610 POSITION 15,5:? #6;"job!"
620 GOSUB 3000
630 POSITION 15,3:? #6;"    "
640 POSITION 15,5:? #6;"    "
650 GOTO 120
1000 POSITION 15,8:? #6;"    "
1010 POSITION 16,10:? #6;"  "
1020 POSITION 14,12:? #6;"      "
1030 POSITION 14,13:? #6;"      "
1040 RETURN
1100 POSITION 14,8:? #6;"      ":POSITION 14,10:? #6;"      "
1110 RETURN
2000 REM COUNT WHITES AND BLACKS
2010 WHITE=0:BLACK=0:D$=S$
2020 FOR I=1 TO 4
2030 IF D$(I,I)=GUESS$(I,I) THEN BLACK=BLACK+1:D$(I,I)=" ":GUESS$(I,I)=" "
2040 NEXT I
2050 FOR I=1 TO 4
2060 IF GUESS$(I,I)=" " THEN 2100
2070 FOR J=1 TO 4
2080 IF D$(J,J)=GUESS$(I,I) THEN WHITE=WHITE+1:D$(J,J)=" ":GOTO 2100
2090 NEXT J
2100 NEXT I
2110 RETURN
3000 REM PLAY AGAIN?
3010 POSITION 14,12:? #6;"BUTTON"
3020 POSITION 16,14:? #6;"TO":POSITION 15,16:? #6;"PLAY"
3030 IF STRIG(0)=1 THEN 3030
3040 POKE 77,0:POSITION 14,12:? #6;"      "
3050 POSITION 16,14:? #6;"  ":POSITION 15,16:? #6;"    "
3060 X=2^2:RETURN
5000 REM DRAW BOARD
5005 GRAPHICS 1+16
5007 POKE 708,30:POKE 712,148
5010 POSITION 2,0:? #6;"GUESS W H"
5030 FOR I=2 TO 20 STEP 2
5040 POSITION 0,I:? #6;INT(I/2)
5050 NEXT I
5060 FOR I=1 TO 11:POSITION 12,I*2-2:? #6;MASTER$(I,I):NEXT I
5100 RETURN
6000 REM SELECT PEG
6005 POKE 77,0:IF STRIG(0)=0 THEN 6005
6010 POSITION 13+M,10:? #6;CHR$(ASC(M$(M))+128)
6020 POKE 77,0:IF STRIG(0)=0 THEN 6500
6030 MOVE=STICK(0):IF MOVE<>7 AND MOVE<>11 THEN 6020
6040 IF MOVE=7 AND M=6 OR MOVE=11 AND M=1 THEN 6020:REM OUT OF RANGE
6045 POKE 53279,3:X=1^1
6050 POSITION 13+M,10:? #6;M$(M)
6060 IF MOVE=7 THEN M=M+1:GOTO 6010
6070 M=M-1:GOTO 6010
6500 POKE 77,0:IF STRIG(0)=0 THEN 6500
6510 RETURN
10000 DIM S$(4),C(6),M$(6),GUESS$(4),D$(4),MASTER$(11)
10010 FOR I=1 TO 6:READ X:C(I)=X:M$(I)=CHR$(X+128):NEXT I:MASTER$="!!!!!!!!!!!"
10100 RETURN
15000 DATA 4,10,11,3,1,28