Attack on the Doomstar (DOOMSTAR.BAS)
Attack on the Doomstar, game by David Plotkin, 104
Description
Attack on the Doomstar, game by David Plotkin, 104
From the Antic disk of September 1987 (Vol. 6 No. 5).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 12.7 KB
- Dialect
- Atari BASIC
- Lines
- 148
- Variables
SCORE,SD,B,HISCORE,F,F1,COL,ST,NUMH,RT,NUML,DL4,DL5,NN,N,Y3,YTEMP,Y,SIZEL,SH,Y2,X,X2,SIZEC,SIZEH,W,SH2,BLANK,XX,FF,SM,Y1,X1,LV,SH1,Q,SH4,SH3,X4,D,E$,P0,PB,P2,P1,P3,P4,XNEW,C,XN,IND,M,BYT,LIN,D$,STRT,PICT,MM,A,JNK,I,DL,DLIC,HI,LO,LBASE,CONSOL,WW
BASIC listing (148 lines)
5 REM DOOMSTAR
8 REM BY DAVE PLOTKIN
9 REM (c)1987, ANTIC PUBLISHING INC.
10 GOSUB 1500:SCORE=0:SD=1200:B=0:HISCORE=0:F=1:F1=1:GOSUB 800
90 COL=PEEK(708):POKE 708,PEEK(709):POKE 709,PEEK(710):POKE 710,COL
100 ST=PEEK(632):IF ((NUMH=RT AND ST=13) OR (NUMH=RT+4 AND ST=14)) THEN ST=15:GOTO 130
110 NUML=NUML+20*(ST=14)-20*(ST=13):NUMH=NUMH+(NUML>255)-(NUML<0):NUML=NUML+256*(NUML<0)-256*(NUML>255)
120 POKE DL4,NUML:POKE DL5,NUMH:NN=2*(ST=13)-2*(ST=14):N=N+NN:Y3=Y3+NN
130 YTEMP=Y:IF SIZEL=0 THEN 175
140 IF SIZEL>1 THEN SIZEL=SIZEL-1:Y=70*(SIZEL=2)+56*(SIZEL=1):SH=68*(SIZEL=2)+76*(SIZEL=1):GOTO 180
150 IF ABS(Y-Y2-7)<5 AND ABS(X-X2)<4 THEN SOUND 1,40,8,8:POKE 656,0:POKE 657,1:SCORE=SCORE+10:? SCORE:SIZEC=1.9
160 IF NOT (ABS(Y3-Y)<3 AND SIZEH<>0) THEN 170
164 POKE 707,82:SOUND 2,100,8,10:B=B+1:POKE 656,0:POKE 657,15:? B:FOR W=1 TO 100:NEXT W:IF B=5 THEN 700
170 SH=84:SOUND 2,0,0,0:SIZEL=0:Y=55
175 IF STRIG(0)=0 THEN SIZEL=3:Y=88:SOUND 2,10,8,8:SH=60
180 IF (SIZEC=0 AND INT((30-5*B)*RND(0))=0) THEN SIZEC=2:Y2=28:X2=120
190 IF SIZEC=0 THEN 280
200 IF SIZEC=2 THEN 210
202 SIZEC=SIZEC-0.1:Y2=Y2-2:X2=X2+5:POKE 53250,X2:F=F+1:IF F>4 THEN F=1
205 SH2=27*(F=1)+188*(F=2)+200*(F=3)+212*(F=4):SOUND 1,X2-120,10,10:IF SIZEC<>0 AND SIZEC<>1.8 THEN 240
207 SH2=BLANK:SOUND 1,0,0,0:GOTO 240
210 XX=RND(0):Y2=Y2+2*(Y2<78)*(ST=13)-2*(ST=14)*(Y2>20)+4*(XX>0.8)*(Y2<78)-4*(XX<0.12)*(Y2>20)
220 FF=FF+2*(X2<112)-2*(X2>130):X2=X2+FF:POKE 53250,X2:SH2=20*(Y2<65 AND Y2>43)+40*(Y2<=43)
225 IF (SIZEC=1.8 OR SIZEC=0) THEN SH2=BLANK:SOUND 1,40*(SIZEC=1.8),8,8*(SIZEC=1.8)
230 IF (SM=0 AND INT(RND(0)*(16-2*B))=0) THEN Y1=Y2:X1=X2-4:POKE 53249,X1:SM=1:SOUND 3,150,8,6
240 IF SM=0 THEN 280
250 Y1=Y1+2*(ST=13)*(Y1<78)-2*(ST=14):SM=SM+0.25*LV
255 SH1=BLANK*(SM=4)+128*(SM<4 AND SM>=3)+148*(SM<3 AND SM>=2)+168*(SM<2)
260 IF SM<>4 THEN 265
262 SOUND 3,0,0,0:IF NOT ((Y1>40-5*(LV=1) AND Y1<60+5*(LV=1))) THEN 265
263 SOUND 3,100,8,8:POKE 712,92:SD=SD-100*LV:FOR Q=1 TO 50:NEXT Q
265 IF SM=4 THEN SM=0:POKE 656,0:POKE 657,8:? SD;" ":POKE 712,0:SOUND 3,0,0,0
270 IF SD<0 THEN SD=0:POKE 656,0:POKE 657,8:? SD;" ":GOTO 600
280 F1=F1+1:IF F1=4 THEN F1=1
282 SH4=224*(F1=1)+232*(F1=2)+240*(F1=3)
285 IF SIZEH=0 THEN 320
290 IF SIZEH<1 THEN SIZEH=SIZEH+0.05:SOUND 0,20*SIZEH,10,6:GOTO 400
300 IF SIZEH=1 THEN Y3=34+N:SH3=372:SIZEH=2:SOUND 0,10,8,3:X4=X4+4*LV:FOR Q=0 TO 3:POKE 53252+Q,X4-4*Q:NEXT Q
305 IF Y3>85 THEN SH3=BLANK:SIZEH=0:GOTO 400+200*(X4>=132)
310 Y3=Y3+3:SH3=92*(Y3-N>=75)+104*(Y3-N>46 AND Y3-N<75)+116*(Y3-N<=46)
320 IF PEEK(19)>=10 THEN POKE 19,0:SIZEH=0.1:POKE 707,196
400 IF YTEMP<>Y THEN D=USR(ADR(E$),P0+YTEMP,PB+BLANK):D=USR(ADR(E$),P0+Y,PB+SH)
410 D=USR(ADR(E$)+50-25*(SIZEC<1.8),P2+Y2,PB+SH2):D=USR(ADR(E$)+50,P1+Y1,PB+SH1)
420 D=USR(ADR(E$)+25,P3+Y3,PB+SH3):D=USR(ADR(E$),P4,PB+SH4):GOTO 90
600 D=USR(ADR(E$),P0+YTEMP,PB+BLANK):D=USR(ADR(E$)+50,P2+Y2,PB+BLANK)
602 D=USR(ADR(E$)+50,P1+Y1,PB+BLANK):D=USR(ADR(E$)+25,P3+Y3,PB+BLANK)
605 IF SD>0 THEN 616
610 FOR W=1 TO 50:POKE 708,RND(0)*255:POKE 709,RND(0)*255:POKE 710,RND(0)*255
615 SOUND INT(RND(0)*4),RND(0)*255,8,8:NEXT W
616 NUML=PEEK(DL4):NUMH=PEEK(DL5)
620 IF NUMH-RT>=4 THEN 635
625 NUML=NUML+20:NUMH=NUMH+(NUML>255):NUML=NUML-256*(NUML>255)
630 POKE DL4,NUML:POKE DL5,NUMH:GOTO 620
635 FOR W=120 TO 1 STEP -1:SOUND 0,100,8,W/10:NEXT W
640 SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 2,0,0,0:SOUND 3,0,0,0
645 POKE 708,232:POKE 709,250:POKE 710,132:POKE 712,0:POKE 704,90
650 FOR XNEW=X4 TO 132:FOR Q=0 TO 3:POKE 53252+Q,XNEW-4*Q:NEXT Q:NEXT XNEW
655 FOR C=10 TO 100 STEP 10:FOR Y=30 TO 13 STEP -1:D=USR(ADR(E$),P0+Y,PB+13):SOUND 1,Y,6,8:NEXT Y
657 POKE P4+INT(RND(0)*8),PEEK(53770)
660 SOUND 0,120-C,8,8:POKE 711,C:FOR W=1 TO 75:NEXT W:NEXT C:SOUND 1,0,0,0
665 D=USR(ADR(E$),P0+13,PB+BLANK)
670 POKE 623,1:POKE 712,14:SOUND 0,140,8,8:FOR N=14 TO 0 STEP -1:SOUND 0,140-N*10,8,8:POKE 712,N
673 FOR NN=1 TO 30:NEXT NN:XN=XN+8:POKE 53252,132+XN:POKE 53255,120-XN:NEXT N:XN=0
677 FOR N=14 TO 0 STEP -1:SOUND 0,140-N*10,8,8:POKE 712,N:FOR NN=1 TO 30:NEXT NN:XN=XN+8
680 POKE 53253,128+XN:POKE 53254,124-XN:NEXT N:XN=0:FOR W=1 TO 500:NEXT W:POKE 53277,0:GRAPHICS 17
681 POKE 711,36
682 SOUND 0,0,0,0:POSITION 0,2:? #6;"the doomstar":? #6;"has destroyed":? #6;"your home base"
683 ? #6:? #6:? #6;" YOU lost!!!!!":? #6
684 IF SCORE>HISCORE THEN HISCORE=SCORE
685 ? #6:? #6;" FINAL SCORE ";SCORE:? #6;" points":? #6;" PRESS FIRE BUTTON":? #6;" TO PLAY AGAIN"
686 ? #6;" HIGH SCORE ";HISCORE
687 IF STRIG(0)=1 THEN 687
690 B=0:SCORE=0:SD=1200:F=1:F1=1:GOSUB 836:GOTO 90
700 D=USR(ADR(E$),P0+YTEMP,PB+BLANK):D=USR(ADR(E$)+50,P2+Y2,PB+BLANK)
701 D=USR(ADR(E$)+50,P1+Y1,PB+BLANK):D=USR(ADR(E$)+25,P3+Y3,PB+BLANK)
703 SOUND 1,0,0,0:SOUND 2,0,0,0:SOUND 3,0,0,0
705 NUML=PEEK(DL4):NUMH=PEEK(DL5):FOR W=1 TO 10:IND=40*(W/2=INT(W/2))-40*(W/2<>INT(W/2))
710 NUML=NUML+IND:NUMH=NUMH+(NUML>255)-(NUML<0):NUML=NUML-256*(NUML>255)+256*(NUML<0)
715 SOUND 0,W*20,8,8:POKE DL4,NUML:POKE DL5,NUMH
720 FOR M=1 TO 100:NEXT M:NEXT W:D=USR(ADR(E$),PB+394,PB+BLANK):POKE 53277,0:BYT=7:LIN=23
725 D$(1)="♥♥♥▄♥♥♥♥♥├jP♥♥♥♥▎?%♥♥♥♥kUz@♥♥├=j_ ♥♥╱V?%d♥♥␛kUzy♥♥␛mU^y♥♥m5▶W←@♥m5*┬←@├6W▶ug♣├4R"
726 D$(81)="*!G♣├6W▶ug♣♥m5*┬←@♥m5▶W←@♥␛mU^y♥♥␛kUzy♥♥╱V?%d♥♥├=j_♣♥♥♥kUz@♥♥♥▎?%♥♥♥♥├jP♥♥♥♥♥▄♥♥"
727 D$(161)="♥":POKE DL4,0:POKE DL5,RT+1:STRT=256*(RT+1)+10*20+6:D=USR(PICT,STRT,ADR(D$),BYT,LIN,20)
728 FOR N=1 TO 150:NEXT N
730 FOR NN=1 TO 200:SOUND 0,NN,8,14:SOUND 1,NN+10,8,14:POKE 712,14-NN/15:NEXT NN:FOR NN=1 TO 36:COL=PEEK(708)
732 POKE 708,PEEK(709):POKE 709,PEEK(710):POKE 710,COL:SOUND 0,NN*6,8,14:SOUND 1,NN*5,8,14
735 FOR MM=1 TO 15:NEXT MM:NEXT NN:POKE 712,0
736 FOR Q=0 TO 2:FOR N=14 TO 0 STEP -1:POKE 708+Q,N:SOUND 0,140-10*N,8,14
740 SOUND 1,152-10*N,8,14:FOR NN=1 TO 30:NEXT NN:NEXT N:FOR NN=1 TO 50:NEXT NN:NEXT Q
745 FOR N=14 TO 0 STEP -1:SOUND 0,140,8,N:SOUND 1,152,8,N:FOR NN=1 TO 30:NEXT NN:NEXT N
775 GRAPHICS 17:POSITION 3,3:? #6;"CONGRATULATIONS WARRIOR":? #6;" YOU HAVE DESTROYED":? #6;" THE"
780 ? #6;" doomstar":GOTO 684
800 DIM D$(650),E$(80)
805 E$="hh┐Lh┐Kh┐Oh┐N ♥1N┌KH@◢Pw◆hh┐Lh┐Kh┐Oh┐N ♥1N┌KH@▘Pw◆hh┐Lh┐Kh┐Oh┐N ♥1N┌KH@●Pw◆"
810 A=PEEK(106)-20:POKE 54279,A:PB=256*A:POKE 53761,168:POKE 53763,168
811 POKE 20,0:FOR A=PB TO PB+247
813 JNK=USR(ADR("h%●◣▔♥RI▶▔▕R▔E▕◆"))
814 READ I:POKE A,I:NEXT A:POKE 709,14
815 DATA 0,0,0,0,0,0,129,129,153,231,231,153,129,129,0,0,0,0,0,0,0,0,0,0,0,0,0,66,90,102,90,66,0,0,0,0,0,0,0,0
816 DATA 0,0,0,0,0,0,0,0,36,60,36,0,0,0,0,0,0,0,0,0,24,24,60,60,60,126,255,219,0,24,24,24,60,126,90,0
820 DATA 0,0,16,16,56,40,0,0,0,0,16,16,124,16,16,0,0,0,0,0,0,24
821 DATA 60,126,255,126,60,24,0,0,0,0,0,24,60,126,60,24,0,0
823 DATA 0,0,0,0,0,24,60,24,0,0,0,0,0,0,24,60,36,126,189,90,90,165,255,165,90,90,189,102,60,24,0,0
825 DATA 0,0,0,24,36,60,60,90,90,36,36,36,90,90,60,36,24,0,0,0,0,0,0,0,0,0,0,24,36,24,24,24,36,24,0,0,0,0,0,0
826 DATA 16,32,96,184,42,60,8,16,0,0,0,0,0,62,8,20,20,8,62,0,0,0,0,0,8,4,6,29,84,60,16,8,0,0,0,0
827 DATA 60,24,255,219,255,153,24,60,60,24,255,109,255,153,24,60,60,24,255,182,255,153,24,60
830 POKE 53256,1:POKE 53257,3:POKE 53258,1:POKE 53259,1:POKE 53260,85
835 FOR A=PB+384 TO PB+1024:POKE A,0:JNK=USR(ADR("h%●◣▔♥RI▶▔▕R▔D▕◆")):NEXT A:RT=PEEK(106)-8
836 POKE 623,17:X=121:X1=X:X2=X:POKE 53248,X:POKE 53250,X:POKE 53251,X
840 POKE 88,0:FOR N=0 TO 8:POKE 89,RT+N:? "↰":NEXT N:POKE 106,RT:GRAPHICS 5:POKE 559,0
845 SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 2,0,0,0
850 PICT=ADR("hh┐Lh┐Kh┐Nh┐Mhh┐Ohh*hh┐P$O◢1M┌K◢@▶Pw┴%KeP┐K♣▕fL┴%MeO┐M♣▕fNJP[◆")
865 POKE 704,98:POKE 705,36:POKE 706,50:POKE 707,196:POKE 708,232:POKE 709,250:POKE 710,132:POKE 711,24
870 D$(1)="▶▶▶▶▶▶▶▶▶p▖▶▶▶▶▶▶▶▶▶*********0▂*********UUUUUUUUU0▂UUUUUUUUU▶▶▶▶▶▶▶▶↰0▂▶▶▶▶▶▶▶▶▶"
871 D$(81)="********-?◀z********UUUUUUUUm**yUUUUUUUUUUUUUUUUmUUyUUUUUUUU▶▶▶▶▶▶▶↰o▶▶y▶▶▶▶▶▶▶▶"
872 D$(161)="▶▶▶▶▶▶▶↰j**)▶▶▶▶▶▶▶▶*******=UUUU◀**************=UUUU◀*******UUUUUUV?▶▶▶▶◀▄UUUUUU"
873 D$(241)="UUUUUUV?▶▶▶▶◀▄UUUUUU▶▶▶▶▶▶V******┬▶▶▶▶▶▶▶▶▶▶▶▶V******┬▶▶▶▶▶▶*****+UUUUUUUWj*****"
874 D$(321)="*****+UUUUUUUWj*****UUUUUk▶▶▶▶▶▶▶▶iUUUUUUUUUUk▶▶▶▶▶▶▶▶iUUUUUUUUUUj********)UUUUU"
875 D$(401)="▶▶▶▶uj********)_▶▶▶▶▶▶▶▶uUUUUUUUUUU_▶▶▶▶▶▶▶▶uUUUUUUUUUU_▶▶▶▶***+uUUUUUUUUUU_j***"
876 D$(481)="***+▶▶▶▶▶▶▶▶▶▶▶▶j******+▶▶▶▶▶▶▶▶▶▶▶▶j***UUU+▶▶▶▶▶▶▶▶▶▶▶▶jUUUUUU**************UUU"
877 D$(561)="UUU**************UUU▶▶U**************W▶▶▶▶UUUUUUUUUUUUUUUW▶▶"
880 POKE 88,0:POKE 89,RT+1:FOR N=1 TO 40:COLOR RND(0)*3+1:PLOT RND(0)*79,RND(0)*47:NEXT N
885 DL=PEEK(560)+256*PEEK(561):DL4=DL+4:DL5=DL+5:NUML=0:NUMH=RT+4:POKE 88,NUML:POKE 89,NUMH
890 STRT=(RT+4)*256+9*20:A=USR(PICT,STRT,ADR(D$),20,31,20):POKE DL4,NUML:POKE DL5,NUMH:A=DL
900 DLIC=ADR("H▔◣T)4▔┴P)◣▔▎Ph@"):HI=INT(DLIC/256):LO=DLIC-HI*256:POKE 512,LO:POKE 513,HI
910 LBASE=DL-2:POKE LBASE+40+6,PEEK(LBASE+40+6)+128:POKE 54286,192
920 IF PEEK(A)<>66 THEN A=A+1:GOTO 920
930 POKE A,71:POKE A+3,6:POKE A+4,6:POKE A+5,65:POKE A+6,PEEK(A+7):POKE A+7,PEEK(A+8)
940 POKE 656,0:POKE 657,20:? "SCORE SHIELDS PORTS"
950 POKE 656,0:POKE 657,1:? SCORE:POKE 656,0:POKE 657,8:? SD:POKE 656,0:POKE 657,15:? B
955 X4=60:FOR N=0 TO 3:POKE 53252+N,X4-4*N:NEXT N:D=USR(ADR(E$),PB+384+10,PB+224)
960 POKE 53277,3:POKE 559,46:Y=56:D=USR(ADR(E$),PB+512+Y,PB+84)
980 SIZEC=0:SM=0:SIZEL=0:N=0:Y3=38:SIZEH=0:FF=1:LV=1:POKE 656,1:POKE 657,0:? "BEGINNER"
990 CONSOL=PEEK(53279):IF CONSOL=3 THEN LV=1:POKE 656,1:POKE 657,0:? "BEGINNER"
1000 IF CONSOL=5 THEN LV=2:POKE 656,1:POKE 657,0:? "EXPERT "
1010 IF CONSOL=6 THEN 1030
1020 GOTO 990
1030 POKE 656,1:POKE 657,0:? " "
1040 SOUND 0,10,8,3:P0=PB+512:P1=PB+640:P2=PB+768:P3=PB+896:P4=PB+394:BLANK=524
1050 SH=84:SH1=BLANK:SH2=BLANK:SH3=BLANK:RETURN
1500 GRAPHICS 18:POKE 712,48:POSITION 2,1:? #6;"DOWN THE TRENCH"
1510 POSITION 6,3:? #6;"attack":POSITION 2,5:? #6;"on the doomstar├":POSITION 2,8:? #6;"BY DAVID PLOTKIN"
1520 POSITION 0,9:? #6;"********************":POSITION 0,10:? #6;"◢c▗ antic publishing"
1530 SOUND 2,55,12,8:RETURN
1535 FOR WW=1 TO 5
1540 FOR W=10 TO 100 STEP 2:SOUND 0,W,10,8:SOUND 1,110-W,10,8:POKE 708,W:NEXT W:NEXT WW
1550 SOUND 2,0,0,0:SOUND 1,0,0,0:SOUND 0,0,0,0
1560 FOR W=10 TO 255:POKE 710,W:SOUND 0,W,10,6:NEXT W:SOUND 0,0,0,0:RETURN
