Flash Cards (FLASH.BAS)
Flash Cards by Andy Barton, 35
Description
Flash Cards by Andy Barton, 35
From the Antic disk of October 1987 (Vol. 6 No. 6).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 4.3 KB
- Dialect
- Atari BASIC
- Lines
- 98
- Variables
MJIF,TLIM,TOT,CT,PAUSE,ERROR,REP,EX,X,Z,PS,A,SET,COR,SIGN$,MP,JIFF,ANS,XA,YA,KEY,CH,KEYCODE$,COUNT,BUZZ,CTUNE,STUNE,ETUNE,T,L,JIF,CH$,B,CB,SHIFT,G,REPEAT
BASIC listing (98 lines)
10 REM FLASH CARDS
15 REM BY ANDY BARTON
20 REM (c)1987, ANTIC PUBLISHING
30 GOTO 10000
50 IF PEEK(MJIF)<TLIM THEN RETURN
60 POP :TOT=TOT+1:POKE 712,68:CT=15
70 PAUSE=PAUSE+25:GOSUB 610
80 IF PAUSE<201 THEN POSITION 6,0:? #6;TOT:ERROR=REP:EX=X:GOTO 370
90 ? #6;"↰":POSITION 0,3:? #6;"HEY KID!! SPEED UP!!":FOR Z=1 TO 2500:NEXT Z:? #6;"↰"
100 GOTO PS
110 REM MAIN PROGRAM
120 REM ADDITION
130 X=INT(RND(0)*10):SETCOLOR 4,0,0:GOTO 240
140 A=X+SET:RETURN
150 REM SUBTRACTION
160 X=INT(RND(0)*10):X=X+SET:SETCOLOR 4,0,0:GOTO 240
170 A=X-SET:RETURN
180 REM MULTIPLY
190 X=INT(RND(0)*10):SETCOLOR 4,0,0:GOTO 240
200 A=X*SET:RETURN
210 REM DIVISION
220 X=INT(RND(0)*10):X=X*SET:SETCOLOR 4,0,0:GOTO 240
230 A=X/SET:RETURN
240 REM PART 2
250 POSITION 0,0:? #6;"TOTAL ";TOT:POSITION 0,1:? #6;"RIGHT ";COR
260 POSITION 12,0:? #6;"SET ";SET:POSITION 12,1:? #6;"COUNT ";CT;" "
270 IF ERROR>0 THEN ERROR=ERROR-1:IF ERROR/2=INT(ERROR/2) THEN SETCOLOR 4,3,10:X=EX:CT=CT+1
280 GOTO PS
285 REM PROBLEM SET UP - VERTICAL
290 POSITION 8,5:IF X<10 THEN ? #6;" ";
300 ? #6;X
310 POSITION 7,6:? #6;SIGN$;" ";SET
320 POSITION 7,7:? #6;"____"
330 GOTO 360
335 REM PROBLEM SET UP - HORIZONTAL
340 POSITION 5,6:IF X<10 THEN ? #6;" ";
350 ? #6;X;" / ";SET;" = "
360 GOSUB MP+10
370 POKE JIFF,0:POKE MJIF,0:ANS=0:POSITION XA,YA:? #6;" ":IF A<10 THEN 420
375 KEY=PEEK(CH):IF KEY=0 THEN KEY=1
380 GOSUB 50
390 IF KEYCODE$(KEY,KEY)=" " THEN 375
400 POKE CH,255:POSITION XA,YA:? #6;KEYCODE$(KEY,KEY)
410 ANS=10*VAL(KEYCODE$(KEY,KEY))
420 KEY=PEEK(CH):IF KEY=0 THEN KEY=1
430 GOSUB 50
440 IF KEYCODE$(KEY,KEY)=" " THEN 420
450 POKE CH,255:POSITION XA+1,YA:? #6;KEYCODE$(KEY,KEY)
460 ANS=ANS+VAL(KEYCODE$(KEY,KEY))
470 FOR Z=0 TO 100:NEXT Z:TOT=TOT+1
480 IF ANS<>A THEN POKE 712,68:CT=COUNT+1:PAUSE=BUZZ:GOSUB 620:POSITION 6,0:? #6;TOT:ERROR=REP:EX=X:GOTO 370
490 COR=COR+1:PAUSE=CTUNE:GOSUB 660
500 CT=CT-1
510 IF CT>0 THEN 540
520 CT=COUNT:SET=SET+1:PAUSE=STUNE:GOSUB 660
530 IF SET>9 THEN ? #6;"↰":POSITION 5,5:? #6;"GOOD WORK":PAUSE=ETUNE:GOSUB 660:FOR Z=0 TO 100:NEXT Z:RUN
540 GOTO MP
600 REM SOUND SUBS
610 REM BUZZER
620 FOR Z=1 TO PAUSE
630 SOUND 0,50,6,10
640 NEXT Z:GOTO 710
650 REM BELL
660 FOR Z=1 TO PAUSE
670 T=(INT(RND(0)*7)+1)*5+40
680 FOR L=14 TO 4 STEP -2
690 SOUND 0,T,10,L
700 NEXT L:NEXT Z
710 SOUND 0,0,0,0:RETURN
9990 REM INITIALIZE
10000 DIM KEYCODE$(256):KEYCODE$(1)=" ":KEYCODE$(256)=" ":KEYCODE$(2)=KEYCODE$
10010 KEYCODE$(24,31)="4 36 521":KEYCODE$(48,53)="9 07 8"
10020 CH=764:MJIF=19:JIF=20:DIM SIGN$(1)
10030 CLOSE #3:OPEN #3,4,0,"K:"
10040 GRAPHICS 2+16:SETCOLOR 0,13,6
10050 DIM CH$(1024):CH$(1)=" ":CH$(1024)=" ":CH$(2)=CH$
10060 A=ADR(CH$):B=INT(A/512+1)*2:CB=B*256-A+1
10070 SHIFT=ADR("hh┐qh┐ph┐Uh┐Th┐oh┐n ♥1p┌TfTP▕fUfpP▕fqFnPjFo♣f◆"):X=USR(SHIFT,57344,B*256,512):POKE 756,B
10080 CH$(CB+120,CB+127)="♥◢♥>♥◢♥♥"
10085 CH$(CB+448,CB+455)="♥B$┴┴$B♥"
10100 ? #6;"↰":POSITION 5,2:? #6;"+ aDD"
10110 POSITION 5,4:? #6;"- sUBTRACT"
10120 POSITION 5,6:? #6;"X mULTIPLY"
10130 POSITION 5,8:? #6;"/ dIVIDE"
10140 GET #3,G
10150 IF CHR$(G)="A" OR CHR$(G)="+" THEN SIGN$="+":MP=130:PS=290:XA=8:YA=8:GOTO 10200
10160 IF CHR$(G)="S" OR CHR$(G)="-" THEN SIGN$="-":MP=160:PS=290:XA=8:YA=8:GOTO 10200
10170 IF CHR$(G)="M" OR CHR$(G)="X" THEN SIGN$="X":MP=190:PS=290:XA=8:YA=8:GOTO 10200
10180 IF CHR$(G)="D" OR CHR$(G)="/" THEN SIGN$="/":MP=220:PS=340:XA=13:YA=6:GOTO 10200
10190 GOTO 10100
10200 ? #6;"↰":POSITION 4,1:? #6;"HI KID"
10210 POSITION 0,3:? #6;"WHAT SET DO YOU WANT"
10220 GET #3,G:IF G<49 OR G>57 THEN GOTO 10220
10230 ? #6;"↰"
10240 SET=VAL(CHR$(G)):TOT=0:COR=0:COUNT=15:CT=COUNT
10250 TLIM=5:REPEAT=3:REP=REPEAT*2-1
10260 CTUNE=5:STUNE=20:ETUNE=100:BUZZ=20
10270 GOTO MP
