Tapeless, print utility (TAPELESS.BAS)

Tapeless, print utility by Robert Grunbok 74

Description

Tapeless, print utility by Robert Grunbok 74

From the Antic disk of August 1987 (Vol. 6 No. 4).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 5.6 KB

Dialect
Atari BASIC
Lines
113
Variables
CP, AR, AW, R, DISK, LTR, P$, PRNTR, OUT, ZERO, FILL, FA, NOWASTE, BL, INDEX, PR, BL$, C, S, W, FROM, FILE$, I, M, H, T, SKIP, KEYBOARD, J, A$, X$, SCREEN, N, X, Y, K, BREAK, KEY
BASIC listing (113 lines)
10 REM TAPELESS
12 REM BY ROBERT GRUNBOK
14 REM (c)1987, ANTIC PUBLISHING INC.
20 TRAP 40000:GOSUB 520:GOSUB 550:GOTO 150
30 REM LOAD ARRAY
40 TRAP 60:FOR CP=AR TO AW*R-R+AR STEP R:GET #DISK,LTR:IF LTR=155 THEN LET CP=AW*R-R+AR:RETURN
50 P$(CP,CP)=CHR$(LTR):NEXT CP:TRAP 40000:RETURN
60 TRAP 40000:RETURN :REM TRAP EOF ERROR
70 REM PRINT
80 TRAP 120:CLOSE #PRNTR:OPEN #PRNTR,OUT,ZERO,"P:":IF (FILL=FA) AND (NOWASTE>ZERO) THEN AW=NOWASTE
90 BL=INT(80-R)/2:INDEX=1:FOR PR=1 TO AW
100 IF BL>ZERO THEN PRINT #PRNTR;BL$(1,BL);
110 PRINT #PRNTR;P$(INDEX,INDEX+R-1):INDEX=INDEX+R:NEXT PR:RETURN
120 IF PEEK(195)=138 THEN 1050
130 TRAP 40000:PR=AW:RETURN
140 REM MAIN PROGRAM
150 TRAP 210:POKE 752,1:C=ZERO:R=ZERO:S=ZERO:W=ZERO:CLOSE #DISK:OPEN #DISK,FROM,ZERO,FILE$:? "↰"
160 GOSUB 1040:POSITION 13,9:? "SIZING ARRAY":POSITION 10,11:? "PLEASE STAND BY..."
170 FOR I=1 TO 500:NEXT I:POKE 559,ZERO
180 GET #DISK,LTR:W=W+1:IF LTR<>155 THEN 180
190 R=R+1:IF W>=C THEN C=W
200 W=ZERO:GOTO 180
210 CLOSE #DISK:IF PEEK(195)=136 THEN TRAP 40000:POKE 559,34
220 IF R>80 THEN ? "↰↰Form has too many rows to print":? "clearly.":? :? "See Documentation...":CLOSE #DISK:END
230 S=R*C:AW=INT(M/R)
240 FILL=C/AW:FA=INT(C/AW):IF FA<FILL THEN FA=FA+1
250 IF S<M THEN AW=C
260 GOSUB 1040:POKE 712,192:? "↰":POSITION 12,9:? "LOADING ARRAY":POSITION 10,11:? "PLEASE STAND BY..."
270 FOR I=1 TO 500:NEXT I:POKE 559,ZERO:CLOSE #DISK:OPEN #DISK,FROM,ZERO,FILE$
280 REM FORM FITS
290 IF FA<2 THEN GOSUB 1030:FOR AR=R TO 1 STEP -1:GOSUB 40:NEXT AR:GOSUB 80:GOTO 420
300 REM DOESN'T FIT, MULTI-FILL
310 H=ZERO:T=C-AW:NOWASTE=ZERO
320 FOR FILL=1 TO FA:GOSUB 1030:FOR AR=R TO 1 STEP -1
330 IF H>ZERO THEN FOR SKIP=1 TO H:GET #DISK,LTR:NEXT SKIP
340 GOSUB 40
350 IF T>ZERO THEN FOR SKIP=1 TO T:GET #DISK,LTR:NEXT SKIP
360 NEXT AR
370 H=H+AW
380 IF FILL=FA-1 THEN NOWASTE=T+1
390 IF T<=AW THEN T=ZERO
400 IF T>AW THEN T=T-AW
410 GOSUB 80:CLOSE #DISK:OPEN #DISK,FROM,ZERO,FILE$:NEXT FILL
420 PRINT #PRNTR;CHR$(12):REM FORM FEED
430 POKE 559,34:POKE 752,1:POKE 712,38:POKE 77,0
440 ? "↰":POSITION 5,8:? "Choose:":POSITION 7,10:? "Another copy of same form":POSITION 7,12:? "New form"
450 POSITION 7,14:? "Quit":CLOSE #KEYBOARD:OPEN #KEYBOARD,FROM,ZERO,"K:":GOSUB 1010
460 POKE 694,0:POKE 702,64:GET #KEYBOARD,J:IF J=65 THEN GOTO 500
470 IF J=78 THEN ? "↰":FA=1:GOTO 570
480 IF J=81 THEN POKE 752,0:END
490 POKE 764,255:GOTO 460
500 IF FA<2 THEN GOSUB 80:? #PRNTR;CHR$(12):CLOSE #PRNTR:GOTO 440
510 GOTO 230
520 DIM A$(40),X$(40),FILE$(20),BL$(80):BL$(1)=" ":BL$(80)=BL$:BL$(2)=BL$:M=INT(FRE(0)-300):DIM P$(M)
530 ZERO=0:KEYBOARD=1:DISK=2:SCREEN=3:FROM=4:PRNTR=7:OUT=8
540 RETURN
550 REM FILE MENU
560 OPEN #SCREEN,12,ZERO,"S:"
570 POKE 752,1:POKE 709,0:POKE 710,12:POKE 712,40
580 POSITION 4,9:? "Insert data disk into Drive #1":POSITION 10,11:? "Then press RETURN";
590 CLOSE #KEYBOARD:OPEN #KEYBOARD,FROM,ZERO,"K:":GOSUB 1010:GET #KEYBOARD,J:? #SCREEN;"↰"
600 POSITION 0,0:? #SCREEN;"┌──────────────────────────────────────┐"
610 POSITION 0,1:? #SCREEN;"|  FILES AVAILABLE TO PRINT SIDEWAYS   |";
620 POSITION 0,2:? #SCREEN;"| Select with arrows then press RETURN |"
630 POSITION 0,3:? #SCREEN;"├──────────────────────────────────────┤"
640 FOR I=4 TO 19:POSITION 0,I:? #SCREEN;"|";:POSITION 39,I:? #SCREEN;"|";:NEXT I
650 POSITION 0,20:? #SCREEN;"| Press [Esc] to see another directory |"
660 POSITION 0,21:? #SCREEN;"└──────────────────────────────────────┘"
670 CLOSE #DISK:OPEN #DISK,6,ZERO,"D:*.*":R=4:C=1
680 TRAP 770:INPUT #DISK,A$:TRAP 40000
690 IF A$(3,13)="DOS     SYS" THEN 720
700 IF A$(5,8)="FREE" THEN 770
710 IF A$(11,13)<>"TXT" AND A$(11,13)<>"   " THEN 680
720 X$=A$(3,10):X$(9,9)=".":X$(10,12)=A$(11,13)
730 FOR I=2 TO 12:IF X$(I,I)=" " THEN X$(I,I)="."
740 NEXT I:POSITION C,R
750 ? #SCREEN;X$(1,12);:C=C+13:IF C=40 THEN C=1:R=R+1:IF R=22 THEN 770
760 GOTO 680
770 R=4:C=1:N=128:GOSUB 910:POKE 764,25
780 CLOSE #KEYBOARD:OPEN #KEYBOARD,FROM,ZERO,"K:"
790 POKE 694,0:POKE 702,64:GET #KEYBOARD,J:X=0:Y=0
800 IF J=45 THEN Y=-1:GOTO 860
810 IF J=61 THEN Y=1:GOTO 860
820 IF J=43 THEN X=-13:GOTO 860
830 IF J=42 THEN X=13:GOTO 860
840 IF J=155 THEN 920
850 IF J=27 THEN POKE 764,255:? #SCREEN;"↰":GOTO 580
860 POKE 764,255:IF X=0 AND Y=0 THEN 790
870 IF C+X<1 OR C+X>39 THEN 790
880 IF R+Y<4 OR R+Y>19 THEN 790
890 POSITION C+X,R+Y:GET #SCREEN,J:IF J=32 THEN 790
900 N=-128:GOSUB 910:N=128:C=C+X:R=R+Y:GOSUB 910:GOTO 790
910 POSITION C,R:FOR I=C TO C+11:GET #SCREEN,J:J=J+N:POSITION I,R:PUT #SCREEN,J:NEXT I:RETURN
920 POSITION C,R:FOR I=1 TO 12:GET #SCREEN,J:A$(I,I)=CHR$(J-128):NEXT I
930 X$(1,2)="D:":K=3:FOR I=1 TO 8:IF A$(I,I)="." THEN POP :GOTO 950
940 X$(K,K)=A$(I,I):K=K+1:NEXT I
950 X$(K,K)=".":K=K+1:FOR I=10 TO 12:IF A$(I,I)="." THEN POP :GOTO 970
960 X$(K,K)=A$(I,I):K=K+1:NEXT I
970 POKE 764,255:IF X$(3,9)="DOS.SYS" THEN DOS
980 FILE$=X$(1,K-1):IF FA=0 THEN RETURN
990 GOTO 150
1000 REM DISABLE [BREAK]
1010 POKE 16,112:POKE 53774,112
1020 RETURN
1030 P$(1)=" ":P$(S)=P$:P$(2)=P$:RETURN
1040 FOR I=200 TO 0 STEP -10:SOUND 0,I,10,10:NEXT I:SOUND 0,0,0,0:RETURN
1050 TRAP 40000:? "↰↰":POSITION 7,10:POKE 559,34:POKE 752,1:? " Check printer or paper! ":POSITION 7,12
1060 ? " Press RETURN when ready":CLOSE #KEYBOARD:OPEN #KEYBOARD,FROM,ZERO,"K:":GET #KEYBOARD,KEY:GOTO 440
1070 REM ****************************
1080 REM *        "TAPELESS"        *
1090 REM *            by            *
1100 REM *      Robert Grunbok      *
1110 REM ****************************