Printing Desk Calculator (DESKCALC.BAS)

Printing Desk Calculator by James W. Brown, 62

Description

Printing Desk Calculator by James W. Brown, 62

From the Antic disk of September 1987 (Vol. 6 No. 5).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 7.5 KB

Dialect
Atari BASIC
Lines
276
Variables
CH$, PR$, T$, E$, N$, D$, P$, BL$, PX$, V$, KPAD$, STM(, R$, OPCHR$, BS, DEL, ESC, EOL, SDMCTL, SHFLOK, CRSINH, DLIST, I, X, Y, J, KPORT, OLDKC, DPT, PRT, ALG, MEM, STATE, TYPE, AC, ENT, MODE, P, OLDOP, C, OP, SVTYPE, L, DP, EP, KC, EN, EL
BASIC listing (276 lines)
1 REM PRINTING DESK CALCULATOR
2 REM BY JAMES W. BROWN
3 REM (c) 1987, ANTIC PUBLISHING
100 DIM CH$(1),PR$(18),T$(15),E$(15)
110 DIM N$(36),D$(10),P$(6),BL$(15)
120 DIM PX$(2),V$(6),KPAD$(16)
130 DIM STM(6,7),R$(24),OPCHR$(4)
200 DATA 18,7,19,6,20,7,21,6,22,7,23,6,26,0,27,0,28,0
210 DATA 0,3,3,3,6,6,6
211 DATA 0,0,1,3,4,4,6
212 DATA 1,1,1,4,4,4,4
213 DATA 0,2,2,3,5,5,6
214 DATA 2,2,2,5,5,5,5
215 DATA 0,1,2,3,5,5,6
216 DATA 0,1,0,0,0,0,0
217 DATA 0,2,2,3,5,5,6
300 BS=126:DEL=254:ESC=27:EOL=155
305 SDMCTL=559:SHFLOK=702:CRSINH=752
310 GRAPHICS 0:POKE SDMCTL,0
315 POKE 708,184:POKE 711,184
320 POKE 710,114:POKE 712,114
325 DLIST=PEEK(560)+256*PEEK(561)
330 FOR I=1 TO 9
335 READ X,Y:POKE DLIST+X,Y
340 NEXT I
350 FOR J=0 TO 7:FOR I=0 TO 6
355 READ X:STM(I,J)=X
360 NEXT I:NEXT J
365 BL$="                 "
370 D$="floatfixed":P$="offon "
375 V$="RPNALG"
380 R$="RET - E -> A            "
385 OPCHR$="+-*/"
400 ? "     ┌──────────────────────────┐"
405 ? "     | PRINTING DESK CALCULATOR |"
410 ? "┌────┴──────────────────────────┴────┐";
420 ? "| A  - Advance paper  N - Note to prt|";
430 ? "| C  - Clear entry    P - Printer ---|";
440 ? "| D  - Decimal -----  S - Subtotal   |";
450 ? "| MC - Clear Memory   T - Total/clr A|";
460 ? "| MR - Recall M -> E  V - Version ---|";
470 ? "| MS - Store  E -> M  RET - E -> A   |";
480 ? "| M+ - Add E to M     ESC - Reset    |";
485 ? "| M- - Subtr E from M   + - * / % = .|";
490 ? "└────────────────────────────────────┘";
495 ?
510 POSITION 1,13:? "MEM 0";
520 POSITION 1,14:? "ACC 0";
530 POSITION 1,15:? "ENT 0";
540 OPEN #1,4,0,"K:"
550 POKE SDMCTL,34:POKE CRSINH,1
810 KPORT=2:OLDKC=0
820 KPAD$="D456N789Y1230.+-"
830 KPAD$(1,1)=CHR$(DEL)
900 DPT=0:GOSUB 4200
910 PRT=1:GOSUB 4500
920 ALG=1:GOSUB 3700
990 MEM=0
2000 REM INIT
2010 STATE=0:TYPE=1
2020 AC=0:ENT=0:MODE=1:P=0:E$=""
2030 OLDOP=1:GOSUB 5500:GOSUB 5700
2040 POSITION 24,14:? " "
3000 REM MAIN LOOP
3005 STATE=STM(STATE,TYPE)
3010 GOSUB 6500:PX$=CH$:TRAP 9000
3015 POSITION 2,16:? BL$;BL$;BL$(1,7);
3020 IF C=BS OR C=DEL THEN 3100
3025 IF C>=ASC("0") AND C<=ASC("9") THEN 3200
3030 IF C>=ASC("A") AND C<=ASC("Z") THEN 3300
3035 IF CH$="+" THEN OP=1:GOSUB 3400:GOTO 3000
3040 IF CH$="-" THEN OP=2:GOSUB 3400:GOTO 3000
3045 IF CH$="*" THEN OP=3:GOSUB 3400:GOTO 3000
3050 IF CH$="/" THEN OP=4:GOSUB 3400:GOTO 3000
3055 IF CH$="%" THEN 3800
3060 IF CH$="=" THEN 4600
3065 IF CH$="." THEN 4800
3070 IF C=EOL THEN 4900
3080 IF C=ESC THEN 3900
3099 GOSUB 9900:GOTO 3000
3100 REM DELETE A KEYSTROKE
3110 IF P<1 THEN 3000
3120 P=LEN(E$)-1
3130 IF P=0 THEN E$=""
3140 IF P>0 THEN E$=E$(1,P)
3150 GOSUB 5000
3199 GOTO 3000
3200 REM DIGIT
3210 TYPE=2
3220 IF MODE THEN E$="":GOSUB 5100
3230 MODE=0
3240 IF P>8 THEN GOSUB 9900:GOTO 3000
3250 P=LEN(E$)+1:E$(P)=CH$
3260 GOSUB 5000:IF ENT<>0 THEN 3000
3270 POSITION 5,15:? E$;
3299 GOTO 3000
3300 REM LETTER
3310 IF CH$="A" THEN 4000
3320 IF CH$="C" THEN 4100
3330 IF CH$="D" THEN GOSUB 4200:GOTO 3000
3340 IF CH$="M" THEN 4300
3350 IF CH$="N" THEN 4400
3360 IF CH$="P" THEN GOSUB 4500:GOTO 3000
3370 IF CH$="S" THEN 4600
3380 IF CH$="T" THEN 4600
3390 IF CH$="V" THEN GOSUB 3700:GOTO 2000
3399 GOSUB 9900:GOTO 3000
3400 REM ARITHMETIC OPERATOR
3405 IF ALG THEN POSITION 24,14:? OPCHR$(OP,OP)
3410 TYPE=0:IF ALG AND (STATE=0 OR STATE=3 OR STATE=6) THEN GOSUB 9900:GOTO 3000
3420 GOSUB 5100
3430 IF ALG=0 THEN OLDOP=OP
3440 ON OLDOP GOTO 3450,3460,3470,3480
3450 AC=AC+ENT:GOTO 3490
3460 AC=AC-ENT:GOTO 3490
3470 AC=AC*ENT:GOTO 3490
3480 AC=AC/ENT
3490 OLDOP=OP:GOSUB 5200
3499 RETURN
3700 REM V
3710 ALG=1-ALG
3720 POSITION 36,7:? V$(1+3*ALG,3+3*ALG);
3730 POSITION 24,8:? R$(1+12*ALG,12+12*ALG);
3740 POSITION 24,14:? " "
3799 RETURN
3800 REM %
3810 TYPE=7:IF ALG AND (STATE=0 OR STATE=3 OR STATE=6) THEN GOSUB 9900:GOTO 3000
3820 GOSUB 5100:GOSUB 5200
3830 ENT=0.01*ENT:GOSUB 5500
3899 GOTO 3000
3900 REM ESC
3910 IF PRT THEN LPRINT "***RESET***"
3999 RUN
4000 REM A
4010 IF PRT THEN LPRINT " "
4099 GOTO 3000
4100 REM C
4110 TYPE=1:E$="0":MODE=0:GOSUB 5100
4199 GOTO 3000
4200 REM D
4210 DPT=1-DPT
4220 POSITION 17,5:? D$(1+5*DPT,5+5*DPT);
4299 RETURN
4300 REM M
4310 GOSUB 6500:PX$(2)=CH$
4320 P=0:MODE=1:TYPE=3+(CH$="R")
4330 IF ALG AND TYPE=3 AND (STATE=0 OR STATE=3) THEN GOSUB 9900:GOTO 3000
4340 IF CH$="C" THEN 6000
4350 IF CH$="R" THEN 6100
4360 IF CH$="S" THEN 6200
4370 IF CH$="+" THEN 6300
4380 IF CH$="-" THEN 6400
4399 GOSUB 9900:GOTO 4300
4400 REM N
4410 POKE SHFLOK,0:POKE CRSINH,0
4420 POSITION 2,16:? "Enter one-line note:";
4430 POSITION 2,17:INPUT N$
4440 POKE CRSINH,1
4450 IF PRT THEN LPRINT N$:POSITION 2,16:? BL$;BL$;
4460 IF PRT=0 THEN POSITION 2,16:? "Printer is toggled off!";
4470 POSITION 2,17:? BL$;BL$;BL$(1,8);
4499 GOTO 3000
4500 REM P
4510 PRT=1-PRT
4520 POSITION 36,4:? P$(1+3*PRT,3+3*PRT);
4599 RETURN
4600 REM S, T, or =
4610 TYPE=5+(CH$="T"):SVTYPE=TYPE
4620 IF ALG AND STATE<2 THEN GOSUB 9900:GOTO 3000
4630 IF ALG THEN GOSUB 3400:OLDOP=1
4640 ENT=AC:TYPE=SVTYPE
4650 IF CH$="T" OR ALG THEN AC=0
4660 GOSUB 5200
4670 GOSUB 5700:GOSUB 5500
4680 IF ALG AND TYPE=6 THEN 2000
4690 POSITION 24,14:? " "
4699 GOTO 3000
4800 REM PERIOD
4810 TYPE=2:IF MODE THEN E$="0.":P=2
4820 IF MODE=0 THEN P=LEN(E$)+1:E$(P)=CH$
4830 MODE=0:ENT=VAL(E$)
4840 POSITION 5,15:? BL$;
4850 POSITION 5,15:? E$;
4860 POSITION 2,16:? ENT:POSITION 2,16:? BL$
4899 GOTO 3000
4900 REM ENTER
4910 IF ALG THEN GOSUB 9900:GOTO 3000
4920 AC=ENT:PX$="EN":GOSUB 5200
4999 GOTO 3000
5000 REM CONVERT ENTRY
5010 IF MODE THEN RETURN
5020 L=LEN(E$):ENT=0
5030 IF L>0 THEN ENT=VAL(E$)
5040 GOSUB 5500
5099 RETURN
5100 REM CONVERT AND RESET
5110 GOSUB 5000:P=0:MODE=1:E$=""
5199 RETURN
5200 REM DISPLAY AC AND PRINT ENT
5210 GOSUB 5700:P=0:MODE=1:E$=""
5220 IF PRT=0 THEN RETURN
5230 PR$=STR$(ENT)
5240 IF DPT THEN GOSUB 5400
5250 L=LEN(PR$)
5260 IF L<15 THEN PR$(L+1,15)=BL$(L+1,15)
5270 PR$(16)=" "
5280 PR$(17)=PX$:LPRINT PR$
5299 RETURN
5400 REM FIX DECIMAL POINT
5410 T$=PR$:L=LEN(T$):DP=0:EP=0
5420 FOR I=1 TO L
5425 IF T$(I,I)="E" THEN EP=I
5430 IF T$(I,I)="." THEN DP=I
5440 NEXT I
5450 IF EP THEN RETURN
5460 IF DP=0 THEN DP=L+1:T$(DP)=".00"
5470 IF DP=L THEN T$(L+1)="00"
5480 IF DP=L-1 THEN T$(L+1)="0"
5490 PR$=BL$:PR$(14-DP,15)=T$(1,DP+2)
5499 RETURN
5500 REM DISPLAY E
5510 POSITION 5,15:? BL$;
5520 POSITION 5,15:? ENT;
5599 RETURN
5600 REM DISPLAY M
5610 POSITION 5,13:? BL$;
5620 POSITION 5,13:? MEM;
5699 RETURN
5700 REM DISPLAY A
5710 POSITION 5,14:? BL$;
5720 POSITION 5,14:? AC;
5799 RETURN
6000 REM MC
6010 MEM=0
6020 GOSUB 5600:GOSUB 5200
6099 GOTO 3000
6100 REM MR
6110 ENT=MEM:GOSUB 5500:GOSUB 5200
6120 E$=STR$(ENT)
6199 GOTO 3000
6200 REM MS
6210 MEM=ENT:GOSUB 5600:GOSUB 5200
6299 GOTO 3000
6300 REM M+
6310 MEM=MEM+ENT
6320 GOSUB 5600:GOSUB 5200
6399 GOTO 3000
6400 REM M-
6410 MEM=MEM-ENT
6420 GOSUB 5600:GOSUB 5200
6499 GOTO 3000
6500 REM GET CHARACTER
6510 POKE SHFLOK,64:POKE 16,112:POKE 53774,112:POKE 77,0
6520 IF PEEK(764)<255 THEN OLDKC=0:GET #1,C:CH$=CHR$(C):RETURN
6530 IF STRIG(KPORT-1) THEN OLDKC=0:GOTO 6500
6540 KC=STICK(KPORT-1)+1
6550 IF KC=OLDKC THEN 6500
6560 CH$=KPAD$(KC,KC):C=ASC(CH$)
6570 SOUND 0,60,10,8
6580 FOR I=1 TO 4:NEXT I
6590 SOUND 0,0,0,0:OLDKC=KC
6599 RETURN
9000 REM TRAP HANDLER
9010 POSITION 2,16:EN=PEEK(195)
9020 EL=PEEK(186)+256*PEEK(187)
9030 IF EN=3 THEN ? "Bad value.";:GOTO 9090
9040 IF EN=11 THEN ? "OVERFLOW.";:GOTO 9090
9050 IF EN>128 AND PRT THEN ? "Check printer.";:GOTO 9090
9060 ? "Error ";EN;" at line ";EL;".";
9090 ? "  Press C";
9099 GOTO 3000
9900 REM BUZZ
9910 SOUND 0,55,12,8
9920 FOR I=1 TO 20:NEXT I
9930 SOUND 0,0,0,0
9999 RETURN