Bibliography Writer (BIBWRITE.BAS)

Bibliography Writer by Alfred Filskov, 89

Description

Bibliography Writer by Alfred Filskov, 89

From the Antic disk of November 1987 (Vol. 6 No. 7).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 10.8 KB

Dialect
Atari BASIC
Lines
288
Variables
F0, F1, F2, F3, F4, F5, F6, F7, F8, F9, F10, F82, F249, F250, A$, B$, C$, IN$, US$, UC$, Q$, BK$, CL$, INV$, WAIT, MAX, J$, A, AMT, YES, NO, TYPE, LM, RM, LIN, CNT, LNTH, STRT, STP, UND, B, DEP, C, D, E, F
BASIC listing (288 lines)
10 REM BIBLIOGRAPHY WRITER
20 REM BY ALFRED FILSKOV
30 REM (c)1987, ANTIC PUBLISHING
40 READ F0,F1,F2,F3,F4,F5,F6,F7,F8,F9,F10,F82,F249,F250
50 DATA 0,1,2,3,4,5,6,7,8,9,10,82,249,250
60 DIM A$(F250),B$(F250),C$(F5),IN$(100),US$(F3),UC$(F3),Q$(F1),BK$(F250),CL$(F1),INV$(F1)
70 GRAPHICS F0:WAIT=F0:MAX=INT(FRE(F0)/F250-F8):DIM J$(MAX*F250)
80 INV$=" ":Q$=CHR$(34):CL$="↰":BK$=" ":BK$(F250)=" ":BK$(F2)=BK$
84 REM
85 REM US$=EPSON CONTROL CODES TO        START UNDERLINING.
86 REM UC$=EPSON CONTROL CODES TO        END UNDERLINING.
90 US$="␛-1":UC$="␛-0"
100 OPEN #F1,F4,F0,"K:":POKE 83,39
110 REM MAIN MENU
120 POKE 764,255:IF WAIT THEN ? :? "Press RETURN":INPUT #16;A$:POKE 767,F0:WAIT=F0
130 POKE 710,56:POKE 709,F0:POKE 752,F0:POKE F82,15
140 ? CL$:? "MAIN MENU":? "==== ====":POKE F82,F4
150 ? :? "1. Erase the current bibliography":? "2. Save the current bibliography"
160 ? "3. Load a bibliography":? "4. Delete a file"
170 ? "5. Disk directory":? "6. Print preview the bibliography"
180 ? "7. Print the bibliography":? "8. Store to word processor file"
190 ? "9. End program":GOSUB 2470
200 IF ((A=F1 OR A=F2 OR A=F6 OR A=F7 OR A=F8) AND  NOT AMT) OR A<F1 OR A>F9 THEN 120
210 ON A GOSUB 270,300,350,400,440,490,520,640,240
220 GOTO 120
230 REM QUIT
240 ? "End program...":GOSUB 2570:IF YES THEN GRAPHICS F0:END
250 RETURN
260 REM ERASE
270 ? "Erase current bibliography...":GOSUB 2570:IF YES THEN AMT=F0
280 RETURN
290 REM SAVE
300 ? "What do you want to name this file?":GOSUB 2610:IF WAIT THEN RETURN
310 OPEN #F2,F8,F0,A$:? "Saving..."
320 FOR A=F1 TO AMT:? #F2;J$(A*F250-F249,A*F250):NEXT A
330 CLOSE #F2:RETURN
340 REM LOAD
350 ? "What is the name of the file to load?":GOSUB 2610:IF WAIT THEN RETURN
360 OPEN #F2,F4,F0,A$:? "Loading...":AMT=F0:TRAP 380
370 INPUT #F2,A$:AMT=AMT+F1:J$(AMT*F250-F249)=A$:IF AMT<MAX THEN 370
380 CLOSE #F2:RETURN
390 REM DELETE
400 ? "Which file do you want to delete?":GOSUB 2610:IF WAIT THEN RETURN
410 GOSUB 2570:IF NO THEN RETURN
420 OPEN #F2,F4,F0,A$:? "Erasing...":XIO 33,#F2,F0,F0,A$:CLOSE #F2:RETURN
430 REM DIRECTORY
440 ? "Disk directory:":? :TRAP 2830
450 OPEN #F2,F6,F0,"D:*.*"
460 INPUT #F2,A$:? A$;"  ";:IF A$(F5,F8)="FREE" THEN CLOSE #F2:? :WAIT=F1:RETURN
470 GOTO 460
480 REM PRINT PREVIEW
490 TYPE=F1:POKE 752,F1:LM=F1:RM=36
500 ? "Press SPACE to pause, ESC to exit.":? :GOTO 680
510 REM PRINT
520 TYPE=F2:LIN=F1:? "Turn the printer on and position the  paper."
530 ? :? "If you want any control codes sent to the printer, type them and press"
540 ? "RETURN.  If not, just press RETURN.":INPUT A$
550 LM=F10:RM=70
560 TRAP 2840:CLOSE #F3:OPEN #F3,F8,F0,"P:":? #F3;A$:LIN=LIN+F1
570 FOR A=F1 TO F10:? #F3:LIN=LIN+F1:NEXT A
580 ? :? "If you want 'Bibliography' as the     title, just press RETURN.  If you"
590 ? "want a different title, type it and   press RETURN."
600 POKE 702,F0:GOSUB 2670:IF IN$="" THEN IN$="Bibliography"
610 ? #F3;BK$(F1,INT((RM+LM)/F2-LEN(IN$)/F2));IN$:? #F3:? #F3:? #F3:LIN=LIN+F4
620 ? "Printing...":GOTO 680
630 REM STORE TO A DISK FILE
640 TYPE=F3:? "What do you want to name the word     processor file?":GOSUB 2610
650 IF WAIT THEN RETURN
660 OPEN #F3,F8,F0,A$:? "Storing the file...":LM=F1:RM=59
670 REM PRINT BIBLIOGRAPHY
680 TRAP 2850:CNT=F0
690 CNT=CNT+F1:LNTH=F250:STRT=F1:B$=J$(CNT*F250-F249)
700 IF B$(LNTH-F9,LNTH)=BK$(F1,F10) THEN LNTH=LNTH-F10:GOTO 700
710 IF B$(LNTH,LNTH)=" " THEN LNTH=LNTH-F1:GOTO 710
720 STP=STRT+RM+F1-LM-F5*(STRT<>F1):IF STP>LNTH THEN STP=LNTH+F1
730 IF B$(STP,STP)=" " OR B$(STP,STP)=INV$ THEN 760
740 STP=STP-F1:IF STP<=STRT THEN STP=STRT+RM-LM-F5*(STRT<>F1):GOTO 760
750 GOTO 730
760 A$=B$(STRT,STP)
770 IF A$(F1,F1)=" " OR A$(F1,F1)=INV$ THEN A$=A$(F2):GOTO 770
780 IF A$(LEN(A$))=" " OR A$(LEN(A$))=INV$ THEN A$=A$(F1,LEN(A$)-F1):GOTO 780
790 ON TYPE GOTO 860,960,1180
800 IF STP<LNTH THEN STRT=STP+F1:GOTO 720
810 IF CNT<AMT THEN 690
820 IF TYPE=F1 THEN WAIT=F1
830 IF TYPE=F2 THEN FOR A=LIN TO 66:? #F3:NEXT A
840 CLOSE #F3:RETURN
850 REM DISPLAY THE LINE
860 IF STRT=F1 THEN ? :? "<SOURCE #";CNT;">":GOTO 880
870 ? "     ";
880 ? A$
890 IF PEEK(764)=28 THEN RETURN
900 IF PEEK(764)<>33 THEN 800
910 ? "<PAUSED--PRESS SPACE>":POKE 764,255
920 IF PEEK(764)=28 THEN RETURN
930 IF PEEK(764)<>33 THEN 920
940 POKE 764,255:GOTO 800
950 REM PRINT THE LINE
960 UND=F0:? #F3;BK$(F1,LM+F5*(STRT<>F1));
970 FOR A=F1 TO LEN(A$)
980 B=ASC(A$(A,A))
990 IF B<128 AND UND THEN ? #F3;UC$;:UND=F0
1000 IF B>=128 AND  NOT UND THEN ? #F3;US$;:UND=F1
1010 ? #F3;CHR$(B-128*(B>=128));
1020 NEXT A
1030 IF UND THEN ? #F3;UC$;
1040 ? #F3:? #F3:LIN=LIN+F2
1050 IF LIN<59 OR (CNT=AMT AND STP>=LNTH) THEN 800
1060 FOR A=LIN TO 71:? #F3:NEXT A:LIN=F6
1070 ? CL$:? "If you are using single sheets,"
1080 ? "insert a new sheet of paper so that"
1090 ? "the print head is 1 inch below the    top of the page."
1100 ? :? "Press RETURN for any of the following that are not necessary:"
1110 ? :? "What page is this";:GOSUB 1150
1120 ? "What is your name";:GOSUB 1150
1130 ? "What class is this for";:GOSUB 1150
1140 ? "Printing...":FOR A=F1 TO F3:? #F3:LIN=LIN+F1:NEXT A:GOTO 800
1150 GOSUB 2670:IF IN$<>"" THEN ? #F3;BK$(F1,RM-LEN(IN$)-F2);IN$:LIN=LIN+F1
1160 RETURN
1170 REM STORE LINE IN DISK FILE
1180 IF STRT>F1 THEN ? #F3;"     ";
1190 ? #F3;A$
1200 GOTO 800
1210 REM ENTRY MENU
1220 POKE 710,232:POKE F82,14:? CL$:? "ENTRY MENU":? "===== ===="
1230 POKE F82,F3:? :? "Which resource is source #";AMT+F1;" from?"
1240 POKE F82,F10:? :? "1. Book":? "2. Encyclopedia":? "3. Magazine":? "4. Newspaper"
1250 ? "5. Personal interview":? "6. None-Compose your own"
1260 GOSUB 2470:POKE 702,F0
1270 IF A<F1 OR A>F6 THEN 1220
1280 IF AMT=MAX THEN ? "Not enough memory.":WAIT=F1:GOTO 120
1290 B$="":? CL$
1300 IF A=F6 THEN 1950
1310 RESTORE 1320:FOR B=F1 TO A:READ A$:NEXT B
1320 DATA Book,Encyclopedia,Magazine,Newspaper,Interview
1330 ? BK$(F1,17-LEN(A$)/F2);A$:?
1340 READ B$:IF B$<>A$ THEN 1340
1350 A$="":DEP=F0
1360 READ TYPE:ON TYPE GOTO 1380,1420,1460,1510,1550,1590,1590,1720
1370 REM REGULAR ENTRY
1380 READ B$:? B$;"?"
1390 GOSUB 2670:IF IN$="" THEN 1390
1400 DEP=F0:GOTO 1690
1410 REM SUPERFLUOUS ENTRY
1420 READ B$:? B$;"?":? "  (Entry is not necessary)"
1430 GOSUB 2670:DEP=F0:IF IN$="" THEN DEP=F1:GOTO 1360
1440 GOTO 1690
1450 REM DEPENDENT ENTRY
1460 READ B$:IF DEP THEN 1360
1470 ? B$;"?":? "  (Entry is not necessary)":GOSUB 2670
1480 IF IN$="" THEN A$=A$(F1,LEN(A$)-F2):GOTO 1360
1490 GOTO 1690
1500 REM UNDERLINE ENTRY
1510 READ B$:? B$;"?"
1520 GOSUB 2670:IF IN$="" THEN 1520
1530 DEP=F0:FOR A=F1 TO LEN(IN$):IN$(A,A)=CHR$(ASC(IN$(A,A))+128):NEXT A:GOTO 1690
1540 REM BACK-UP 2 IF NO ENTRY
1550 READ B$:? B$;"?":? "  (Entry is not necessary)"
1560 GOSUB 2670:DEP=F0:IF IN$="" THEN DEP=F1:A$=A$(F1,LEN(A$)-F2):GOTO 1360
1570 GOTO 1690
1580 REM PUNCTUATION
1590 READ B$:IF DEP AND TYPE=F7 THEN 1360
1600 FOR A=F1 TO LEN(B$):C$=B$(A,A)
1610 IF C$="Q" THEN B$(A,A)=Q$
1620 IF C$="C" THEN B$(A,A)=","
1630 IF C$="_" THEN B$(A,A)=" "
1640 NEXT A
1650 IN$=B$:IF LEN(A$)=F0 THEN 1690
1660 C$=A$(LEN(A$)):IF C$="." OR C$="!" OR C$="?" THEN A$(LEN(A$))=CHR$(ASC(C$)-128)
1670 C$=A$(LEN(A$)):IF (C$="." OR C$="!" OR C$="?") AND B$(F1,F1)="." THEN IN$=B$(F2)
1680 REM BUILD A$
1690 IF LEN(IN$)<F250-LEN(A$) THEN A$(LEN(A$)+F1)=IN$:GOTO 1360
1700 ? :? "Source too long and not accepted!":GOTO 1750
1710 REM STOP
1720 ? "Entry complete.":? "Are there any mistakes (Y=yes)?";:GOSUB 2580
1730 IF NO THEN AMT=AMT+F1:J$(AMT*F250-F249)=A$:J$(LEN(J$)+F1)=BK$:GOTO 1220
1740 ? "Incorrect source not accepted!"
1750 ? :? "Press RETURN":INPUT A$:GOTO 1220
1760 DATA Book,2,Last name of author,7,C_,3,First name (and names of others)
1770 DATA 7,.__,4,Title of book,6,.__,1,City printed in,6,:_
1780 DATA 1,Printing company,6,C_,1,Year printed,6,C_
1790 DATA 5,Pages used (include p. or pp.),6,.,8
1800 DATA Encyclopedia,2,Last name of author,7,C_,3,First name,7,.__,6,Q
1810 DATA 1,Title of article,6,.Q__,4,Name of encyclopedia,6,.__
1820 DATA 1,Year printed,6,_ed.,8
1830 DATA Magazine,2,Last name of author,7,C_,3,First name,7,.__,6,Q
1840 DATA 1,Title of article,6,.Q__,4,Name of magazine,6,C_
1850 DATA 1,Full date (date month year),6,C_
1860 DATA 1,Pages used (include p. or pp.),6,.,8
1870 DATA Newspaper,2,Last name of author,7,C_,3,First name,7,.__,6,Q
1880 DATA 1,Title of article,6,.Q__,4,Name of newspaper,6,C_
1890 DATA 1,Full date (date month year),6,C_Sec._,1,Section,6,C_
1900 DATA 1,Pages used (include p. or pp.),6,C_
1910 DATA 1,Columns (include col. or cols.),6,.,8
1920 DATA Interview,1,Last name of person,6,C_,1,First name,6,.__
1930 DATA 1,Type (Personal or Telephone),6,_interview.__
1940 DATA 1,Full date (date month year),6,.,8
1950 REM COMPOSE YOUR OWN
1960 AMT=AMT+F1:? "   Compose your own bibliography"
1970 ? :? "You must type-in the source in its    correct format."
1980 ? :? "Press the INVERSE key at the":? "beginning and end of an underlined"
1990 ? "area.":? :? "Use DELETE to make corrections.":? :STRT=AMT*F250-F250
2000 FOR B=F1 TO 36:? "=";:NEXT B:? :A=F1
2010 GET #F1,B
2020 IF B<>126 THEN 2070
2030 IF A<>F1 THEN ? CHR$(126);:A=A-F1
2040 IF A=114 THEN RESTORE 2050:FOR C=F1 TO F5:READ D:? CHR$(D);:NEXT C
2050 DATA 28,30,32,28,30
2060 GOTO 2010
2070 IF B=155 THEN 2110
2080 IF B<32 OR B>250 OR (B>122 AND B<160) THEN 2010
2090 J$(STRT+A)=CHR$(B):? #F6;CHR$(B);:A=A+F1
2100 IF A<F249 THEN 2010
2110 IF A=F1 THEN AMT=AMT-F1:GOTO 1220
2120 J$(STRT+A)=BK$:GOTO 1220
2130 REM EDIT MENU
2140 POKE 710,168:POKE F82,15:? CL$:? "EDIT MENU":? "==== ===="
2150 POKE F82,F10:? :? "1. Move a source":? "2. Delete a source":? "3. Alphabetical sort"
2160 GOSUB 2470:TRAP 2140
2170 IF A<F0 OR A>F3 THEN 2140
2180 IF AMT+(A=F2)>F1 THEN ON A GOTO 2210,2310,2370
2190 ? "Not enough sources in memory.":WAIT=F1:GOTO 120
2200 REM MOVE A SOURCE
2210 ? "Which # source do you want to move    (1-";AMT;")?"
2220 INPUT A:IF A>AMT OR A<F1 OR A<>INT(A) THEN 2140
2230 ? :? J$(A*F250-F249,A*F250)
2240 ? :? "Where do you want to move it?":INPUT B
2250 TRAP 2820:IF B=A OR B>AMT OR B<F1 OR B<>INT(B) THEN 2140
2260 B$=J$(A*F250-F249)
2270 IF A>B THEN FOR C=A-F1 TO B STEP -F1:J$(C*F250+F1,C*F250+F250)=J$(C*F250-F249):NEXT C
2280 IF A<B THEN FOR C=A TO B-F1:J$(C*F250-F249,C*F250)=J$(C*F250+F1):NEXT C
2290 J$(B*F250-F249,B*F250)=B$:GOTO 2450
2300 REM DELETE A SOURCE
2310 ? "Which # source do you want to delete  (1-";AMT;")?"
2320 INPUT A:IF A<F1 OR A>AMT OR A<>INT(A) THEN 2140
2330 ? :? J$(A*F250-F249,A*F250):GOSUB 2570:IF NO THEN 2140
2340 AMT=AMT-F1:IF A>AMT THEN 2450
2350 J$(A*F250-F249)=J$(A*F250+F1):GOTO 2450
2360 REM ALPHABETIC SORT
2370 ? "Working...":FOR A=F1 TO AMT-F1:POSITION 13,F1:? AMT-A;" ":FOR B=A+F1 TO AMT
2380 C=(J$(A*F250-F249,A*F250-F249)=Q$):D=(J$(B*F250-F249,B*F250-F249)=Q$)
2390 FOR E=F1+C TO F5+C:F=ASC(J$(A*F250-F250+E,A*F250-F250+E)):B$(E-C)=CHR$(F-128*(F>=128)):NEXT E
2400 FOR E=F1+D TO F5+D:F=ASC(J$(B*F250-F250+E,B*F250-F250+E)):C$(E-D)=CHR$(F-128*(F>=128)):NEXT E
2410 IF B$<=C$ THEN 2440
2420 A$=J$(B*F250-F249):J$(B*F250-F249,B*F250)=J$(A*F250-F249)
2430 J$(A*F250-F249,A*F250)=A$
2440 NEXT B:NEXT A
2450 ? :? "DONE.";:FOR A=F1 TO 60:NEXT A:GOTO 2140
2460 REM GET A MENU OPTION
2470 POSITION F10,14:POKE F82,F9:? "    A - Main menu":? "     B - Entry menu":? "     C - Edit menu"
2480 ? :? "Sources in memory: ";AMT
2490 ? :? "Choose an option ->";
2500 POKE 16,112:POKE 53774,112:POKE 702,64:POKE F82,F2:GET #F1,A:IF A>=128 THEN A=A-128:POKE 764,39
2510 IF A>64 AND A<68 THEN A=A-37
2520 IF A=28 THEN POP :GOTO 120
2530 IF A=29 THEN POP :GOTO 1220
2540 IF A=30 THEN POP :GOTO 2140
2550 ? CL$:A=A-48:TRAP 2820:RETURN
2560 REM ARE YOU SURE?
2570 ? :? "Are you sure (Y=yes)?";
2580 YES=F0:NO=F0:GET #F1,B:IF B<>89 AND B<>121 THEN ? "N":NO=F1:RETURN
2590 ? "Y":? :YES=F1:RETURN
2600 REM GET FILENAME
2610 ? :? "D1:";:GOSUB 2670:IF  NOT LEN(IN$) THEN ? "No entry made!":WAIT=F1:RETURN
2620 IF LEN(IN$)<F4 THEN 2640
2630 IF IN$(F1,F1)="D" AND IN$(F3,F3)=":" THEN A$=IN$:GOTO 2650
2640 A$="D1:":A$(F4)=IN$
2650 TRAP 2830:RETURN
2660 REM INPUT ROUTINE
2670 IN$="":? ">";
2680 GET #F1,B
2690 IF B<>155 THEN 2730
2700 IF  NOT LEN(IN$) THEN 2800
2710 IF IN$(LEN(IN$))<>" " THEN 2800
2720 B=126
2730 IF B<>126 OR  NOT LEN(IN$) THEN 2760
2740 ? CHR$(126);:IF LEN(IN$)=F1 THEN IN$="":GOTO 2680
2750 IN$=IN$(F1,LEN(IN$)-F1)
2760 IF B>127 THEN B=B-128:POKE 764,39
2770 IF B<32 OR B>122 OR (B=32 AND  NOT LEN(IN$)) THEN 2680
2780 IF LEN(IN$)<100 THEN IN$(LEN(IN$)+F1)=CHR$(B):? CHR$(B);
2790 GOTO 2680
2800 FOR C=F1 TO F6:? :NEXT C:FOR C=F1 TO F5:? CHR$(28);:NEXT C:? :RETURN
2810 REM ERRORS
2820 ? :? "ERROR #";PEEK(195);" at line ";PEEK(186)+PEEK(187)*256:WAIT=F1:POP :GOTO 120
2830 ? :? "Disk access error!":WAIT=F1:CLOSE #F2:RETURN
2840 ? :? "Printer access error!":WAIT=F1:CLOSE #F3:RETURN
2850 ? :? "Error in printing!  Try deleting      source #";CNT:WAIT=F1:CLOSE #F3:RETURN