Annual Percentage Rate (APR.BAS)

Annual Percentage Rate by Bob Mueller, 91

Description

Annual Percentage Rate by Bob Mueller, 91

From the Antic disk of September 1987 (Vol. 6 No. 5).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 10.9 KB

Dialect
Atari BASIC
Lines
260
Variables
B$, BL$, N4, N80, A$, N1, N3, NUM, XE, M(, N0, D, N2, K, CRSINH, FIND, CHNUM, S$, LAST, E, AMT, C, LL, N5, CHCOLOR, INS, F, N48, N8, MENU, UPDATE, INSERT, DISPLAY, CORRECT, DELETE, ANALYZE, N10, EXIT, UNTRAP, MR, RETRIEVE, ADD, X, FIX, TYPE, N6, N11, N27, DECIMAL, N12, N9, N13, N16, N15, C$, L, N7, TITLE, DAY, LPT, N20, HEADING, BAL, IN, DXA, DXASTD, P, IL, YLD, DAYS, YR, YR0, AVBAL, DAY0, DAYL, DAYI, Y, AVBALSTD, YLDSTD, FILL, N28, N40, R$, N123, N14, GROUP, LO, HI, MOVE, AFTER, D$, SS$, A, B
BASIC listing (260 lines)
10 REM APR - ANNUAL PERCENTAGE RATE
20 REM BY BOB MUELLER
30 REM (c)1987, ANTIC PUBLISHING INC.
35 REM ->DO NOT RENUMBER THIS PROGRAM!
40 GRAPHICS 0:POKE 709,12:POKE 710,244:POKE 712,244:POKE 752,1:POKE 82,3:POSITION 3,7
50 ? "┌────────────────────────────────┐"
60 ? "|                                |"
70 ? "|  APR - ANNUAL PERCENTAGE RATE  |"
80 ? "|                                |"
90 ? "└────────────────────────────────┘":? :?
100 ? "EFFECTIVE ANNUAL RETURN ON SAVINGS"
1000 REM APR REV 1.0
1010 POKE 16,112:POKE 53774,112:GOTO 3140
1020 REM CHNUM
1030 B$=BL$:B$(N4,N80)=A$(N4):B$(N1,N3)=STR$(NUM):IF  NOT XE THEN RETURN
1040 POINT #N4,M(NUM,N0),M(NUM,N1):PRINT #N4;B$:RETURN
1050 REM CHCOLOR
1060 D=D+N2:SETCOLOR N2,D,N4:SETCOLOR N4,D,N4:POKE 16,112:POKE 53774,112:RETURN
1070 REM MR - MENU RETURN
1080 PRINT "↰↓           PRESS KEY FOR MENU ":GET #N1,K:RETURN
1090 REM TITLE
1100 POKE CRSINH,N1:PRINT "↰↓NO   T  MO/DA/YR  -$0000.00  +$0000.00  ":RETURN
1110 REM FIX
1120 NUM=FIND:IF XE THEN GOTO CHNUM
1130 GOSUB CHNUM:S$(FIND*N80-79,LEN(S$))=B$:RETURN
1140 REM ADD
1150 NUM=LAST:IF XE THEN GOTO CHNUM
1160 GOSUB CHNUM:S$(LEN(S$)+N1)=B$:RETURN
1170 REM RETRIEVE
1180 IF XE THEN POINT #N4,M(FIND,N0),M(FIND,N1):INPUT #N4;A$:RETURN
1190 A$=S$(FIND*N80-79):RETURN
1200 REM DECIMAL
1210 E=INT(ABS(AMT)*C+0.5)/C:LL=LEN(STR$(INT(E)))-N1:IF AMT<N0 THEN LL=LL+N1:E=N0-E
1220 AMT=E:RETURN
1230 REM MENU
1240 POKE 82,N5:PRINT "↰":GOSUB CHCOLOR:POKE CRSINH,N1:INS=N0:CLOSE #N1:OPEN #N1,N4,N0,"K:"
1250 PRINT "     ┌─────────────────┐"
1260 PRINT "     |  MAIN APR MENU  |"
1270 PRINT "     └─────────────────┘↓"
1280 PRINT "(1) ADD AN ENTRY (";F-LAST;" MORE)↓"
1290 PRINT "(2) INSERT NEW ENTRY WITHIN↓"
1300 PRINT "(3) DISPLAY ENTRIES (";LAST;" NOW)↓"
1310 PRINT "(4) CORRECTIONS TO AN ENTRY↓"
1320 PRINT "(5) DELETE/MOVE/SWAP ENTRIES↓"
1330 PRINT "(6) CALCULATE & DISPLAY YIELDS↓"
1340 PRINT "(7) CALCULATE & PRINT ENTRIES↓"
1350 PRINT "(8) UPDATE THE DISK AND QUIT↓"
1360 PRINT "        PRESS ( ) KEY ":POKE 82,N0:GET #N1,K
1370 K=K-N48:IF K<N1 OR K>N8 THEN GOTO MENU
1380 ON K GOSUB UPDATE,INSERT,DISPLAY,CORRECT,DELETE,ANALYZE,ANALYZE+N10,EXIT
1390 TRAP UNTRAP:GOTO MENU
1400 REM INSERT
1410 PRINT "↰":IF LAST<N1 THEN RETURN
1420 PRINT " NOW ";LAST;" ENTRIES; ROOM FOR ";F-LAST;" MORE↓":IF F-LAST<N1 THEN GOTO MR
1430 ? " INPUT NUMBER TO INSERT AFTER";:POKE CRSINH,N0:TRAP INSERT:INPUT K:IF K=LAST THEN GOTO UPDATE
1440 IF K<N0 OR K>LAST THEN GOTO INSERT
1450 POKE CRSINH,N1:PRINT "↰ STAND BY AS ENTRIES ARE MOVED ..."
1460 FIND=LAST:GOSUB RETRIEVE:LAST=LAST+N1:GOSUB ADD
1470 IF LAST-K>N2 THEN FOR X=LAST-N2 TO K+N1 STEP -N1:FIND=X:GOSUB RETRIEVE:FIND=X+N1:GOSUB FIX:NEXT X
1480 FIND=K+N1:INS=N1
1490 REM UPDATE
1500 PRINT "↰":A$=BL$:IF F-LAST<N1 THEN PRINT ,"  NO ROOM FOR MORE":GOTO MR
1510 GOSUB CHCOLOR:IF  NOT INS THEN LAST=LAST+N1:FIND=LAST
1520 IF FIND=N1 THEN ? " (3) INPUT THE INITIAL DEPOSIT OR":? "     BALANCE ON AN INTEREST DATE":K=N3:GOTO 1600
1530 POKE CRSINH,N1:PRINT "↰ THIS IS ENTRY ";LAST;"; ROOM FOR ";F-LAST;" MORE↓"
1540 PRINT "   (1) GAIN CREDIT (FUND CHANGE)↓"
1550 PRINT "   (2) GAIN CHECK (NO FUND CHANGE)↓"
1560 PRINT "   (3) DEPOSIT (FUND INCREASE)↓"
1570 PRINT "   (4) WITHDRAWAL (FUND DECREASE)↓"
1580 PRINT "   (5) CALCULATION (NO FUND CHANGE)↓":PRINT ," PRESS ( ) TYPE KEY "
1590 GET #N1,K:K=K-N48:IF K<N1 OR K>N5 THEN 1530
1600 POKE CRSINH,N0
1610 TYPE=K:A$(N6,N6)=STR$(TYPE):A$(N11,N80)="/0 /0":IF TYPE=N5 THEN 1650
1620 PRINT "↓ INPUT THE AMOUNT FOR (";TYPE;")";:TRAP 1620:INPUT AMT:IF AMT<N0 AND TYPE<>N1 THEN 1620
1630 IF TYPE=N4 THEN A$(25,N27)=".00":GOSUB DECIMAL:LL=24-LL:A$(LL,N27)=STR$(AMT):GOTO 1650
1640 A$(36,N80)=".00":GOSUB DECIMAL:LL=35-LL:A$(LL,N80)=STR$(AMT)
1650 PRINT :PRINT " INPUT  MONTH  (1 = JAN)";:TRAP 1650:INPUT K
1660 IF K<N1 OR K>N12 THEN 1650
1670 IF K<N10 THEN A$(N10,N10)=STR$(K)
1680 IF K>N9 THEN A$(N9,N10)=STR$(K)
1690 PRINT :PRINT " ENTER   DAY   (1 TO 31)";:TRAP 1690:INPUT K
1700 IF K<N1 OR K>31 THEN 1690
1710 IF K<N10 THEN A$(N13,N13)=STR$(K)
1720 IF K>N9 THEN A$(N12,N13)=STR$(K)
1730 PRINT :PRINT " ENTER  YEAR   (87=1987)";:TRAP 1730:INPUT K
1740 IF K<N0 OR K>99 THEN 1730
1750 IF K<N10 THEN A$(N16,N16)=STR$(K)
1760 IF K>N9 THEN A$(N15,N16)=STR$(K)
1770 IF TYPE<N3 THEN C$="INTEREST CREDIT":GOTO 1800
1780 IF TYPE=N5 THEN A$(41,N80)="ACCRUED INTEREST (TO BE COMPUTED) 0.00":GOTO 1810
1790 PRINT :PRINT " INPUT THE DESCRIPTION UP TO ARROW  ␛↓":INPUT C$:PRINT
1800 A$(41,N80)=C$:IF TYPE=N2 THEN A$(50,N80)="CHECK "
1810 IF INS THEN GOTO FIX
1820 GOTO ADD
1830 REM DISPLAY
1840 PRINT "↰":L=N0:IF LAST=N0 THEN PRINT ,"THERE ARE NO ENTRIES":GOTO MR
1850 X=N1:C$="   PRESS KEY FOR MORE (ESC FOR MENU) ":IF LAST<N7 THEN 1880
1860 PRINT LAST;" TO DISPLAY↓":PRINT "INPUT STARTING NUMBER";:POKE CRSINH,N0:TRAP 1880:INPUT X
1870 IF X<N1 OR X>LAST THEN X=N1
1880 FOR FIND=X TO LAST:GOSUB RETRIEVE:L=L+N1:IF L=N1 THEN GOSUB TITLE
1890 PRINT A$:IF L=N6 AND FIND<LAST THEN L=N0:PRINT C$:GET #N1,K:IF K=N27 THEN POP :RETURN
1900 NEXT FIND:PRINT "↓           PRESS KEY FOR MENU ":GET #N1,K:RETURN
1910 REM CORRECT
1920 POKE CRSINH,N0:PRINT "↰"
1930 TRAP MENU:PRINT LAST;" ENTRIES":PRINT :PRINT "INPUT ENTRY NUMBER TO CORRECT";:INPUT K:TRAP UNTRAP
1940 IF K<N1 OR K>LAST THEN PRINT "↓↰NOT ACTIVE":GOTO MR
1950 FIND=K:GOSUB RETRIEVE:GOSUB TITLE:PRINT A$:POKE CRSINH,N0
1960 PRINT :PRINT "EDIT ENTRY AND PRESS RETURN";:INPUT A$:IF A$="" THEN RETURN
1970 GOTO FIX
1980 REM DAYS
1990 RETURN
2000 DAY=DAY+31:RETURN
2010 DAY=DAY+59:RETURN
2020 DAY=DAY+90:RETURN
2030 DAY=DAY+120:RETURN
2040 DAY=DAY+151:RETURN
2050 DAY=DAY+181:RETURN
2060 DAY=DAY+212:RETURN
2070 DAY=DAY+243:RETURN
2080 DAY=DAY+273:RETURN
2090 DAY=DAY+304:RETURN
2100 DAY=DAY+334:RETURN
2110 REM ANALYZE
2120 LPT=N0:IF LAST>N1 THEN PRINT "↰↓↓↓↓↓↓↓↓      CRUNCHING ENTRY NUMBER:":GOTO 2200
2130 LPT=N1:IF LAST<N2 THEN PRINT "↰","   TOO FEW ENTRIES":GOTO MR
2140 PRINT "↰":GOSUB CHCOLOR:B$="EFFECTIVE ANNUAL YIELD FOR ":PRINT "INPUT THE FUND NAME TO ARROW     ␛↓"
2150 POKE CRSINH,N0:INPUT C$:B$(LEN(B$)+N1)=C$:X=N1:IF LAST<N20 THEN 2180
2160 PRINT "↓↓THERE ARE ";LAST;" ENTRIES;":PRINT "INPUT THE STARTING NUMBER FOR PRINTING":TRAP 2180:INPUT X
2170 IF X<N1 OR X>LAST THEN X=N1
2180 POKE CRSINH,N1:PRINT "↰↓↓↓↓↓ALIGN PAPER & PRESS A KEY (ESC FOR MENU)";:GET #N1,K:IF K=N27 THEN RETURN
2190 PRINT "↰↓↓↓↓↓      GETTING THE NUMBERS ON PAPER":TRAP 2180:CLOSE #N2:OPEN #N2,N8,N0,"P:"
2200 TRAP 2360:FIND=LAST:GOSUB RETRIEVE:C$=A$(N9,N16):IF LPT THEN GOSUB HEADING
2210 BAL=N0:IN=N0:DXA=N0:DXASTD=N0:L=N0:P=N0:IL=N0:YLD=N5
2220 FOR FIND=N1 TO LAST:IF  NOT LPT THEN POSITION 30,N8:PRINT FIND
2230 GOSUB RETRIEVE:TYPE=VAL(A$(N6)):IF TYPE=N5 THEN AMT=N0
2240 IF TYPE<>N5 THEN AMT=VAL(A$(19,38)):IF A$(25,25)="." THEN AMT=N0-AMT
2250 DAY=VAL(A$(N12,N13)):GOSUB DAYS+(VAL(A$(N9,N10))-N1)*N10
2260 YR=VAL(A$(N15,N16)):IF YR<YR0 THEN YR=YR+C
2270 IF FIND=N1 THEN YR0=YR:BAL=AMT:AVBAL=AMT:DAY0=DAY:DAYL=DAY:DAYI=DAY:GOTO 2390
2280 DAY=DAY+(YR-YR0)*Y:IF DAY<DAYL THEN PRINT "↰    CHECK DATE SEQUENCE THRU ENTRY ";FIND:GOTO MR
2290 IF TYPE>N2 THEN 2370
2300 IN=IN+AMT:DXA=DXA+BAL*(DAY-DAYL):AVBAL=DXA/(DAY-DAYI):IF TYPE=N1 THEN BAL=BAL+AMT
2310 YLD=Y*C*AMT/AVBAL/(DAY-DAYI):DXASTD=DXASTD+AVBAL*(DAY-DAYI)
2320 AVBALSTD=DXASTD/(DAY-DAY0):YLDSTD=Y*C*IN/AVBALSTD/(DAY-DAY0)
2330 DAYL=DAY:DAYI=DAY:DXA=N0
2340 IF LPT AND FIND>=X THEN IL=N1:GOSUB FILL:IL=N0
2350 GOTO 2400
2360 POP :PRINT "↰       TROUBLE ANALYZING ENTRY ";FIND:GOTO MR
2370 DXA=DXA+BAL*(DAY-DAYL):DAYL=DAY:BAL=BAL+AMT
2380 IF TYPE=N5 THEN A$(58,74)=BL$:AMT=DXA*YLD/Y/C:GOSUB DECIMAL:LL=75-LL:A$(LL,N80)=STR$(AMT):GOSUB FIX
2390 IF LPT AND FIND>=X THEN GOSUB FILL
2400 NEXT FIND:TRAP UNTRAP:CLOSE #N2
2410 REM RESULT
2420 PRINT "↰":GOSUB CHCOLOR
2430 PRINT "           ┌────────────────┐"
2440 PRINT "           | AS OF ";C$;" |"
2450 PRINT "           └────────────────┘"
2460 POSITION N8,N6:PRINT "CURRENT BALANCE = $";BAL
2470 POSITION N10,N8:PRINT "CURRENT YIELD = ";INT(C*YLD+0.5)/C;"%"
2480 POSITION N11,N10:PRINT "ACCRUED GAIN = $";INT(DXA*YLD/Y+0.5)/C
2490 POSITION N10,N13:PRINT "GAINS TO DATE = $";IN
2500 POSITION N8,N15:PRINT "OVERALL AVG BAL = $";INT(C*AVBALSTD+0.5)/C
2510 POSITION N10,17:PRINT "YIELD TO DATE = ";INT(C*YLDSTD+0.5)/C;"%↓":GOTO MR
2520 REM FILL
2530 L=L+N1:P=P+N1:IF L=N4 THEN PRINT #N2;CHR$(N27);CHR$(N28);:L=N1:IF P>N40 THEN GOSUB HEADING
2540 R$=BL$:R$(N1)=A$(N9,N16):R$(N11)=A$(N1,N3):R$(N16)=A$(41,N80):R$(55)=A$(18,38)
2550 IF TYPE=N5 THEN R$(33,55)=A$(58):GOTO 2620
2560 AMT=BAL:R$(85)=".00":GOSUB DECIMAL:LL=84-LL:R$(LL,N123)=STR$(AMT)
2570 IF  NOT IL THEN 2620
2580 AMT=AVBALSTD:R$(97)=".00":GOSUB DECIMAL:LL=96-LL:R$(LL)=STR$(AMT)
2590 AMT=IN:R$(107)=".00":GOSUB DECIMAL:LL=106-LL:R$(LL)=STR$(AMT)
2600 AMT=YLD:R$(114)=".00":GOSUB DECIMAL:LL=113-LL:R$(LL)=STR$(AMT)
2610 AMT=YLDSTD:R$(121)=".00":GOSUB DECIMAL:LL=120-LL:R$(LL,N123)=STR$(AMT)
2620 PRINT #N2;"    ";R$:RETURN
2630 REM HEADING
2640 R$=BL$:R$(34-LEN(B$)/N2,N80)=B$:E=N2:IF P>N40 THEN E=N9:P=N1
2650 FOR K=N1 TO E:PRINT #N2;" ":NEXT K:POKE 77,N0
2660 PRINT #N2;CHR$(N27);CHR$(N20);CHR$(N27);CHR$(N14);R$(N1,65):R$=BL$:R$(64)="AS OF"
2670 PRINT #N2;CHR$(N27);CHR$(N28);R$
2680 R$=BL$:R$(29)=C$
2690 PRINT #N2;CHR$(N27);CHR$(N28);CHR$(N27);CHR$(N20);CHR$(N27);CHR$(N14);R$;CHR$(N10);CHR$(N10)
2700 R$=BL$:R$=" DATE     NO   DESCRIPTION                    ACCRUED      DEBIT     CREDIT"
2710 R$(N80,N123)=" BALANCE     AVG BAL    INT $   TERM%   YLD%":PRINT #N2;"    ";R$;CHR$(N10):RETURN
2720 REM DELETE
2730 POKE CRSINH,N1:GOSUB CHCOLOR:PRINT "↰↓↓↓↓"
2740 PRINT ,"(1) DELETE ONE ENTRY↓"
2750 PRINT ,"(2) DELETE A GROUP↓"
2760 PRINT ,"(3) DELETE  ALL  ";LAST
2770 PRINT ,"↓(4) MOVE ONE ENTRY↓"
2780 PRINT ,"(5) SWAP TWO ENTRIES↓"
2790 PRINT ,"(6) RETURN MAIN MENU↓"
2800 PRINT ,"     PRESS ( ) KEY ":GET #N1,K:IF LAST=N0 THEN RETURN
2810 K=K-N48:IF K<N1 OR K>N6 THEN 2730
2820 POKE CRSINH,N0:PRINT "↰THERE ARE ";LAST;" ENTRIES↓":TRAP DELETE
2830 ON K GOTO 2840,2860,2950,2980,3060,3120
2840 PRINT "INPUT THE ENTRY NUM TO DELETE";:INPUT K:IF K<N1 OR K>LAST THEN GOTO DELETE
2850 GROUP=N0:GOTO 2890
2860 GROUP=N1:PRINT "DELETE A GROUP OF ENTRIES":IF LAST<N3 THEN GOTO DELETE
2870 PRINT "INPUT LO,HI NUMS (4,8)";:INPUT LO,HI:IF LO>=HI OR HI>LAST OR LO<N1 THEN GOTO DELETE
2880 FOR K=HI TO LO STEP -N1
2890 PRINT "ENTRY ";K;" WAS DELETED":IF K=LAST THEN 2910
2900 FOR X=K+N1 TO LAST:FIND=X:GOSUB RETRIEVE:FIND=X-N1:GOSUB FIX:NEXT X
2910 LAST=LAST-N1:IF  NOT LAST AND  NOT XE THEN S$="":GOTO 2930
2920 IF  NOT XE THEN S$=S$(N1,N80*LAST)
2930 IF  NOT GROUP OR  NOT LAST THEN RETURN
2940 NEXT K:RETURN
2950 PRINT "DELETE ALL!  ARE YOU SURE? (Y/N)";:GET #N1,K:IF CHR$(K)<>"Y" THEN RETURN
2960 LAST=N0:IF  NOT XE THEN S$=""
2970 RETURN
2980 IF LAST<N3 THEN GOTO DELETE
2990 PRINT "INPUT ENTRY NUMBER TO MOVE";:INPUT MOVE:PRINT :IF MOVE<N1 OR MOVE>LAST THEN GOTO DELETE
3000 PRINT "INPUT ENTRY NUMBER TO MOVE AFTER";:INPUT AFTER
3010 IF MOVE=AFTER OR AFTER>LAST THEN GOTO DELETE
3020 FIND=MOVE:GOSUB RETRIEVE:C$=A$:IF MOVE>AFTER THEN 3040
3030 FOR X=MOVE+N1 TO AFTER:FIND=X:GOSUB RETRIEVE:FIND=X-N1:GOSUB FIX:NEXT X:FIND=AFTER:GOTO 3050
3040 FOR X=MOVE-N1 TO AFTER+N1 STEP -N1:FIND=X:GOSUB RETRIEVE:FIND=X+N1:GOSUB FIX:NEXT X:FIND=AFTER+N1
3050 A$=C$:GOSUB FIX:RETURN
3060 IF LAST<N3 THEN GOTO DELETE
3070 PRINT "INPUT NUMBERS TO BE SWAPPED"
3080 PRINT "EXAMPLE: 18,34";:INPUT LO,HI:IF LO<N1 OR HI<N2 OR LO=HI THEN GOTO DELETE
3090 IF HI>LAST THEN PRINT "NUMBER TOO HIGH":GOTO 3070
3100 FIND=LO:GOSUB RETRIEVE:C$=A$:FIND=HI:GOSUB RETRIEVE:FIND=LO:GOSUB FIX
3110 A$=C$:FIND=HI:GOSUB FIX
3120 RETURN
3130 REM INITIALIZE
3140 DATA 1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,20,27,28,40,48,80,100,123,365,752,40000
3150 READ N1:READ N2:READ N3:READ N4:READ N5:READ N6:READ N7:READ N8:READ N9:READ N10
3160 READ N11:READ N12:READ N13:READ N14:READ N15:READ N16:READ N20:READ N27:READ N28
3170 READ N40:READ N48:READ N80:READ C:READ N123:READ Y:READ CRSINH:READ UNTRAP
3180 DATA 1150,2120,1060,1030,1920,1990,1210,2730,1840,3320,2530,1120,2640,1410,1240,1080,1180,1100,1500
3190 READ ADD:READ ANALYZE:READ CHCOLOR:READ CHNUM:READ CORRECT:READ DAYS
3200 READ DECIMAL:READ DELETE:READ DISPLAY:READ EXIT:READ FILL:READ FIX
3210 READ HEADING:READ INSERT:READ MENU:READ MR:READ RETRIEVE:READ TITLE:READ UPDATE
3220 DIM A$(N80),B$(N80),BL$(N123),C$(N80),D$(N10),R$(N123),SS$(N80)
3230 D$="D1:APR.DAT":BL$(N1)=" ":BL$(N123)=BL$:BL$(N2)=BL$
3240 TRAP 3250:OPEN #N3,N4,N0,D$:TRAP UNTRAP:GOTO 3260
3250 CLOSE #N3:OPEN #N3,N8,N0,D$:PRINT #N3;LAST:CLOSE #N3:OPEN #N3,N4,N0,D$
3260 INPUT #N3;LAST
3270 TRAP 3280:OPEN #N4,N8,N0,"D8:APR.DAT":GOTO 3390
3280 F=INT((FRE(N0)-Y)/N80):DIM S$(F*N80):IF LAST=N0 THEN 3300
3290 FOR X=N1 TO LAST:INPUT #N3;SS$:S$(LEN(S$)+N1)=SS$:NEXT X
3300 CLOSE #N3:GOTO MENU
3310 REM EXIT
3320 PRINT "↰":IF LAST=N0 THEN 3350
3330 PRINT ,"↓SAVING DATA TO DISK":IF XE THEN 3450
3340 OPEN #N3,N8,N0,D$:PRINT #N3;LAST:FOR X=N1 TO LEN(S$) STEP N80:SS$=S$(X):PRINT #N3;SS$:NEXT X:CLOSE #N3
3350 POSITION 2,10:? "Do you really want to QUIT (Y/N)?";:GET #1,K:IF  NOT (K=89 OR K=78) THEN 3350
3351 IF K=78 THEN RETURN
3355 POKE 82,2:GRAPHICS N0:END
3360 POKE N16,64:POKE 53774,64:SETCOLOR N1,N0,N12:IF XE THEN OPEN #N4,N12,N0,"D8:APR.DAT"
3370 GOTO MENU
3380 REM 130XE
3390 XE=N1:F=770:B$=BL$:DIM M(F,N1):POSITION N11,N20:PRINT "RAMDISK ENTRY:":IF LAST=N0 THEN 3410
3400 FOR X=N1 TO LAST:INPUT #N3;A$:NOTE #N4,A,B:PRINT #N4;A$:M(X,N0)=A:M(X,N1)=B:POSITION 26,N20:? X:NEXT X
3410 TRAP 3430:FOR X=LAST+N1 TO F:NOTE #N4,A,B:PRINT #N4;B$:M(X,N0)=A:M(X,N1)=B:POSITION 26,N20:? X:NEXT X
3420 TRAP UNTRAP:CLOSE #N3:CLOSE #N4:OPEN #N4,N12,N0,"D8:APR.DAT":GOTO MENU
3430 POP :F=X-N1:GOTO 3420
3440 REM 130XE EXIT
3450 POINT #N4,M(N1,N0),M(N1,N1):OPEN #N3,N8,N0,D$:PRINT #N3;LAST
3460 FOR X=N1 TO LAST:INPUT #N4;A$:PRINT #N3;A$:NEXT X:CLOSE #N4:GOTO 3350