Football Predictor (FBPRED.BAS)
Football Predictor by David Cowles & Bill Marquardt, 123
Description
Football Predictor by David Cowles & Bill Marquardt, 123
From the Antic disk of October 1987 (Vol. 6 No. 6).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 14.9 KB
- Dialect
- Atari BASIC
- Lines
- 356
- Variables
T,A(,B(,C(,D(,E(,F(,G(,H(,RO(,PO(,YO(,SO(,RD(,PD(,YD(,SD(,TN$,TEMP$,D$,K$,TS(,C$,P$,BL$,CT(,Z,LINE$,P,PRED$,I,W,KY,WK,K,GAME,C,CON,MV,A1,B1,C1,D1,E1,A2,B2,C2,D2,E2,F1,G1,F2,G2,R,RV,S,J,PR,LP,K1,K2
BASIC listing (356 lines)
10 REM FOOTBALL PREDICTOR
20 REM BY DAVID COWLES & BILL MARQUARDT
30 REM (c)1987, ANTIC PUBLISHING
100 REM INITIALIZATION
110 T=28:REM SET TO # OF TEAMS AT LINE 31700
120 DIM A(T),B(T),C(T),D(T),E(T),F(T),G(T),H(T)
140 DIM RO(T),PO(T),YO(T),SO(T),RD(T),PD(T),YD(T),SD(T)
150 DIM TN$(20*T),TEMP$(20),D$(15),K$(1),TS(2),C$(1),P$(40),BL$(5)
160 DIM CT(T):C$=CHR$(125):Z=0
170 DIM LINE$(40):LINE$(1,1)=CHR$(18):LINE$(40,40)=LINE$(1,1):LINE$(2)=LINE$
182 P=T/2*80:DIM PRED$(P):BL$=" "
185 FOR I=1 TO T/2:PRED$(80*I,80*I)=CHR$(155):NEXT I
200 TN$(1)=" ":TN$(20*T)=" ":TN$(2)=TN$
210 D$(1,3)="D1:":REM DATA DISK IS IN DRIVE #1
290 POKE 712,208
300 GRAPHICS 2:POKE 710,PEEK(712):POSITION 6,4:? #6;"FOOTBALL"
310 POSITION 6,5:? #6;"PREDICTOR"
320 POKE 752,1:? " FOR ENTERTAINMENT PURPOSES ONLY!"
330 ? " By David Cowles & Bill Marquardt"
340 ? " (c) 1987 by Antic Publishing"
350 FOR I=1 TO 1200:NEXT I
500 FOR I=1 TO T:READ TEMP$:TN$((I-1)*20+1,I*20)=TEMP$:NEXT I
510 ? C$:POKE 82,Z
520 POKE 764,255:? "Ensure proper disk is in Drive #";D$(2,2);" and"
530 ? " press RETURN ."
540 IF PEEK(764)=255 THEN 540
550 W=Z:TRAP 1200:REM SKIP "OPEN" IF NO FILE ON DISK
560 D$(4,11)="WKNUMBER":OPEN #1,4,0,D$:GET #1,W:CLOSE #1
600 IF W<1 THEN 1200
700 D$(4,11)="SEASTOTL":? C$:GOSUB 14500:GOSUB 14000
1200 REM MAIN MENU
1205 PRED$(1,1)=" ":PRED$(P,P)=PRED$:PRED$(2)=PRED$
1206 FOR I=1 TO T/2:PRED$(I*80,I*80)=CHR$(155):NEXT I
1210 GRAPHICS Z:POKE 82,Z:POKE 712,PEEK(710):CLOSE #1:TRAP 1200
1220 POKE 764,255:POKE 752,1
1230 ? LINE$;" Current week is Week #";W:? LINE$
1240 IF W=Z THEN ? " (No weekly data files were loaded.)":?
1250 ? "Select by number:":? :?
1260 ? " 1 ENTER data for Week #";W+1:?
1270 ? " 2 PREDICT scores for Week #";W+1:?
1280 ? " 3 REVIEW-PRINT-REVISE weekly stats":?
1290 ? " 4 REVIEW-PRINT season stats":?
1300 ? " 5 QUIT":?
1310 ? LINE$:? "Your selection =>";:INPUT KY
1320 IF KY<1 OR KY>5 THEN 1200
1330 ON KY GOTO 2000,4000,6000,8000,9000
2000 REM ENTER WEEKLY DATA
2010 WK=W+1
2050 FOR I=1 TO T:TRAP 2060
2060 ? C$;LINE$;" Entering stats for Week #";WK:? LINE$
2076 ? "Enter stats for: ";TN$((I-1)*20+1,I*20):?
2090 ? "Total yards gained rushing =>";:TRAP 2090:INPUT K:RO(I)=K
2100 ? "Total yards gained passing =>";:TRAP 2100:INPUT K:PO(I)=K
2110 YO(I)=RO(I)+PO(I):REM TOTAL YARDS GAINED
2120 ? "Total points scored =>";:TRAP 2120:INPUT K:SO(I)=K:?
2130 ? "Total yards given up rushing =>";:TRAP 2130:INPUT K:RD(I)=K
2140 ? "Total yards given up passing =>";:TRAP 2140:INPUT K:PD(I)=K
2150 YD(I)=RD(I)+PD(I):REM TOTAL YARDS "GIVEN-UP"
2160 ? "Total points given up =>";:INPUT K:SD(I)=K:?
2170 ? LINE$:? "Is this information correct (y/n)";:INPUT K$
2180 IF K$<>"Y" AND K$<>"y" THEN 2060
2190 NEXT I
3000 REM CREATE WEEKLY DATAFILE
3010 D$(4,11)="WKDATA ":D$(10,11)=STR$(WK):OPEN #1,8,0,D$
3020 GOSUB 12000:W=WK
3130 D$(4,11)="WKNUMBER":OPEN #1,8,0,D$
3140 PUT #1,WK:CLOSE #1:TRAP 3200
3150 D$(4,11)="SEASTOTL":GOSUB 15500:GOSUB 14000
3180 GOTO 1200
3200 ? "↰ERROR ";PEEK(195);"at line ";PEEK(186)+PEEK(187)*256:? :STOP
4000 REM PREDICT THE WINNERS
4001 ? C$;LINE$;" Predictions for Football Week #";W+1:? LINE$:TRAP 4000
4002 FOR I=1 TO T:CT(I)=Z:NEXT I:GAME=Z
4009 IF W=Z THEN ? :? "Cannot predict first week!":? :GOSUB 10500:GOTO 1200
4010 POKE 764,255:C=1:? C$
4014 POSITION 14,9:? "▂▂▂▂▂▂▂▂▂▂▂";:IF GAME>8 THEN ? "▂"
4015 POSITION 0,10:? LINE$;
4020 POSITION 14,10:? " GAME #";GAME+(GAME<(T/2));" "
4025 POSITION 14,11:? "▔▔▔▔▔▔▔▔▔▔▔";:IF GAME>8 THEN ? "▔"
4030 POSITION Z,12:? "Home Team"
4050 POSITION Z,14:? "Visitors "
4070 POKE 53279,7:C=1
4075 FOR I=1 TO T:POSITION Z,2
4076 POKE 764,255
4077 IF I>T THEN I=T:GOTO 4130
4078 IF GAME=(T/2) THEN ? C$;" I can only predict ";T/2;" games!":? :GOTO 4092
4079 IF CT(I)=1 THEN I=I+1:GOTO 4077
4080 ? " OPTION to scroll through teams":?
4090 ? " SELECT => ";TN$((I-1)*20+1,I*20):?
4092 IF GAME>Z THEN ? " START to print predictions.":?
4093 ? " ESC to quit"
4094 IF C<3 AND GAME<(T/2) THEN POSITION 10,10+C*2:? "=>"
4095 CON=PEEK(53279)
4096 IF PEEK(764)=28 THEN 1200:REM esc key
4100 IF CON=7 THEN 4110
4104 IF CON=6 AND GAME>Z THEN GOSUB 23000:GAME=Z:GOTO 1200
4105 IF CON=5 AND C<3 THEN TS(C)=I:POSITION 10,10+C*2:? TN$((I-1)*20+1,I*20):CT(I)=1
4106 IF CON<>3 THEN POKE 53279,7:C=C+1:GOTO 4130
4110 IF C>2 THEN I=T:GOTO 4130
4120 IF CON=7 THEN 4095
4130 NEXT I:IF C<3 THEN 4075
4140 POSITION 0,18:FOR I=1 TO 14:? :NEXT I
4150 IF MV THEN 4700
4500 REM PREDICT USING SEASON TOTALS
4505 A1=(A(TS(1))+E(TS(2)))/2
4510 B1=(B(TS(1))+F(TS(2)))/2
4520 C1=A1+B1
4525 IF D(TS(1))=Z THEN D(TS(1))=3
4530 D1=C(TS(1))/D(TS(1))
4535 IF H(TS(1))=Z THEN H(TS(1))=3
4540 E1=G(TS(1))/H(TS(1))
4550 A2=(A(TS(2))+E(TS(1)))/2
4560 B2=(B(TS(2))+F(TS(1)))/2
4570 C2=A2+B2
4575 IF D(TS(2))=Z THEN D(TS(2))=3
4580 D2=C(TS(2))/D(TS(2))
4585 IF H(TS(2))=Z THEN H(TS(2))=3
4590 E2=G(TS(2))/H(TS(2))
4600 F1=(D1+E2)/2
4610 G1=INT(C1/F1+0.5)
4620 F2=(D2+E1)/2
4630 G2=INT(C2/F2+0.5)
5000 REM DISPLAY WINNER
5005 GAME=GAME+1
5010 POSITION 34+(G1<10),3:? G1
5015 POSITION 34+(G2<10),5:? G2:?
5016 ? LINE$:? "The ";
5020 IF G1=G2 THEN GOSUB 5100:GOSUB 25000:GOTO 5030
5021 IF G1>G2 THEN ? TN$(((TS(1)-1)*20+1),TS(1)*20);" will defeat the ";
5022 ? TN$(((TS(2)-1)*20)+1,TS(2)*20);:IF G1>G2 THEN ? " by ";G1-G2;:GOTO 5024
5023 ? " will defeat the ";:? TN$(((TS(1)-1)*20+1),TS(1)*20);" by ";G2-G1;
5024 ? " point";:IF ABS(G1-G2)>1 THEN ? "s";
5030 ? "!":? :? LINE$
5032 IF G1>G2 THEN GOSUB 25000
5034 IF G2>G1 THEN GOSUB 26000
5035 IF GAME=1 THEN ? "(Print option coming up ...)":?
5045 POKE 764,255:? "Press any key ...";
5047 IF PEEK(764)=255 THEN 5047
5050 ? C$:GOTO 4010
5100 ? TN$(((TS(1)-1)*20+1),TS(1)*20);" versus the ";
5110 ? TN$(((TS(2)-1)*20+1),TS(2)*20);" is a toss-up";
5140 RETURN
6000 REM REVIEW PAST STATS.
6005 IF W=Z THEN 1200
6010 ? C$;LINE$;" Current week is Week #";W:? LINE$:TRAP 6010
6020 ? :? :? "Enter number of week you wish to review"
6030 POSITION 17,8:? "=>";:INPUT R
6040 IF R<1 OR R>W THEN 6010
6050 D$(4,11)="WKDATA ":D$(10,11)=STR$(R):OPEN #1,4,0,D$
6052 ? :? "Reading ";D$
6055 TEMP$=" Stats for week #":TEMP$(LEN(TEMP$)+1)=STR$(R)
6060 GOSUB 16000
6330 ? "Revise (correct) these stats (y/n)";:INPUT K$
6340 IF K$<>"Y" AND K$<>"y" THEN 7000
6350 ? C$:POSITION 12,0:? ">>> WARNING <<<<":?
6360 ? "Revised statistics will be saved to disk";
6370 ? "and become permanent file. This option"
6375 ? "should only be used to correct bad data"
6376 ? "entered earlier.":?
6377 ? "Do you wish to proceed (y/n)";:INPUT K$
6380 IF K$<>"Y" AND K$<>"y" THEN 7040
6382 RV=1
6385 ? C$;LINE$;"New statistics -":? TN$((S-1)*20+1,S*20);" Week #";R:? LINE$
6390 ? :? "Change:"
6400 ? RO(S);" rushing yds gained to =>";:TRAP 6400:INPUT K:RO(S)=K
6410 ? PO(S);" passing yds gained to =>";:TRAP 6410:INPUT K:PO(S)=K
6420 YO(S)=PO(S)+RO(S)
6430 ? SO(S);" points scored to =>";:TRAP 6430:INPUT K:SO(S)=K:?
6440 ? RD(S);" rushing yds given up to =>";:TRAP 6440:INPUT K:RD(S)=K
6450 ? PD(S);" passing yds given up to =>";:TRAP 6450:INPUT K:PD(S)=K
6460 YD(S)=PD(S)+RD(S)
6470 ? SD(S);" points given up to =>";:TRAP 6470:INPUT K:SD(S)=K
6471 ? :? LINE$:? :? "Is this information correct (y/n)";:INPUT K$
6472 IF K$<>"Y" AND K$<>"y" THEN 6385
6473 ? "Review stats for another team (y/n)";:INPUT K$
6474 IF K$="Y" OR K$="y" THEN 7060
6475 ? :RV=0:TRAP 40000
6480 OPEN #1,8,0,D$:GOSUB 12000:WK=R
6490 FOR I=1 TO T:A(I)=Z:B(I)=Z:C(I)=Z:D(I)=Z:E(I)=Z:F(I)=Z:G(I)=Z:H(I)=Z:NEXT I
6495 GOSUB 18000:GOTO 1200
7000 REM REPEAT CHOICE
7040 ? "Review stats for another team (y/n)";:INPUT K$
7045 IF K$<>"Y" AND K$<>"y" AND RV=1 THEN 6475
7050 IF K$<>"Y" AND K$<>"y" THEN POP :GOTO 1200
7060 GOSUB 16300:IF KY=3 THEN 6330
7070 GOTO 7000
8000 REM REVIEW SEASON TOTALS
8010 D$(4,11)="SEASTOTL":OPEN #1,4,0,D$:? "Reading ";D$
8020 TEMP$=" Season totals":GOSUB 16000
8030 GOSUB 7000:GOTO 8030
9000 REM EXIT PROGRAM
9010 POKE 752,Z:END
10000 REM PRINT STATS
10005 ? C$;LINE$;
10006 ? TN$((S-1)*20+1,S*20);TEMP$:? LINE$
10010 ? "Offense:"
10020 ? " rushing yards gained =>";BL$(1,5-LEN(STR$(RO(S))));RO(S)
10030 ? " passing yards gained =>";BL$(1,5-LEN(STR$(PO(S))));PO(S)
10050 ? " points scored =>";BL$(1,5-LEN(STR$(SO(S))));SO(S):?
10060 ? "Defense:"
10070 ? " rushing yards given up =>";BL$(1,5-LEN(STR$(RD(S))));RD(S)
10080 ? " passing yards given up =>";BL$(1,5-LEN(STR$(PD(S))));PD(S)
10100 ? " points given up =>";BL$(1,5-LEN(STR$(SD(S))));SD(S):?
10105 ? LINE$:GOSUB 10500:RETURN
10500 REM WAIT FOR KEYPRESS
10510 POKE 764,255:? "Press any key to continue ..."
10520 IF PEEK(764)=255 THEN 10520
10530 POKE 764,255:RETURN
12000 REM SAVE STATS
12003 ? :? "Saving ";D$
12005 FOR I=1 TO T
12010 K=RO(I):GOSUB 20000:K=PO(I):GOSUB 20000
12020 K=YO(I):GOSUB 20000:K=SO(I):GOSUB 20000
12030 K=RD(I):GOSUB 20000:K=PD(I):GOSUB 20000
12040 K=YD(I):GOSUB 20000:K=SD(I):GOSUB 20000
12090 NEXT I:CLOSE #1:RETURN
13000 REM READ DATAFILES
13005 IF D$(4,9)="WKDATA" THEN D$(10,11)=" ":D$(10,11)=STR$(J)
13010 OPEN #1,4,0,D$:? "Reading ";D$
13020 FOR I=1 TO T
13030 GOSUB 21000:A(I)=A(I)+K:GOSUB 21000:B(I)=B(I)+K
13040 GOSUB 21000:C(I)=C(I)+K:GOSUB 21000:D(I)=D(I)+K
13050 GOSUB 21000:E(I)=E(I)+K:GOSUB 21000:F(I)=F(I)+K
13060 GOSUB 21000:G(I)=G(I)+K:GOSUB 21000:H(I)=H(I)+K
13110 NEXT I:CLOSE #1:RETURN
13500 REM UPDATE "SEASON TOTALS" FILE
13510 D$(4,11)="SEASTOTL":OPEN #1,8,0,D$
13515 ? "Saving ";D$
13520 FOR I=1 TO T
13530 K=A(I):GOSUB 20000:K=B(I):GOSUB 20000
13540 K=C(I):GOSUB 20000:K=D(I):GOSUB 20000
13550 K=E(I):GOSUB 20000:K=F(I):GOSUB 20000
13560 K=G(I):GOSUB 20000:K=H(I):GOSUB 20000
13610 NEXT I:CLOSE #1:RETURN
14000 REM DETERMINE WEEKLY AVERAGES
14010 FOR I=1 TO T
14020 A(I)=A(I)/W:B(I)=B(I)/W
14030 C(I)=C(I)/W:D(I)=D(I)/W
14040 E(I)=E(I)/W:F(I)=F(I)/W
14050 G(I)=G(I)/W:H(I)=H(I)/W
14060 NEXT I:RETURN
14500 REM ENTER SEASON TOTALS
14510 FOR I=1 TO T:A(I)=Z:B(I)=Z:C(I)=Z:D(I)=Z
14515 E(I)=Z:F(I)=Z:G(I)=Z:H(I)=Z:NEXT I
14520 GOSUB 13000:RETURN
15500 REM UPDATE SEASON TOTALS
15510 IF W>1 THEN GOSUB 14500
15520 FOR I=1 TO T
15530 A(I)=A(I)+RO(I):B(I)=B(I)+PO(I)
15540 C(I)=C(I)+YO(I):D(I)=D(I)+SO(I)
15550 E(I)=E(I)+RD(I):F(I)=F(I)+PD(I)
15560 G(I)=G(I)+YD(I):H(I)=H(I)+SD(I)
15570 NEXT I:CLOSE #1
15580 GOSUB 13500:RETURN
16000 REM ENTER STATS.
16005 TRAP 40000
16010 FOR I=1 TO T
16020 GOSUB 21000:RO(I)=K:GOSUB 21000:PO(I)=K
16030 GOSUB 21000:YO(I)=K:GOSUB 21000:SO(I)=K
16040 GOSUB 21000:RD(I)=K:GOSUB 21000:PD(I)=K
16050 GOSUB 21000:YD(I)=K:GOSUB 21000:SD(I)=K
16095 NEXT I:CLOSE #1
16100 REM SELECTION & PRINTING
16110 ? C$;LINE$;" Reviewing ... ";TEMP$:? LINE$:? :TRAP 16100
16120 ? " 1 Print totals for all ";T;" teams":?
16140 ? " 2 Print totals for selected teams"
16145 IF KY=3 THEN ? " (includes revision option)"
16150 ? :? " 3 Return to Main Menu":?
16160 ? LINE$:? " Your selection =>";:INPUT K
16170 ON K GOTO 16200,16300,16800
16180 IF K<1 OR K>3 THEN 16110
16200 GOSUB 17000:GOTO 16110
16300 ? C$;LINE$;" Reviewing ... ";TEMP$:? LINE$:? :S=Z
16310 FOR I=1 TO T:POSITION 0,5
16320 ? " OPTION to scroll through teams":?
16330 ? " SELECT the ";TN$((I-1)*20+1,I*20):POKE 53279,7
16340 IF PEEK(53279)=5 THEN S=I:I=T:POKE 53279,7:GOTO 16360
16350 IF PEEK(53279)<>3 THEN 16340
16360 NEXT I:IF S<1 THEN 16310
16370 GOSUB 10000:RETURN
16800 POP :GOTO 1200
17000 REM PRINT STATS FOR ALL TEAMS
17002 ? :? "Use screen or printer (s/p)";:INPUT K$
17004 PR=Z:IF K$="P" OR K$="p" THEN PR=1
17010 POKE 764,255
17015 IF NOT PR THEN 17170
17020 ? :? "Set-up printer and press any key."
17030 IF PEEK(764)=255 THEN 17030
17035 CLOSE #2:OPEN #2,8,0,"P:"
17040 ? #2;TEMP$:? #2:? #2
17050 ? #2;" TEAM OFFENSE";
17060 ? #2;" DEFENSE":? #2
17070 ? #2;" RUSH PASS PTS";
17080 ? #2;" RUSH PASS PTS":? #2
17090 LP=7+T:FOR I=1 TO T
17100 ? #2;TN$((I-1)*20+1,I*20);" ";BL$(1,5-LEN(STR$(RO(I))));RO(I);BL$;
17110 ? #2;BL$(1,5-LEN(STR$(PO(I))));PO(I);BL$;
17120 ? #2;BL$(1,5-LEN(STR$(SO(I))));SO(I);BL$;
17130 ? #2;" ";BL$(1,5-LEN(STR$(RD(I))));RD(I);BL$;
17140 ? #2;BL$(1,5-LEN(STR$(PD(I))));PD(I);BL$;
17150 ? #2;BL$(1,5-LEN(STR$(SD(I))));SD(I)
17160 NEXT I:CLOSE #2:GOSUB 19500:GOTO 17180
17170 FOR S=1 TO T:GOSUB 10000:NEXT S:K$=""
17180 POKE 764,255:RETURN
18000 REM REVISE SEASON TOTAL FILES
18010 ? :? "Re-totalling all files - this may take"
18020 ? "a few minutes...":?
18030 D$(4,11)="WKDATA "
18040 FOR J=W TO 1 STEP -1:GOSUB 13000
18050 NEXT J:GOSUB 13500:GOSUB 14000:RETURN
19500 REM SKIP TO TOP OF PAGE
19510 FOR I=1 TO 66-LP
19520 LPRINT :NEXT I:LP=Z:RETURN
20000 REM CONVERT TO TWO BYTES
20010 K1=INT(K/256):IF K1>255 THEN K1=255
20015 PUT #1,K1
20020 K2=K-(K1*256):IF K2>255 THEN K2=255
20030 PUT #1,K2:RETURN
21000 REM RECONSTRUCT TWO-BYTE NUMBER
21010 GET #1,K1:K=256*K1
21020 GET #1,K2:K=K+K2
21030 RETURN
23000 REM PRINT PREDICTION REPORT
23010 ? C$;"Set-up printer and press any key ...":POKE 764,255
23011 IF PEEK(764)=255 THEN 23011
23012 TRAP 23000:POKE 764,255
23014 ? :? "How many copies";:INPUT K
23016 FOR J=1 TO K
23018 LPRINT " Football Predictions for Week #";W+1:LPRINT
23030 LPRINT " Favorite Underdog SPREAD":LPRINT
23040 LPRINT PRED$:LP=GAME+4
23050 GOSUB 19500:NEXT J
23060 TRAP 40000:RETURN
25000 REM FIRST TEAM IS FAVORITE
25010 PRED$((GAME-1)*80+1,GAME*80-60)=TN$(((TS(1)-1)*20+1),TS(1)*20)
25020 PRED$((GAME-1)*80+26,GAME*80-35)=TN$(((TS(2)-1)*20+1),TS(2)*20)
25030 PRED$(GAME*80-30+(1*(G1-G2)<10))=STR$(G1-G2):RETURN
26000 REM SECOND TEAM IS FAVORITE
26010 PRED$((GAME-1)*80+1,GAME*80-60)=TN$(((TS(2)-1)*20+1),TS(2)*20)
26020 PRED$((GAME-1)*80+26,GAME*80-35)=TN$(((TS(1)-1)*20+1),TS(1)*20)
26030 PRED$(GAME*80-30+(1*(G2-G1)<10))=STR$(G2-G1):RETURN
31700 REM 28 NFL teams - see LINE 110
31702 DATA Atlanta Falcons,Buffalo Bills
31704 DATA Chicago Bears,Cincinnati Bengals
31706 DATA Cleveland Browns,Dallas Cowboys
31708 DATA Denver Broncos,Detroit Lions
31710 DATA Green Bay Packers,Houston Oilers
31712 DATA Indianapolis Colts,Kansas City Chiefs
31714 DATA Los Angeles Raiders,Los Angeles Rams
31716 DATA Miami Dolphins,Minnesota Vikings
31718 DATA New England Patriots,New Orleans Saints
31720 DATA New York Giants,New York Jets
31722 DATA Philadelphia Eagles,Pittsburgh Steelers
31724 DATA San Diego Chargers,San Francisco 49ers
31726 DATA Seattle Seahawks,St. Louis Cardinals
31728 DATA Tampa Bay Buccaneers,Washington Redskins
