Haiku Writer (HAIKU.BAS)
Haiku Writer by Albert Baggetta, 77
Description
Haiku Writer by Albert Baggetta, 77
From the Antic disk of August 1987 (Vol. 6 No. 4).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 8.3 KB
- Dialect
- Atari BASIC
- Lines
- 191
- Variables
CHSET,WORD$,HAIKU$,PHR$,NOU1$,NOU2$,T$,MP1$,MP2$,MP3$,CHANG$,SX$,OUT,MAKEPHS,IO,JNK,SND,DEL,COUNTER,P,D,E,DECIDE,CT,C,R,RR,I,X,ATCH,ART,VAR,NOUN,BANK,ADJ,SUP,VERB,ADV,PREP,CHOICE,MP,XQ,SOUND,CONSOL,CNSOL,DEBUG
BASIC listing (191 lines)
10 REM HAIKU WRITER
20 REM BY A. BAGGETTA
30 REM (c) 1987, ANTIC PUBLISHING
40 DEBUG=PEEK(53279)<>5
90 CHSET=(PEEK(106)-8):POKE 106,CHSET:GRAPHICS 0:POKE 709,134:POKE 710,134:POKE 712,134
92 POKE 752,1:POKE 82,0
100 DIM WORD$(40),HAIKU$(600),PHR$(100),NOU1$(30),NOU2$(30),T$(2)
105 DIM MP1$(40),MP2$(40),MP3$(40),CHANG$(40),SX$(5):OUT=0:MAKEPHS=0
110 SX$="♣yl◆Q"
120 REM TITLE SCREEN
130 POSITION 0,0:GOSUB 2291
160 POSITION 9,10:? "JAPANESE HAIKU WRITER":POSITION 9,12:? " BY A. BAGGETTA"
170 POSITION 0,20:GOSUB 2291
200 REM LOAD CHARACTER SET
205 POKE 756,CHSET
210 CLOSE #1:OPEN #1,4,0,"D:JAPAN.FNT":IO=848:POKE IO+2,7:POKE IO+4,0:POKE IO+5,CHSET
220 POKE IO+8,0:POKE IO+9,4:JNK=USR(ADR("hhh*LVd"),16):CLOSE #1:GOSUB 2580
730 REM SET-UP HAIKU SCREEN
740 FOR SND=8 TO 0 STEP -0.5:SOUND 0,30,14,SND:SOUND 1,30,10,SND:FOR DEL=1 TO 5:NEXT DEL
745 POKE 709,14-SND:NEXT SND:FOR DEL=1 TO 1000:JNK=RND(0):NEXT DEL
750 POKE 77,0:COUNTER=COUNTER+1:? "↰ haiku writer POEM ";COUNTER
760 ? :? :? " !#$ ";CHR$(8);CHR$(10);" *"
770 ? " %&' ";CHR$(8);CHR$(7);CHR$(136);CHR$(138)
780 ? " ()* * ";CHR$(136)
790 ? " *"
800 POSITION 5,16:? "!#$ !#$ !#$"
810 POSITION 5,17:? "%&' %&' %&'"
820 POSITION 5,18:? "()* ()* ()*"
830 GOTO 980
840 REM JAPANESE SONG ROUTINE
850 SND=INT(RND(0)*5)+1
860 P=ASC(SX$(SND,SND))
920 FOR D=0 TO 4 STEP 0.3:SOUND 0,P,10,D:SOUND 1,1,8,1:NEXT D
930 SOUND 0,P,10,D:SOUND 1,1,8,1
940 FOR E=1 TO INT(RND(0)*170):CNSOL=PEEK(53279):NEXT E
950 SOUND 1,0,0,0:SOUND 0,0,0,0:REM REMOVE REM FOR DELAY BETWEEN NOTES AB=1^1
960 RETURN
970 REM OPTION FOR THREE PHRASES
980 MAKEPHS=INT(RND(0)*10)+1:IF MAKEPHS<>1 THEN 1010
990 GOSUB 2010:GOTO 1280
1000 REM START WITH AN ARTICLE
1010 HAIKU$="":GOSUB 1380
1020 HAIKU$(1,LEN(WORD$))=WORD$:WORD$=""
1030 REM DECIDE ON ADJ OR NOUN
1040 DECIDE=INT(RND(0)*2)+1
1050 IF DECIDE=1 THEN GOSUB 1540:GOSUB 1970:GOSUB 1990:WORD$=""
1060 GOSUB 1400:NOU1$=WORD$:GOSUB 1970:GOSUB 1990:WORD$=""
1070 REM ADD A VERB
1080 GOSUB 1700:GOSUB 1970:GOSUB 1990:WORD$=""
1090 REM DECIDE ON ADV OR ADV PHRASE
1100 DECIDE=INT(RND(0)*2)+1
1110 IF DECIDE=1 THEN GOSUB 1810
1120 IF DECIDE<>1 THEN 1140
1130 GOSUB 1970:GOSUB 1990:WORD$=""
1140 IF INT(RND(0)*2)=2 THEN 1170
1150 GOSUB 2010
1160 GOSUB 1970:HAIKU$(LEN(HAIKU$)+1)=PHR$
1170 TRAP 750:CT=0:C=4:R=7:RR=0:FOR I=1 TO LEN(HAIKU$)
1180 CT=CT+1
1190 IF HAIKU$(I,I)=" " THEN X=X+1
1200 IF X=3 THEN ? :X=0:RR=RR+2:CT=0
1210 POSITION C+CT,R+RR:? HAIKU$(I,I);
1220 NEXT I
1230 ATCH=INT(RND(0)*5)+1:IF ATCH=1 THEN POSITION C+CT+1,R+RR:? ".":GOTO 1270
1240 IF HAIKU$(LEN(HAIKU$),LEN(HAIKU$))="S" THEN POSITION C+CT+1,R+RR:? "ES.":GOTO 1270
1245 IF HAIKU$(LEN(HAIKU$),LEN(HAIKU$))="H" THEN POSITION C+CT+1,R+RR:? "ES.":GOTO 1270
1250 IF HAIKU$(LEN(HAIKU$),LEN(HAIKU$))="Y" THEN POSITION C+CT,R+RR:? "IES.":GOTO 1270
1260 POSITION C+CT+1,R+RR:? "S."
1270 POSITION 25,17:? "-- retu pmoc"
1280 POKE 764,255
1290 CNSOL=7:GOSUB 850:OUT=OUT+1
1300 IF OUT=30 THEN 1340
1310 IF CNSOL=6 THEN SOUND 0,0,0,0:SOUND 1,0,0,0:GOSUB 2150
1320 IF CNSOL=5 THEN 2310
1330 IF PEEK(764)=255 THEN 1290
1340 HAIKU$="":PHR$="":OUT=0:GOTO 750
1350 REM ============================
1360 REM ARTICLES OR POSS PRONOUNS
1370 DATA THE,MY,HIS,HER,OUR,ITS,YOUR
1380 ART=INT(RND(0)*7)+1:RESTORE 1370:VAR=ART:GOSUB 1950:RETURN
1390 REM NOUNS
1400 DATA FRIEND,HAPPINESS,NIGHT,SUMMER,SUNSET,CHERRY TREE,BLOSSOM,BUD,PROSPERITY,SNOW,WINTER,FALL,SPRING,HOPE
1410 DATA POND,CROW,BALANCE,AUTUMN,SWAN,SAND,TEMPLE,GARDEN,PETAL,WILLOW,ISLAND,TEACHER,TWILIGHT,NOCTURNE
1420 DATA VILLAGE,BELL,MOUNTAIN,SEASHORE,DEWDROP,SHELL,CLOVER,BUSH,FLOWER
1430 DATA MOGAMI RIVER,BUTTERFLY,TOMB,LOCUST,HERON
1440 DATA GOD,VASE,SKY,SURF,TWIG,POEM,HONEYSUCKLE,OCEAN,MEADOW,
1450 DATA STRANGER,HUT,ROAD,DRAGONFLY,WEED
1460 NOUN=INT(RND(0)*14)+1
1470 BANK=INT(RND(0)*4)+1
1480 IF BANK=1 THEN RESTORE 1400:GOTO 1520
1490 IF BANK=2 THEN RESTORE 1410:GOTO 1520
1500 IF BANK=3 THEN RESTORE 1420:GOTO 1520
1510 RESTORE 1440
1520 VAR=NOUN:GOSUB 1950:RETURN
1530 REM ADJECTIVES
1540 DATA HAPPY,SAD,LONELY,TIRED,QUIET,JOYOUS,TROUBLED,SLEEPING,FEARFUL,RUSTY,ANCIENT,SWEEPING,BURIED,WEEPING
1550 DATA WEAKEST
1560 DATA OLD,WITHERED,GRAY,WILD,DRIFTING,PULSING,MILK-WHITE,DRUNKEN,BUNGLING,SIFTED,IMMORTAL,FRIENDLY,NAMELESS
1570 DATA FRESHEST,HAPPIEST,QUIETEST,SWEETEST,FRIENDLIEST,NOISIEST,FRESHER,HAPPIER,QUIETER,SWEETER,FRIENDLIER
1580 DATA NOISIER,HUMBLER,HUMBLEST,PRETTIER
1590 DATA COLD,SAUCY
1600 ADJ=INT(RND(0)*15)+1
1610 BANK=INT(RND(0)*3)+1
1620 IF BANK=1 THEN RESTORE 1540:GOTO 1650
1630 IF BANK=2 THEN RESTORE 1560:GOTO 1650
1640 RESTORE 1570
1650 VAR=ADJ:GOSUB 1950
1660 SUP=INT(RND(0)*5):IF SUP<>1 AND BANK>1 THEN 1680
1670 CHANG$=WORD$:WORD$="MOST ":WORD$(6)=CHANG$
1680 RETURN
1690 REM VERBS
1700 DATA WALKS,SLEEPS,FLIES,HOPES,CRIES,CROSSES,TREMBLES,AWAKENS,CALLS,DREAMS,CARRIES,MOVES,ANSWERS,FOLLOWS,SAW
1710 DATA IS,WAS,CAN BE,WILL BE,SHALL BE
1720 DATA BALANCED,TAUNTED,REVERBERATED,BLOOMED,LOOMED,ECHOED,DISSOLVED,BATHED,FUSED,WALKED,SLEPT,HOPED,CRIED
1730 DATA WOULD BE,MUST BE,MIGHT BE,COULD HAVE BEEN,SHOULD HAVE BEEN
1740 DATA CROSSED,MOVED
1750 VERB=INT(RND(0)*20)+1
1760 BANK=INT(RND(0)*2)+1
1770 IF BANK=1 THEN RESTORE 1700:GOTO 1790
1780 RESTORE 1720
1790 VAR=VERB:GOSUB 1950:RETURN
1800 REM ADVERBS
1810 DATA QUICKLY,SWEETLY,SMOOTHLY,ROUGHLY,CHILDISHLY,FINALLY,FREQUENTLY,NOW,SELDOM,RARELY,ONCE,PRESENTLY,FIRST
1820 ADV=INT(RND(0)*13)+1:RESTORE 1810
1830 VAR=ADV:GOSUB 1950:RETURN
1840 REM PREPOSITIONS
1850 DATA BY,WITH,FOR,ON,AFTER,BEFORE,AROUND,WITHOUT,BETWEEN,AMONG,UPON,IN,TO,INTO,OFF
1860 DATA ABOARD,ABOUT,ABOVE,ACROSS,AGAINST,ALONG,AMID,AT,BEHIND,BELOW,BENEATH,BESIDE,BEYOND,CONCERNING,UNTIL
1870 DATA DOWN,DURING,BY,FROM,INSIDE,LIKE,NEAR,OF,ONTO,OUTSIDE,OVER,PAST,SINCE,THROUGH,WITHIN
1880 PREP=INT(RND(0)*15)+1
1890 BANK=INT(RND(0)*3)+1
1900 IF BANK=1 THEN RESTORE 1850:GOTO 1930
1910 IF BANK=2 THEN RESTORE 1860:GOTO 1930
1920 RESTORE 1870
1930 VAR=PREP:GOSUB 1950:RETURN
1940 REM CHOICE LOOP
1950 FOR CHOICE=1 TO VAR:READ WORD$:NEXT CHOICE:RETURN
1960 REM PUT SPACE IN STRING
1970 HAIKU$(LEN(HAIKU$)+1)=" ":RETURN
1980 REM HAIKU$ PART = WORD$
1990 HAIKU$(LEN(HAIKU$)+1)=WORD$:RETURN
2000 REM CONSTRUCT PHRASE
2010 PHR$=""
2020 GOSUB 1850:PHR$=WORD$:WORD$=""
2030 GOSUB 1370:PHR$(LEN(PHR$)+1)=" ":PHR$(LEN(PHR$)+1)=WORD$:WORD$=""
2040 GOSUB 1400
2050 IF WORD$=NOU1$ OR WORD$=NOU2$ THEN 2040
2060 NOU2$=WORD$:PHR$(LEN(PHR$)+1)=" ":PHR$(LEN(PHR$)+1)=WORD$:WORD$=""
2070 IF MAKEPHS<>1 THEN RETURN
2080 MP=MP+1
2090 IF MP=1 THEN MP1$=PHR$:GOTO 2010
2100 IF MP=2 THEN MP2$=PHR$:GOTO 2010
2110 IF MP=3 THEN MP3$=PHR$:GOTO 2010
2120 POSITION 5,7:? MP1$;",":POSITION 5,9:? MP2$;",":POSITION 5,11:? MP3$;".":MP=0
2130 POSITION 25,17:? "-- retu pmoc":RETURN
2140 REM PRINT POEM
2150 CLOSE #2:OPEN #2,8,0,"P:"
2160 IF MAKEPHS=1 THEN 2250
2170 CT=0:X=0
2180 FOR I=1 TO LEN(HAIKU$)
2190 CT=CT+1
2200 IF HAIKU$(I,I)=" " THEN X=X+1
2210 IF X=3 THEN ? #2:X=0:CT=0
2220 IF I=1 THEN ? #2;" ";
2230 ? #2;HAIKU$(I,I);
2240 NEXT I:GOTO 2280
2250 ? #2;MP1$
2260 ? #2;MP2$
2270 ? #2;MP3$
2280 ? #2:? #2;" --Retu Pmoc"
2290 ? #2:? #2:CLOSE #2:GOSUB 2580:RETURN
2291 FOR XQ=1 TO 8:? " !#$ ";:NEXT XQ
2292 FOR XQ=1 TO 8:? " %&' ";:NEXT XQ
2293 FOR XQ=1 TO 8:? " ()* ";:NEXT XQ:RETURN
2300 REM CLOSING SCREEN 'SAYANARA'
2310 ? CHR$(125):? :? :? " RETU PMOC":? :? " BIDS YOU":? :?
2315 POKE 675,0:POKE 676,17:POKE 677,113:REM "▶" IS [CTRL]+[TAB]
2320 ? "▶▶┌┬┬┬┬┐":? "▶ ◢ ◣":? "▶ ◢╱ ╱ ╲ ╲◣":? "▶ ◢╱ ╲◣"
2370 REM ( INVERSE CTRL-M = "▔" )
2380 ? "▶ ◆◆◆◆◆◆◆◆◆◆◆◆":? "▶ ▔▔▔▔▔▔▔▔▔▔▔▔":? "▶▌ ▔╲ ╱▔ ▌":? "▶ ◣ ● ● ◢"
2460 ? "▶ ◣ ◢":? "▶ ◣ / \ ◢":? "▶▶◢ ▄▄ ◣":? "▶▶ ◣ ◢"
2500 ? :? :? " SAYANARA"
2510 FOR SOUND=0 TO 15 STEP 0.2
2520 SOUND 0,1+SOUND/2,8,SOUND
2530 NEXT SOUND
2540 FOR SOUND=15 TO 0 STEP -0.1
2550 SOUND 0,20+SOUND,8,SOUND:SOUND 1,255,10,SOUND+2
2560 NEXT SOUND
2570 POKE 675,1:POKE 676,1:POKE 677,1:END
2580 IF DEBUG THEN POKE 16,112:POKE 53774,112
2590 RETURN
