Link BASIC (LINKBAS.BAS)

Link BASIC (with compiled version), programming utility by Robin Alan Sherer and Stan Gilbert, 99 (BASIC, binary load)

Description

Link BASIC (with compiled version), programming utility by Robin Alan Sherer and Stan Gilbert, 99 (BASIC, binary load)

From the Antic disk of August 1987 (Vol. 6 No. 4).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 3.9 KB

Dialect
Atari BASIC
Lines
139
Variables
A$, C$, F$, S$, V$, LN, R, A, V, L, J, CF, I, X, BYTE, LS, P, K
BASIC listing (139 lines)
1000 REM LINKBAS.BAS
1010 REM BY ROBIN SHERER
1020 REM (c) 1987, ANTIC PUBLISHING
1110 REM VERSION 2.05
1150 DIM A$(40),C$(2048),F$(20)
1160 DIM S$(2048),V$(40)
1170 LN=2000:R=6
1180 CLOSE #3:OPEN #3,4,0,"E:"
1190 POKE 82,1
1200 ? "↰┌────────────────────────────────────┐"
1210 ? "| LINK BASIC                         |"
1220 ? "└────────────────────────────────────┘"
1230 POSITION 1,20
1240 ? "┌────────────────────────────────────┐"
1250 ? "| Q|QUIT                             |"
1260 ? "└────────────────────────────────────┘":POKE 82,2
1270 REM GET DESTINATION FILENAME
1280 TRAP 1410
1290 POSITION 21,4
1300 ? "               "
1310 POSITION 2,4
1320 ? "LIST (D:TEMP.LST)? ";
1330 INPUT #3;A$:IF A$="Q" THEN 2440
1340 IF LEN(A$)<2 THEN 1370
1350 IF A$(2,2)=":" THEN 1390
1360 IF A$(3,3)=":" THEN 1390
1370 IF LEN(A$)=0 THEN A$="TEMP.LST"
1380 F$="D:"
1390 F$(LEN(F$)+1)=A$
1400 POSITION 21,4:? F$:GOTO 1440
1410 POSITION 11,21
1420 ? "↰ CANNOT OPEN DESTINATION ";
1430 GOTO 1280
1440 CLOSE #1:OPEN #1,8,0,F$
1450 REM GET STARTING LINE NUMBER
1460 POSITION 11,21
1470 ? "                         ";
1480 TRAP 1570
1490 POSITION 21,5
1500 ? "          "
1510 POSITION 2,5
1520 ? "START LINE (2000)? ";
1530 INPUT #3;A$:IF A$="Q" THEN 2440
1540 IF A$="" THEN A$="2000"
1550 LN=VAL(A$)
1560 POSITION 21,5:? LN:GOTO 1610
1570 POSITION 11,21
1580 ? "↰ NEED A NUMBER ";
1590 GOTO 1480
1600 REM GET SOURCE FILENAME
1610 POSITION 11,21
1620 ? "               ";
1630 POKE 752,0:TRAP 1780
1640 A=0:V=0:R=R+1:IF R>17 THEN R=7
1650 POSITION 2,R
1660 ? "SOURCEFILE/VAR<@>? ";
1670 POSITION 2,R+1
1680 ? "                   ↑";
1690 INPUT #3,A$:L=LEN(A$)
1700 IF A$="Q" OR A$="" THEN 2440
1710 IF A$(L,L)="@" THEN A=1
1720 FOR J=1 TO LEN(A$)
1730 IF A$(J,J)="/" THEN 1810
1740 NEXT J
1750 POSITION 11,21
1760 ? "↰ NO /VARIABLE NAME "
1770 GOTO 1640
1780 POSITION 11,21
1790 ? "↰ BAD FILENAME SPEC "
1800 GOTO 1630
1810 POP :V$=A$(J+1,L-A):L=LEN(V$)
1820 V=L+1:V$(V)="$":A$=A$(1,J-1)
1830 IF LEN(A$)<2 THEN 1860
1840 IF A$(2,2)=":" THEN 1880
1850 IF A$(3,3)=":" THEN 1880
1860 IF LEN(A$)=0 THEN A$="TEMP.OBJ"
1870 F$="D:"
1880 F$(LEN(F$)+1)=A$:L=LEN(F$)
1890 IF F$(L,L)="." THEN F$(L)=".OBJ"
1900 S$="":CF=0
1910 POKE 752,1:POSITION 11,21
1920 ? "                   "
1930 IF A=1 THEN 1970
1940 POSITION 11,21
1950 ? "↰ INSERT SOURCE [KEY]";
1960 GOSUB 2460
1970 CLOSE #2:OPEN #2,4,0,F$
1980 POKE 752,1:POSITION 11,21
1990 ? " READING SOURCE     "
2000 C$(1)=" ":C$(2048)=" ":C$(2)=C$
2010 IF F$(L)<>".OBJ" THEN 2030
2020 FOR I=1 TO 6:GET #2,X:NEXT I
2030 TRAP 2070
2040 GET #2,BYTE
2050 S$(LEN(S$)+1)=CHR$(BYTE)
2060 LS=LEN(S$):GOTO 2040
2070 IF A=1 THEN 2110
2080 POSITION 11,21
2090 ? "↰ INSERT DESTINATION [KEY] ";
2100 GOSUB 2460
2110 POSITION 11,21
2120 ? " WRITING TO DESTINATION   "
2130 REM PUT TO DESTINATION FILE
2140 ? #1;LN;" REM"
2150 LN=LN+10
2160 ? #1;LN;" DIM";V$;"(";LEN(S$);
2170 ? #1;"):REM ";F$(3)
2180 LN=LN+10
2190 P=1
2200 IF P<10000 THEN L=23
2210 IF P<1000 THEN L=24
2220 IF P<100 THEN L=25
2230 IF P<10 THEN L=26
2240 L=L-V:IF P+L>LS THEN L=LS-P+1
2250 ? #1;LN;V$;"(";P;")=";CHR$(34);
2260 FOR I=P TO P+L-1
2270 IF S$(I,I)<>CHR$(34) THEN 2290
2280 C$(I,I)="1":S$(I,I)=" ":CF=1
2290 ? #1;S$(I,I);
2300 NEXT I
2310 ? #1;CHR$(34)
2320 LN=LN+10:P=P+L
2330 IF P<=LS THEN 2200
2340 CLOSE #2:IF CF=0 THEN 2410
2350 FOR I=1 TO LEN(S$)
2360 IF C$(I,I)<>"1" THEN 2400
2370 ? #1;LN;V$;"(";I;",";I;
2380 ? #1;")=CHR$(34)"
2390 LN=LN+10
2400 NEXT I:CLOSE #1
2410 POSITION 11,21
2420 ? "                          "
2430 GOTO 1630
2435 REM BRANCH TO DOS
2440 CLOSE #1:X=USR(ADR("hl◣♥"))
2450 REM KEYBOARD TEST
2460 POKE 764,255
2470 K=PEEK(764):IF K=255 THEN 2470
2480 POKE 764,255:RETURN