graphics demo (POLYMOVE.BAS)

graphics demo by Robert Geddings, 39

Description

graphics demo by Robert Geddings, 39

From the Antic disk of August 1987 (Vol. 6 No. 4).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 4.7 KB

Dialect
Atari BASIC
Lines
149
Variables
MODE, SEL, CNTR, COUNTER, TEMPX(, TEMPY(, LOOP, STPSX(, STPSY(, NUM, LOOP2, X(, Y(, LAST, DELAY, LOW, X1, XTOP, Y1, YTOP, C, FLAG, COLOUR, XOLD, YOLD, TX, TY, DONE, WORK, TMP, A, TM(, DEBUG, B, XL, NN, X
BASIC listing (149 lines)
10 REM POLYMOVE
20 REM BY ROBERT GEDDINGS
30 REM (c) 1987, ANTIC PUBLISHING
40 GOTO 440
50 REM PLAYBACK
60 GRAPHICS MODE:POKE 710,0
70 ON SEL GOTO 90,290
80 REM CONTINOUS LOOP
90 CNTR=1
100 FOR COUNTER=1 TO 5:REM # OF TWEEN STEPS
110 IF STRIG(0)<>1 THEN 1300
120 PLOT TEMPX(1,CNTR),TEMPY(1,CNTR):REM STARTING POINT FOR EACH POLYGON
130 FOR LOOP=2 TO 8
140 DRAWTO TEMPX(LOOP,CNTR),TEMPY(LOOP,CNTR):REM FINISH POLYGON
150 NEXT LOOP
160 REM TWEEN PART
170 FOR LOOP=1 TO 8
180 TEMPX(LOOP,CNTR)=TEMPX(LOOP,CNTR)+STPSX(LOOP,CNTR):TEMPY(LOOP,CNTR)=TEMPY(LOOP,CNTR)+STPSY(LOOP,CNTR)
190 NEXT LOOP
200 ? #6;"↰";
210 NEXT COUNTER
220 CNTR=CNTR+1:IF CNTR<=NUM THEN 100
230 FOR LOOP=1 TO NUM
240 FOR LOOP2=1 TO 8
250 TEMPX(LOOP2,LOOP)=X(LOOP2,LOOP)
260 TEMPY(LOOP2,LOOP)=Y(LOOP2,LOOP)
270 NEXT LOOP2:NEXT LOOP:GOTO 90
280 REM SINGLE LOOP
290 FOR CNTR=1 TO NUM-1
300 FOR COUNTER=1 TO 5
310 PLOT TEMPX(1,CNTR),TEMPY(1,CNTR)
320 FOR LOOP=2 TO 8:DRAWTO TEMPX(LOOP,CNTR),TEMPY(LOOP,CNTR):NEXT LOOP
330 FOR LOOP=1 TO 8
340 TEMPX(LOOP,CNTR)=TEMPX(LOOP,CNTR)+STPSX(LOOP,CNTR):TEMPY(LOOP,CNTR)=TEMPY(LOOP,CNTR)+STPSY(LOOP,CNTR)
350 NEXT LOOP
360 ? #6;"↰";
370 NEXT COUNTER:NEXT CNTR
380 PLOT X(1,NUM),Y(1,NUM)
390 FOR LAST=2 TO 8
400 DRAWTO X(LAST,NUM),Y(LAST,NUM)
410 NEXT LAST
420 FOR DELAY=1 TO 500:NEXT DELAY
430 GOTO 1300
440 GOSUB 920
450 LOW=0:X1=INT(XTOP/2+0.5):Y1=INT(YTOP/2):C=1
460 FLAG=0
470 REM
480 FOR CNTR=1 TO NUM
490 GRAPHICS MODE:POKE 710,0:COLOR C
500 LOCATE X1,Y1,COLOUR:PLOT X1,Y1:XOLD=X1:YOLD=Y1
510 IF STRIG(0)<>1 THEN GOSUB 730
520 IF FLAG THEN 610
530 GOSUB 840
540 IF  NOT (TX OR TY) THEN 510
550 COLOR COLOUR:PLOT XOLD,YOLD:COLOR C
560 X1=X1+TX:IF X1>XTOP THEN X1=XTOP
570 IF X1<LOW THEN X1=LOW
580 Y1=Y1+TY:IF Y1>YTOP THEN Y1=YTOP
590 IF Y1<LOW THEN Y1=LOW
600 GOTO 500
610 X1=INT(XTOP/2+0.5):Y1=INT(YTOP/2):C=1
620 FLAG=0:COUNTER=0
630 FOR DONE=15 TO 0 STEP -0.15:SOUND 0,100,10,DONE:NEXT DONE:SOUND 0,0,0,0
640 NEXT CNTR
650 REM CALC STEPS
660 FOR CNTR=1 TO NUM:FOR LOOP=1 TO 8
670 WORK=CNTR+1:IF WORK>NUM THEN WORK=1
680 STPSX(LOOP,CNTR)=(X(LOOP,WORK)-X(LOOP,CNTR))/5
690 STPSY(LOOP,CNTR)=(Y(LOOP,WORK)-Y(LOOP,CNTR))/5
700 NEXT LOOP:NEXT CNTR
710 GOTO 1160
720 REM POINT ARRAY LOADER
730 FOR DELAY=15 TO 0 STEP -0.75:SOUND 0,60,10,DELAY:NEXT DELAY:SOUND 0,0,0,0
740 COUNTER=COUNTER+1
750 X(COUNTER,CNTR)=X1:Y(COUNTER,CNTR)=Y1
760 TEMPX(COUNTER,CNTR)=X1:TEMPY(COUNTER,CNTR)=Y1
770 PLOT X(1,CNTR),Y(1,CNTR):IF COUNTER=1 THEN 810
780 FOR TMP=2 TO COUNTER
790 DRAWTO X(TMP,CNTR),Y(TMP,CNTR)
800 NEXT TMP
810 IF COUNTER+1>8 THEN FLAG=1
820 RETURN
830 REM JOYSTICK ROUTINE
840 A=STICK(0)
850 TX=(A=5 OR A=6 OR A=7)-(A=9 OR A=10 OR A=11)
860 TY=(A=5 OR A=9 OR A=13)-(A=6 OR A=10 OR A=14)
870 IF PEEK(53279)<>6 THEN 900
880 GRAPHICS MODE+16:? "↰X = ";XOLD,"Y = ";YOLD
890 FOR NN=0 TO 1:NN=(PEEK(53279)<>6):NEXT NN:GRAPHICS MODE+32
900 RETURN
910 REM INIT AND OPENING SCREEN
920 DIM X(8,10),Y(8,10),TEMPX(8,10),TEMPY(8,10),TM(8,2)
930 DIM STPSX(8,10),STPSY(8,10)
940 XL=1:TRAP 1490:GRAPHICS 15
950 GRAPHICS 0:POKE 752,1
960 POSITION 14,0:? "┌──────────┐"
970 POSITION 14,1:? "| POLYMOVE |"
980 POSITION 14,2:? "└──────────┘"
990 POSITION 11,4:? "by Robert Geddings"
1000 ? :? :? :?
1010 ? "Each Polygon that you create should":? "have 8 points, which you select with"
1020 ? "the joystick."
1030 ? :? "You can have up to 10 polygons."
1040 ? "How many do you want: ";:INPUT NUM
1050 POSITION 2,17:? "Graphics mode? (3/5/7/8";
1060 IF XL THEN ? "/15";
1070 ? ")  ←←";:INPUT MODE
1080 IF  NOT (MODE=3 OR MODE=5 OR MODE=7 OR MODE=8 OR (XL=1 AND MODE=15)) THEN ? "↑↑↰":GOTO 1050
1090 IF MODE=3 THEN XTOP=39:YTOP=23
1100 IF MODE=5 THEN XTOP=79:YTOP=47
1110 IF MODE=7 THEN XTOP=159:YTOP=95
1120 IF MODE=8 THEN XTOP=319:YTOP=191
1130 IF MODE=15 THEN XTOP=159:YTOP=191
1140 MODE=MODE+16:RETURN
1150 REM LOOP/SINGLE PLAYBACK
1160 GRAPHICS 0:POKE 752,1
1170 POSITION 16,3:? "┌────────┐"
1180 POSITION 16,4:? "| SELECT |"
1190 POSITION 16,5:? "└────────┘"
1200 ? :? :? :?
1210 ? "     1) CONTINOUS LOOP"
1220 ?
1230 ? "     2) SINGLE LOOP"
1240 ? :? :?
1250 ? "Enter Number of selection: ";:INPUT SEL
1260 IF SEL=1 THEN POSITION 7,22:? "PRESS BUTTON TO EXIT LOOP"
1270 FOR DELAY=1 TO 400:NEXT DELAY
1280 GOTO 60
1290 REM AGAIN AND IF SO, HOW SO
1300 GRAPHICS 0:POKE 752,1
1310 POSITION 16,3:? "┌────────┐"
1320 POSITION 16,4:? "| SELECT |"
1330 POSITION 16,5:? "└────────┘"
1340 ? :? :? :?
1350 ? "     1) Do again, Same polygons":?
1360 ? "     2) Do again, Different polygons":?
1370 ? "     3) Quit"
1380 ? :? :? "Enter Number of selection: ";:INPUT SEL
1390 ON SEL GOTO 1410,1470,1480
1400 GOTO 1300
1410 FOR LOOP=1 TO NUM
1420 FOR LOOP2=1 TO 8
1430 TEMPX(LOOP2,LOOP)=X(LOOP2,LOOP):TEMPY(LOOP2,LOOP)=Y(LOOP2,LOOP)
1440 NEXT LOOP2
1450 NEXT LOOP
1460 GOTO 1160
1470 RUN
1480 POKE 752,0:END
1490 XL=0:TRAP 40000:GOTO 950