Checkbook Balancer (BALANCE.BAS)

Checkbook Balancer by Rod Saylor, 49

Description

Checkbook Balancer by Rod Saylor, 49

From the Antic disk of October 1987 (Vol. 6 No. 6).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 6.0 KB

Dialect
Atari BASIC
Lines
122
Variables
N, Q, C(, A(, CB(, Q$, L, E, Z, D, STR, X, K, J, NN, I, NB, NP, FX, STK, CH, DLY, ERR, ERL, TIM, A
BASIC listing (122 lines)
2 REM CHECKBOOK BALANCER
4 REM BY ROD SAYLOR
6 REM (c)1987, ANTIC PUBLISHING
10 TRAP 50:OPEN #3,4,0,"K:"
20 GRAPHICS 1:POKE 710,0:? #6:? #6:? #6:? #6;" rod's CHECKBOOK or":? #6:? #6;" checking made easy"
30 POKE 709,37:POKE 755,4:FOR N=1 TO 1500:NEXT N:POKE 755,0
40 ? " Written by Rod Saylor 1987 Germany":? :? "    Press any key to continue":GET #3,Q:Q=0
50 GRAPHICS 0:POKE 709,3:POKE 710,7:DIM C(100),A(100),CB(100),Q$(3):POKE 755,0
60 TRAP 160:REM TRAP TO MENU,SETUP SCREEN
70 POSITION 0,0:? " E#|CHECK #| AMOUNT | C/B BAL  |ACCOUNT";
80 POSITION 0,1:? "───┼───────┼────────┼──────────┤END BAL";
90 FOR L=2 TO 20
100 POSITION 0,L:? "   |       |        |          |";:NEXT L
110 POSITION 31,3:? "├────────";:POSITION 32,4:? "DEPOSIT";
120 POSITION 0,21:? "▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔";:GOTO 690
130 GOSUB 250:? "  display block(1-99),deposit(0)";:INPUT E:IF E=0 THEN 530
140 IF E>99 THEN 130
150 GOSUB 550
160 POKE 755,2:TRAP 160:GOSUB 250:? " 1-Enter 2-Delete 3-Change data";:INPUT Q$
170 IF Q$="1" OR Q$="E" THEN 360
190 IF Q$="2" OR Q$="D" THEN 460
210 IF Q$="3" OR Q$="C" THEN 130
230 IF Q$="Q" THEN GOSUB 1210
240 GOTO 260
250 POSITION 0,22:? "                                        ";:POSITION 0,22
255 POKE 16,112:POKE 53774,112:RETURN
260 GOSUB 250
270 ? " 4-Save 5-Retrieve 6-New 7-Print data";:INPUT Q$
280 IF Q$="S" OR Q$="4" THEN 600
300 IF Q$="R" OR Q$="5" THEN 690
320 IF Q$="N" OR Q$="6" THEN 790
330 IF Q$="Q" THEN GOSUB 1210
340 IF Q$="P" OR Q$="7" THEN GOSUB 820
350 GOTO 160
360 GOSUB 250:? " enter data  E#";:INPUT E:IF E>99 THEN 360
365 IF E<>INT(E) THEN 360
370 IF C(E)<>0 THEN 360
380 GOSUB 250:? "     check #";:INPUT Z:C(E)=Z:Z=0
390 GOSUB 250:? "    amount $";:INPUT Z:A(E)=Z:Z=0
400 GOSUB 250:? "E#";E;" check #";C(E);" for ";A(E);"$,SURE+";:INPUT Q$
410 IF  NOT (Q$="+" OR Q$="Y") THEN C(E)=0:A(E)=0:GOTO 360
420 GOSUB 450
430 GOSUB 550
440 GOTO 160
450 D=D-A(E):CB(E)=D:RETURN :REM FIG
460 GOSUB 250:? "***DELETE CHECK* E#";:GOSUB 900
470 GOSUB 250:? "*DELETE CHECK #";C(E);" $";A(E);" SURE-FIRE";:STR=STRIG(0)
480 IF STRIG(0)=0 OR PEEK(764)=12 THEN 510
490 IF STICK(0)<>15 OR PEEK(764)=28 THEN E=E-X+2:GOTO 160
500 GOTO 480
510 A(E)=0:C(E)=0:CB(E)=0
520 GOSUB 550:GOTO 460
530 GOSUB 250:? "  amount of deposit ";:INPUT Z:D=D+Z:POSITION 32,5:? "       ";:POSITION 32,5:? Z:Z=0
540 POSITION 32,7:? "BAL...";:POSITION 32,8:? "       ";:POSITION 32,8:? D:GOTO 790
550 FOR L=2 TO 20:REM PRT
560 POSITION 0,L:? "   ";:POSITION 4,L:? "      ";:POSITION 12,L:? "        ";:POSITION 21,L:? "        ":NEXT L
570 FOR L=2 TO 20:IF E+L>101 THEN 590
580 POSITION 0,L:? (L-2)+E:POSITION 4,L:? C((L-2)+E):POSITION 12,L:? A((L-2)+E):POSITION 21,L:? CB((L-2)+E)
590 NEXT L:RETURN
600 GOSUB 250:? "SAVE DATA, Y/N";:INPUT Q$:IF Q$<>"Y" THEN 160
610 GOSUB 250:? "       TOO LATE NOW, SAVING DATA       ";:TRAP 1000:POKE 77,128
620 CLOSE #1:OPEN #1,8,0,"D1:CHECK.DAT"
630 ? #1;D
640 FOR N=1 TO 100
650 L=C(N):K=A(N):J=CB(N)
660 ? #1;L:? #1;K:? #1;J
670 NEXT N
680 CLOSE #1:POKE 77,0:GOTO 160
690 GOSUB 250:GOSUB 1110:? "GETTING CHECKS, PLEASE WAIT":TRAP 1000:POKE 77,128:OPEN #1,4,0,"D1:CHECK.DAT"
700 INPUT #1;D
710 FOR NN=1 TO 100
720 INPUT #1;L:INPUT #1;K:INPUT #1;J
730 C(NN)=L:A(NN)=K:CB(NN)=J
740 NEXT NN
750 CLOSE #1:POKE 77,0:E=0
760 E=E+1:IF C(E)>0 THEN E=E:GOSUB 550:GOTO 540
770 IF E<99 THEN 760
780 E=1:GOSUB 550:GOTO 540
790 GOSUB 250:? "  working on new balance..standby....";
800 FOR I=1 TO 100:NB=NB+A(I):NEXT I:NB=NB+D
810 POSITION 32,2:? "        ";:POSITION 32,2:? NB:NP=NB:NB=0:GOTO 160
820 TRAP 970:LPRINT "   OUTSTANDING CHECKS":LPRINT
830 L=0:FOR L=1 TO 99
840 IF C(L)=0 THEN 860
850 LPRINT L,C(L),A(L),CB(L):FX=1
860 NEXT L
870 IF FX=0 THEN LPRINT "NO CHECKS IN MEMORY"
880 LPRINT :LPRINT "  NEW ACCOUNT END BAL$";NP
890 RETURN
900 X=3:POKE 764,255
910 STK=STICK(0):STR=STRIG(0):CH=PEEK(764)
920 POKE 752,1:IF (STK=14 OR CH=14 OR CH=142) THEN X=X-1:POKE 764,255:IF X<2 THEN X=20
930 IF (STK=13 OR CH=15 OR CH=143) THEN X=X+1:POKE 764,255:IF X>20 THEN X=2
940 POSITION 2,X:? "●":FOR DLY=1 TO 10:NEXT DLY:POSITION 2,X:? " "
950 IF STR=0 OR CH=12 THEN E=E+X-2:FOR DLY=1 TO 50:NEXT DLY:POKE 764,255:RETURN
960 GOTO 910
970 GOSUB 250:? "  ***NO PRINTER***";:FOR DLY=1 TO 200:NEXT DLY:GOTO 890
980 END
1000 ERR=PEEK(195):ERL=PEEK(186)+PEEK(187)*256:GOSUB 250:POKE 77,0:SOUND 0,150,10,15
1010 IF ERR=170 THEN ? " *** FILE NOT FOUND***";
1020 IF ERR=144 THEN ? "***DISK PROTECTED,NOT THERE***";
1030 IF ERR=136 THEN ? "*** END OF FILE ***";
1040 IF ERR=162 THEN ? "*** DISK FULL ***";
1050 IF ERR=167 THEN ? "*** FILE LOCKED ***";
1060 IF ERR=138 THEN ? "*** TURN ON DRIVE ***";
1070 IF ERR=139 THEN ? "*** DEVICE NAK ie:wrong density**";
1080 IF ERR=129 THEN ? "**IOCB ALREADY OPEN,CLOSED NOW**";
1090 ? ERR;:CLOSE #1
1100 FOR DLY=1 TO 400:NEXT DLY:TRAP 1000:SOUND 0,0,0,0:IF ERL<1110 THEN 160
1110 POKE 764,255:TRAP 1120:CLOSE #1:OPEN #1,4,0,"D1:CHECK.DAT":CLOSE #1:GOSUB 250:RETURN
1120 POKE 764,255:GOSUB 250:? "        Can't find D:CHECK.DAT!":FOR TIM=1 TO 200:NEXT TIM
1130 GOSUB 250:? "  Press [SPACEBAR] to create a new one":FOR TIM=1 TO 200:NEXT TIM
1140 GOSUB 250:? "       Press [ESCAPE] to re-try":FOR TIM=1 TO 200:NEXT TIM
1150 IF PEEK(764)=28 THEN 1110
1160 IF PEEK(764)=33 THEN 1180
1170 GOTO 1120
1180 GOSUB 250:? "Creating CHECK.DAT"
1190 POKE 764,255:TRAP 1000:CLOSE #1:OPEN #1,8,0,"D1:CHECK.DAT"
1200 FOR N=1 TO 301:? #1;A:NEXT N:CLOSE #1:GOSUB 250:RETURN
1210 GOSUB 250:? "  Are you sure you want to Quit";:INPUT Q$
1220 IF Q$<>"Y" THEN RETURN
1230 POP :GRAPHICS 0:END