Antic Prompter (PROMPTER.BAS)

Antic Prompter by Heidi Brumbaugh, 70

Description

Antic Prompter by Heidi Brumbaugh, 70

From the Antic disk of October 1987 (Vol. 6 No. 6).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 8.5 KB

Dialect
Atari BASIC
Lines
209
Variables
SCR, OPT, T$, T2$, SEC, B, P, M, JOY, X, J, E, I, X$, S, B2, E2, R, A, ERR, ERL, IOERR, FNERR, MODE, N, BL$, C, LSCR, L
BASIC listing (209 lines)
10 REM ANTIC PROMPTER
20 REM BY HEIDI BRUMBAUGH
30 REM (c) 1987, ANTIC PUBLISHING INC.
40 REM (DO NOT RENUMBER THIS PROGRAM!)
50 GRAPHICS 0:SCR=PEEK(88)+256*PEEK(89)
100 GRAPHICS 2:POKE 712,148:POKE 708,202
110 POSITION 6,4:? #6;"ANTIC":? #6;"      PROMPTER":POKE 752,1
120 ? "By Heidi Brumbaugh↰←←←←←←←←←←←←←←←←←←▶▶▶▶▶▶▶▶▶↓↓"
130 GOSUB 10000:GOSUB 12000
510 ? "↰Main menu:"
520 ? "      1 - Screen editor"
530 ? "      2 - Save text to disk"
540 ? "      3 - Load file from disk"
550 ? "      4 - Prompt speech"
560 ? "      5 - Exit"
600 TRAP 640:? :? "Option";:INPUT OPT
610 ON OPT GOSUB 7000,3000,2000,700,32767:GOTO 510
640 ? :? "Please enter a number between 1 and 5.":GOTO 600
700 TRAP 40000
705 IF LEN(T$)>0 THEN ? "↰";:POSITION 10,5:POKE 752,1:? "One moment...":GOSUB 5300
710 IF LEN(T2$)>0 THEN GOSUB 1000:RETURN
720 ? "↰Please enter text (or the name of an":? "ASCII file) before using prompter."
730 SEC=1:GOSUB 14000:RETURN
999 REM MAIN SCROLL ROUTINE STARTS HERE
1000 TRAP 40000:REM DISABLE TRAP
1020 B=1:P=50:M=0:JOY=15:POKE 764,255
1025 GRAPHICS 18:POKE 708,84:POKE 710,122:POKE 709,84:POKE 711,122
1030 GOSUB 1510:REM DRAW FIRST SCREEN
1040 IF PEEK(644)=0 THEN M=0:X=2^2:GOTO 1200
1060 IF JOY=14 THEN M=20:GOSUB 1500
1070 IF JOY=13 THEN M=-20:GOSUB 1500
1080 IF JOY=7 THEN P=P+10:GOSUB 1500
1090 IF JOY<>11 THEN GOSUB 1500:GOTO 1100
1092 P=P-10:IF P<0 THEN P=0
1094 GOSUB 1500
1100 IF M=0 THEN 1200
1110 GOTO 1040
1200 REM STOPPED
1205 IF PEEK(764)<>255 THEN 1300:REM GET OUT
1210 JOY=PEEK(632):IF JOY=15 THEN 1205
1220 GOTO 1060
1300 POKE 764,255:FOR J=1 TO 100:NEXT J:RETURN :REM EXIT TELEPROMPTER HERE
1499 REM SCROLL UNTIL JOYSTICK OR TRIGGER PRESSED
1500 IF M=0 OR (E>=LEN(T2$)-19 AND M=20) OR (B=1 AND M=-20) THEN M=0:GOTO 1640
1510 B=B+M:E=B+119:JOY=15
1520 FOR I=1 TO 20
1530 X$(I,I)=CHR$(ASC(T2$(B+I-1,B+I-1))+128)
1540 NEXT I
1550 IF M=20 THEN 1570
1560 S=1:B2=B+39:E2=E:R=2:POSITION 0,0:? #6;X$(1,20):FOR J=1 TO P:NEXT J:GOTO 1580
1570 S=-1:B2=E:E2=B+20:R=10
1580 FOR I=B2 TO E2 STEP 20*S
1590 POSITION 0,R:? #6;T2$(I-19,I)
1610 FOR J=1 TO P:NEXT J:R=R+(2*S)
1617 IF JOY=15 THEN JOY=PEEK(632)
1618 IF PEEK(644)=0 THEN M=0
1620 NEXT I
1630 POSITION 0,0:? #6;X$(1,20)
1640 IF PEEK(764)<>255 THEN M=0:JOY=15:GOTO 1700
1650 IF JOY=15 THEN JOY=PEEK(632)
1660 IF PEEK(644)=0 THEN M=0
1670 IF JOY=15 AND M<>0 THEN 1500
1700 RETURN
2000 TRAP 40000:? "↰What is the filename";:INPUT X$
2010 TRAP 2100:CLOSE #1:OPEN #1,4,0,X$:I=1
2020 ? "↰";:POSITION 10,5:? "Reading file...";
2030 GET #1,A:IF A=155 THEN A=32:GOTO 2035
2032 IF A<32 OR (A>=123 AND A<=159) THEN 2030:REM IGNORE CONTROL CHARS
2035 T$(I)=CHR$(A):I=I+1:GOTO 2030
2040 ? "completed."
2045 SEC=1:GOSUB 14000:T2$=""
2050 RETURN
2100 ERR=PEEK(195):ERL=PEEK(187)*256+PEEK(186):CLOSE #1
2110 IF ERR=136 THEN 2040:REM EOF
2115 IF ERR=5 AND ERL=2035 THEN ? :? :? "File too long...truncating.":GOTO 2045
2120 IF ERR=170 THEN ? :? "Error-- file not found.":SEC=1:GOSUB 14000:RETURN
2130 IOERR=2050:FNERR=2000:GOTO 20030
3000 TRAP 40000:REM OUTPUT TEXT TO DISK FILE
3003 IF LEN(T$)>0 THEN 3010
3005 ? "↰Error-- you haven't entered text, or":? "have already used prompter."
3007 SEC=1:GOSUB 14000:RETURN
3010 TRAP 3500:REM SEE IF FILE EXISTS
3020 ? "↰File name";:INPUT X$
3030 OPEN #1,4,0,X$
3040 CLOSE #1
3050 ? "↰File already exists.":?
3060 ? "     1 - Overwrite file"
3070 ? "     2 - Append text to file"
3080 ? "     3 - Cancel"
3090 ? :? "What would you like to do";:TRAP 3110:INPUT OPT
3100 ON OPT GOTO 3200,3300,3400
3110 ? :? "Please enter 1, 2 or 3.":GOTO 3090:REM INVALID RESPONSE
3200 MODE=8:GOTO 3600
3300 MODE=9:GOTO 3600
3400 GOTO 3999
3500 IF PEEK(195)=170 THEN CLOSE #1:MODE=8:GOTO 3600:REM CREATE NEW FILE
3510 IOERR=3999:FNERR=3010:GOTO 20000
3600 REM WRITE TEXT TO FILE
3610 IOERR=3999:FNERR=3010:TRAP 20000:OPEN #1,MODE,0,X$
3620 ? #1;T$
3630 CLOSE #1
3999 RETURN
5299 REM PARSE STRING
5300 TRAP 5600:B=1
5320 E=21
5330 IF T$(E,E)=" " THEN 5340
5332 IF E>1 THEN E=E-1:GOTO 5330:REM FIND END OF 20 COLUMN LINE
5335 E=21
5340 T2$(B,B+E-2)=T$(1,E-1):B=B+E-1:REM PUT LINE INTO NEW TEXT STRING
5350 N=21-E:IF N>0 THEN T2$(B,B+N)=BL$(1,N):B=B+N:REM FILL TO END OF LINE
5360 IF T$(E,E)=" " THEN E=E+1:GOTO 5360:REM BEGINNING OF NEW LINE
5370 T$=T$(E,LEN(T$)):GOTO 5320:REM UPDATE OLD TEXT
5400 T2$(B,B+LEN(T$))=T$
5410 T2$(LEN(T2$)+1,LEN(T2$)+20-LEN(T$))=BL$(1,21-LEN(T$))
5500 FOR I=1 TO 4:T2$(LEN(T2$)+1)=BL$:NEXT I
5510 T2$(LEN(T2$)+1)="       *END*        ":T$=""
5599 RETURN
5600 TRAP 40000:ERL=PEEK(187)*256+PEEK(186):ERR=PEEK(195)
5610 IF ERL=5330 AND (ERR=9 OR ERR=5) THEN 5400
5620 IF ERL=5360 AND (ERR=9 OR ERR=5) THEN 5500
5630 ? "ERROR ";ERR;" AT LINE ";ERL;" .":END
7000 REM SCREEN EDITOR
7010 TRAP 40000:OPEN #1,4,0,"K:":POKE 82,0:? "↰";
7020 R=0:C=0
7030 GET #1,X
7040 IF X=255 OR X=157 THEN 7030:REM DISABLE INSERT MODE
7050 IF X=27 THEN 7500:REM EXIT WITH ESC
7060 IF X=155 AND R=23 THEN ? "↑";:REM THROW OFF CR AT END OF SCREEN
7070 IF X=30 AND C=0 THEN ? CHR$(X);
7080 ? CHR$(X);:R=PEEK(84):C=PEEK(85)+256*PEEK(86):REM PRINT CHARACTER AND ADJUST POSITION
7090 IF R=23 AND C>38 THEN POSITION 38,R:C=38:? CHR$(253);:REM CAN'T TYPE PAST END OF SCREEN
7100 IF C=39 THEN C=0:R=R+1:? CHR$(155);:REM LEAVE ONE SPACE AS RIGHT MARGIN
7110 GOTO 7030
7500 REM ESCAPE PRESSED; READ SCREEN VALUE
7510 CLOSE #1:POKE 752,1:? "→";
7530 I=SCR+LSCR
7540 IF PEEK(I)=0 THEN POKE I,10:I=I-1:GOTO 7540
7550 L=I-SCR+1:C=1
7560 FOR I=1 TO L
7565 IF INT(I/40)=I/40 THEN 7640
7570 X=PEEK(I+SCR-1)
7580 IF X<=63 THEN X=X+32:GOTO 7630
7590 IF X<=95 THEN X=X-64:GOTO 7630
7600 IF X<=127 THEN 7630
7610 IF X<=191 THEN X=X+32:GOTO 7630
7620 IF X<=223 THEN X=X-64:GOTO 7630
7630 IF X=155 THEN X=32
7635 T$(C,C)=CHR$(X):POKE I+SCR-1,10:C=C+1
7640 NEXT I
7650 POKE 752,0:T2$=""
7700 RETURN
10000 REM CALC. SCREEN
10010 LSCR=(24*40)-1
10100 L=2000:DIM T$(L),T2$(L+500),X$(255),BL$(20)
10110 BL$=" ":BL$(20)=BL$:BL$(2)=BL$
10999 RETURN
12000 GOSUB 13000
12020 GOSUB 5300:REM PARSE STRING
12030 T2$(LEN(T2$)-99)=BL$
12040 T2$(LEN(T2$)+1)="    (C) 1987        "
12050 T2$(LEN(T2$)+1)="       BY           "
12060 T2$(LEN(T2$)+1)=" ANTIC PUBLISHING   "
12070 T2$(LEN(T2$)+1)=BL$
12080 T2$(LEN(T2$)+1)="  PRESS ANY KEY     "
12090 T2$(LEN(T2$)+1)="   TO CONTINUE      "
12100 GRAPHICS 18:POKE 708,84:POKE 710,122
12110 P=50:M=0:B=1:JOY=15:TRAP 40000:POKE 764,255:GOSUB 1510
12120 M=20:GOSUB 1040
12130 T2$="":RETURN
13000 T$(1,85)="ANTIC CORDIALLY WELCOMES YOU TO THE ANTIC PROMPTER! THIS JOYSTICK-DRIVEN TELEPROMPTER"
13010 T$(86,170)=" IS EASY TO USE; SIMPLY TYPE IN YOUR TEXT (OR THE NAME OF AN ASCII FILE ON DISK) AND "
13020 T$(171,255)="YOU'RE READY TO GO! PUSH THE JOYSTICK UP TO MOVE FORWARD; IF YOU WANT TO GO BACKWARD "
13030 T$(256,340)="SIMPLY PULL THE JOYSTICK BACK. PRESSING THE TRIGGER TEMPORARILY STOPS MOVEMENT. TO SC"
13040 T$(341,425)="ROLL FASTER MOVE THE JOYSTICK LEFT; MOVE IT RIGHT TO SLOW THINGS DOWN. TO RETURN TO T"
13050 T$(426,466)="HE MAIN MENU JUST PRESS ANY CONSOLE KEY. "
13060 RETURN
14000 REM PAUSE
14010 POKE 19,0:POKE 20,0
14020 IF PEEK(19)<SEC THEN 14020
14100 RETURN
20000 TRAP 40000:REM DISABLE TRAP
20010 CLOSE #1:REM CLOSE CHANNEL
20020 ERR=PEEK(195):ERL=PEEK(187)*256+PEEK(186)
20030 IF (ERR>=138 AND ERR<=140) OR ERR=142 OR ERR=164 THEN 20200
20040 IF ERR=162 OR ERR=169 OR ERR=144 THEN 20300
20050 IF ERR=130 OR ERR=160 OR ERR=165 THEN 20400
20060 ? "Error--";ERR;" at line ";ERL;"."
20070 END :REM UNPREDICTED ERROR
20200 ? :? "I/O error # ";ERR;" has occurred"
20210 ? "while trying to access disk."
20220 ? "Check the disk and"
20230 ? "try again.":?
20240 SEC=3:GOSUB 14000:GOTO IOERR
20300 ? :? "I/O error # ";ERR;" has occurred"
20310 ? "while trying to write file."
20320 ? "The disk or directory is full, or"
20330 ? "the disk is write protected."
20340 ? "Please replace disk and try again.":?
20350 SEC=3:GOSUB 14000:GOTO IOERR
20400 ? :? "Illegal file name."
20410 ? "Filenames must be in the form:":?
20420 ? "    D:FILENAME.EXT":?
20430 ? "Where D: is the device name, filename"
20440 ? "is the name, which must begin with"
20450 ? "a capital letter and contain only"
20460 ? "letters and numbers, and .ext is the"
20470 ? "extension."
20480 ? :? "Please try again.":?
20490 SEC=3:GOSUB 14000:GOTO FNERR